Télécharger flam2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : flam2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5.  
  6. ************************************************************************
  7. * COMPARAISON DES CALCULS DE FLAMBAGE D'UN TUBE
  8. * SOUS PRESSION EXTERNE (D'APRèS R.J. GIBERT)
  9. ************************************************************************
  10.  
  11. *------------------- OPTIONS -----------------------
  12.  
  13. * OPTI DIME 3 ELEM QUA4 ECHO 0;
  14. OPTI DIME 3 ELEM QUA4 ;
  15. OPTI EPSI LINEAIRE;
  16. MESS ' COMPARAISON DES CALCULS DE FLAMBAGE';
  17. MESS 'D UN TUBE SOUS PRESSION EXTERNE MODéLISé';
  18. MESS ' AVEC COQ3 ET COQ4';
  19.  
  20. *------------- DEFINITION DU MAILLAGE -----------------
  21.  
  22. P0 = 0. 0. 0.;
  23. P1 = 0. 1. 0.;
  24. P2 = 0. 0. 1.;
  25. P3 = 0.08 0. 0.;
  26. P4 = 0.08 1. 0.;
  27. P5 = 0.08 0. 1.;
  28. C1 = CERC 20 P1 P0 P2;
  29. C2 = CERC 20 P4 P3 P5;
  30. L1 = D 1 P1 P4;
  31. L2 = D 1 P2 P5;
  32. OBJ4 = C1 TRAN 1 P3;
  33. ELIM (OBJ4 ET L1 ET L2 ET C1 ET C2) 1.E-3;
  34. OBJ3 = CHAN 'TRI3' OBJ4;
  35.  
  36. *------------- CONDITIONS AUX LIMITES -------------
  37.  
  38. BC1 = BLOQ C1 'UX' 'RY' 'RZ';
  39. BC2 = BLOQ C2 'UX' 'RY' 'RZ';
  40. * BL1 = BLOQ L1 'UZ' 'RX' 'RY';
  41. * BL2 = BLOQ L2 'UY' 'RX' 'RZ';
  42. BL1 = BLOQ L1 'UZ' 'RX';
  43. BL2 = BLOQ L2 'UY' 'RX';
  44. CL = BC1 ET BC2 ET BL1 ET BL2;
  45.  
  46. *------------- MODELE, MATERIAU, MATRICES -------------
  47.  
  48. * MODELE
  49. MOD3 = MODE OBJ3 MECANIQUE ELASTIQUE ISOTROPE COQ3;
  50. * MOD3 = MODE OBJ3 MECANIQUE ELASTIQUE ISOTROPE DKT;
  51. MOD4 = MODE OBJ4 MECANIQUE ELASTIQUE ISOTROPE COQ4;
  52. *
  53. MOP1 = 'MODE' OBJ3 'CHARGEMENT' 'PRESSION' COQ3 ;
  54. MOP2 = 'MODE' OBJ4 'CHARGEMENT' 'PRESSION' COQ4 ;
  55. *
  56. * MATERIAU
  57. MAT3 = MATE MOD3 YOUN 2.E11 NU 0.3 EPAI 0.05;
  58. MAT4 = MATE MOD4 YOUN 2.E11 NU 0.3 EPAI 0.05;
  59. *
  60. MAP1 = 'MATE' MOP1 'PRES' -1000000. ;
  61. MAP2 = 'MATE' MOP2 'PRES' -1000000. ;
  62. *
  63. MOD3 = MOD3 ET MOP1 ; MAT3 = MAT3 ET MAP1 ;
  64. MOD4 = MOD4 ET MOP2 ; MAT4 = MAT4 ET MAP2 ;
  65. * RIGIDITé
  66. RIG3 = RIGI MOD3 MAT3;
  67. RIG4 = RIGI MOD4 MAT4;
  68.  
  69. *------------- CALCUL ELASTIQUE DES PRECONTRAINTES -------------
  70.  
  71. * CHARGEMENT
  72. PR3 = 'PRES' MOP1 MAP1 ;
  73. PR4 = 'PRES' MOP2 MAP2 ;
  74. *
  75. * CALCUL ELASTIQUE
  76. DEP3 = RESO (RIG3 ET CL) PR3;
  77. DEP4 = RESO (RIG4 ET CL) PR4;
  78.  
  79. * CALCUL DES CONTRAINTES
  80. SIG3 = SIGM MAT3 MOD3 DEP3;
  81. SIG4 = SIGM MAT4 MOD4 DEP4;
  82.  
  83. * MATRICE KS ET KP
  84. CHP3 = MANU 'CHPO' OBJ3 1 'SCAL' -1000000.;
  85. CHP4 = MANU 'CHPO' OBJ4 1 'SCAL' -1000000.;
  86. KS3 = KSIG SIG3 MOD3 mat3 FLAM;
  87. KS4 = KSIG SIG4 MOD4 mat4 FLAM;
  88. KP3 = KP MOP1 CHP3 FLAM;
  89. KP4 = KP MOP2 CHP4 FLAM;
  90. RAI3 = KP3 ET ((-1.)*KS3);
  91. RAI4 = KP4 ET ((-1.)*KS4);
  92. RAS3 = (-1.)*KS3;
  93. RAS4 = (-1.)*KS4;
  94.  
  95. *------------- RECHERCHE DE LA CHARGE CRITIQUE -------------
  96. wshift = 0.4;
  97. *REM: difficulte a converger pour VIBR IRAM pour wshift < 0.2 ...;
  98.  
  99. * calcul via VIBR PROCHE :
  100. * en prenant en compte Ksigma et KP :
  101. * wshift = 0.417;
  102. XMOD3 = VIBR PROCHE (PROG wshift) (RIG3 ET CL) RAI3 'TBAS';
  103. XMOD4 = VIBR PROCHE (PROG wshift) (RIG4 ET CL) RAI4 'TBAS';
  104. * en prenant en compte Ksigma seulement :
  105. * wshift = 0.482;
  106. XMOD3S = VIBR PROCHE (PROG wshift) (RIG3 ET CL) RAS3 'TBAS';
  107. XMOD4S = VIBR PROCHE (PROG wshift) (RIG4 ET CL) RAS4 'TBAS';
  108.  
  109. * calcul via VIBR IRAM :
  110. * en prenant en compte Ksigma et KP :
  111. * opti impi 5;
  112. TMOD3 = VIBR 'IRAM' wshift 1 (RIG3 ET CL) RAI3 'TBAS';
  113. TMOD4 = VIBR 'IRAM' wshift 1 (RIG4 ET CL) RAI4 'TBAS';
  114. * en prenant en compte Ksigma seulement :
  115. TMOD3S = VIBR 'IRAM' wshift 1 (RIG3 ET CL) RAS3 'TBAS';
  116. TMOD4S = VIBR 'IRAM' wshift 1 (RIG4 ET CL) RAS4 'TBAS';
  117. * opti impi 0;
  118.  
  119. * POST-TRAITEMENT :
  120. * solution theorique :
  121. XTH = ((2.E11/(4*(1 - 0.09)))*((0.05/1.)**3))/1000000.;
  122. * solutions calculees :
  123. FF3 = XMOD3.'MODES'. 1 .'FREQUENCE';
  124. FF4 = XMOD4.'MODES'. 1 .'FREQUENCE';
  125. FF3S = XMOD3S.'MODES'. 1 .'FREQUENCE';
  126. FF4S = XMOD4S.'MODES'. 1 .'FREQUENCE';
  127. IFF3 = TMOD3.'MODES'. 1 .'FREQUENCE';
  128. IFF4 = TMOD4.'MODES'. 1 .'FREQUENCE';
  129. IFF3S = TMOD3S.'MODES'. 1 .'FREQUENCE';
  130. IFF4S = TMOD4S.'MODES'. 1 .'FREQUENCE';
  131. X2PI = 2.D0 * PI;
  132. * solutions coq3 :
  133. XCOQ3 = (X2PI * (PROG FF3 IFF3 FF3S IFF3S)) ** 2;
  134. * solutions coq4 :
  135. XCOQ4 = (X2PI * (PROG FF4 IFF4 FF4S IFF4S)) ** 2;
  136. * erreur relative
  137. ERR3 = ABS (100*((extr XCOQ3 (lect 1 2)) - XTH)/XTH);
  138. ERR4 = ABS (100*((extr XCOQ4 (lect 1 2)) - XTH)/XTH);
  139.  
  140. MESS '--------------------------------------------------------------';
  141. MESS '--- VALEUR THEORIQUE : ' XTH;
  142. MESS '--------------------------------------------------------------';
  143. MESS '--- COQ3 : PROCH IRAM';
  144. MESS ' VALEUR CALCULéE AVEC KP : ' (extr XCOQ3 1) (extr XCOQ3 2);
  145. MESS ' ERREUR (%) : ' (extr ERR3 1) (extr ERR3 2) ;
  146. MESS ' VALEUR CALCULéE SANS KP : ' (extr XCOQ3 3) (extr XCOQ3 4);
  147. MESS ' VARIATION (THéORIQUE : 4/3) : '
  148. ((extr XCOQ3 3)/(extr XCOQ3 1)) ((extr XCOQ3 4)/(extr XCOQ3 2)) ;
  149. MESS '--------------------------------------------------------------';
  150. MESS '--- COQ3 : PROCH IRAM';
  151. MESS ' VALEUR CALCULéE AVEC KP : ' (extr XCOQ4 1) (extr XCOQ4 2);
  152. MESS ' ERREUR (%) : ' (extr ERR3 1) (extr ERR3 2) ;
  153. MESS ' VALEUR CALCULéE SANS KP : ' (extr XCOQ4 3) (extr XCOQ4 4);
  154. MESS ' VARIATION (THéORIQUE : 4/3) : '
  155. ((extr XCOQ4 3)/(extr XCOQ4 1)) ((extr XCOQ4 4)/(extr XCOQ4 2)) ;
  156. MESS '--------------------------------------------------------------';
  157.  
  158. *------------------ CODE DE BON FONCTIONNEMENT -------------------------
  159. SI (((MAXI ERR3 'ABS') < 5) ET ((MAXI ERR4 'ABS') < 5));
  160. ERRE 0;
  161. SINON;
  162. ERRE 5;
  163. FINSI;
  164.  
  165. FIN;
  166.  
  167.  
  168.  
  169.  
  170.  
  171.  
  172.  
  173.  
  174.  
  175.  
  176.  
  177.  
  178.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales