Télécharger fluage_fibre_norton_1.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. * Test du modele de fluage de Norton pour les modeles de section *
  3. * (appeles aussi modeles de poutre a fibre) *
  4. * --> chargement uniaxial en traction *
  5. * --> comparaison a la solution analytique *
  6. ************************************************************************
  7.  
  8.  
  9.  
  10. ** Options generales
  11. OPTI 'DIME' 3 'ELEM' 'QUA4' 'ECHO' 0 ;
  12. itrac = FAUX ;
  13.  
  14.  
  15. ** Parametres geometrie (poutre a section rectangulaire)
  16. a = 0.05 ;
  17. b = 0.02 ;
  18. l = 1. ;
  19. se = a * b ;
  20.  
  21.  
  22. ** Nombres d'elements
  23. nea = 5 ;
  24. neb = 5 ;
  25. nel = 10 ;
  26.  
  27.  
  28. ** Parametres materiau
  29. yo = 1.E8 ;
  30. nu = 0.3 ;
  31. af1 = 3.E-13 ;
  32. af2 = 1. ;
  33. af3 = 1.4 ;
  34.  
  35.  
  36. ** Parametres chargement
  37. ftrac = 10000. ;
  38. tl = 1000. ;
  39.  
  40.  
  41. ** Maillage et modele de section
  42. lig1 = DROI nea ((-0.5 * a) (-0.5 * b) 0.) ((0.5 * a) (-0.5 * b) 0.) ;
  43. s1 = lig1 TRAN neb (0. b 0.) ;
  44. s1 = SURF (CONT s1) 'PLAN' ;
  45. mos = MODE s1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'NORTON' 'QUAS' 'TRIS' ;
  46. mas = MATE mos 'YOUN' yo 'NU' nu 'AF1' af1 'AF2' af2 'AF3' af3 'SMAX' (yo / 1000.) 'ALPY' 0.66 'ALPZ' 0.66 ;
  47.  
  48.  
  49. ** Maillage et modele de poutre TIMO
  50. p0 = 0. 0. 0. ;
  51. p1 = l 0. 0. ;
  52. lf = DROI nel p0 p1 ;
  53. mop = MODE lf 'MECANIQUE' 'ELASTIQUE' 'SECTION' 'PLASTIQUE' 'SECTION' 'TIMO' ;
  54. map = MATE mop 'MODS' mos 'MATS' mas 'VECT' (0. 1. 0.) ;
  55.  
  56.  
  57. ** Conditions aux limites
  58. tl0 = 1.E-5 ;
  59. evcha = EVOL 'MANU' (PROG 0. tl0 tl) (PROG 0. 1. 1.) ;
  60. bl1p = BLOQ 'DEPL' 'ROTA' p0 ;
  61. ftp = FORC (ftrac 0. 0.) p1 ;
  62. chaftp = CHAR 'MECA' ftp evcha ;
  63.  
  64.  
  65. ** Resolution
  66. xpas = tl / 50. ;
  67. ltc = PROG tl0 'PAS' xpas tl ;
  68. tp = TABL ;
  69. tp . 'MODELE' = mop ;
  70. tp . 'CARACTERISTIQUES' = map ;
  71. chmsg0 = ZERO mos 'CONTRAIN' ;
  72. chmvi0 = ZERO mos 'VARINTER' ;
  73. tp . 'VARIABLES_INTERNES' = TABL ;
  74. tp . 'VARIABLES_INTERNES' . 0 = MANU 'CHML' mop 'VONS' chmsg0 'VAIS' chmvi0 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  75. tp . 'BLOCAGES_MECANIQUES' = bl1p ;
  76. tp . 'CHARGEMENT' = chaftp ;
  77. tp . 'TEMPS_CALCULES' = ltc ;
  78. PASAPAS tp ;
  79. itp1 = TEMP 'ENTI' 'HORL' ;
  80. MESS 'Temps horloge :' ' ' itp1 ;
  81.  
  82.  
  83. ** Post traitement
  84. n1 = DIME (tp . 'TEMPS') ;
  85. * deplacements de l'extremite
  86. lup = EXTR (EVOL 'TEMP' tp 'DEPLACEMENTS' 'UX' p1) 'ORDO' ;
  87. * force de reaction a l'encastrement
  88. lfp = EXTR (EVOL 'TEMP' tp 'REACTIONS' 'FX' p0) 'ORDO' ;
  89. * defomration inelastique moyenne dans la poutre
  90. ltps = PROG ;
  91. lep = PROG 0. ;
  92. REPE b1 (n1 - 1) ;
  93. tps1 = tp . 'TEMPS' . &b1 ;
  94. ltps = ltps ET tps1 ;
  95. up = tp . 'DEPLACEMENTS' . &b1 ;
  96. tabv = TABL ;
  97. tabv . 'DEPLACEMENTS' = TABL ;
  98. tabv . 'DEPLACEMENTS' . 1 = up ;
  99. tabv . 'VONS' = TABL ;
  100. tabv . 'VONS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . &b1) 'VONS' ;
  101. tabv . 'VAIS' = TABL ;
  102. tabv . 'VAIS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . &b1) 'VAIS' ;
  103. mail1 = POUT2MAS mop map 'GAUSS' tabv ;
  104. vips = tabv . 'VAIS_3D' . 1 ;
  105. mobid = MODE mail1 'MECANIQUE' ;
  106. cham1 = CHAN 'CHAM' mobid vips ;
  107. epsep = (INTG mobid cham1 'EPSE') * l / nel / se ;
  108. lep = lep ET epsep ;
  109. FIN b1 ;
  110.  
  111.  
  112. ** Solutions analytiques
  113. sigt = (ABS ftrac) / se ;
  114. let = af1 * (sigt ** af2) * (ltps ** af3) ;
  115. lut = (let + (sigt / yo)) / l ;
  116. lft = PROG 0. (n1 - 1)*(-1. * ftrac) ;
  117. let = (PROG 0.) ET let ;
  118. lut = (PROG 0.) ET lut ;
  119. ltps = (PROG 0.) ET ltps ;
  120. evut = EVOL 'MANU' 'DEFA' ltps lut ;
  121. evft = EVOL 'MANU' 'DEFA' ltps lft ;
  122. evet = EVOL 'MANU' 'DEFA' ltps let ;
  123.  
  124.  
  125. ** Analyse/trace des resultats
  126. tleg = TABL ;
  127. tleg . 2 = MOT 'MARQ ROND NOLI' ;
  128. tleg . 'TITRE' = TABL ;
  129. tleg . 'TITRE' . 1 = 'Soluce analytique' ;
  130. tleg . 'TITRE' . 2 = 'Modele poutre fibre' ;
  131. MESS 'Ecart relatif max.' ;
  132. evup = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Deplacement' lup ;
  133. difu = (MAXI (ABS (lup - lut))) / (MAXI (ABS lut)) ;
  134. MESS '-- deplacement :' difu ;
  135. SI itrac ;
  136. DESS (evut ET evup) 'TITR' 'Deplacement vs. Temps' 'LEGE' tleg ;
  137. FINSI ;
  138. evfp = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Force' lfp ;
  139. diff = (MAXI (ABS (lfp - lft))) / (MAXI (ABS lft)) ;
  140. MESS '-- effort :' diff ;
  141. SI itrac ;
  142. DESS (evft ET evfp) 'TITR' 'Force vs. Temps' 'LEGE' tleg ;
  143. FINSI ;
  144. evep = EVOL 'ROUG' 'MANU' 'TEMPS' ltps 'ESPE' lep ;
  145. dife = (MAXI (ABS (lep - let))) / (MAXI (ABS let)) ;
  146. MESS '-- def. fluage :' dife ;
  147. SI itrac ;
  148. DESS (evet ET evep) 'TITR' 'Deformation non lin. (EPSE) vs Temps' 'LEGE' tleg ;
  149. FINSI ;
  150.  
  151.  
  152. ** Erreur si l'ecart relatif est trop eleve
  153. lerr = PROG difu diff dife ;
  154. errmax = MAXI lerr ;
  155. SI (errmax > 2.E-3) ;
  156. MESS 'Echec du cas test !' ;
  157. ERRE 5 ;
  158. SINON ;
  159. MESS 'Succes du cas test !' ;
  160. FINSI ;
  161.  
  162.  
  163. FIN ;
  164.  
  165.  
  166.  
  167.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales