Télécharger elasp.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elasp.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. SAUT PAGE;
  5. *
  6. ********************************************************************
  7. * *
  8. * TEST ELASP *
  9. * *
  10. * MEMBRANE ELLIPTIQUE (Contraintes planes) *
  11. * *
  12. * cas-test NAFEMS : test numero LE1 *
  13. * *
  14. * *
  15. * Une membrane elliptique obtenue par projection d'arcs de *
  16. * cercles sur un plan, est soumis a une force lineique sur l'un *
  17. * de ces cotes. Le but de ce test est de controler l'élément *
  18. * polygone. Il est issu du test elas8. *
  19. * *
  20. * Vue les symetries le probleme est traite en contraintes *
  21. * planes. *
  22. * *
  23. * On se propose de calculer la contrainte smyy au point D. *
  24. * *
  25. ********************************************************************
  26. *
  27. OPTI ECHO 0;
  28. *
  29. OPTI ELEM POLY;
  30. *
  31. GRAPH = 'N';
  32. *
  33. *==================================================================*
  34. * geometrie : maillage *
  35. *==================================================================*
  36. *
  37. * Dimension en metres
  38. *
  39. * Points
  40. *
  41. PB = 0. 2.75 0.;
  42. PB1 = 0. 2.75 (((3.25 ** 2) - (2.75 ** 2)) ** 0.5);
  43. PC = 3.25 0. 0.;
  44. *
  45. C1 = PC CERC 30 (0. 0. 0.) PB1;
  46. C2 = C1 PROJ CYLI (0. 0. 1) PLAN (0 0 0) (1 0 0) (0 1 0);
  47. *
  48. PA = 0. 1. 0.;
  49. PA1 = 0. 1. (((2. ** 2) - (1. ** 2)) ** 0.5);
  50. PD = 2. 0. 0.;
  51. *
  52. C3 = PD CERC 24 (0. 0. 0.) PA1;
  53. C4 = C3 PROJ CYLI (0. 0. 1) PLAN (0 0 0) (1 0 0) (0 1 0);
  54. *
  55. D1 = PA DROI 26 PB;
  56. D3 = PC DROI 26 PD;
  57. *
  58. ELIM (D1 ET C2 ET D3 ET C4) 0.0001;
  59. SUR1 = SURF (D1 ET C2 ET D3 ET C4) PLAN;
  60. *
  61. SI (NEG GRAPH 'N');
  62. TITR 'ELASP : MAILLAGE';
  63. TRAC (0 0 1000) QUAL SUR1;
  64. FINSI;
  65. *
  66. OPTI MODE PLAN CONT;
  67. *
  68. *==================================================================*
  69. * modele - affecte - materiau - caracteristique *
  70. * rigidite - conditions aux limites *
  71. *==================================================================*
  72. *
  73. MODL1 = MODE SUR1 MECANIQUE ELASTIQUE ISOTROPE POLY;
  74. MATR1 = MATE MODL1 YOUN 210E9 NU 0.3;
  75. RI1 = RIGI MODL1 MATR1;
  76. *
  77. * Conditions aux limites
  78. * - droite d1 : symetrie par rapport a l'axe des ordonnees,
  79. * - droite d2 : symetrie par rapport a l'axe des abscisses.
  80. *
  81. CL1 = SYMT DEPL ROTA (0 0) (0 1) SUR1 0.0001;
  82. CL2 = SYMT DEPL ROTA (0 0) (1 0) SUR1 0.0001;
  83. *
  84. RIG1 = RI1 ET CL1 ET CL2;
  85. *
  86. *==================================================================*
  87. * Chargement *
  88. *==================================================================*
  89. *
  90. * Pression externe uniforme de 10e6Pa.
  91. *
  92. CHA1 = PRES MASS MODL1 -10.E6 C2;
  93. *
  94. *==================================================================*
  95. * resolution : champs de deplacements *
  96. *==================================================================*
  97. *
  98. DEP1 = RESO RIG1 CHA1;
  99. *
  100. * Trace facultatif de la deformee et des reactions
  101. *
  102. SI (NEG GRAPH 'N');
  103. AMPVEC = 1.E-7;
  104. REA1 = REAC DEP1 RIG1;
  105. VECT1 = VECT CHA1 AMPVEC FX FY ROUGE;
  106. VECT2 = VECT REA1 AMPVEC FX FY BLEU;
  107. DEF0 = DEFO 0. DEP1 SUR1;
  108. DEF1 = DEFO 150. DEP1 SUR1 (VECT1 ET VECT2) VERT;
  109. TITR 'ELAS8 : DEFORMEE, CHARGEMENT, REACTIONS';
  110. TRAC SUR1 (DEF0 ET DEF1);
  111. FINSI;
  112. *
  113. *==================================================================*
  114. * champs de contraintes *
  115. *==================================================================*
  116. *
  117. CHAM1 = SIGM MODL1 MATR1 DEP1;
  118. *
  119. * Interpolation aux noeuds du maillage
  120. *
  121. CHAM11 = CHAN NOEUD CHAM1 MODL1;
  122. CHP11 = CHAN CHPO CHAM11 MODL1;
  123. *
  124. *==================================================================*
  125. * extraction et affichage d'une contrainte *
  126. *==================================================================*
  127. *
  128. * On cherche la contrainte smyy a point D.
  129. *
  130. SMYYD = EXTR CHP11 SMYY PD;SMYYD = SMYYD / 1.E6;
  131. *
  132. SMYYD1 = 92.7;
  133. ERG = 100 * (ABS ((SMYYD - SMYYD1) / SMYYD1));
  134. *
  135. MESS ' RESULTATS ';
  136. MESS ' --------- ';
  137. MESS ' CONTRAINTE SMYY THEORIQUE AU POINT D :' SMYYD1 'MPA';
  138. MESS ' CONTRAINTE SMYY CALCULEE AU POINT D :' SMYYD 'MPA';
  139. MESS ' SOIT UN ECART DE :' ERG '%';
  140. *
  141. NBNOSUR1 = NBNO SUR1;
  142. NBELSUR1 = NBEL SUR1;
  143. MESS ' NOMBRE D ELEMENTS :' NBELSUR1 'POLY';
  144. MESS ' NOMBRE DE NOEUDS ;' NBNOSUR1 ;
  145. *
  146. *==================================================================*
  147. * code fonctionnement *
  148. *==================================================================*
  149. *
  150. SI (ERG <EG 5.);
  151. ERRE 0;
  152. SINON;
  153. ERRE 5;
  154. FINSI;
  155. *
  156. TEMPS;
  157. *
  158. FIN;
  159.  
  160.  
  161.  
  162.  
  163.  
  164.  
  165.  
  166.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales