Télécharger fiabi1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : fiabi1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test fiabi1.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. *
  7. * CAS TEST DU 01/04/10 PROVENANCE : TEST
  8. SAUT PAGE;
  9. *
  10. *******************************************************
  11. * *
  12. * TEST FIABI1 *
  13. * *
  14. * TIGE EN TRACTION - Méthodes F.O.R.M./QUADRATURE *
  15. * *
  16. * *
  17. * La tige est soumise à une traction P. L'aire *
  18. * de la section droite est A. La limite élastique *
  19. * de la résistance est FY. *
  20. * *
  21. * On se propose de calculer la probabilité de *
  22. * défaillance de la tige à la rège de dimensionnement*
  23. * FY * A - P > 0. *
  24. * *
  25. * Dans ce premier test, on ne s'appuie sur aucun *
  26. * maillage. l'objectif est de comparer deux méthodes *
  27. * de fiabilité (F.O.R.M.) et de sensibilité *
  28. * (QUADRATURE), en terme de précision. *
  29. * *
  30. *******************************************************
  31. *
  32. *Variables testées et leur loi de distribution:
  33.  
  34. * Fy :limite élastique de l'acier ( MPa )
  35. * Normale (272.72E6 , 16.36E6)
  36. * P : traction appliquée ( MN )
  37. * Normale (70E6 , 15E6)
  38. * A est tout d'abord fixée (m²):
  39. A = 0.42 ;
  40.  
  41. *======================================================*
  42. *======================================================*
  43. * CALCUL NUMERIQUE *
  44. *======================================================*
  45. *======================================================*
  46.  
  47. OPTI ECHO 0 ;
  48. *Données préalables:
  49.  
  50. MESS 'Le domaine de défaillance est défini par :';
  51. MESS 'FY * A - P > 0';
  52.  
  53. *Ecrivons la densité conjointe de probabilité de la loi
  54. *normale centrée réduite comme une évolution:
  55.  
  56. Mfy = 272.72E6; Sfy = 16.36E6;
  57. Mp = 70.E6; Sp = 15.E6;
  58. A = 0.42 ;
  59.  
  60. * D'ou l'indice de fiabilité
  61. *
  62.  
  63. bta = (((A*Mfy)-Mp)/((((A*Sfy)**2)+(Sp**2))**0.5));
  64. MR =A * Mfy; MS=MP; SR= A * Sfy; SS=SP;
  65.  
  66. * On intègre sur le domaine :
  67.  
  68. Lbta = PROG ((-1)*100) PAS ((100-bta)/100000) ((-1)*bta);
  69. LDens = ((EXP(0.5*(-1)*(Lbta**2))) / ((2*PI)**0.5));
  70. LFa = EVOL MANU 'X' Lbta 'DENSITE' LDens;
  71.  
  72. *L'opérateur SOMM calcule l'intégrale des ordonnées
  73. *de cette densité sur ses abscisses par la méthode
  74. *des trapèzes.
  75.  
  76. PfN =(INTG LFa ('ABSO')) ;
  77. PfN =EXTR PfN 1;
  78.  
  79. *======================================================*
  80. *======================================================*
  81. * Méthode de fiabilité : *
  82. * APPROXIMATION AU PREMIER ORDRE DE L'ÉTAT-LIMITE *
  83. * (First Order Reliability Method) *
  84. *======================================================*
  85. *======================================================*
  86.  
  87. DEBPROC PERF lr1*listreel;
  88. Fy=extr 1 lr1;
  89. P=extr 2 lr1;
  90. *A = O.42;
  91. limit = ((Fy*0.42) - P)/1e6;
  92. FINPROC limit;
  93. *
  94. DEBPROC intmci lr1*listreel;
  95. txv0=table;
  96. h1=0.1;
  97. lrx1=prog 0 0 ;
  98. lr2=prog;
  99. nbva=dime lr1;
  100.  
  101. REPETER bou1 nbva;
  102. lrx2=lrx1 * 1.;
  103. remp lrx2 &bou1 h1;
  104. * list lrx2;
  105. lr2 =lr2 et (prog ((PERF (lr1 - lrx2)) - (PERF (lr1 + lrx2))/(-2*h1)));
  106. FIN bou1;
  107.  
  108. FINPROC lr2;
  109. *
  110. tab=table;
  111. *tab . form = 'mexcel';
  112. tab . param_optimisation =table;
  113. tab . param_optimisation . methode = sta;
  114. tab . param_optimisation . t0 =0.8;
  115. tab . param_optimisation . s0 =0.3;
  116. tab . param_optimisation . vxmin =prog 2E8 5E7;
  117. tab . param_optimisation . vxmax =prog 3E8 9E9 ;
  118. tab . param_optimisation . vcmax = prog 0;
  119. tab . param_optimisation . maxiteration= 100;
  120. tab . noms_des_variables = mots xFy xP;
  121. tab . max_iteration = 100;
  122.  
  123. tab . fct_limite=table;
  124. tab . fct_limite . 1 = 'PERF';
  125. tab . grad_fct_limite=table;
  126. tab . grad_fct_limite . 1 = 'INTMCI';
  127. tab . param_va =table;
  128. tab . param_va . 1 =table;
  129. tab . param_va . 2 =table;
  130.  
  131. tab . param_va . 1 . typva =loi_normale;
  132. tab . param_va . 2 . typva =loi_normale;
  133.  
  134. tab . param_va . 1 . MOYENNE = 272.72E6;
  135. tab . param_va . 1 . ECART_TYPE = 16.36E6;
  136. tab . param_va . 2 . MOYENNE = 70E6;
  137. tab . param_va . 2 . ECART_TYPE = 15E6;
  138.  
  139. tab . points_initiaux = table;
  140. tab . points_initiaux . 1 = prog 250E6 70E6;
  141. tab . resu=table;
  142.  
  143. *appel a fiabilite
  144. *list mexcel;
  145.  
  146. fiabili tab;
  147. list tab . resu . 1 . indfiab;
  148. list tab . resu . 1 . 'XFY ';
  149. list tab . resu . 1 . 'XP ';
  150.  
  151. *Calcul de la probabilité de défaillance en
  152. *fonction de l'indice de fiabilité BETA
  153.  
  154. BET = (extr (tab . resu . 1 . indfiab)
  155. (dime(tab . resu . 1 . indfiab)));
  156.  
  157. LBETA = PROG ((-1)*10) PAS ((100-BET)/1000) ((-1)*BET);
  158. LDensF = ((EXP(0.5*(-1)*(LBETA**2))) / ((2*PI)**0.5));
  159. LFF = EVOL MANU 'X' LBETA 'DENSITE' LDensF;
  160. *dess LFF;
  161. PfF =INTG LFF ('ABSO') ;
  162. PfF =EXTR PfF 1;
  163.  
  164. ERFN = (ABS (PfN - PfF))/(MAXI (PROG PfN PfF))*100;
  165.  
  166. *======================================================*
  167. *======================================================*
  168. * Méthode de sensibilité : *
  169. * APPROXIMATION PAR QUADRATURE *
  170. *======================================================*
  171. *======================================================*
  172.  
  173. *================================
  174. *CALCULS DES POINTS D'INTEGRATION
  175. *================================
  176.  
  177. NP_FY = 4;
  178. NP_P = 4;
  179.  
  180. TAB_FY = QUADRATU 'NORM' 272.72E6 16.36E6 NP_FY ;
  181. TAB_P = QUADRATU 'NORM' 70.E6 15.E6 NP_P;
  182.  
  183. *=====================
  184. *DEFINITION DES TABLES
  185. *=====================
  186.  
  187. TABLIM = TABLE;
  188. TabGLO = TABLE;
  189. ITEM = 0 ;
  190. REPE Bc_FY NP_FY;
  191. REPE Bc_P NP_P;
  192.  
  193. ITEM = ITEM + 1 ;
  194. TabGLO .ITEM = TABLE;
  195. TabGLO .ITEM. 'POIDS' =
  196. TAB_FY .&Bc_FY. 'POIDS' *
  197. TAB_P .&Bc_P. 'POIDS' ;
  198.  
  199. TabGLO .ITEM. 'FY' = TAB_FY .&Bc_FY. 'POINT';
  200. TabGLO .ITEM. 'P' = TAB_P .&Bc_P. 'POINT';
  201.  
  202. FIN Bc_P;
  203. FIN Bc_FY;
  204.  
  205. *=================================================
  206. * PROCEDURE DEFINISSANT LA FONCTION DE PERFORMANCE
  207. *=================================================
  208.  
  209. DEBPROC PERF FY P;
  210. A = 0.42;
  211. G = ((FY*A) - P);
  212. FINPROC G;
  213.  
  214. list cas;
  215. *=========================================
  216. * CALCUL DE LA PROBABILITE DE DEFAILLANCE
  217. *=========================================
  218.  
  219.  
  220. N = DIME TABglo;
  221. list N;
  222. TabRES = TABLE;
  223. ITEM = 0;
  224. REPE BOUC N;
  225. *Mess &bouc ;
  226. TabRES .&BOUC = TABLE;
  227. TabRES .&BOUC. POIDS = TABGLO .&BOUC. POIDS;
  228. TabRES .&BOUC. G = PERF TABglo .&BOUC. FY
  229. TABglo .&BOUC. P;
  230. FIN BOUC;
  231.  
  232. TABG = table;
  233.  
  234. REPE BOUC N;
  235.  
  236. TABG .&BOUC = table;
  237. TABG .&BOUC. POIDS = TabRES .&BOUC. POIDS;
  238. TABG .&BOUC. POINT = TabRES .&BOUC. G;
  239.  
  240. FIN BOUC;
  241.  
  242. *Calcul des moments
  243.  
  244. mog sig syg apg = PARASTAT TABG;
  245.  
  246. *Calcul de Pf
  247.  
  248. PfQ = PROB mog sig syg apg 0.;
  249. betaQ = INDIBETA 0. 7. pfQ;
  250.  
  251. ERQN = (ABS(PfN - PfQ))/(MAXI (PROG PfN PfQ))*100;
  252.  
  253.  
  254. *=======================================================*
  255. * Affichage des resultats *
  256. *=======================================================*
  257. *
  258.  
  259. OPTI ECHO 1 ;
  260. MESS 'RESULTATS POUR UNE LOI NORMALE';
  261. MESS '******************************';
  262. MESS ' VALEURS PAR INTEGRATION NUMERIQUE ';
  263. MESS ' --------------------------------- ';
  264. MESS ' L indice de fiabilite est : ' bta;
  265. MESS ' La probabilite associee est :'PFN;
  266. MESS ' RESULTATS TEST F.O.R.M. ';
  267. MESS ' ----------------------- ';
  268. MESS ' L indice de fiabilite est : ' BET;
  269. MESS ' La probabilite associee est :' PFF;
  270. MESS ' Soit un ecart de :' ERFN '%';
  271. MESS ' RESULTATS TEST QUADRATURE ';
  272. MESS ' ------------------------- ';
  273. MESS ' L indice de fiabilite est : ' betaQ;
  274. MESS ' La probabilité associee est :' PFQ;
  275. MESS ' Soit un ecart de :' ERQN '%';
  276.  
  277. *========================================================*
  278. * code fonctionnement *
  279. *========================================================*
  280. *
  281. * L'écart maximum entre valeurs approchées et numérique
  282. * doit etre inferieure a 5%.
  283. *
  284. SAUT 2 LIGNE;
  285. SI ((ERFN <EG 5) OU (ERQN <EG 5)) ;
  286. ERRE 0;
  287. SINON;
  288. ERRE 5;
  289. FINSI;
  290. *
  291. TEMPS;
  292. *
  293. FIN;
  294.  
  295.  
  296.  
  297.  
  298.  
  299.  
  300.  
  301.  
  302.  
  303.  
  304.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales