Télécharger la plaquette Cast3M


fr en

Télécharger formation_debutant_1_maillage.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : formation_debutant_1_maillage.dgibi
  2. *
  3. ************************************************************************
  4. *      FORMATION DEBUTER AVEC CAST3M - CALCULS THERMO-MECANIQUES       *
  5. *                                                                      *
  6. * Modelisation du comportement thermo-mecanique d'une structure avec   *
  7. * une cavite                                                           *
  8. *                                                                      *
  9. * Ce fichier est la partie 1 sur 3 de la formation debutant a Cast3M   *
  10. *                                                                      *
  11. * Partie 1 : maillage                                                  *
  12. *            creation de points, lignes, surfaces                      *
  13. *            maillage libre puis regle                                 *
  14. *            sauvegarde des objets                                     *
  15. *                                                                      *
  16. ************************************************************************
  17.  
  18.  
  19.  
  20.  
  21. * OBJET LOGIQUE POUR INDIQUER SI L'ON FAIT LES TRACES OU NON
  22. * ----------------------------------------------------------
  23. ITRAC    = FAUX ;
  24.  
  25.  
  26.  
  27. * UNITES
  28. * ------
  29. * IL N'Y A PAS DE SYSTEME D'UNITES PREDEFINI DANS CAST3M
  30. * L'UTILISATEUR DOIT S'ASSURER DE LA COHERENCE DES VALEURS INTRODUITES
  31. * DANS LE PRESENT JEU DE DONNEES, ON CHOISIT LES UNITES SUIVANTES :
  32. * MASSE:                        kg
  33. * LONGUEUR:                     m
  34. * TEMPS:                        s
  35. * TEMPERATURE                   degre Celsius
  36. * FORCE:                        N
  37. * ENERGIE                       J
  38. * PUISSANCE                     W
  39. * CONTRAINTE                    Pa (N/m2)
  40. * MASSE VOLUMIQUE               kg/m3
  41. * CAPACITE CALORIFIQUE MASSIQUE J/kg/K
  42. * CONDUCTIVITE THERMIQUE        W/m/K
  43. * COEFFICIENT DE DILATATION     1/K
  44.  
  45.  
  46.  
  47.  
  48.  
  49.  
  50. ************************************************************************
  51. * CHAPITRE 1 : GENERALITES ET MAILLAGE                                 *
  52. ************************************************************************
  53.  
  54.  
  55. * OPTIONS GENERALES ET TYPE D'ELEMENTS GEOMETRIQUES
  56. * -------------------------------------------------
  57. OPTI 'DIME' 2 'ELEM' 'QUA8' ;
  58.  
  59.  
  60. * DEFINITION DES LONGUEURS ET DENSITES DE MAILLES
  61. * -----------------------------------------------
  62. LONG     = 24.E-1 ;
  63. HAUT     = 10.E-1 ;
  64. RAYON    = 2.E-1 ;
  65.  
  66. NLONG    = 24 ;
  67. NHAUT    = 4 ;
  68. NBASG    = 10 ;
  69. NBASD    = 10 ;
  70. NQCG     = 8 ;
  71. NQCD     = 8 ;
  72.  
  73.  
  74. * CREATION DES POINTS D'APPUI DU MAILLAGE
  75. * ---------------------------------------
  76. PA       = 0. 0. ;
  77. PB       = ((0.5 * LONG) - RAYON) 0. ;
  78. PC       = (0.5 * LONG) RAYON ;
  79. PD       = ((0.5 * LONG) + RAYON) 0. ;
  80. PE       = LONG 0. ;
  81. PF       = LONG HAUT ;
  82. PG       = 0. HAUT ;
  83. PCEN     = (0.5 * LONG) 0. ;
  84.  
  85.  
  86. * CREATION DES LIGNES D'APPUI DU MAILLAGE
  87. * ---------------------------------------
  88.  
  89. * LIGNES ELEMENTAIRES
  90. LIAB     = DROI NBASG PA PB ;
  91. CE1      = CERC NQCG PB PCEN PC ;
  92. CE       = CERC NQCD CE1 PCEN PD ;
  93. LIDE     = DROI NBASD PD PE ;
  94. LIEF     = DROI NHAUT PE PF ;
  95. LIFG     = DROI NLONG PF PG ;
  96. LIGA     = DROI NHAUT PG PA ;
  97.  
  98. * CONTOUR FERME OBTENU PAR ASSEMBLAGE DE LIGNES ELEMENTAIRES
  99. CO       = LIAB ET CE ET LIDE ET LIEF ET LIFG ET LIGA ;
  100.  
  101.  
  102. * CREATION DU MAILLAGE 2D PAR APPEL AU MAILLEUR LIBRE
  103. * ---------------------------------------------------
  104. SU       = SURF CO ;
  105. SI ITRAC ;
  106.   TRAC SU 'TITR' '[1] Maillage libre de la structure' ;
  107. FINSI ;
  108.  
  109.  
  110. * CREATION DU MAILLAGE 2D PAR UN MAILLEUR REGLE
  111. * MAILLAGE DU QUART GAUCHE DE LA STRUCTURE AVEC REGL
  112. * --------------------------------------------------
  113. NHAUT    = 10 ;
  114. NQCG     = 20 ;
  115. PH       = (0.5 * LONG) HAUT ;
  116. LIHG     = DROI (NQCG - NHAUT) PH PG ;
  117. LIGA     = DROI NHAUT PG PA ;
  118. CE1      = CERC NQCG PB PCEN PC ;
  119. SU1      = REGL  'DINI' 0.05 'DFIN' 0.1 (INVE CE1) (LIHG ET LIGA) ;
  120. SU2      = SU1 SYME 'DROI' PCEN PH ;
  121. SU       = SU1 ET SU2 ;
  122. ELIM SU 1.E-9 ;
  123. SI ITRAC ;
  124.   TRAC SU 'TITR' '[1] Maillage regle de la structure' ;
  125. FINSI ;
  126.  
  127.  
  128. * RECUPERATION DU MAILLAGE DU DEMI CERCLE, DE LA LIGNE SUPPERIEURE
  129. * ET DES LIGNES INFERIEURES AVEC 'POIN' ET 'ELEM'
  130. * ----------------------------------------------------------------
  131. CSU      = CONT SU ;
  132. PCE      = SU POIN 'SPHE' PCEN PC 1.E-9 ;
  133. CE       = CSU ELEM 'APPU' 'STRI' PCE ;
  134. PLHAUT   = SU POIN 'DROI' PF PG 1.E-9 ;
  135. LHAUT    = CSU ELEM 'APPU' 'STRI' PLHAUT ;
  136. PLBAS    = SU POIN 'DROI' PA PB 1.E-9 ;
  137. LBAS     = CSU ELEM 'APPU' 'STRI' PLBAS ;
  138.  
  139.  
  140. * SAUVEGARDE DES OBJETS CREES
  141. * ---------------------------
  142. OPTI 'SAUV' 'formation_debutant_1_maillage.sauv' ;
  144.  
  145.  
  146. FIN ;
  147.  
  148.  
  149.  
  150.  
  151.  
  152.  
  153.  
  154.  
  155.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales