Télécharger la plaquette Cast3M


fr en

Télécharger elas16.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  elas16.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. graph='N';
  5. saut page;
  6. ********************************************************************
  7. * Etude d'une poutre sur appuis simple chargee de facon repartie 
  8. * (on en etudie que la demi-longueur)
  9. *
  10. *
  11. *  symetrie                           appuis simple
  12. *
  13. *     |-------------------------------------*
  14. *                                           ^
  15. *     p1                                    p2
  16. ********************************************************************
  17. * Notations:
  18. *
  19. * t =epaisseur
  20. * L =longueur totale
  21. * I =moment d'inertie
  22. *
  23. * q =charge par unite de longueur
  24. * e =module d'Young
  25. * nu=Poisson
  26. ********************************************************************
  27. * Solution theorique:
  28. *
  29. * deflection/(qL**4/24eI) =  5/16 + (t/L)**2(1+nu)(1/2) 
  30. ********************************************************************
  31. * Objectif du test:
  32. *
  33. * on cherche a verifier la solution theorique pour la suite
  34. * d'epaisseur reduite suivante:
  35. *
  36. * t/L = .0001 .001 .01 .1  1. 10.
  37. ********************************************************************
  38. * 
  39. * 1) option de calcul
  40. opti dime 3 elem seg2;
  41. *
  42. * 2) quelques donees et calcul de quelques constantes
  43. *     pour la solution theorique
  44. *
  45. q=1.; e=1.e10; nu=.3; L=1.; 
  46. *
  47. qL4s24e=(q * (L ** 4))/(24. * e);
  48. cinqs16=5. / 16.;
  49. nup1s2 = (nu + 1.)/2.;
  50. *
  51. * 3) maillage
  52. *
  53. nel=50;
  54. p1 = 0 0 0; p2 = (L/2.) 0 0;
  55. d1= p1 d nel p2;
  56. *
  57. * 4) modele et materiaux
  58. *
  59. modti=MODE d1 mecanique elastique timo;
  60. mater=MATE modti 'YOUN' e 'NU' nu;
  61. *
  62. * 5) chargement reparti sur la poutre
  63. *
  64. j=0; repe loopel nel; j=j+1;
  65.   elj=d1 elem j;
  66.   pee=elj point init;
  67.   pde=elj point final;
  68.   vec=pde moin pee;
  69.   xl=norm vec;
  70. *
  71.   valf1 = (q * xl) * 0.5 ;
  72.   valf2 = valf1;
  73. *
  74.   chrtij=(manu 'CHPO' pee 1 fz valf1 nature discret)
  75.      et  (manu 'CHPO' pde 1 fz valf2 natu discret);
  76. *
  77.   si (j ega 1); chrti=chrtij;
  78.   sinon;        chrti=chrtij et chrti;
  79.   finsi;
  80. *
  81. fin loopel;
  82. *
  83. * 6) bloquage
  84. *
  85. bloqtot=bloq d1 'UY' 'RX' 'RZ';
  86. bloqp1 =bloq p1 'UX' 'RY';
  87. bloqp2 =bloq p2 'UZ';
  88. *
  89. * 7) definition des differentes epaisseurs
  90. *
  91. tt=prog .0001 .001 .01 .1  1. 10.;
  92. nt=dime tt;
  93. *
  94. * 8) loop sur les epaisseurs
  95. *
  96. cerre=0;
  97. j=0; repe loopep nt; j=j+1;
  98.   t=extr tt j;
  99. *
  100. ** 8.1) etablissement des caracteristiques geometriques
  101. *
  102.   b=1.;
  103.   section=b*t; inery=(b/12) * (t ** 3);
  104.   inerz=1.d+10; torsion=1.d+10;
  105.   carac= 'CARA' modti 'SECT' section 'INRY' inery 'INRZ' inerz
  106.                        'TORS' torsion 'SECZ' section;
  107.   mc=mater et carac;
  108. *
  109. ** 8.2) calcul de la rigidite
  110. *
  111.   rigti=rigi modti mc;
  112.   rigtti=rigti et bloqtot et bloqp1 et bloqp2;
  113. *
  114. ** 8.3) solution
  115. *
  116.   depti=reso rigtti chrti;
  117. *
  118. ** 8.4) deflections theoriques en p1
  119. *
  120.   qL4s24ei=qL4s24e / inery;
  121.   theorie=cinqs16 + (((t / L) ** 2) * nup1s2);
  122.   calcul=(extr depti 'UZ' p1) / qL4s24ei;
  123.   erreur=abs ((calcul - theorie) / theorie);
  124. *
  125. ** 8.5) comparaison et message
  126. *
  127.   mess 'deflection pour t/L=' (t/L);
  128.   mess 'calcul,theorie,erreur:  ' calcul theorie erreur;
  129.   mess '***********************';
  130. *
  131. ** 8.6) erreur
  132. *
  133.   si (erreur > 5.d-4); cerre=cerre+1; finsi;
  134. *
  135. fin loopep;
  136. si (cerre > 0); erre 5;
  137. sinon;          erre 0; finsi;
  138. fin;
  139.  
  140.  
  141.  
  142.  
  143.  
  144.  
  145.  
  146.  
  147.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales