Télécharger formation_pasapas_2_solution.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. * FORMATION AVANCEE SUR LA PROCEDURE PASAPAS *
  3. * *
  4. * Rupture d'une plaque trouee en traction *
  5. * Comportement elastique lineaire *
  6. * *
  7. * Ce fichier constitue la mise donnee solution du probleme et realise *
  8. * - le maillage *
  9. * - la definition du modele et des parametres materiaux *
  10. * - la definition du chargement *
  11. * - la resolution avec PASAPAS *
  12. * - la suppression d'elements du maillage selon un critere de rupture *
  13. * base sur la 1ere contrainte principale (avec la procedure PERSO1) *
  14. * - le post traitement (contraintes, courbe force/deplacement) *
  15. * *
  16. ************************************************************************
  17.  
  18.  
  19. ** Options generales
  20. OPTI 'DIME' 2 'ELEM' 'QUA8' 'MODE' 'PLAN' 'DEFO' 'ECHO' 0 ;
  21. ITRAC = FAUX ;
  22.  
  23.  
  24. ** Parametres geometriques
  25. L1 = 1. ;
  26. R1 = 0.15 ;
  27.  
  28.  
  29. ** Maillage
  30. DENS1 = R1 / 15. ;
  31. DENS2 = L1 / 15. ;
  32. P0 = 0. 0. ;
  33. P1 = R1 0. ;
  34. P2 = 0. R1 ;
  35. P3 = L1 0. ;
  36. P4 = L1 L1 ;
  37. P5 = 0. L1 ;
  38. CER = CERC 20 P1 P0 P2 ;
  39. LID = DROI 10 P3 P4 ;
  40. LIH = DROI 10 P4 P5 ;
  41. S1 = REGL CER (LID ET LIH) 'DINI' DENS1 'DFIN' DENS2 ;
  42. LIG = S1 COTE 2 ;
  43. LIB = S1 COTE 4 ;
  44. CS1 = CONT S1 ;
  45.  
  46.  
  47. ** Modele et materiau
  48. MO = MODE S1 'MECANIQUE' 'ELASTIQUE' ;
  49. MA = MATE MO 'YOUN' 200.E9 'NU' 0.3 ;
  50.  
  51.  
  52. ** Blocages mecaniques
  53. BL1 = BLOQ 'UY' LIB ;
  54. BL2 = BLOQ 'UX' LIG ;
  55. BL3 = BLOQ 'UY' LIH ;
  56. BL = BL1 ET BL2 ET BL3 ;
  57.  
  58.  
  59. ** Chargement en deplacement impose
  60. UMAX = L1 / 20. ;
  61. F1 = DEPI BL3 UMAX ;
  62. EV1 = EVOL 'MANU' (PROG 0. 1.) (PROG 0. 1.) ;
  63. CH = CHAR 'DIMP' F1 EV1 ;
  64.  
  65.  
  66. ** Procedure PERSO1 pour supprimer les elements selon un critere sur
  67. * les contraintes principales
  68. DEBP PERSO1 T1*'TABLE' ;
  69. * modele et maillage courant
  70. MO1 = T1 . 'WTABLE' . 'MO_TOT' ;
  71. MAIL1 = EXTR MO1 'MAIL' ;
  72. * 1ere contrainte principale
  73. SG1 = T1 . 'ESTIMATION' . 'CONTRAINTES' ;
  74. SGP1 = PRIN SG1 MO1 ;
  75. * maillage des elements a conserver (et ceux a retirer)
  76. SG11 = CHAN 'GRAVITE' (EXCO 'SI11' SGP1) MO1 ;
  77. MAIL2 = SG11 ELEM 'INFERIEUR' 2.2E10 ;
  78. MAIL3 = DIFF MAIL1 MAIL2 ;
  79. NE3 = NBEL MAIL3 ;
  80. * suppression des elements du modele
  81. SI (NE3 > 0) ;
  82. MESS ' [PERSO1 :] Suppression de' NE3 'elements' ;
  83. MO2 = REDU MO1 MAIL2 ;
  84. T1 . 'WTABLE' . 'MO_TOT' = MO2 ;
  85. T1 . 'WTABLE' . 'MO_TOTAL' = MO2 ;
  86. T1 . 'WTABLE' . 'MOD_MEC' = MO2 ;
  87. FINSI ;
  88. FINP ;
  89.  
  90.  
  91. ** Resolution
  92. TAB1 = TABL ;
  93. TAB1 . 'MODELE' = MO ;
  94. TAB1 . 'CARACTERISTIQUES' = MA ;
  95. TAB1 . 'BLOCAGES_MECANIQUES' = BL ;
  96. TAB1 . 'CHARGEMENT' = CH ;
  97. TAB1 . 'TEMPS_CALCULES' = PROG 0.1 'PAS' 0.1 0.6 'PAS' 0.01 1. ;
  98. TAB1 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  99. TAB1 . 'PROCEDURE_PERSO1' = VRAI ;
  100. PASAPAS TAB1 ;
  101.  
  102.  
  103. ** Post-traitement (deformees, contraintes, reaction aux appuis, courbe force/deplacement)
  104. TT = TAB1 . 'TEMPS' ;
  105. TU = TAB1 . 'DEPLACEMENTS' ;
  106. TS = TAB1 . 'CONTRAINTES' ;
  107. TR = TAB1 . 'REACTIONS' ;
  108. LISO = PROG 0. 'PAS' 4.E9 4.E10 ;
  109. DEF0 = DEFO CS1 (TU . 0) 0. 'ROUG' ;
  110. LTPS = PROG 0. ;
  111. LDEP = PROG 0. ;
  112. LFOR = PROG 0. ;
  113. NT1 = (DIME TT) - 1 ;
  114. REPE B1 NT1 ;
  115. * instant
  116. TPS1 = TT . &B1 ;
  117. LTPS = LTPS ET TPS1 ;
  118. * contraintes
  119. SG1 = TS . &B1 ;
  120. SP1 = EXCO 'SI11' (PRIN SG1 MO) ;
  121. * deplacements
  122. U1 = TU . &B1 ;
  123. UY1 = EXTR U1 'UY' P5 ;
  124. LDEP = LDEP ET UY1 ;
  125. * reactions
  126. R1 = TR . &B1 ;
  127. VEC1 = VECT R1 5.E-10 'FORC' 'ROSE' ;
  128. RES1 = MAXI 'ABS' (RESU (REDU R1 LIB)) ;
  129. LFOR = LFOR ET RES1 ;
  130. * deformees
  131. DEF1 = DEFO S1 U1 1. VEC1 SP1 MO ;
  132. * traces
  133. TIT1 = CHAI 'Contraintes au temps ' TPS1 ;
  134. SI ITRAC ;
  135. TRAC (DEF1 ET DEF0) 'TITR' TIT1 LISO ;
  136. FINSI ;
  137. FIN B1 ;
  138. * courbe force vs deplacement
  139. EVFC = EVOL 'MANU' 'Deplacement' LDEP 'Force' LFOR ;
  140. SI ITRAC ;
  141. DESS EVFC 'TITR' 'Force vs Deplacement' ;
  142. FINSI ;
  143.  
  144.  
  145. FIN ;
  146.  
  147.  
  148.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales