Télécharger formation_debutant_3_mecanique.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : formation_debutant_3_mecanique.dgibi
  2. *
  3. ************************************************************************
  4. * FORMATION DEBUTER AVEC CAST3M - CALCULS THERMO-MECANIQUES *
  5. * *
  6. * Modelisation du comportement thermo-mecanique d'une plaque perforee *
  7. * *
  8. * Ce fichier est la partie 3 sur 3 de la formation debutant a Cast3M *
  9. * *
  10. * Partie 3 : calculs mecaniques *
  11. * restitution des objets *
  12. * elasticite lineaire, plasticite parfaite *
  13. * chargement thermique *
  14. * caracteristiques variables *
  15. * *
  16. ************************************************************************
  17.  
  18.  
  19.  
  20.  
  21. * RESTITUTION DES OBJETS CREES
  22. * ----------------------------
  23. OPTI 'REST' 'formation_debutant_2_thermique.sauv' ;
  24.  
  25.  
  26. * OBJET LOGIQUE POUR INDIQUER SI L'ON FAIT LES TRACES OU NON
  27. * ----------------------------------------------------------
  28. ITRAC = FAUX ;
  29.  
  30.  
  31. * CARACTERISTIQUES MECANIQUES DU MATERIAU
  32. * ---------------------------------------
  33. YOUNGMAT = 70.E9 ;
  34. NUMAT = 0.36 ;
  35. ALPHAMAT = 24.E-6 ;
  36. SIGYMAT = 130.E6 ;
  37.  
  38.  
  39.  
  40.  
  41.  
  42.  
  43. ************************************************************************
  44. * CHAPITRE 5 : MECANIQUE ELASTIQUE LINEAIRE *
  45. ************************************************************************
  46.  
  47.  
  48. * HYPOTHESE SUR LES CONTRAINTES PLANES
  49. * ------------------------------------
  50. OPTI 'MODE' 'PLAN' 'CONT' ;
  51.  
  52.  
  53. * MODELE MECANIQUE A MATERIAU CONSTANT
  54. * ------------------------------------
  55. MOM1 = MODE SU 'MECANIQUE' 'ELASTIQUE' ;
  56. MAM1 = MATE MOM1 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' ALPHAMAT ;
  57.  
  58.  
  59. * CALCUL DE LA MATRICE DE RAIDEUR
  60. * -------------------------------
  61. RI = RIGI MOM1 MAM1 ;
  62.  
  63.  
  64. * CONDITIONS AUX LIMITES: DEPLACEMENT IMPOSE
  65. * ------------------------------------------
  66. BLMX = BLOQ PA 'UX' ;
  67. BLMY = BLOQ LBAS 'UY' ;
  68. RITOT = RI ET BLMX ET BLMY ;
  69.  
  70.  
  71. * CONDITIONS AUX LIMITES: TRACTION IMPOSEE
  72. * ----------------------------------------
  73. TR = PRES 'MASS' MOM1 LHAUT (-100.E6) ;
  74.  
  75.  
  76. * CALCUL DU CHAMP DE DEPLACEMENT PAR APPEL AU SOLVEUR
  77. * ---------------------------------------------------
  78. U5 = RESO RITOT TR ;
  79.  
  80.  
  81. * POST TRAITEMENT
  82. * ---------------
  83. * DEFORMEES
  84. DEF_5 = DEFO SU U5 150. 'ROUG' ;
  85. DEF_INI = DEFO SU U5 0. ;
  86. SI ITRAC ;
  87. TRAC (DEF_INI ET DEF_5) 'TITR' '[5] Deformee elastique sous traction uniforme' ;
  88. FINSI ;
  89. DEF_5C = DEFO CSU U5 150. 'ROUG' ;
  90. DEF_INIC = DEFO CSU U5 0. ;
  91. SI ITRAC ;
  92. TRAC (DEF_INIC ET DEF_5C) 'TITR' '[5] Deformee du contour sous traction uniforme' ;
  93. FINSI ;
  94. * DEFORMATIONS
  95. DEF = EPSI U5 MOM1 ;
  96. * CONTRAINTES (PAR DEUX OPERATEURS => RESULTATS EQUIVALENTS)
  97. SIG = ELAS DEF MOM1 MAM1 ;
  98. SIG = SIGM U5 MOM1 MAM1 ;
  99. SI ITRAC ;
  100. TRAC SIG MOM1 CSU 15 'TITR' '[5] Contraintes, traction uniforme' ;
  101. FINSI ;
  102. DEF_5B = DEFO SU U5 150. ;
  103. SI ITRAC ;
  104. TRAC SIG MOM1 DEF_5B CSU 15 'TITR' '[5] Contraintes, traction uniforme, maillage deforme' ;
  105. FINSI ;
  106. * TRACE DES CONTRAINTES AUX POINTS DE GAUSS
  107. SIGYY = EXCO SIG 'SMYY' ;
  108. MESS 'Mini et Maxi de Sigma YY : ' (MINI SIGYY) (MAXI SIGYY) ;
  109. SI ITRAC ;
  110. TRAC SIGYY MOM1 'TITR' '[5] Contrainte YY interpolee partout dans le maillage' ;
  111. FINS;
  112. SIGYYG = CHAN 'CHPO' SIGYY MOM1 'SUPP' ;
  113. MPGAUSS = EXTR SIGYYG 'MAIL' ;
  114. SI ITRAC ;
  115. TRAC SIGYYG MPGAUSS 'TITR' '[5] Contrainte YY aux points de Gauss seulement' ;
  116. FINS;
  117.  
  118. * EVOLUTION DE LA CONCENTRATION DE CONTRAINTE DU TROU VERS LE BORD
  119. SIGB = CHAN 'CHPO' SIG MOM1 ;
  120. LBASG = LBAS ELEM 'COMP' PB PA ;
  121. EVSIG = EVOL 'CHPO' SIGB 'SMYY' LBASG ;
  122. EVK = EVSIG / 100.E6 ;
  123. SI ITRAC ;
  124. DESS EVK 'TITR' '[5] Concentration de contrainte le long de LBAS' ;
  125. FINSI ;
  126. * EVOLUTION DE LA CONTRAINTE LE LONG D'UNE LIGNE QUELCONQUE
  127. OPTI 'ELEM' 'SEG2' ;
  128. LIG1 = DROI 50 (0.1 0.1) (2.3 0.9) COUL 'ORAN' ;
  129. SI ITRAC ;
  130. TRAC (CSU ET LIG1) 'TITR' '[5] Ligne quelconque LIG1' ;
  131. FINS;
  132. SIGT = CHAN 'NOEUD' MOM1 SIG ;
  133. SIGLBAS = PROI SIGT LIG1 ;
  134. EVSIG2 = EVOL 'CHPO' SIGLBAS 'SMXY' LIG1 ;
  135. SI ITRAC ;
  136. DESS EVSIG2 'TITR' '[5] Contrainte XY le long de LIG1' ;
  137. FINSI ;
  138. * EFFORTS DE REACTION AUX APPUIS
  139. REAC1 = REAC U5 (BLMX ET BLMY) ;
  140. VREAC = VECT REAC1 'FORC' 'ROUG' ;
  141. VFIMP = VECT TR 'FORC' 'VERT' ;
  142. SI ITRAC ;
  143. TRAC (VFIMP ET VREAC) CSU 'TITR' '[5] Efforts imposes(V) et reactions aux appuis(R)' ;
  144. FINSI ;
  145.  
  146.  
  147. * [BONUS] : TRACTION EN DEPLACEMENT IMPOSE
  148. * ----------------------------------------
  149. * MATRICES DE BLOCAGE
  150. BLMY2 = BLOQ LHAUT 'UY' ;
  151. RITOT2 = RI ET BLMX ET BLMY ET BLMY2 ;
  152.  
  153. * SECOND MEMBRE ASSOCIE AU BLOCAGE EN DEPLACEMENT NON NUL
  154. TR2 = DEPI BLMY2 (8.E-3 * RAYON) ;
  155.  
  156. * RESOLUTION
  157. U52 = RESO RITOT2 TR2 ;
  158.  
  159. * POST TRAITEMENT
  160. DEF_5C2 = DEFO CSU U52 150. 'VERT' ;
  161. SI ITRAC ;
  162. TRAC (DEF_INIC ET DEF_5C ET DEF_5C2) 'TITR' '[5] Deformee du contour sous traction uniforme' ;
  163. FINSI ;
  164.  
  165.  
  166.  
  167.  
  168.  
  169.  
  170.  
  171. ************************************************************************
  172. * CHAPITRE 6 : MECANIQUE ELASTIQUE LINEAIRE *
  173. * CHARGEMENT THERMIQUE *
  174. ************************************************************************
  175.  
  176.  
  177. * DEFORMATIONS THERMIQUES PURES AVEC LE DERNIER CHAMP DE TEMPERATURE
  178. * DU CALCUL THERMIQUE AVEC CONVECTION + RAYONNEMENT
  179. DELTA_TE = (TAB1 . 'TEMPERATURES' . (N1 - 1)) - T_INI ;
  180. EPT = EPTH DELTA_TE MOM1 MAM1 ;
  181.  
  182.  
  183. * PSEUDO CONTRAINTES CORRESPONDANT A CES DEFORMATIONS THERMIQUES
  184. * --------------------------------------------------------------
  185. SIT = ELAS EPT MOM1 MAM1 ;
  186.  
  187.  
  188. * FORCES NODALES POUR CETTE DEFORMATION THERMIQUE
  189. * -----------------------------------------------
  190. FFT = BSIG SIT MOM1 ;
  191.  
  192.  
  193. * DEPLACEMENTS, PAR APPEL AU SOLVEUR EN SUPERPOSANT LES FORCES
  194. * PUREMENT MECANIQUES ET LES PSEUDO FORCES THERMIQUES
  195. * ------------------------------------------------------------
  196. U6 = RESO RITOT (TR ET FFT) ;
  197.  
  198.  
  199. * DEFORMEE THERMOMECANIQUE
  200. * ------------------------
  201. DEF_6 = DEFO SU U6 150. ;
  202. DEF_6C = DEFO CSU U6 150. 'ORAN' ;
  203. SI ITRAC ;
  204. TRAC (DEF_INIC ET DEF_5C ET DEF_6C) 'TITR' '[6] Deformees, traction seule(R), traction + temperature(O)' ;
  205. FINSI ;
  206.  
  207.  
  208. * DEFORMATIONS TOTALES
  209. * --------------------
  210. EP = EPSI U6 MOM1 ;
  211.  
  212.  
  213. * DEFORMATIONS ELASTIQUES
  214. * -----------------------
  215. EPE = EP - EPT ;
  216.  
  217.  
  218. * LES CONTRAINTES SONT CALCULEES A PARTIR DES DEFORMATIONS ELASTIQUES
  219. * -------------------------------------------------------------------
  220. SIGT = ELAS EPE MOM1 MAM1 ;
  221. SI ITRAC ;
  222. TRAC SIGT MOM1 DEF_6 CSU 15 'TITR' '[6] Contraintes, traction + temperature' ;
  223. FINSI ;
  224.  
  225.  
  226.  
  227.  
  228.  
  229.  
  230.  
  231. ************************************************************************
  232. * CHAPITRE 7 : MECANIQUE ELASTIQUE LINEAIRE *
  233. * CHARGEMENT THERMIQUE *
  234. * MATERIAU VARIABLE DANS L'ESPACE *
  235. ************************************************************************
  236.  
  237.  
  238. * ON REND LE COEFFICIENT DE DILATATION LINEAIRE ALPHA
  239. * VARIABLE EN FONCTION DE LA COORDONNEE X
  240. * ALPHA(X) = ALPHA0 * (1 + BETA*((X-XMOYEN)/(XMAX-XMIN))**3)
  241.  
  242. * RECUPERATION DE LA COORDONNEE X ET FORMATION D'UN
  243. * CHAMP PAR POINTS (CHPOINT) PORTANT CETTE INFORMATION
  244. * ----------------------------------------------------
  245. XX = COOR SU 1 ;
  246.  
  247.  
  248. * VALEURS EXTREMES ET MOYENNE DE LA COORDONNEE X DU MAILLAGE
  249. * ----------------------------------------------------------
  250. XMAX = MAXI XX ;
  251. XMIN = MINI XX ;
  252. XMOY = 0.5 * (XMAX + XMIN) ;
  253.  
  254.  
  255. * CALCUL DU CHAMP PAR POINTS SCALAIRE DE ALPHA VARIABLE
  256. * -----------------------------------------------------
  257. BETA = 7. ;
  258. CHP_ALPH = ALPHAMAT * (1. + (BETA * (((XX - XMOY) / (XMAX - XMIN)) ** 3))) ;
  259.  
  260.  
  261. * CONVERSION DU CHPOINT -> EN MCHAML
  262. * ----------------------------------
  263. CHM_ALPH = CHAN 'CHAM' CHP_ALPH MOM1 ;
  264.  
  265.  
  266. * MISE A JOUR DU MCHAML DU MATERIAU AVEC ALPHA VARIABLE
  267. * -----------------------------------------------------
  268. MAM1B = MATE MOM1 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' CHM_ALPH ;
  269.  
  270.  
  271. * MISE A JOUR DES DEFORMATIONS THERMIQUES PURES AVEC ALPHA VARIABLE
  272. * -----------------------------------------------------------------
  273. EPT = EPTH DELTA_TE MOM1 MAM1B ;
  274.  
  275.  
  276. * MISE A JOUR DES PSEUDO CONTRAINTES THERMIQUES AVEC ALPHA VARIABLE
  277. * -----------------------------------------------------------------
  278. SIT = ELAS EPT MOM1 MAM1B ;
  279.  
  280.  
  281. * MISE A JOUR DES FORCES NODALES POUR CETTE DEFORMATION THERMIQUE
  282. * ---------------------------------------------------------------
  283. FFT = BSIG SIT MOM1 ;
  284.  
  285.  
  286. * DEPLACEMENTS AVEC ALPHA VARIABLE
  287. * --------------------------------
  288. U7 = RESO RITOT (TR ET FFT) ;
  289.  
  290.  
  291. * DEFORMEE AVEC ALPHA VARIABLE
  292. * ----------------------------
  293. DEF_7 = DEFO SU U7 150. ;
  294. DEF_7C = DEFO CSU U7 150. 'ROUG' ;
  295. SI ITRAC ;
  296. TRAC (DEF_INIC ET DEF_6C ET DEF_7C) 'TITR' '[7] Deformees, theromeca(O), + alpha var.(R)' ;
  297. FINSI ;
  298.  
  299.  
  300. * DEFORMATIONS TOTALES AVEC ALPHA VARIABLE
  301. * ----------------------------------------
  302. EP = EPSI U7 MOM1 ;
  303.  
  304.  
  305. * DEFORMATION ELASTIQUES AVEC ALPHA VARIABLE
  306. * ------------------------------------------
  307. EPE = EP - EPT ;
  308.  
  309.  
  310. * CONTRAINTES AVEC ALPHA VARIABLE
  311. * -------------------------------
  312. SIGT = ELAS EPE MOM1 MAM1B ;
  313. SI ITRAC ;
  314. TRAC SIGT MOM1 DEF_7 CSU 15 'TITR' '[7] Contraintes, thermomeca, alpha var.' ;
  315. FINSI ;
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324. ************************************************************************
  325. * CHAPITRE 8 : MECANIQUE ELASTIQUE LINEAIRE ET PLASTIQUE PARFAIT *
  326. * THERMIQUE TRANSITOIRE PRECEDENT (COND. + CONV. + RAYO.) *
  327. * MATERIAU VARIABLE DANS L'ESPACE *
  328. ************************************************************************
  329.  
  330.  
  331. * MISE A JOUR DU MODELE MECANIQUE
  332. * -------------------------------
  333. MOM2 = MODE SU 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'PARFAIT' ;
  334.  
  335.  
  336. * MISE A JOUR DU MATERIAU (AJOUT DE LA LIMITE D'ELASTICITE 'SIGY')
  337. * ----------------------------------------------------------------
  338. MAM2 = MATE MOM2 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' CHM_ALPH 'SIGY' SIGYMAT ;
  339.  
  340.  
  341. * DEFINITION DU CHARGEMENT MECANIQUE INCREMENTAL
  342. * ----------------------------------------------
  343. * NOTA : EN PLASTICITE ON NE PEUT GENERALEMENT PAS APPLIQUER
  344. * BRUTALEMENT UN CHARGEMENT FINAL POUR LEQUEL IL Y AURAIT
  345. * DEPASSEMENT EXCESSIF DE LA LIMITE D'ELASTICITE DES LA
  346. * PREMIERE ITERATION DU CALCUL NON LINEAIRE ITERATIF
  347.  
  348. * EVOLUTION TEMPORELLE DU CHARGEMENT MECANIQUE
  349. * --------------------------------------------
  350. EVTM = EVOL 'MANU' 'Temps' (PROG 0. (0.98 * TPSFIN) TPSFIN)
  351. 'Coef' (PROG 0. 0. 1.) ;
  352. CHM = CHAR 'MECA' EVTM TR ;
  353.  
  354.  
  355. * PREPARATION DE LA TABLE POUR PASAPAS
  356. * ------------------------------------
  357. TAB2 = TABL ;
  358. TAB2 . 'MODELE' = MOT ET MOC ET MOR ET MOM2 ;
  359. TAB2 . 'CARACTERISTIQUES' = MAT ET MAC ET MAR ET MAM2 ;
  360. TAB2 . 'BLOCAGES_MECANIQUES' = BLMX ET BLMY ;
  361. TAB2 . 'BLOCAGES_THERMIQUES' = BLT ;
  362. TAB2 . 'CHARGEMENT' = CHT ET CHACONV ET CHARAYE ET CHM ;
  363. TAB2 . 'TEMPS_CALCULES' = PROG 0. 'PAS' (0.02 * TPSFIN) (0.98 * TPSFIN)
  364. 'PAS' (0.001 * TPSFIN) TPSFIN ;
  365. TAB2 . 'TEMPERATURES' = TABL ;
  366. TAB2 . 'TEMPERATURES' . 0 = T_INI ;
  367. TAB2 . 'CELSIUS' = VRAI ;
  368.  
  369.  
  370. * APPEL A PASAPAS
  371. * ---------------
  372. PASAPAS TAB2 ;
  373.  
  374.  
  375. * POST TRAITEMENT
  376. * ---------------
  377. * COMPARAISON DE LA DEFORMEE FINALE AVEC LES CALCULS PRECEDENTS
  378. N2 = DIME (TAB2 . 'DEPLACEMENTS') ;
  379. U8 = TAB2 . 'DEPLACEMENTS' . (N2 - 1) ;
  380. DEF_8 = DEFO SU U8 150. ;
  381. DEF_8C = DEFO CSU U8 150. 'VIOL' ;
  382. SI ITRAC ;
  383. TRAC (DEF_INIC ET DEF_7C ET DEF_8C) 'TITR' '[8] Deformees, elas.(R), + plas.(V)' ;
  384. FINSI ;
  385.  
  386. * BOUCLE SUR LES PAS DE TEMPS ET TRACE DES CONTRAINTES ET DE LA
  387. * DEFORMATION PLASTIQUE EQUIVALENTE CUMULEE
  388. LISO2 = PROG 0. 'PAS' 10.E6 160.E6 ;
  389. SI ITRAC ;
  390. REPE B1 N2 ;
  391. TPS_I = TAB2 . 'TEMPS' . (&B1 - 1) ;
  392. U_I = TAB2 . 'DEPLACEMENTS' . (&B1 - 1) ;
  393. DEF_I = DEFO SU U_I 150. ;
  394. S_I = TAB2 . 'CONTRAINTES' . (&B1 - 1) ;
  395. MOT_I = CHAI '[8] Contraintes au temps ' TPS_I ;
  396. TRAC S_I MOM2 DEF_I CSU LISO2 'TITR' MOT_I ;
  397. FIN B1 ;
  398. VI = TAB2 . 'VARIABLES_INTERNES' . (N2 - 1) ;
  399. EQ_MAX = MAXI (EXCO 'EPSE' VI) ;
  400. LISO3 = PROG 0. 'PAS' (EQ_MAX / 15.) EQ_MAX ;
  401. REPE B1 N2 ;
  402. TPS_I = TAB2 . 'TEMPS' . (&B1 - 1) ;
  403. U_I = TAB2 . 'DEPLACEMENTS' . (&B1 - 1) ;
  404. DEF_I = DEFO SU U_I 150. ;
  405. V_I = TAB2 . 'VARIABLES_INTERNES' . (&B1 - 1) ;
  406. MOT_I = CHAI '[8] Def. plas. eq. cumulee au temps ' TPS_I ;
  407. TRAC V_I MOM2 DEF_I CSU LISO3 'TITR' MOT_I ;
  408. FIN B1 ;
  409. FINSI ;
  410.  
  411.  
  412.  
  413.  
  414.  
  415.  
  416.  
  417.  
  418.  
  419. ************************************************************************
  420. * CHAPITRE 9 : MECANIQUE ELASTIQUE LINEAIRE ET PLASTIQUE PARFAIT *
  421. * CHARGEMENT THERMIQUE *
  422. * MATERIAU VARIABLE DANS L'ESPACE *
  423. * MATERIAU DEPENDANT DE LA TEMPERATURE *
  424. ************************************************************************
  425.  
  426.  
  427. * VARIATION DE LA LIMITE ELASTIQUE EN FONCTION DE T
  428. * -------------------------------------------------
  429. EVSIGY = EVOL 'MANU' 'T' (PROG 50. 200.) 'SIGY' (PROG 300.E6 100.E6) ;
  430.  
  431.  
  432. * MISE A JOUR DU MATERIAU
  433. * -----------------------
  434. MAM2 = MATE MOM2 'YOUN' YOUNGMAT 'NU' NUMAT 'ALPH' CHM_ALPH 'SIGY' EVSIGY ;
  435.  
  436.  
  437. * MISE A JOUR DES DONNEES D'ENTREE DANS LA TABLE DE PASAPAS
  438. * ----------------------------------------------------------
  439. TAB2 = TABL ;
  440. TAB2 . 'MODELE' = MOT ET MOC ET MOR ET MOM2 ;
  441. TAB2 . 'CARACTERISTIQUES' = MAT ET MAC ET MAR ET MAM2 ;
  442. TAB2 . 'BLOCAGES_MECANIQUES' = BLMX ET BLMY ;
  443. TAB2 . 'BLOCAGES_THERMIQUES' = BLT ;
  444. TAB2 . 'CHARGEMENT' = CHT ET CHACONV ET CHARAYE ET CHM ;
  445. TAB2 . 'TEMPS_CALCULES' = PROG 0. 'PAS' (0.02 * TPSFIN) (0.98 * TPSFIN)
  446. 'PAS' (0.001 * TPSFIN) TPSFIN ;
  447. TAB2 . 'TEMPERATURES' = TABL ;
  448. TAB2 . 'TEMPERATURES' . 0 = T_INI ;
  449. TAB2 . 'CELSIUS' = VRAI ;
  450.  
  451.  
  452. * APPEL A PASAPAS
  453. * ---------------
  454. PASAPAS TAB2 ;
  455.  
  456.  
  457. * POST TRAITEMENT
  458. * ---------------
  459. * COMPARAISON DE LA DEFORMEE FINALE AVEC LES CALCULS PRECEDENTS
  460. N2 = DIME (TAB2 . 'DEPLACEMENTS') ;
  461. U9 = TAB2 . 'DEPLACEMENTS' . (N2 - 1) ;
  462. DEF_9 = DEFO SU U9 150. ;
  463. DEF_9C = DEFO CSU U9 150. 'BLEU' ;
  464. MOT1 = CHAI '[9] Deformees, elas.(R), + plas.(V), + Sy var.(B)' ;
  465. SI ITRAC ;
  466. TRAC (DEF_INIC ET DEF_7C ET DEF_8C ET DEF_9C) 'TITR' MOT1 ;
  467. FINSI ;
  468.  
  469. * DEFORMATIONS PLASTIQUES CUMULEES
  470. SI ITRAC ;
  471. VI = TAB2 . 'VARIABLES_INTERNES' . (N2 - 1) ;
  472. EQ_MAX = MAXI (EXCO 'EPSE' VI) ;
  473. LISO3 = PROG 0. 'PAS' (EQ_MAX / 15.) EQ_MAX ;
  474. REPE B1 N2 ;
  475. TPS_I = TAB2 . 'TEMPS' . (&B1 - 1) ;
  476. U_I = TAB2 . 'DEPLACEMENTS' . (&B1 - 1) ;
  477. DEF_I = DEFO SU U_I 150. ;
  478. V_I = TAB2 . 'VARIABLES_INTERNES' . (&B1 - 1) ;
  479. MOT_I = CHAI '[9] Def. plas. eq. cumulee au temps ' TPS_I ;
  480. TRAC V_I MOM2 DEF_I CSU LISO3 'TITR' MOT_I ;
  481. FIN B1 ;
  482. FINSI ;
  483.  
  484.  
  485. FIN ;
  486.  
  487.  
  488.  
  489.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales