Télécharger fibre1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : fibre1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ************************************************************************
  5. ************************************************************************
  6. * CAS TEST fibre1.dgibi *
  7. * Exemple d'utilisation du modèle à fibre *
  8. * *
  9. * Poutre avec un déplacement imposé *
  10. * L=1800 mm *
  11. * *
  12. * D. Combescure - Décembre 2006 *
  13. * Laboratoire DYN - CEA Saclay *
  14. ************************************************************************
  15. ************************************************************************
  16. *
  17. *-----------------------------------------------------------------------
  18. * Géométrie : 200mm x 100mmx L=1500m +2*150.
  19. * Beton: fcj = 25,1 MPa, ftj = 3,08 MPa, Eij = 23GPa
  20. * Aciers :
  21. * 1 lit inférieur 2HA12 + 1 lit supérieur avec 2HA6
  22. * cadres n = 1, fi6e200
  23. *-----------------------------------------------------------------------
  24. *FLAGVISU = VRAI;
  25. *FLAGLONG = VRAI;
  26. *
  27. FLAGVISU = FAUX;
  28. FLAGLONG = FAUX;
  29. *
  30. OPTI DIME 2 ELEM QUA4;
  31.  
  32. *
  33. phi6 = 0.006;
  34. phi8 = 0.008;
  35. phi10 = 0.010;
  36. phi12 = 0.012;
  37. phi13 = 0.013;
  38. phi19 = 0.019;
  39.  
  40. ceq6 = 3.14159*phi6 /4.0;
  41. ceq8 = 3.14159*phi8 /4.0;
  42. ceq10 = 3.14159*phi10 /4.0;
  43. ceq12 = 3.14159*phi12/4.0;
  44. ceq13 = 3.14159*phi13/4.0;
  45. ceq19 = 3.14159*phi19/4.0;
  46.  
  47. sec6 = 3.14159*((phi6**2)/4.);
  48. sec8 = 3.14159*((phi8**2)/4.);
  49. sec10 = 3.14159*((phi10**2)/4.);
  50. sec12 = 3.14159*((phi12**2)/4.);
  51. sec13 = 3.14159*((phi13**2)/4.);
  52. sec19 = 3.14159*((phi19**2)/4.);
  53. *
  54. fyacier = 700.E6;
  55. valtraf = 5.;
  56. *
  57. * Dimensions de la poutre et ferraillage
  58. *
  59. Happui = 1.50;
  60. Htot = Happui +(2.*0.15);
  61. phiacier = phi12;
  62. secacier = sec12;
  63. hgthc = 0.20;
  64. wdthc = 0.10;
  65. epenro = 0.020;
  66. *
  67. *-------------------------------------------------------------------------
  68. * Maillage fibre acier - supérieur
  69. *-------------------------------------------------------------------------
  70. CA1 = (((-0.5)*wdthc) + epenro) ((-0.5*hgthc) + epenro) ;
  71. CA2 = ((0.5*wdthc) - epenro) ((-0.5*hgthc) + epenro) ;
  72. SAINF = CA1 ET CA2;
  73.  
  74. CA3 = (((-0.5)*wdthc) + epenro) ((0.5*hgthc) - epenro) ;
  75. CA4 = ((0.5*wdthc) - epenro) ((0.5*hgthc) - epenro) ;
  76. SASUP = CA3 ET CA4;
  77.  
  78. SACIER = (SAINF COUL ROSE) et (SASUP COUL ROUGE);
  79.  
  80.  
  81. *-----------------------------------------------------------------------
  82. * Description du coffrage poteau et des sections BA correspondantes.
  83. *-----------------------------------------------------------------------
  84.  
  85.  
  86. pbc1 = (-0.5*wdthc) (-0.5*hgthc);
  87. pbc2 = (-0.5*wdthc) ( 0.5*hgthc);
  88. vbc3 = wdthc 0.000;
  89.  
  90. SBET = DROI 8 pbc1 pbc2 TRAN 1 vbc3;
  91.  
  92.  
  93. *-----------------------------------------------------------------------
  94. * Modèles sur maillage sections
  95. *-----------------------------------------------------------------------
  96.  
  97. OPTI DIME 3 elem qua4;
  98.  
  99. *-------------------------- Matériau Béton ----------------------------
  100.  
  101. EBET = 23.0E9 ;
  102. NUBET = 0.25 ;
  103. FCBET = 25.1E6 ;
  104. FTBET = 3.08E6 ;
  105. RBET = 2500.;
  106.  
  107. modBC = MODE sBET MECANIQUE ELASTIQUE PLASTIQUE BETON_BAEL QUAS;
  108. matBC = MATE modBC 'YOUN' EBET 'NU' NUBET 'RHO' 2500. 'FC' FCBET;
  109.  
  110.  
  111. carBC = CARA modBC ALPY .66 ALPZ .66;
  112.  
  113. *-------------------------- Matériau Acier ----------------------------
  114.  
  115. * Acier sans prise en compte de l'adhérence
  116. * Béton: confiné, adhérence: bonne
  117.  
  118. paci = ((2.*sec6) + (2.*sec12))/(hgthc*wdthc);
  119. *
  120. * Modèles, matériaux et caractéristiques
  121.  
  122. MESHFIB = SBET et SAINF et SASUP;
  123.  
  124. *
  125. * Acier PARFAIT_UNI
  126. *
  127. modAINF = MODE SAINF MECANIQUE ELASTIQUE PLASTIQUE PARFAIT_UNI POJS;
  128.  
  129. matAINF = MATE modAINF YOUN 2.0E11 NU 0.3 RHO 7100
  130. 'SECT' sec12 'SIGY' fyacier H (0.01*2.0E11);
  131.  
  132. carAINF = CARA modAINF ALPY .66 ALPZ .66;
  133. *
  134. modASUP = MODE SASUP MECANIQUE ELASTIQUE PLASTIQUE PARFAIT_UNI POJS;
  135.  
  136. matASUP = MATE modASUP YOUN 2.0E11 NU 0.3 RHO 7100
  137. 'SECT' sec6 'SIGY' fyacier H (0.01*2.0E11);
  138.  
  139. carASUP = CARA modASUP ALPY .66 ALPZ .66;
  140. *
  141. *
  142. modstot = modBC ET modAINF et modASUP;
  143.  
  144.  
  145. matstot = matBC ET carBC ET matAINF ET carAINF
  146. ET matASUP ET carASUP;
  147.  
  148.  
  149.  
  150. *-----------------------------------------------------------------------
  151. * Géométrie de la poutre en 3D.
  152. *-----------------------------------------------------------------------
  153.  
  154. OPTI ELEM SEG2;
  155.  
  156. oeil = 0. -10000. 0.;
  157. SI FLAGLONG;
  158. n1 = 3;
  159. n2 = 15;
  160. SINON;
  161. n1 = 1;
  162. n2 = 3;
  163. FINSI;
  164. p0 = 0. 0. 0.;
  165. p1d = (0.5*Happui) 0. 0.;
  166. p2d = (0.5*Htot) 0. 0.;
  167. p1g = (-0.5*Happui) 0. 0.;
  168. p2g = (-0.5*Htot) 0. 0.;
  169.  
  170. Lpoutre = (d n1 p2g p1g) et (d n2 p1g p0)
  171. et (d n2 p0 p1d) et (d n1 p1d p2d);
  172.  
  173.  
  174. *-----------------------------------------------------------------------
  175. * Adaptation des modèles et caractéristiques des matériaux béton et
  176. * acier sur maillage frame: modèles a fibres d'élément de Timoshenko
  177. *-----------------------------------------------------------------------
  178.  
  179. modpout = MODE Lpoutre MECANIQUE ELASTIQUE SECTION
  180. PLASTIQUE SECTION TIMO;
  181. matpout = MATE modpout MODS modsTOT MATS matsTOT VECT (0 1 0);
  182.  
  183.  
  184. * Image 3D de la poutre
  185.  
  186. TITR 'Maillage 3D: Partie courante du poteau' ;
  187. tabtrac = table;
  188. tabtrac.'MATS' = exco matpout MATS;
  189. pot3D = POUT2MAS modpout matpout gauss tabtrac;
  190. *
  191. SI (EGA FLAGVISU VRAI);
  192. opti sort 'Representation3D.inp';
  193. sort avs pot3D (tabtrac.'MATS_3D');
  194. opti trac open;
  195. TRAC (700 -1000 700) (Lpoutre et pot3D);
  196. FINSI;
  197. *
  198. *-----------------------------------------------------------------------
  199. * Conditions aux limites
  200. *-----------------------------------------------------------------------
  201.  
  202. con1 = BLOQ UY RX LPOUTRE;
  203. con2 = BLOQ UZ (p1g et p1d);
  204. con3 = BLOQ UX p0;
  205.  
  206. *-----------------------------------------------------------------------
  207. * Construction de la matrice de rigidité : rigpot
  208. *-----------------------------------------------------------------------
  209.  
  210. rigpout = RIGI modpout matpout ;
  211. rigtot = rigpout et con1 et con2 et con3;
  212.  
  213. *-----------------------------------------------------------------------
  214. * Construction de la matrice de masse et verification de la masse
  215. *-----------------------------------------------------------------------
  216.  
  217. Maspout = MASS modpout matpout ;
  218. ch1 = MANU CHPO lpoutre 1 1.0 UZ ;
  219. mt1 = ch1 * maspout ;
  220. mt = RESU mt1 ;
  221. * mt contient la masse totale
  222.  
  223. *-----------------------------------------------------------------------
  224. * Calcul des fréquences propres du système.
  225. *-----------------------------------------------------------------------
  226. *besoin de def lineaire pour le calcul modal
  227. OPTI EPSI LINEAIRE;
  228. freqsol = VIBR 'PROCHE' (prog 1.) (lect 2)
  229. rigtot maspout ;
  230.  
  231. freq1 = freqsol.MODES.1 .FREQUENCE;
  232. dptm1 = freqsol.MODES.1 .DEFORMEE_MODALE;
  233.  
  234. freq2 = freqsol.MODES.2 .FREQUENCE;
  235. dptm2 = freqsol.MODES.2 .DEFORMEE_MODALE;
  236.  
  237. df0 = DEFO lpoutre dptm1 0.0 JAUN ;
  238. df1 = DEFO lpoutre dptm1 0.5 BLEU ;
  239. df2 = DEFO lpoutre dptm2 0.5 BLEU ;
  240. tabtrac = table;
  241. tabtrac.DEPLACEMENTS = TABLE;
  242. tabtrac.DEPLACEMENTS . 1 = dptm1;
  243. tabtrac.DEPLACEMENTS . 2 = dptm2;
  244.  
  245. mesh3D = pout2mas modpout matpout gauss tabtrac;
  246.  
  247. df3D1 = defo mesh3D
  248. (tabtrac.DEPLACEMENTS_3D . 1) 0.5;
  249. df3D2 = defo mesh3D
  250. (tabtrac.DEPLACEMENTS_3D . 2) 0.5;
  251. *
  252. SI (EGA FLAGVISU VRAI);
  253. TITR (chain 'Mode 1 - Frequence' freq1 'Hz');
  254. TRAC oeil (df0 ET df1 et df3D1) ;
  255. TITR (chain 'Mode 2 - Frequence' freq2 'Hz');
  256. TRAC oeil (df0 ET df2 et dF3D2) ;
  257. FINSI;
  258. *
  259.  
  260. **********************************************
  261. *
  262. * Chargement statique à déplacement imposé
  263. *
  264. *********************************************
  265. * et on repasse en def quadratique pour le calcul pasapas...
  266. OPTI EPSI QUADRATIQUE;
  267. * Déplacement imposé vers le bas
  268. * Pour L=1.80m
  269. *
  270. dmax = -0.010 ;
  271. *
  272. dp = -0.0002 ;
  273. ld6 = PROG 0. PAS dp dmax;
  274. nt6 = dime ld6 ;
  275. MESS 'Nombre de pas de calcul = ' nt6 ;
  276. tm6 = nt6 - 1.0 ;
  277. lt6 = prog 0.0 pas 1.0 tm6;
  278. titr 'Déplacement en tête, nombre de pas =' nt6 ;
  279. evpzm = EVOL MANU 'Temps' lt6 'Dépl(mm)' ld6 ;
  280.  
  281. * Déplacement imposé
  282.  
  283. upzm = BLOQ UZ p0;
  284. dpzm = DEPI upzm 1.0 ;
  285. chpzm = CHAR DIMP dpzm evpzm ;
  286.  
  287. *-----------------------------------------------------------------------
  288. * Calcul statique - chargement monotone
  289. *-----------------------------------------------------------------------
  290. SI (EGA FLAGLONG VRAI);
  291. tcalc = PROG 0. pas 1.0 (ENTI tm6) ;
  292. SINON;
  293. tcalc = PROG 0. pas 1.0 2.0 ;
  294. FINSI;
  295. tsauv = tcalc ;
  296. *
  297. TAB1 = TABLE;
  298. TAB1 . BLOCAGES_MECANIQUES = con1 et con2 et con3 et
  299. upzm;
  300. TAB1 . MODELE = modpout;
  301. TAB1 . CARACTERISTIQUES = matpout;
  302. TAB1 . CHARGEMENT = chpzm ;
  303. TAB1 . TEMPS_CALCULES = tcalc ;
  304. TAB1 . TEMPS_SAUVES = tsauv ;
  305. TAB1 . PRECISION = 1.E-6 ;
  306. TAB1. MAXDEFOR = 1.E-5;
  307. TAB1 . MOVA = RIEN ;
  308. TAB1 . MAXITERATION = 150 ;
  309.  
  310. PASAPAS TAB1;
  311.  
  312.  
  313. N_REP = (DIME (TAB1.'TEMPS')) - 1 ;
  314. T_REP = TAB1.'TEMPS'.N_REP ;
  315. LIST N_REP;
  316. LIST T_REP;
  317.  
  318.  
  319. *-----------------------------------------------------------------------
  320. * Post-Traitement
  321. *-----------------------------------------------------------------------
  322.  
  323. dep0 = TAB1.'DEPLACEMENTS';
  324. tim0 = tab1. TEMPS;
  325. sig0 = TAB1.'CONTRAINTES';
  326. var0 = TAB1.'VARIABLES_INTERNES';
  327. ind0 = INDE dep0;
  328. time = PROG (tim0 . 0);
  329.  
  330. uzp0 = PROG 0.;
  331. fzp0 = PROG 0.;
  332.  
  333. ep1 = prog 0.;
  334. si1 = prog 0.;
  335. nn = (('DIME' ind0) - 1);
  336.  
  337. j = 1;
  338. REPE lab1 (('DIME' ind0) - 1);
  339. j = j + 1;
  340. indj = ind0.j;
  341. depj = dep0.indj;
  342. sigj = sig0.indj;
  343. epsj = epsi depj modpout matpout;
  344. vecj = bsigma sigj modpout matpout;
  345. time = time et (prog tim0. &lab1);
  346. uzp0 = uzp0 ET (PROG (EXTR depj 'UZ' p0));
  347. fzp0 = fzp0 ET (PROG (EXTR vecj 'FZ' p0));
  348. FIN lab1;
  349. *
  350. evtiuz = evol manu 'TEMPS(s)' time
  351. 'Depl (mm)' ((1000.)*uzp0);
  352. evtifz = evol manu 'TEMPS(s)' time
  353. 'Force (kN)' ((0.001)*fzp0);
  354. *
  355. SI (EGA FLAGVISU VRAI);
  356. TITR 'Deplacement p0' ;
  357. dess evtiuz;
  358. TITRE 'Force';
  359. dess evtifz;
  360. FINSI;
  361. *
  362. tabtrac = table;
  363. tabtrac. 'DEPLACEMENTS' = table;
  364. tabtrac. 'VAIS' = table;
  365. tabtrac. 'VONS' = table;
  366. nlab2 = entier ((('DIME' ind0))) - 1;
  367. depj = dep0.nlab2;
  368. varj = var0.nlab2;
  369. tabtrac. 'DEPLACEMENTS' . 1 =depj;
  370. tabtrac. 'VAIS' . 1 = exco varj 'VAIS';
  371. tabtrac. 'VONS' . 1 = exco varj 'VONS';
  372. deft = defo Lpoutre depj 100;
  373. mesh3D = pout2mas modpout matpout gauss tabtrac;
  374. *
  375. *
  376. * Analyse des contraintes et déformations dans les fibres
  377. *
  378. SI (EGA FLAGVISU VRAI);
  379. nn = DIME tabtrac.deplacements_3D;
  380. opti trac open;
  381. trac (defo mesh3D (tabtrac.deplacements_3D. nn));
  382. trac mesh3D
  383. (exco (tabtrac.VONS_3D. nn) smxx);
  384. list (maxi (exco (tabtrac.VONS_3D. nn) smxx));
  385. list (mini (exco (tabtrac.VONS_3D. nn) smxx));
  386. *
  387. * Exportation vers PARAVIEW via AVS
  388. *
  389. opti sort 'visualisationSMXX3D.inp';
  390. sort avs (mesh3D coul vert)
  391. ((tabtrac.deplacements_3D. nn) et (tabtrac.VAIS_3D. nn) et
  392. (tabtrac.VONS_3D. nn));;
  393. FINSI;
  394. *
  395. FIN;
  396.  
  397.  
  398.  
  399.  
  400.  
  401.  
  402.  
  403.  
  404.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales