Télécharger elas2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : elas2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. * Test elas2.dgibi: Jeux de données *
  7. * --------------------------------- *
  8. *******************************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18. OPTI ECHO 1 ;
  19. OPTI TRAC PSC ;
  20. SINO ;
  21. OPTI ECHO 0 ;
  22. FINSI ;
  23.  
  24. *______________________________________________________
  25. * TEST ELAS2
  26. *
  27. * Un cylindre est pincé à une de ses extrémités,
  28. * l'autre extrémité étant encastrée.
  29. *
  30. * Pour des raisons de symétrie seul 1/4 de la structure
  31. * a est modélisé.
  32. *
  33. * Les conditions aux limites sont imposées pour
  34. * respecter les symétries.
  35. * Une force ponctuelle est appliquée diametralement.
  36. *
  37. * Le déplacement en X d'un point de la base est comparé
  38. * au déplacement théorique (déplacement nul puisque
  39. * encastré).
  40. * Le déplacement en Z du point d'application de force
  41. * est comparé à la valeur théorique (-1.140)
  42. *______________________________________________________
  43.  
  44. OPTION DIME 3 ELEM TRI3 ;
  45. TITRE 'CYLINDRE PINCE A BORDS ENCASTRES' ;
  46. TEMPS ;
  47. *-----------------------------------------------------
  48. * DEFINITION DE LA GEOMETRIE
  49. *-----------------------------------------------------
  50. P1=7 0 0 ;P2=0 0 7 ;C1=0 0 0 ;VECT=0 70 0 ;
  51. LIG1=C 6 P1 C1 P2 ;SURF=LIG1 TRAN 30 VECT ;
  52. LIG1 LIG2 LIG3 LIG4=COTE SURF ;P3=LIG2 POIN FINA ;
  53. *
  54. OEIL1 = 100 100 100;
  55. SI(NEG GRAPH 'N');
  56. TRAC OEIL1 SURF 'QUAL';
  57. FINSI;
  58. *-----------------------------------------------------
  59. * DEFINITION DU MODELE
  60. *-----------------------------------------------------
  61. MOD1=MODE SURF MECANIQUE ELASTIQUE DKT ;
  62. MAT1=MATE MOD1 YOUN 3.E7 NU 0.3 ;
  63. EPEE=CARA MOD1 EPAI 0.1 ;
  64. MAT1=MAT1 ET EPEE;
  65. *-----------------------------------------------------
  66. *** CALCUL RIGIDITE ET MASSE ;
  67. *-----------------------------------------------------
  68. *
  69. RIG1=RIGI MOD1 MAT1;
  70. *
  71. *-----------------------------------------------------
  72. * CONDITIONS AUX LIMITES
  73. *-----------------------------------------------------
  74. ENC1=BLOQ LIG4 UZ ;ENC2=BLOQ LIG4 RX ;ENC3=BLOQ LIG4 RY ;
  75. ENC4=BLOQ LIG2 UX ;ENC5=BLOQ LIG2 RY ;ENC6=BLOQ LIG2 RZ ;
  76. ENC7=BLOQ LIG3 UY ;ENC8=BLOQ LIG3 RX ;ENC9=BLOQ LIG3 RZ ;
  77. ENC10=BLOQ LIG1 DEPL ROTA ;
  78. ENC11=ENC1 ET ENC2 ET ENC3 ET ENC4 ET ENC5 ET ENC6 ET
  79. ENC7 ET ENC8 ET ENC9 ET ENC10 ;
  80. *------------------------------------------------------
  81. * FORCES
  82. *------------------------------------------------------
  83. F1=0 0 -2500 ;
  84. EFOR=FORC F1 P3 ;
  85. RIG2=RIG1 ET ENC11;
  86. *------------------------------------------------------
  87. * RESOLUTION ET RESULTATS
  88. *------------------------------------------------------
  89. DE1=RESOU RIG2 EFOR;
  90. D1X = EXTR DE1 UX P1 ;
  91. D3Z = EXTR DE1 UZ P3 ;
  92.  
  93. DEFO1= DEFO SURF DE1;
  94. DZ = EXCO DE1 UZ;
  95. SI (NEG GRAPH 'N') ;
  96. TRAC OEIL1 'CACH' DEFO1 DZ;
  97. FINSI;
  98.  
  99. *------------------------------------------------------
  100. * SORTIE DES RESULTATS
  101. *------------------------------------------------------
  102. SAUT PAGE ;
  103. MESS ' DEPLACEMENT EN X DE LA BASE VALEUR THEORIQUE : 0.00' ;
  104. MESS ' DEPLACEMENT EN X DE LA BASE VALEUR CALCULEE : ' D1X ;
  105. SAUT 2 LIGNE ;
  106. MESS ' DEPLACEMENT EN Z THEORIQUE : -1.140' ;
  107. MESS ' DEPLACEMENT EN Z CALCULE : ' D3Z ;
  108. TEMPS ;
  109. * CODE FONCTIONNEMENT
  110. DZREF=-1.14;
  111. RESI1=ABS((D3Z-DZREF)/DZREF);
  112. SI( RESI1 <EG 6E-4 );
  113. ERRE 0;
  114. SINO;
  115. ERRE 5;
  116. FINSI;
  117.  
  118. DXREF= 0.0;
  119. RESI2= ABS D1X;
  120. SI( RESI2 <EG DXREF);
  121. ERRE 0;
  122. SINO;
  123. ERRE 5;
  124. FINSI;
  125.  
  126. FIN;
  127.  
  128.  
  129.  
  130.  
  131.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales