Télécharger effmarti.dgibi

Retour à la liste

Numérotation des lignes :

  1. OPTI DIME 3 MODE TRID ELEM QUA4;
  2. *
  3. **********************************************************
  4. * Test sur la procedure de EFFMARTI pour tester la
  5. * projection des efforts globaux sur un element coque
  6. * vers le modele à trois couches de MARTI.
  7. * On teste un seul element avec les caracteristiques
  8. * suivantes:
  9. *
  10. * Epaisseur 0.1 m
  11. * Enrobage externe 0.025 m
  12. * Enrobage interne 0.025 m
  13. * cotg(th) 1.43
  14. *
  15. * Le cas test consiste à projeter le tenseur des efforts suivant:
  16. *
  17. * N11 = 1 N/m
  18. * N22 = 2 N/m
  19. * N12 = 3 N/m
  20. * M11 = 4 Nm/m
  21. * M22 = 5 Nm/m
  22. * M12 = 6 Nm/m
  23. * V1 = 7 N/m
  24. * V2 = 8 N/m
  25. *
  26. * On laisse l'option pour effectuer le meme calcul sur un element
  27. * plus complexe (CAS1 = 2)
  28. *
  29. * Develloppé par Alberto FRAU /DEN/DANS/DM2S/SEMT/EMSI
  30. * et Nicolas ILE /DEN/DANS/DM2S/SEMT/EMSI
  31. *
  32. **********************************************************
  33. *
  34. * selection du calcul
  35. * si CAS1 egal à 1 -> alors on lance le cas test
  36. * si CAS1 egal à 2 -> alors on lance le cas test
  37. CAS1 = 1.;
  38. *
  39. SI (CAS1 EGA 1);
  40. * Calcul de test pour la procedure EFFMARTI
  41. *
  42. * Proprietés geometriques
  43. H1 = 0.1;
  44. ER1 = 0.025;
  45. ER2 = 0.025;
  46. COT1 = 1.43;
  47. *
  48. * Definition de l'element
  49. P0 = 0. 0. 0.;
  50. P1 = 1. 0. 0.;
  51. P2 = 1. 1. 0.;
  52. P3 = 0. 1. 0.;
  53. *
  54. L1 = D 1 P0 P1;
  55. L2 = D 1 P1 P2;
  56. L3 = D 1 P2 P3;
  57. L4 = D 1 P3 P0;
  58. *
  59. * definition de l'element
  60. SUR1 = DALL L1 L2 L3 L4;
  61. *
  62. * Contruction du modele et du materiau
  63. MOD1 = MODE SUR1 MECANIQUE ELASTIQUE ISOTROPE COQ4;
  64. MAT1 = MATE MOD1 YOUNG 30000.E6 NU 0.2 RHO 2500. EPAI H1;
  65. *
  66. * Definition du tensueur des efforts
  67. *
  68. N11_A = 1;
  69. N22_A = 2;
  70. N12_A = 3;
  71. M11_A = 4;
  72. M22_A = 5;
  73. M12_A = 6;
  74. V1_A = 7;
  75. V2_A = 8;
  76. SIG1 = MANU CHML MOD1 'TYPE' 'CONTRAINTES'
  77. 'N11' N11_A 'N22' N22_A 'N12' N12_A
  78. 'M11' M11_A 'M22' M22_A 'M12' M12_A
  79. 'V1' V1_A 'V2' V2_A;
  80. *
  81. SIG1 = RTENS SIG1 MOD1 MAT1 (1.0 0. 0.) (0. 1. 0.);
  82. *
  83. * Projection des efforts sur les trois couches de MARTI
  84. SIG2 = EFFMARTI SIG1 MOD1 MAT1 (1. 0. 0.) (0. 1. 0.)
  85. H1 ER1 ER2 COT1;
  86. *
  87. * extractions des efforts projetés
  88. N11E_A = EXTR SIG2 'N11E' 1 1 1;
  89. N22E_A = EXTR SIG2 'N22E' 1 1 1;
  90. N12E_A = EXTR SIG2 'N12E' 1 1 1;
  91. N11I_A = EXTR SIG2 'N11I' 1 1 1;
  92. N22I_A = EXTR SIG2 'N22I' 1 1 1;
  93. N12I_A = EXTR SIG2 'N12I' 1 1 1;
  94. VR_A = EXTR SIG2 'VR' 1 1 1;
  95. *
  96. * calcul des efforts projétés
  97. DD1 = H1 - ER1 - ER2;
  98. VR_B = ((V1_A*V1_A) + (V2_A*V2_A))**(0.5);
  99. N11E_B = (N11_A*0.5) + (M11_A/DD1) +
  100. ((V1_A*V1_A)/((2*VR_B)*(COT1)));
  101. N22E_B = (N22_A*0.5) + (M22_A/DD1) +
  102. ((V2_A*V2_A)/((2*VR_B)*(COT1)));
  103. N12E_B = (N12_A*0.5) + (M12_A/DD1) +
  104. ((V1_A*V2_A)/((2*VR_B)*(COT1)));
  105. N11I_B = (N11_A*0.5) - (M11_A/DD1) +
  106. ((V1_A*V1_A)/((2*VR_B)*(COT1)));
  107. N22I_B = (N22_A*0.5) - (M22_A/DD1) +
  108. ((V2_A*V2_A)/((2*VR_B)*(COT1)));
  109. N12I_B = (N12_A*0.5) - (M12_A/DD1) +
  110. ((V1_A*V2_A)/((2*VR_B)*(COT1)));
  111. *
  112. * test
  113. SI (ABS(N11E_B - N11E_A)>(1.E-10));
  114. ERRE 5;
  115. FINSI;
  116. SI (ABS(N22E_B - N22E_A)>(1.E-10));
  117. ERRE 5;
  118. FINSI;
  119. SI (ABS(N12E_B - N12E_A)>(1.E-10));
  120. ERRE 5;
  121. FINSI;
  122. SI (ABS(N11I_B - N11I_A)>(1.E-10));
  123. ERRE 5;
  124. FINSI;
  125. SI (ABS(N22I_B - N22I_A)>(1.E-10));
  126. ERRE 5;
  127. FINSI;
  128. SI (ABS(N12I_B - N12I_A)>(1.E-10));
  129. ERRE 5;
  130. FINSI;
  131. SINON;
  132. * Calcul des efforts projetés sur une plaque
  133. * de dimensions 2x4 chargée par une force sur
  134. * un cote et encastrée dans l'autre
  135. * Proprietés geometriques
  136. OPTI EPSI LINEAIRE;
  137. H1 = 0.1;
  138. ER1 = 0.025;
  139. ER2 = 0.025;
  140. COT1 = 1.43;
  141. *
  142. * Definition de l'element
  143. P0 = 0. 0. 0.;
  144. P1 = 4. 0. 0.;
  145. P2 = 4. 2. 0.;
  146. P3 = 0. 2. 0.;
  147. *
  148. L1 = D 20 P0 P1;
  149. L2 = D 10 P1 P2;
  150. L3 = D 20 P2 P3;
  151. L4 = D 10 P3 P0;
  152. *
  153. * definition de l'element
  154. SUR1 = DALL L1 L2 L3 L4;
  155. *
  156. * Construction du modele et du materiau
  157. MOD1 = MODE SUR1 MECANIQUE ELASTIQUE ISOTROPE COQ4;
  158. MAT1 = MATE MOD1 YOUNG 30000.E6 NU 0.2 RHO 2500. EPAI H1;
  159. *
  160. * Forces
  161. FOR1 = FORCE L2 'FZ' -1000.;
  162. *
  163. * Blocages
  164. BL1 = (BLOQUER 'UZ' L4) ET
  165. (BLOQUER 'UX' L4) ET
  166. (BLOQUER 'RY' L4) ET
  167. (BLOQUER 'UY' P0);
  168. *
  169. * Resolution
  170. RIG1 = RIGI MOD1 MAT1;
  171. RES1 = RESO (RIG1 ET BL1) (FOR1);
  172. *
  173. * Determination des efforts generalisés
  174. SIG1 = SIGM RES1 MOD1 MAT1;
  175. SIG1 = RTENS SIG1 MOD1 MAT1 (1.0 0. 0.) (0. 1. 0.);
  176. *
  177. SIG2 = EFFMARTI SIG1 MOD1 MAT1 (1. 0. 0.) (0. 1. 0.)
  178. H1 ER1 ER2 COT1;
  179. *
  180. TRAC (EXCO SIG1 'M11') MOD1 TITR 'Mxx';
  181. TRAC (EXCO SIG1 'M22') MOD1 TITR 'Myy';
  182. TRAC (EXCO SIG1 'M12') MOD1 TITR 'Mxy';
  183. *
  184. TRAC (EXCO SIG1 'V1') MOD1 TITR 'Vx';
  185. TRAC (EXCO SIG1 'V2') MOD1 TITR 'Vy';
  186. *
  187. TRAC (EXCO SIG2 'N11E') MOD1 TITR 'Nxx Externe';
  188. TRAC (EXCO SIG2 'N22E') MOD1 TITR 'Nyy Externe';
  189. TRAC (EXCO SIG2 'N12E') MOD1 TITR 'Nxy Externe';
  190. *
  191. TRAC (EXCO SIG2 'N11I') MOD1 TITR 'Nxx Interne';
  192. TRAC (EXCO SIG2 'N22I') MOD1 TITR 'Nyy Interne';
  193. TRAC (EXCO SIG2 'N12I') MOD1 TITR 'Nxy Interne';
  194. *
  195. FINSI;
  196. *
  197. FIN;
  198.  
  199.  
  200.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales