Télécharger fluage_fibre_norton_3.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. * Comparaison du modele de fluage de Norton : *
  3. * - modele poutre a fibre VS modele massif *
  4. * - chargement uniaxial, traction puis compression *
  5. * - en deplacement impose *
  6. ************************************************************************
  7.  
  8.  
  9.  
  10. ** Options generales
  11. OPTI 'DIME' 3 'ELEM' 'CU20' 'ECHO' 0 ;
  12. itrac = FAUX ;
  13.  
  14.  
  15. ** Parametres geometrie (poutre a section rectangulaire)
  16. a = 0.05 ;
  17. b = 0.02 ;
  18. l = 1. ;
  19. se = a * b ;
  20.  
  21.  
  22. ** Nombres d'elements
  23. nea = 1 ;
  24. neb = 1 ;
  25. nel = 1 ;
  26.  
  27.  
  28. ** Parametres materiau
  29. yo = 1.E8 ;
  30. nu = 0.3 ;
  31. af1 = 3.E-13 ;
  32. af2 = 1.2 ;
  33. af3 = 1.4 ;
  34.  
  35.  
  36. ** Parametres chargement
  37. utrac = 0.01 ;
  38. tl = 200. ;
  39.  
  40.  
  41. ** Maillage et modele volumique
  42. p0 = 0. 0. 0. ;
  43. p1 = 0. a 0. ;
  44. l1 = DROI nea p0 p1 ;
  45. s1 = l1 TRAN neb (0. 0. b) ;
  46. p2 = s1 POIN 'PROC' (0. 0. b) ;
  47. v1 = s1 VOLU 'TRAN' nel (l 0. 0.) ;
  48. env1 = ENVE v1 ;
  49. are1 = ARET v1 ;
  50. p3 = v1 POIN 'PROC' (l 0. 0.) ;
  51. s2 = v1 FACE 2 ;
  52. mov = MODE v1 'MECANIQUE' 'ELASTIQUE' 'FLUAGE' 'NORTON' ;
  53. mav = MATE mov 'YOUN' yo 'NU' nu 'AF1' af1 'AF2' af2 'AF3' af3 ;
  54.  
  55.  
  56. ** Maillage et modele de section
  57. OPTI 'ELEM' 'CUB8' ;
  58. lig1 = DROI nea ((-0.5 * a) (-0.5 * b) 0.) ((0.5 * a) (-0.5 * b) 0.) ;
  59. s3 = lig1 TRAN neb (0. b 0.) ;
  60. s3 = SURF (CONT s3) 'PLAN' ;
  61. mos = MODE s3 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'NORTON' 'QUAS' 'TRIS' ;
  62. mas = MATE mos 'YOUN' yo 'NU' nu 'AF1' af1 'AF2' af2 'AF3' af3 'SMAX' (yo / 1000.) 'ALPY' 0.66 'ALPZ' 0.66 ;
  63.  
  64.  
  65. ** Maillage et modele de poutre TIMO
  66. lf = DROI nel p0 p3 ;
  67. mop = MODE lf 'MECANIQUE' 'ELASTIQUE' 'SECTION' 'PLASTIQUE' 'SECTION' 'TIMO' ;
  68. map = MATE mop 'MODS' mos 'MATS' mas 'VECT' (0. 1. 0.) ;
  69.  
  70.  
  71. ** Conditions aux limites
  72. tl0 = 1.E-5 ;
  73. tl2 = 2. * tl ;
  74. tl3 = 3. * tl ;
  75. tl4 = 4. * tl ;
  76. evcha = EVOL 'MANU' (PROG 0. tl0 tl (tl + tl0) tl2 (tl2 + tl0) tl3 (tl3 + tl0) tl4)
  77. (PROG 0. 0.999 1. 0.001 0. -0.999 -1. -0.001 0.) ;
  78.  
  79. * pour le modele volumique
  80. * encastrement
  81. bl1 = (BLOQ 'UX' s1) ET (BLOQ 'UY' 'UZ' p0) ET (BLOQ 'UZ' p1) ;
  82. * deplacement impose
  83. bl2 = BLOQ 'UX' s2 ;
  84. bl1 = bl1 ET bl2 ;
  85. ft = DEPI bl2 utrac ;
  86. chaft = CHAR 'DIMP' ft evcha ;
  87.  
  88. * pour le modele TIMO
  89. * encastrement
  90. bl1p = BLOQ 'DEPL' 'ROTA' p0 ;
  91. * deplacement impose
  92. bl2p = BLOQ 'UX' p3 ;
  93. bl1p = bl1p ET bl2p ;
  94. ftp = DEPI bl2p utrac ;
  95. chaftp = CHAR 'DIMP' ftp evcha ;
  96.  
  97.  
  98. ** Resolution
  99. xpas = tl / 20. ;
  100. ltc = PROG tl0 'PAS' xpas tl
  101. (tl + tl0) 'PAS' xpas tl2
  102. (tl2 + tl0) 'PAS' xpas tl3
  103. (tl3 + tl0) 'PAS' xpas tl4 ;
  104.  
  105. tv = TABL ;
  106. tv . 'MODELE' = mov ;
  107. tv . 'CARACTERISTIQUES' = mav ;
  108. tv . 'BLOCAGES_MECANIQUES' = bl1 ;
  109. tv . 'CHARGEMENT' = chaft ;
  110. tv . 'TEMPS_CALCULES' = ltc ;
  111. PASAPAS tv ;
  112. itp1 = TEMP 'ENTI' 'HORL' ;
  113.  
  114. tp = TABL ;
  115. tp . 'MODELE' = mop ;
  116. tp . 'CARACTERISTIQUES' = map ;
  117. chmsg0 = ZERO mos 'CONTRAIN' ;
  118. chmvi0 = ZERO mos 'VARINTER' ;
  119. tp . 'VARIABLES_INTERNES' = TABL ;
  120. tp . 'VARIABLES_INTERNES' . 0 = MANU 'CHML' mop 'VONS' chmsg0 'VAIS' chmvi0 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  121. tp . 'BLOCAGES_MECANIQUES' = bl1p ;
  122. tp . 'CHARGEMENT' = chaftp ;
  123. tp . 'TEMPS_CALCULES' = ltc ;
  124. PASAPAS tp ;
  125. itp11 = TEMP 'ENTI' 'HORL' ;
  126.  
  127. MESS 'Temps horloge : ' ;
  128. MESS (CHAI '- modele massif :' ' ' itp1) ;
  129. MESS (CHAI '- modele poutre :' ' ' itp11) ;
  130.  
  131.  
  132. ** Post traitement
  133. n1 = DIME (tv . 'TEMPS') ;
  134. ltps = PROG ;
  135. * deplacements de l'extremite
  136. luv = EXTR (EVOL 'TEMP' tv 'DEPLACEMENTS' 'UX' p3) 'ORDO' ;
  137. lup = EXTR (EVOL 'TEMP' tp 'DEPLACEMENTS' 'UX' p3) 'ORDO' ;
  138. * force de reaction a l'encastrement
  139. lfv = PROG ;
  140. REPE b1 n1 ;
  141. i1 = &b1 - 1 ;
  142. ltps = ltps ET (tv . 'TEMPS' . i1) ;
  143. fv = 0. ;
  144. SI (NEG i1 0) ;
  145. fv = MAXI (EXCO 'FX' (RESU (REDU (tv . 'REACTIONS' . i1) s1))) ;
  146. FINSI ;
  147. lfv = lfv ET fv ;
  148. FIN b1 ;
  149. lfp = EXTR (EVOL 'TEMP' tp 'REACTIONS' 'FX' p0) 'ORDO' ;
  150. * defomration inelastique
  151. lev = PROG ;
  152. lep = PROG ;
  153. vol1 = MESU v1 ;
  154. REPE b1 n1 ;
  155. i1 = &b1 - 1 ;
  156. tps1 = tv . 'TEMPS' . i1 ;
  157. lev = lev ET ((INTG mov (tv . 'VARIABLES_INTERNES' . i1) 'EPSE') / vol1) ;
  158. uv = tv . 'DEPLACEMENTS' . i1 ;
  159. up = tp . 'DEPLACEMENTS' . i1 ;
  160. tabv = TABL ;
  161. tabv . 'DEPLACEMENTS' = TABL ;
  162. tabv . 'DEPLACEMENTS' . 1 = up ;
  163. tabv . 'VONS' = TABL ;
  164. tabv . 'VONS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . i1) 'VONS' ;
  165. tabv . 'VAIS' = TABL ;
  166. tabv . 'VAIS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . i1) 'VAIS' ;
  167. mail1 = POUT2MAS mop map 'GAUSS' tabv ;
  168. vips = tabv . 'VAIS_3D' . 1 ;
  169. mobid = MODE mail1 'MECANIQUE' ;
  170. cham1 = CHAN 'CHAM' mobid vips ;
  171. epsep = (INTG mobid cham1 'EPSE') * l / (NBEL lf) / se ;
  172. lep = lep ET epsep ;
  173. FIN b1 ;
  174.  
  175.  
  176. ** Analyse/trace des resultats
  177. tleg = TABL ;
  178. tleg . 1 = MOT 'MARQ LOSA NOLI' ;
  179. tleg . 2 = MOT 'MARQ ROND NOLI' ;
  180. tleg . 'TITRE' = TABL ;
  181. tleg . 'TITRE' . 1 = 'Modele 3D massif' ;
  182. tleg . 'TITRE' . 2 = 'Modele poutre fibre' ;
  183. MESS 'Ecart relatif max.' ;
  184. evuv = EVOL 'VERT' 'MANU' 'Temps' ltps 'Deplacement' luv ;
  185. evup = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Deplacement' lup ;
  186. difu = (MAXI (ABS (lup - luv))) / (MAXI (ABS luv)) ;
  187. MESS '-- deplacement :' difu ;
  188. SI itrac ;
  189. DESS (evuv ET evup) 'TITR' 'Deplacement vs. Temps' 'LEGE' tleg ;
  190. FINSI ;
  191. evfv = EVOL 'VERT' 'MANU' 'Temps' ltps 'Force' lfv ;
  192. evfp = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Force' lfp ;
  193. diff = (MAXI (ABS (lfp - lfv))) / (MAXI (ABS lfv)) ;
  194. MESS '-- effort :' diff ;
  195. SI itrac ;
  196. DESS (evfv ET evfp) 'TITR' 'Force vs. Temps' 'LEGE' tleg ;
  197. FINSI ;
  198. evev = EVOL 'VERT' 'MANU' 'TEMPS' ltps 'EPSE' lev ;
  199. evep = EVOL 'ROUG' 'MANU' 'TEMPS' ltps 'ESPE' lep ;
  200. dife = (MAXI (ABS (lep - lev))) / (MAXI (ABS lev)) ;
  201. MESS '-- def. fluage :' dife ;
  202. SI itrac ;
  203. DESS (evev ET evep) 'TITR' 'Deformation non lin. (EPSE) vs Temps' 'LEGE' tleg ;
  204. FINSI ;
  205.  
  206.  
  207. ** Erreur si l'ecart relatif est trop eleve
  208. lerr = PROG difu diff dife ;
  209. errmax = MAXI lerr ;
  210. SI (errmax > 6000.) ;
  211. MESS 'Echec du cas test !' ;
  212. ERRE 5 ;
  213. SINON ;
  214. MESS 'Succes du cas test !' ;
  215. FINSI ;
  216.  
  217.  
  218. FIN ;
  219.  
  220.  
  221.  
  222.  
  223.  
  224.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales