Télécharger fluage_fibre_norton_2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : fluage_fibre_norton_2.dgibi
  2. ************************************************************************
  3. * Comparaison du modele de fluage de Norton : *
  4. * - modele poutre a fibre VS modele massif *
  5. * - chargement uniaxial, traction puis compression *
  6. * - en force imposee *
  7. ************************************************************************
  8.  
  9.  
  10.  
  11. ** Options generales
  12. OPTI 'DIME' 3 'ELEM' 'CU20' 'ECHO' 0 ;
  13. itrac = FAUX ;
  14.  
  15.  
  16. ** Parametres geometrie (poutre a section rectangulaire)
  17. a = 0.05 ;
  18. b = 0.02 ;
  19. l = 1. ;
  20. se = a * b ;
  21.  
  22.  
  23. ** Nombres d'elements
  24. nea = 1 ;
  25. neb = 1 ;
  26. nel = 1 ;
  27.  
  28.  
  29. ** Parametres materiau
  30. yo = 1.E8 ;
  31. nu = 0.3 ;
  32. af1 = 3.E-13 ;
  33. af2 = 1.2 ;
  34. af3 = 1.4 ;
  35.  
  36.  
  37. ** Parametres chargement
  38. ftrac = 10000. ;
  39. tl = 200. ;
  40.  
  41.  
  42. ** Maillage et modele volumique
  43. p0 = 0. 0. 0. ;
  44. p1 = 0. a 0. ;
  45. l1 = DROI nea p0 p1 ;
  46. s1 = l1 TRAN neb (0. 0. b) ;
  47. p2 = s1 POIN 'PROC' (0. 0. b) ;
  48. v1 = s1 VOLU 'TRAN' nel (l 0. 0.) ;
  49. env1 = ENVE v1 ;
  50. are1 = ARET v1 ;
  51. p3 = v1 POIN 'PROC' (l 0. 0.) ;
  52. s2 = v1 FACE 2 ;
  53. mov = MODE v1 'MECANIQUE' 'ELASTIQUE' 'FLUAGE' 'NORTON' ;
  54. mav = MATE mov 'YOUN' yo 'NU' nu 'SMAX' 0. 'AF1' af1
  55. 'AF2' af2 'AF3' af3 ;
  56.  
  57.  
  58. ** Maillage et modele de section
  59. OPTI 'ELEM' 'CUB8' ;
  60. lig1 = DROI nea ((-0.5 * a) (-0.5 * b) 0.) ((0.5 * a) (-0.5 * b) 0.) ;
  61. s3 = lig1 TRAN neb (0. b 0.) ;
  62. s3 = SURF (CONT s3) 'PLAN' ;
  63. mos = MODE s3 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'NORTON' 'QUAS' 'TRIS' ;
  64. mas = MATE mos 'YOUN' yo 'NU' nu 'AF1' af1 'AF2' af2 'AF3' af3 'SMAX' (yo / 1000.) 'ALPY' 0.66 'ALPZ' 0.66 ;
  65.  
  66.  
  67. ** Maillage et modele de poutre TIMO
  68. lf = DROI nel p0 p3 ;
  69. mop = MODE lf 'MECANIQUE' 'ELASTIQUE' 'SECTION' 'PLASTIQUE' 'SECTION' 'TIMO' ;
  70. map = MATE mop 'MODS' mos 'MATS' mas 'VECT' (0. 1. 0.) ;
  71.  
  72.  
  73. ** Conditions aux limites
  74. tl0 = 1.E-5 ;
  75. tl2 = 2. * tl ;
  76. tl3 = 3. * tl ;
  77. tl4 = 4. * tl ;
  78. evcha = EVOL 'MANU' (PROG 0. tl0 tl (tl + tl0) tl2 (tl2 + tl0) tl3 (tl3 + tl0) tl4)
  79. (PROG 0. 0.999 1. 0.001 0. -0.999 -1. -0.001 0.) ;
  80.  
  81. * pour le modele volumique
  82. * encastrement
  83. bl1 = (BLOQ 'UX' s1) ET (BLOQ 'UY' 'UZ' p0) ET (BLOQ 'UZ' p1) ;
  84. * force imposee
  85. ft = FSUR 'MASS' mov s2 ((ftrac / se) 0. 0.) ;
  86. chaft = CHAR 'MECA' ft evcha ;
  87.  
  88. * pour le modele TIMO
  89. * encastrement
  90. bl1p = BLOQ 'DEPL' 'ROTA' p0 ;
  91. * force imposee
  92. ftp = FORC (ftrac 0. 0.) p3 ;
  93. chaftp = CHAR 'MECA' ftp evcha ;
  94.  
  95.  
  96. ** Resolution
  97. xpas = tl / 20. ;
  98. ltc = PROG tl0 'PAS' xpas tl
  99. (tl + tl0) 'PAS' xpas tl2
  100. (tl2 + tl0) 'PAS' xpas tl3
  101. (tl3 + tl0) 'PAS' xpas tl4 ;
  102.  
  103. tv = TABL ;
  104. tv . 'MODELE' = mov ;
  105. tv . 'CARACTERISTIQUES' = mav ;
  106. tv . 'BLOCAGES_MECANIQUES' = bl1 ;
  107. tv . 'CHARGEMENT' = chaft ;
  108. tv . 'TEMPS_CALCULES' = ltc ;
  109. PASAPAS tv ;
  110. itp1 = TEMP 'HORL' ;
  111.  
  112. tp = TABL ;
  113. tp . 'MODELE' = mop ;
  114. tp . 'CARACTERISTIQUES' = map ;
  115. chmsg0 = ZERO mos 'CONTRAIN' ;
  116. chmvi0 = ZERO mos 'VARINTER' ;
  117. tp . 'VARIABLES_INTERNES' = TABL ;
  118. tp . 'VARIABLES_INTERNES' . 0 = MANU 'CHML' mop 'VONS' chmsg0 'VAIS' chmvi0 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  119. tp . 'BLOCAGES_MECANIQUES' = bl1p ;
  120. tp . 'CHARGEMENT' = chaftp ;
  121. tp . 'TEMPS_CALCULES' = ltc ;
  122. PASAPAS tp ;
  123. itp11 = TEMP 'HORL' ;
  124.  
  125. MESS 'Temps horloge : ' ;
  126. MESS (CHAI '- modele massif :' ' ' itp1) ;
  127. MESS (CHAI '- modele poutre :' ' ' itp11) ;
  128.  
  129.  
  130. ** Post traitement
  131. n1 = DIME (tv . 'TEMPS') ;
  132. ltps = PROG ;
  133. * deplacements de l'extremite
  134. luv = EXTR (EVOL 'TEMP' tv 'DEPLACEMENTS' 'UX' p3) 'ORDO' ;
  135. lup = EXTR (EVOL 'TEMP' tp 'DEPLACEMENTS' 'UX' p3) 'ORDO' ;
  136. * force de reaction a l'encastrement
  137. lfv = PROG ;
  138. REPE b1 n1 ;
  139. i1 = &b1 - 1 ;
  140. ltps = ltps ET (tv . 'TEMPS' . i1) ;
  141. fv = 0. ;
  142. SI (NEG i1 0) ;
  143. fv = MAXI (EXCO 'FX' (RESU (REDU (tv . 'REACTIONS' . i1) s1))) ;
  144. FINSI ;
  145. lfv = lfv ET fv ;
  146. FIN b1 ;
  147. lfp = EXTR (EVOL 'TEMP' tp 'REACTIONS' 'FX' p0) 'ORDO' ;
  148. * defomration inelastique
  149. lev = PROG ;
  150. lep = PROG ;
  151. vol1 = MESU v1 ;
  152. REPE b1 n1 ;
  153. i1 = &b1 - 1 ;
  154. tps1 = tv . 'TEMPS' . i1 ;
  155. lev = lev ET ((INTG mov (tv . 'VARIABLES_INTERNES' . i1) 'EPSE') / vol1) ;
  156. uv = tv . 'DEPLACEMENTS' . i1 ;
  157. up = tp . 'DEPLACEMENTS' . i1 ;
  158. tabv = TABL ;
  159. tabv . 'DEPLACEMENTS' = TABL ;
  160. tabv . 'DEPLACEMENTS' . 1 = up ;
  161. tabv . 'VONS' = TABL ;
  162. tabv . 'VONS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . i1) 'VONS' ;
  163. tabv . 'VAIS' = TABL ;
  164. tabv . 'VAIS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . i1) 'VAIS' ;
  165. mail1 = POUT2MAS mop map 'GAUSS' tabv ;
  166. vips = tabv . 'VAIS_3D' . 1 ;
  167. mobid = MODE mail1 'MECANIQUE' ;
  168. cham1 = CHAN 'CHAM' mobid vips ;
  169. epsep = (INTG mobid cham1 'EPSE') * l / (NBEL lf) / se ;
  170. lep = lep ET epsep ;
  171. FIN b1 ;
  172.  
  173.  
  174. ** Analyse/trace des resultats
  175. tleg = TABL ;
  176. tleg . 1 = MOT 'MARQ LOSA NOLI' ;
  177. tleg . 2 = MOT 'MARQ ROND NOLI' ;
  178. tleg . 'TITRE' = TABL ;
  179. tleg . 'TITRE' . 1 = 'Modele 3D massif' ;
  180. tleg . 'TITRE' . 2 = 'Modele poutre fibre' ;
  181. MESS 'Ecart relatif max.' ;
  182. evuv = EVOL 'VERT' 'MANU' 'Temps' ltps 'Deplacement' luv ;
  183. evup = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Deplacement' lup ;
  184. difu = (MAXI (ABS (lup - luv))) / (MAXI (ABS luv)) ;
  185. MESS '-- deplacement :' difu ;
  186. SI itrac ;
  187. DESS (evuv ET evup) 'TITR' 'Deplacement vs. Temps' 'LEGE' tleg ;
  188. FINSI ;
  189. evfv = EVOL 'VERT' 'MANU' 'Temps' ltps 'Force' lfv ;
  190. evfp = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Force' lfp ;
  191. diff = (MAXI (ABS (lfp - lfv))) / (MAXI (ABS lfv)) ;
  192. MESS '-- effort :' diff ;
  193. SI itrac ;
  194. DESS (evfv ET evfp) 'TITR' 'Force vs. Temps' 'LEGE' tleg ;
  195. FINSI ;
  196. evev = EVOL 'VERT' 'MANU' 'TEMPS' ltps 'EPSE' lev ;
  197. evep = EVOL 'ROUG' 'MANU' 'TEMPS' ltps 'ESPE' lep ;
  198. dife = (MAXI (ABS (lep - lev))) / (MAXI (ABS lev)) ;
  199. MESS '-- def. fluage :' dife ;
  200. SI itrac ;
  201. DESS (evev ET evep) 'TITR' 'Deformation non lin. (EPSE) vs Temps' 'LEGE' tleg ;
  202. FINSI ;
  203.  
  204.  
  205. ** Erreur si l'ecart relatif est trop eleve
  206. lerr = PROG difu diff dife ;
  207. errmax = MAXI lerr ;
  208. SI (errmax > 6000.) ;
  209. MESS 'Echec du cas test !' ;
  210. ERRE 5 ;
  211. SINON ;
  212. MESS 'Succes du cas test !' ;
  213. FINSI ;
  214.  
  215.  
  216. FIN ;
  217.  
  218.  
  219.  
  220.  
  221.  
  222.  
  223.  
  224.  
  225.  
  226.  
  227.  
  228.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales