Télécharger faceaface3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : faceaface3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. *......../........./........./........./........./........./........./72
  7. * test de calcul FACE a FACE avec PASAPAS
  8. * Echange thermique entre deux faces proches (L/e>>10) ,
  9. * en convection, en rayonnement
  10. * et mixte rayonnement plus convection
  11. * Philippe YALA le 14/12/09
  12. *
  13. * VERSION 3D de faceaface.dgibi
  14. ************************************************************************
  15. OPTI DIME 3 ELEM CUB8 ;
  16. ************************************************************************
  17. * CALCUL EN GEOMETRIE 3D
  18. * deux cylindres coaxiaux avec convection externe
  19. * 1 calcul avec CONV dans le jeu ; H=Cd_Air/Ep
  20. * 2 calcul avec RAYO dans le jeu
  21. * 3 calcul complet avec CONV et RAYO
  22. ************************************************************************
  23. *DONNEES GEOMETRIQUES
  24. * rayon arbre
  25. rarbre = 10.e-3 ;
  26. * jeu type H7 g6 ; soit en micron : +15/0 -5/-14
  27. jeumin = 0. + 5.e-6 ;
  28. jeumax = 15.e-6 + 14.e-6 ;
  29. graph= mot 'N';
  30. jeu = jeumax ;
  31. * ou jeu = jeumin ;
  32.  
  33. * epaisseur alesage
  34. epal = 5.e-3 ;
  35. * hauteur
  36. haut = 5.e-3 ;
  37. ************************************************************************
  38. * MAILLAGE presque sans discretisation du jeu ( noeud double)
  39. P0 = 0. 0. 0.;
  40. P1 = 0. haut 0.;
  41. laxe = P0 droit P1 DINI 0.002 DFIN 0.001 ;
  42. arbre = (laxe trans (rarbre 0. 0.) DINI 0.002 DFIN 0.001 ) coul vert ;
  43. lor1 lhaut lcot1 lbas = cote arbre ;
  44. EPS = 1.e-5 ;
  45. * Remarque ne fonctionne pas avec EPS=0. pour RAYO
  46. *lcot2 = lcot1 plus ( EPS 0. 0.) ;
  47. lcot2 = lcot1 plus ( EPS*10 0. 0.) ;
  48. alesage = ( lcot2 trans ( epal 0. 0.) DINI 0.001 DFIN 0.002 )
  49. coul rouge ;
  50. lor2 lhaut2 lcotext lbas2 = cote alesage ;
  51.  
  52. arbre = VOLU arbre 60 ROTA -360 (0. 0. 0.) (0. -1. 0.) ;
  53. alesage = VOLU alesage 60 ROTA -360 (0. 0. 0.) (0. -1. 0.) ;
  54.  
  55. ARBRE = ARBRE COUL VERT ;
  56. ALESAGE = ALESAGE COUL ROUG;
  57.  
  58. elim arbre 0.000001 ;
  59. elim alesage 0.000001 ;
  60.  
  61. arbre = REGENERER ARBRE ;
  62.  
  63. tot = arbre et alesage ;
  64. si ( ega graph 'O');
  65. trac CACHE TOT face;
  66. FINSI ;
  67. LCOTEXT = LCOTEXT ROTA 60 -360 (0. 0. 0.) (0. -1. 0.) ;
  68. ELIM ( ALESAGE ET LCOTEXT) 0.000001 ;
  69.  
  70.  
  71.  
  72.  
  73. ************************************************************************
  74. *DONNEES THERMIQUES
  75. MESS 'DONNEES THERMIQUES';
  76. TK = 273.15 ;MESS 'Zero °C' TK ;
  77. EMA = 0.8 ;MESS 'Emissivité ARBRE' EMA ;
  78. EMB = 0.9 ;MESS 'Emissivité ALESAGE cote interne' EMB ;
  79. EMC = 1.0 ;MESS 'Emissivité ALESAGE cote externe ' EMC ;
  80. TAMB = 30.0 ;MESS 'Température ambiance' TAMB '°C' ;
  81. TINI = 500.0 ;MESS 'Température initiale' TINI '°C' ;
  82. TAMB = TAMB + TK ; TINI = TINI +TK ;
  83.  
  84. ************************************************************************
  85. *MODELISISATION THERMIQUES
  86. *conduction
  87. MCD1 = MODE ARBRE THERMIQUE ISOTROPE ;
  88. MCD2 = MODE ALESAGE THERMIQUE ISOTROPE ;
  89. MAT1 = MATE MCD1 'K' 15.0 'C' 500.0 'RHO' 7800.0 ;
  90. MAT2 = MATE MCD2 'K' 132. 'C' 945.0 'RHO' 2670.0 ;
  91. ************************************************************************
  92. * convection extérieure
  93. MOHEX = MODE lcotext 'THERMIQUE' 'CONVECTION' ;
  94. MAHEX = MATE MOHEX 'H' EMC ;
  95. TCHA = PROG 0. 1.e10 ;
  96. PINC = PROG 1. 1. ;
  97. MEVOLTE = EVOL 'MANU' 'TEMP' TCHA 'AMP' PINC ;
  98. CH_TE = 'MANU' 'CHPO' lcotext 1 'T' TAMB ;
  99. CHAT = CHAR 'TECO' CH_TE MEVOLTE ;
  100. ************************************************************************
  101. * initialisation en temperature
  102. TEM0 = MANU CHPO TOT 1 T TINI ;
  103. ************************************************************************
  104. * Temps calculés
  105. PTPS1 = prog 0. 0.01 0.02 0.05 0.1 0.2 0.5 1. 2. 4. 6. pas 2. 100. ;
  106. PTPS2 = prog 20. pas 5. 50. pas 10. 100. pas 20. 600. ;
  107. PTPS = PTPS1 ;
  108. *ptps= prog 0. 0.01 0.02 0.05 ;
  109. * Temps sauvés
  110. PTPSS = prog 0. pas 4. 100. ;
  111. ************************************************************************
  112.  
  113. * Convection bilatérale (face a face)
  114. *-------------------------------
  115. cont1 = enve arbre ;
  116. elim (cont1 et arbre) eps ;
  117. PT1 = point cont1 cyli ( 0 0 0 ) (0 -1. 0 ) (rarbre 0. 0.) 0.0001 ;
  118. lcot1 = elem cont1 appu strict PT1 ;
  119. elim (lcot1 et cont1 et arbre) 0.0001 ;
  120. cont2 = enve alesage ;
  121. elim (cont2 et alesage) eps ;
  122. PT2 = point cont2 cyli ( 0 0 0 ) (0 -1. 0)
  123. ((rarbre+(EPS*10)) 0. 0.) 0.0001 ;
  124. lcot2 = elem cont2 appu strict PT2 ;
  125. elim (lcot2 et cont2 et alesage) 0.0001 ;
  126. rac12 = LIAI 1.1e-4 lcot1 lcot2 ;
  127.  
  128. mcv12 = MODE rac12 thermique CONVECTION ;
  129. h12 = 0.004 /jeu ;
  130. ma12 = MATE mcv12 'H' h12 ;
  131.  
  132.  
  133. *****************ASSEMBLAGE DES MATÉRIAUX ET DES MODÈLES****************
  134. *CALCUL source + convection face a face + rayo. ext.
  135.  
  136. MODU1 = MCD1 et MCD2 et MOHEX et mcv12 ;
  137. MATU1 = MAT1 et MAT2 et MAHEX et ma12;
  138.  
  139. ********************CRÉATION DE LA TABLE POUR PASAPAS*******************
  140. TAPAS = TABLE ;
  141. TAPAS.CELSIUS = FAUX ;
  142. TAPAS.CRITERE = 1E-4 ;
  143. TAPAS.MODELE = MODU1 ;
  144. TAPAS.CARACTERISTIQUES = MATU1 ;
  145. TAPAS.TEMPERATURES = TABLE ;
  146. TAPAS.TEMPERATURES . 0 = TEM0 ;
  147. TAPAS.CHARGEMENT = CHAT ;
  148. TAPAS.PROCEDURE_THERMIQUE = DUPONT ;
  149. *TAPAS.PROCEDURE_THERMIQUE = NONLINEAIRE ;
  150. *TAPAS.RELAXATION_THETA = 0.6 ;
  151. TAPAS.TEMPS_CALCULES = PTPS ;
  152. TAPAS.TEMPS_SAUVES = PTPSS ;
  153.  
  154.  
  155. ************************************************************************
  156. PASAPAS TAPAS ;
  157.  
  158. CTK1 = TAPAS.TEMPERATURES.((DIME PTPSS) - 1 ) ;
  159. CTC1 = CTK1 - TK ;
  160. titre NOMCAL '-Isothermes ' ;
  161. *TRAC CTC1 TOT ;
  162. * suivi de la temperature
  163. TEMP1 = PROG ;TEMP2 = PROG ;
  164. ITER = 0 ;
  165. NBT1 = (DIME PTPSS) ;
  166. REPETER BCL1 NBT1 ;
  167. TP1 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) arbre ;
  168. T1 = MAXIMUM ( TP1 ) - TK ;
  169. TEMP1 = INSERER TEMP1 &BCL1 T1 ;
  170. TP2 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) alesage ;
  171. T2 = MAXIMUM ( TP2 ) - TK ;
  172. TEMP2 = INSERER TEMP2 &BCL1 T2 ;
  173. ITER = ITER + 1;
  174. FIN BCL1 ;
  175.  
  176. TITRE ' EVOLUTION DES TEMPERATURES' ;
  177. EV1 = EVOL VERT MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP1 ;
  178. EV2 = EVOL VERT MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP2 ;
  179. TABDES = TABLE; TABDES.'TITRE' = TABLE ;
  180. TABDES.1 = 'MARQ TRIA' ;TABDES.'TITRE'. 1 = 'Arbre_Conv' ;
  181. TABDES.2 = 'MARQ CROI' ;TABDES.'TITRE'. 2 = 'Alesage_Conv' ;
  182. *DESS (EV1 ET EV2 ) TABDES 'MIMA' 'LEGE' ;
  183. * opti donn 5;
  184. ************************************************************************
  185. * CALCUL 2 jeu en rayonnement pur
  186. ************************************************************************
  187. * RAYONNEMENT bilatérale (face a face)
  188. *-----------------------------------------------------------------------
  189. geor = diff ( rac12 chan ligne ) (CHAN LIGN (lcot1 et lcot2)) ;
  190. *list geor ;
  191. *trac geor ;
  192. mcv12r = MODE RAC12 THERMIQUE 'CONVECTION' ;
  193.  
  194. mora1 = mode lcot1 THERMIQUE 'RAYONNEMENT'
  195. fac_a_fac lcot1 lcot2 geor mcv12r CONS 'FACAFAC1';
  196. mora2 = mode lcot2 THERMIQUE 'RAYONNEMENT'
  197. fac_a_fac lcot1 lcot2 geor mcv12r CONS 'FACAFAC1';
  198.  
  199. MORA12 = mora1 et mora2 ;
  200.  
  201.  
  202.  
  203. mar1 = MATE mora1 'EMIS' EMA ;
  204. mar2 = MATE mora2 'EMIS' EMB ;
  205. MAR12 = mar1 et mar2 ;
  206.  
  207. *****************ASSEMBLAGE DES MATÉRIAUX ET DES MODÈLES***************
  208.  
  209. *CALCUL source + rayonnement face a face + rayo. ext.
  210.  
  211. MODU2 = MCD1 et MCD2 et MOHEX et mora12;
  212. MATU2 = MAT1 et MAT2 et MAHEX et MAR12 ;
  213. ******************* MODIFICATION DE LA TABLE POUR PASAPAS *************
  214. TAPAS = TABLE ;
  215. TAPAS.CELSIUS = FAUX ;
  216. TAPAS.CRITERE = 1E-4 ;
  217. TAPAS.MODELE = MODU2;
  218. TAPAS.CARACTERISTIQUES = MATU2 ;
  219. TAPAS.TEMPERATURES = TABLE ;
  220. TAPAS.TEMPERATURES . 0 = TEM0 ;
  221. TAPAS.CHARGEMENT = CHAT ;
  222. TAPAS.PROCEDURE_THERMIQUE = DUPONT ;
  223. TAPAS.TEMPS_CALCULES = PTPS ;
  224. TAPAS.TEMPS_SAUVES = PTPSS ;
  225. ***********************************************************************
  226. PASAPAS TAPAS ;
  227. *opti donn 5;
  228. CTK1 = TAPAS.TEMPERATURES.((DIME PTPSS) - 1) ;
  229. CTC1 = CTK1 - TK ;
  230. titre NOMCAL '-Isothermes - ' ;
  231. *TRAC CTC1 TOT ;
  232. * suivi de la temperature
  233. TEMP1 = PROG ;TEMP2 = PROG ;
  234. ITER = 0 ;
  235. NBT1 = (DIME PTPSS) ;
  236. REPETER BCL1 NBT1 ;
  237. TP1 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) arbre ;
  238. T1 = MAXIMUM ( TP1 ) - TK ;
  239. TEMP1 = INSERER TEMP1 &BCL1 T1 ;
  240. TP2 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) alesage ;
  241. T2 = MAXIMUM ( TP2 ) - TK ;
  242. TEMP2 = INSERER TEMP2 &BCL1 T2 ;
  243. ITER = ITER + 1;
  244. FIN BCL1 ;
  245.  
  246. TITRE ' EVOLUTION DES TEMPERATURES' ;
  247. EV3 = EVOL BLEU MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP1 ;
  248. EV4 = EVOL BLEU MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP2 ;
  249.  
  250. TABDES.3 = 'MARQ TRIA' ;TABDES.'TITRE'. 3 = 'Arbre_Rayo' ;
  251. TABDES.4 = 'MARQ CROI' ;TABDES.'TITRE'. 4 = 'Alesage_Rayo' ;
  252. *DESS (EV1 ET EV2 et EV3 ET EV4 ) TABDES 'MIMA' 'LEGE' ;
  253. *opti donn 5;
  254. ************************************************************************
  255. * CALCUL 3 jeu en convection et rayonnement
  256. ************************************************************************
  257. *****************ASSEMBLAGE DES MATÉRIAUX ET DES MODÈLES***************
  258. MODU3 = MODU1 et mora12;
  259. MATU3 = MATU1 et MAR12 ;
  260. ******************* MODIFICATION DE LA TABLE POUR PASAPAS *************
  261. TAPAS = TABLE ;
  262. TAPAS.CELSIUS = FAUX ;
  263. TAPAS.CRITERE = 1E-4 ;
  264. TAPAS.MODELE = MODU3 ;
  265. TAPAS.CARACTERISTIQUES = MATU3 ;
  266. TAPAS.TEMPERATURES = TABLE ;
  267. TAPAS.TEMPERATURES . 0 = TEM0 ;
  268. TAPAS.CHARGEMENT = CHAT ;
  269. TAPAS.PROCEDURE_THERMIQUE = DUPONT ;
  270. TAPAS.TEMPS_CALCULES = PTPS ;
  271. TAPAS.TEMPS_SAUVES = PTPSS ;
  272. TAPAS.RAYONNEMENT = TABLE ;
  273. ****************************************ª****j**(**********************
  274. PASAPAS TAPAS ;
  275.  
  276. CTK1 = TAPAS.TEMPERATURES.((DIME PTPSS) - 1) ;
  277. CTC1 = CTK1 - TK ;
  278. titre NOMCAL '-Isothermes - ' ;
  279. *TRAC CTC1 TOT ;
  280. * suivi de la temperature
  281. TEMP1 = PROG ;TEMP2 = PROG ;
  282. ITER = 0 ;
  283. NBT1 = (DIME PTPSS) ;
  284. REPETER BCL1 NBT1 ;
  285. TP1 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) arbre ;
  286. T1 = MAXIMUM ( TP1 ) - TK ;
  287. TEMP1 = INSERER TEMP1 &BCL1 T1 ;
  288. TP2 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) alesage ;
  289. T2 = MAXIMUM ( TP2 ) - TK ;
  290. TEMP2 = INSERER TEMP2 &BCL1 T2 ;
  291. ITER = ITER + 1;
  292. FIN BCL1 ;
  293. TITRE ' EVOLUTION DES TEMPERATURES' ;
  294. EV5 = EVOL ROUG MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP1 ;
  295. EV6 = EVOL ROUG MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP2 ;
  296. TABDES.5 = 'MARQ TRIA' ;TABDES.'TITRE'. 5 = 'Arbre_Conv&Rayo' ;
  297. TABDES.6 = 'MARQ CROI' ;TABDES.'TITRE'. 6 = 'Alesage_Conv&Rayo' ;
  298. si ( ega graph 'O');
  299. DESS (EV1 ET EV2 et EV3 ET EV4 et EV5 ET EV6) TABDES 'MIMA' 'LEGE' ;
  300. finsi;
  301. aa1 = extr ev1 ordo;aa1 = mini aa1 ;er1= abs(aa1 - 499.07);
  302. aa2 = extr ev2 ordo;aa2 = mini aa2 ;er2= abs(aa2 - 496.77);
  303. aa3= extr ev3 ordo; aa3 = mini aa3 ;er3= abs(aa3 - 499.38);
  304. aa4= extr ev4 ordo; aa4 = mini aa4 ;er4= abs(aa4 - 496.37);
  305. aa5= extr ev5 ordo; aa5 = mini aa5 ;er5= abs(aa5 - 498.83);
  306. aa6= extr ev6 ordo; aa6 = mini aa6 ;er6= abs(aa6 - 497.08);
  307.  
  308.  
  309. mess aa1 aa2 aa3 aa4 aa5 aa6 ;
  310. mess er1 er2 er3 er4 er5 er6 ;
  311. err= er1 + er2 + er3 + er4 + er5 + er6;
  312. list err;
  313. si ( err > 5.e-2) ; erreur 5; finsi;
  314.  
  315.  
  316. ************************************************************************
  317. * FIN DU FICHIER *
  318. ************************************************************************
  319. FIN ;
  320.  
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  
  327.  
  328.  
  329.  
  330.  
  331.  
  332.  
  333.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales