Télécharger la plaquette Cast3M


fr en

Télécharger formation_pasapas_1_initial.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : formation_pasapas_1_initial.dgibi
  2. ************************************************************************
  3. *              FORMATION AVANCEE SUR LA PROCEDURE PASAPAS              *
  4. *                                                                      *
  5. * Flexion d'une poutre en grands deplacements avec chargemet suiveur   *
  6. *                                                                      *
  7. * Ce fichier constitue la mise donnee initiale du probleme et realise  *
  8. * - le maillage                                                        *
  9. * - la definition du modele et des parametres materiaux                *
  10. * - la definition du chargement sur la configuration initiale          *
  11. * - la resolution avec PASAPAS en hypothese petites perturbations      *
  12. * - le post traitement du deplacement de la poutre                     *
  13. *                                                                      *
  14. ************************************************************************
  15.  
  16.  
  17. ** Options generales
  18. OPTI 'DIME' 2 'ELEM' 'SEG2' 'ECHO' 0 ;
  19. ITRAC = FAUX ;
  20. XPAS = 0.05 ;
  21.  
  22.  
  23. ** Parametres geometriques
  24. LONG = 1. ;
  25. SEC = 1.E-2 ;
  26. INR1 = 1.E-4 ;
  27.  
  28.  
  29. ** Maillage
  30. P1 = 0. 0. ;
  31. P2 = 0. LONG ;
  32. L1 = DROI 25 P1 P2 ;
  33.  
  34.  
  35. ** Modele et materiau (elastique)
  36. MO1 = MODE L1 'MECANIQUE' 'ELASTIQUE' 'POUT' ;
  37. MA1 = MATE MO1 'YOUN' 50.E6 'NU' 0.3 'SECT' SEC 'INRZ' INR1 ;
  38.  
  39.  
  40. ** Blocages mecaniques (encastrement de la base)
  41. BLO1 = BLOQ 'DEPL' 'ROTA' P1 ;
  42.  
  43.  
  44. ** Chargement en effort impose
  45. F1 = FORC (1. 0.) P2 ;
  46. EV1 = EVOL 'MANU' 'Temps' (PROG 0. 1.) 'Coef' (PROG 0. 2.E4) ;
  47. CHAR1 = CHAR 'MECA' F1 EV1 ;
  48.  
  49.  
  50. ** Resolution
  51. TAB1                         = TABL ;
  52. TAB1 . 'MODELE'              = MO1 ;
  53. TAB1 . 'CARACTERISTIQUES'    = MA1 ;
  54. TAB1 . 'BLOCAGES_MECANIQUES' = BLO1 ;
  55. TAB1 . 'CHARGEMENT'          = CHAR1 ;
  56. TAB1 . 'TEMPS_CALCULES'      = PROG XPAS 'PAS' XPAS 1. ;
  57. PASAPAS TAB1 ;
  58.  
  59.  
  60. ** Post-traitement
  61. TT = TAB1 . 'TEMPS' ;
  62. TU1 = TAB1 . 'DEPLACEMENTS' ;
  63. TR1 = TAB1 . 'REACTIONS' ;
  64. DEF0 = DEFO L1 (TU1 . 0) 0. ;
  65. CONF0 = FORM ;
  66. * trace des deformees successives
  67. REPE B1 (DIME TT) ;
  68.   I1 = &B1 - 1 ;
  69.   TPS1 = TT . I1 ;
  70.   U1 = TU1 . I1 ;
  71.   R1 = TR1 . I1 ;
  72.   V1 = VECT R1 5.E-5 'FORC' 'ROUG' ;
  73.   DEF1 = DEFO L1 U1 1. V1 'BLEU' ;
  74.   SI ITRAC ;
  75.     TRAC (DEF0 ET DEF1) 'TITR' (CHAI 'Deformee au temps ' TPS1) ;
  76.   FINSI ;
  77. FIN B1 ;
  78. * evolution des deplacements du sommet au cours du temps
  79. TLEG = TABL ;
  80. TLEG . 'TITRE' = TABL ;
  81. TLEG . 'TITRE' . 1 = 'Ux' ;
  82. TLEG . 'TITRE' . 2 = 'Uy' ;
  83. EVUX1 = EVOL 'ROUG' 'TEMP' TAB1 'DEPLACEMENTS' 'UX' P2 ;
  84. EVUY1 = EVOL 'BLEU' 'TEMP' TAB1 'DEPLACEMENTS' 'UY' P2 ;
  85. SI ITRAC ;
  86.   DESS (EVUX1 ET EVUY1) 'TITR' 'Deplacements vs Temps' 'LEGE' TLEG ;
  87. FINSI ;
  88.  
  89. FIN ;
  90.  
  91.  
  92.  
  93.  
  94.  
  95.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales