Télécharger fluage_fibre_blackburn_1.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. * Test du modele de fluage de Blackburn pour les modeles de section *
  3. * (appeles aussi modeles de poutre a fibre) *
  4. * --> chargement uniaxial en traction *
  5. * --> comparaison a la solution analytique *
  6. ************************************************************************
  7.  
  8.  
  9.  
  10. ** Options generales
  11. OPTI 'DIME' 3 'ELEM' 'QUA4' 'ECHO' 0 ;
  12. itrac = FAUX ;
  13.  
  14.  
  15. ** Parametres geometrie (poutre a section rectangulaire)
  16. a = 0.05 ;
  17. b = 0.02 ;
  18. l = 1. ;
  19. se = a * b ;
  20.  
  21.  
  22. ** Nombres d'elements
  23. nea = 5 ;
  24. neb = 5 ;
  25. nel = 10 ;
  26.  
  27.  
  28. ** Parametres materiau
  29. yo = 1.E8 ;
  30. nu = 0.3 ;
  31. af1 = 3.E-4 ;
  32. af2 = 1.E-5 ;
  33. af3 = 1.E-5 ;
  34. af4 = 0.2 ;
  35. rf1 = 5.E-2 ;
  36. rf2 = 1.E-6 ;
  37. rf3 = 1.E-12 ;
  38. rf4 = 1.4 ;
  39. bf1 = 0. ;
  40. bf2 = 0. ;
  41. bf3 = 0. ;
  42. bf4 = 0. ;
  43. bf5 = 0. ;
  44.  
  45.  
  46. ** Parametres chargement
  47. ftrac = 500. ;
  48. tl = 150. ;
  49.  
  50.  
  51. ** Maillage et modele de section
  52. lig1 = DROI nea ((-0.5 * a) (-0.5 * b) 0.) ((0.5 * a) (-0.5 * b) 0.) ;
  53. s1 = lig1 TRAN neb (0. b 0.) ;
  54. s1 = SURF (CONT s1) 'PLAN' ;
  55. mos = MODE s1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'BLACKBURN' 'QUAS' 'TRIS' ;
  56. mas = MATE mos 'YOUN' yo 'NU' nu 'AF1' af1 'AF2' af2 'AF3' af3 'AF4' af4
  57. 'RF1' rf1 'RF2' rf2 'RF3' rf3 'RF4' rf4
  58. 'BF1' bf1 'BF2' bf2 'BF3' bf3 'BF4' bf4 'BF5' bf5
  59. 'SMAX' (yo / 1000.) 'ALPY' 0.66 'ALPZ' 0.66 ;
  60.  
  61.  
  62. ** Maillage et modele de poutre TIMO
  63. p0 = 0. 0. 0. ;
  64. p1 = l 0. 0. ;
  65. lf = DROI nel p0 p1 ;
  66. mop = MODE lf 'MECANIQUE' 'ELASTIQUE' 'SECTION' 'PLASTIQUE' 'SECTION' 'TIMO' ;
  67. map = MATE mop 'MODS' mos 'MATS' mas 'VECT' (0. 1. 0.) ;
  68.  
  69.  
  70. ** Conditions aux limites
  71. tl0 = 1.E-5 ;
  72. evcha = EVOL 'MANU' (PROG 0. tl0 tl) (PROG 0. 1. 1.) ;
  73. bl1p = BLOQ 'DEPL' 'ROTA' p0 ;
  74. ftp = FORC (ftrac 0. 0.) p1 ;
  75. chaftp = CHAR 'MECA' ftp evcha ;
  76.  
  77.  
  78. ** Resolution
  79. xpas = tl / 50. ;
  80. ltc = PROG tl0 'PAS' xpas tl ;
  81. tp = TABL ;
  82. tp . 'MODELE' = mop ;
  83. tp . 'CARACTERISTIQUES' = map ;
  84. chmsg0 = ZERO mos 'CONTRAIN' ;
  85. chmvi0 = ZERO mos 'VARINTER' ;
  86. tp . 'VARIABLES_INTERNES' = TABL ;
  87. tp . 'VARIABLES_INTERNES' . 0 = MANU 'CHML' mop 'VONS' chmsg0 'VAIS' chmvi0 'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  88. tp . 'BLOCAGES_MECANIQUES' = bl1p ;
  89. tp . 'CHARGEMENT' = chaftp ;
  90. tp . 'TEMPS_CALCULES' = ltc ;
  91. PASAPAS tp ;
  92. itp1 = TEMP 'ENTI' 'HORL' ;
  93. MESS 'Temps horloge :' ' ' itp1 ;
  94.  
  95.  
  96. ** Post traitement
  97. n1 = DIME (tp . 'TEMPS') ;
  98. * deplacements de l'extremite
  99. lup = EXTR (EVOL 'TEMP' tp 'DEPLACEMENTS' 'UX' p1) 'ORDO' ;
  100. * force de reaction a l'encastrement
  101. lfp = EXTR (EVOL 'TEMP' tp 'REACTIONS' 'FX' p0) 'ORDO' ;
  102. * defomration inelastique moyenne dans la poutre
  103. ltps = PROG ;
  104. lep = PROG 0. ;
  105. REPE b1 (n1 - 1) ;
  106. tps1 = tp . 'TEMPS' . &b1 ;
  107. ltps = ltps ET tps1 ;
  108. up = tp . 'DEPLACEMENTS' . &b1 ;
  109. tabv = TABL ;
  110. tabv . 'DEPLACEMENTS' = TABL ;
  111. tabv . 'DEPLACEMENTS' . 1 = up ;
  112. tabv . 'VONS' = TABL ;
  113. tabv . 'VONS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . &b1) 'VONS' ;
  114. tabv . 'VAIS' = TABL ;
  115. tabv . 'VAIS' . 1 = EXCO (tp . 'VARIABLES_INTERNES' . &b1) 'VAIS' ;
  116. mail1 = POUT2MAS mop map 'GAUSS' tabv ;
  117. vips = tabv . 'VAIS_3D' . 1 ;
  118. mobid = MODE mail1 'MECANIQUE' ;
  119. cham1 = CHAN 'CHAM' mobid vips ;
  120. epsep = (INTG mobid cham1 'EPSE') * l / nel / se ;
  121. lep = lep ET epsep ;
  122. FIN b1 ;
  123.  
  124.  
  125. ** Solutions analytiques
  126. sigt = (ABS ftrac) / se ;
  127. aa = (af1 * (EXP (af2 * sigt))) + (af3 * (sigt ** af4)) ;
  128. rr = (rf1 * (EXP (rf2 * sigt))) + (rf3 * (sigt ** rf4)) ;
  129. bb = (bf1 * ((SINH (bf2 * sigt)) ** bf3)) + (bf4 * (EXP (bf5 * sigt))) ;
  130. let = (aa * (1. - (EXP (-1. * rr * ltps)))) + (bb * ltps) ;
  131. lut = (let + (sigt / yo)) / l ;
  132. lft = PROG 0. (n1 - 1)*(-1. * ftrac) ;
  133. let = (PROG 0.) ET let ;
  134. lut = (PROG 0.) ET lut ;
  135. ltps = (PROG 0.) ET ltps ;
  136. evut = EVOL 'MANU' 'DEFA' ltps lut ;
  137. evft = EVOL 'MANU' 'DEFA' ltps lft ;
  138. evet = EVOL 'MANU' 'DEFA' ltps let ;
  139.  
  140.  
  141. ** Analyse/trace des resultats
  142. tleg = TABL ;
  143. tleg . 2 = MOT 'MARQ ROND NOLI' ;
  144. tleg . 'TITRE' = TABL ;
  145. tleg . 'TITRE' . 1 = 'Soluce analytique' ;
  146. tleg . 'TITRE' . 2 = 'Modele poutre fibre' ;
  147. MESS 'Ecart relatif max.' ;
  148. evup = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Deplacement' lup ;
  149. difu = (MAXI (ABS (lup - lut))) / (MAXI (ABS lut)) ;
  150. MESS '-- deplacement :' difu ;
  151. SI itrac ;
  152. DESS (evut ET evup) 'TITR' 'Deplacement vs. Temps' 'LEGE' tleg ;
  153. FINSI ;
  154. evfp = EVOL 'ROUG' 'MANU' 'Temps' ltps 'Force' lfp ;
  155. diff = (MAXI (ABS (lfp - lft))) / (MAXI (ABS lft)) ;
  156. MESS '-- effort :' diff ;
  157. SI itrac ;
  158. DESS (evft ET evfp) 'TITR' 'Force vs. Temps' 'LEGE' tleg ;
  159. FINSI ;
  160. evep = EVOL 'ROUG' 'MANU' 'TEMPS' ltps 'ESPE' lep ;
  161. dife = (MAXI (ABS (lep - let))) / (MAXI (ABS let)) ;
  162. MESS '-- def. fluage :' dife ;
  163. SI itrac ;
  164. DESS (evet ET evep) 'TITR' 'Deformation non lin. (EPSE) vs Temps' 'LEGE' tleg ;
  165. FINSI ;
  166.  
  167.  
  168. ** Erreur si l'ecart relatif est trop eleve
  169. lerr = PROG difu diff dife ;
  170. errmax = MAXI lerr ;
  171. ****** (FDP) CRITERE VOLONTAIREMENT ELEVE A 5%
  172. ****** (FDP) IL RESTE ENCORE DES CHOSES A AMELIORER DANS LE MODELE POUR LES POUTRES A FIBRE
  173. SI (errmax > 5.E-2) ;
  174. MESS 'Echec du cas test !' ;
  175. ERRE 5 ;
  176. SINON ;
  177. MESS 'Succes du cas test !' ;
  178. FINSI ;
  179.  
  180.  
  181. FIN ;
  182.  
  183.  
  184.  
  185.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales