Télécharger la plaquette Cast3M


fr en

Télécharger dyne03.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : dyne03.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ****************************************************
  5. *
  6. *   EXEMPLE D'UTILISATION DE L'OPERATEUR DYNE
  7. *
  8. *   Rupture de tuyauterie avec impact
  9. *   Calcul sur base modale avec raideur de choc
  10. *   Opérateur Dyne
  11. *   D. Combescure
  12. *   Aout 2006
  13. *
  14. *****************************************************
  15. * GRAPH = VRAI;
  16. GRAPH = FAUX;
  17. *
  18. opti dime 3 elem seg2;
  19. *
  20. L1 = 3.;
  21. n1 = 20;
  22. L = 6.;
  23. n2 = 20;
  24. H = 2.;
  25. nh = 20;
  26. *
  27. p1 = 0. 0. 0.;
  28. p2 = L1 0. 0.;
  29. p2b = L1 0. 0.;
  30. p3 = L 0. 0.; 
  31. p3b = L 0. 0.; 
  32. lig1 = d n1 p1 p2;
  33. lig2 = d n2 p2 p3;
  34. mesh = lig1 et lig2;
  35. *
  36. P4 = L 0. ((-1.)*H);
  37. *
  38. meshV = d nh P4 P3b;
  39. *
  40. R = 0.30;
  41. P0 = 3.6D6;
  42. sigy = 219.D6;
  43. e = (P0/sigy)*R;
  44. I1 = 0.5*2.*pi*(R**3)*e;
  45. S1 = 2.0*pi*R*e;
  46. S0 = pi* (R**2);
  47. *
  48. R2 = 0.10;
  49. ep2 = 0.01;
  50. I2 = 0.5*2.*pi*(R2**3)*ep2;
  51. S2 = 2.0*pi*R2*ep2;
  52. *
  53. F0 = 1.26*P0*S0;
  54. *
  55. E1 = 200000.D6;
  56. E2= E1;
  57. *
  58. nu1 =0.2;
  59. ro1 = 7.8D3;
  60. *
  61. ro2 = ro1;
  62. nu2 = nu1;
  63. *
  64. *
  65. ustat = ((L**3)/(3.*E1*I1))*F0;
  66. mul = 4.*2.*sigy*e*(R**2);
  67. *
  68. mod1 = 'MODELI' mesh mecanique elastique POUT;
  69. mat1 = mate mod1 YOUN E1 NU nu1 RHO ro1
  70.                  INRY I1 INRZ I1 TORS (2.*I1)
  71.                  SECT S1;
  72. K1 =  (3.*E1*I1/((L**3)));
  73. *
  74. mod2 = 'MODELI' meshV mecanique elastique POUT;
  75. mat2 = mate mod2 YOUN E2 NU nu2 RHO ro2
  76.                  INRY I2 INRZ I2 TORS (2.*I2)
  77.                  SECT S2;
  78. K2 =  (3.*E2*I2/((H**3)));
  79. *
  80. modT = mod1 et mod2;
  81. Matt = mat1 et mat2;
  82. MeshT = mesh et MeshV;
  83. * 
  84. rig1 = RIGI modT matT;
  85. mas1 = mass modT matT;
  86. bl1 = (BLOQ p1 RY) 
  87.    et (BLOQ p1 UY) et (BLOQ p1 RZ);
  88. bl2b = BLOQ p2b DEPL;
  89. bl3b = (BLOQ P4 DEPL ROTA) et (BLOQ p3b UX);
  90. blM = (BLOQ  mesh UZ) et (BLOQ mesh RX)
  91.     et (BLOQ mesh UX);
  92. *
  93. For1 = FORCE (0. (F0) 0.) p3;
  94. *
  95. *
  96. * Caractéristiques liaisons
  97. *
  98. umax = 1.17;
  99. Kliai = 15.6D6;
  100. Jeuliai = 0.500;
  101. ******************************
  102. ******************************
  103. *
  104. * Cas 1: 2 modes avec choc mou
  105. *
  106. ******************************
  107. ******************************
  108. nmode = 2;
  109. FR = VIBR PROCHE (PROG 11. ) (LECT nmode) 
  110.           (RIG1 et bl1 et blm et bl3b) MAS1;
  111. *
  112. Mequi3 = TABLE;
  113. *
  114. *
  115. lmot2 = MOTS UX UY UZ RX RY RZ;
  116. lmot1 = MOTS FX FY FZ MX MY MZ;
  117. lmot3 = lmot2;
  118. IdFYT = (manu chpo meshT 6 UX 0. UY (-1.0) UZ 0. RX 0. RY 0. RZ 0.
  119.        NATURE DISCRET);
  120. *
  121. oeil = 10. 10. 2.;
  122. Repeter bou1 nmode;
  123.   FIFI = FR . MODES . &Bou1 . FREQUENCE      ;
  124.   TT = FR . MODES . &Bou1 .  DEFORMEE_MODALE  ;
  125.   DEf1 = DEFO meshT TT;
  126.   SI GRAPH;
  127.     titre (CHAIN 'Frequence=' Fifi);
  128.     trac oeil def1;
  129.   FINSI;
  130.   Mm1 = resu ((mas1*(TT)) '*' (TT) lmot1 lmot2 lmot3);
  131.   Mm1V =  ( ((maxi (exco Mm1 UX))) +
  132.           ((maxi (exco Mm1 UY))) +
  133.           ((maxi (exco Mm1 UZ))) +
  134.           ((maxi (exco Mm1 RX))) +
  135.           ((maxi (exco Mm1 RY))) +
  136.           ((maxi (exco Mm1 RZ))) );
  137.   Mequi3.&bou1 = MM1V/((extr TT P3 UY)**2);
  138. fin bou1;
  139. *
  140. Cliai = 2.*((Kliai*(Mequi3.1))**0.5);
  141. *
  142. * Appel à DYNE
  143. *
  144. ************************************************
  145. * TEMPS
  146. *************************
  147. *
  148. DT  = MINI (PROG (1.E-5) (0.1/(2.*pi*fifi))) ;
  149. NTT = ENTIER (0.1/DT)               ;
  150. *
  151. *************************
  152. * TABLE AMORTISSEMENT
  153. *************************
  154. *
  155. TAMOR = TABLE 'AMORTISSEMENT'       ;
  156. ValAmor = 0.;
  157. AMO = PROG NMODE*ValAmor                ;
  158. TAMOR . AMORTISSEMENT = AMOR FR AMO ;
  159. *
  160. *************************
  161. * TABLE CHARGEMENT (CHARG1 CHARG2 CHARG3)
  162. *************************
  163. TCHAR = TABLE 'CHARGEMENT'          ;
  164. *
  165. Ampl = 1.0;
  166. Evotime = evol manu (prog 0. 0.01 100.)
  167.                     (Ampl*(prog 0. 1. 1.));
  168. CHA1 = CHAR For1 Evotime; 
  169. CHAP1 = PJBA FR CHA1;     
  170. TCHAR.'BASE_A' = CHAP1;
  171. ***********************************************************
  172. *
  173. * LIAISONS POINT-POINT
  174. *
  175. ***********************************************************
  176. *
  177. TILIA = TABLE 'LIAISON'  ;
  178. TTLB = TABLE 'LIAISON_B' ;
  179. TILIA.'LIAISON_B' = TTLB ;
  180. *
  181. TLA12 = TABLE 'LIAISON_ELEMENTAIRE' ;
  182. TTLB .  1 = TLA12 ;
  183. *
  184. TLA12 . 'TYPE_LIAISON' = MOT 'POINT_POINT';
  185. TLA12 . 'POINT_A' = P3 ;
  186. TLA12 . 'POINT_B' = P3b ;
  187. TLA12. 'NORMALE' = ( 0. 1. 0.);
  188. TLA12 . 'RAIDEUR' = Kliai ;
  189. TLA12 . 'JEU' = JeuLiai      ;
  190. TLA12 . 'AMORTISSEMENT' = Cliai;
  191. *************************
  192. * TABLE SORTIE
  193. *************************
  194. *
  195. TABSOR = TABLE 'SORTIE';
  196. *
  197. TABSOR2 = TABLE 'LIAISON_B' ;
  198. TABSOR.'LIAISON_B' = TABSOR2  ;
  199. *
  200. TVARPP = TABLE 'VARIABLE'    ;
  201. TVARPP.'FORCE_DE_CHOC_POINT_A' = VRAI ;
  202. TVARPP.'FORCE_DE_CHOC_POINT_B' = VRAI ;
  203. TVARPP.'UY_POINT_A' = VRAI ;
  204. TVARPP.'UY_POINT_B' = VRAI ;
  205. *
  206. TVARGD = TABLE 'VARIABLE'    ;
  207. TVARGD.'FORCE_DE_CHOC' = VRAI ;
  208. TVARGD.'UY' = VRAI ;
  209. *
  210. TABSOR2. TLA12 = TVARPP;
  211. *
  212. ************************************************
  213. * CALCUL TEMPOREL PROPREMENT DIT
  214. *************************
  215. *
  216. TRESU = DYNE DE_VOGELAERE FR TAMOR TCHAR TILIA
  217.              NTT DT 1 TABSOR  ;
  218. *
  219. ************************************************
  220. * TRACE DES DEPLACEMNTS EN FONCTION DU TEMPS
  221. *************************
  222. *
  223. UXP2 = EVOL VERT RECO TRESU FR 'DEPL' P2  UY  ;
  224. UXP3 = EVOL BLEU RECO TRESU FR 'DEPL' P3  UY  ;
  225. UXPB3 = EVOL BLEU RECO TRESU FR 'DEPL' P3B  UY  ;
  226. UXPB3 = evol manu (extr UXPB3 absc)
  227.      ((extr UXPB3 ordo) + (prog (dime (extr UXPB3 ordo))*jeuliai));
  228. *
  229. TDS = TRESU . 'TEMPS_DE_SORTIE' ;
  230. RESCHOC = TRESU . TLA12;
  231. FchocB = RESCHOC. FORCE_DE_CHOC_POINT_B;
  232. FchocA = RESCHOC. FORCE_DE_CHOC_POINT_A;
  233. *
  234. EVFchoA = 'EVOL' 'MANU' TDS FChocA;
  235. EVFchoB = 'EVOL' 'MANU' TDS FChocB;
  236. *
  237. *
  238. Ncont = 10.;
  239. REPETER bo3 (ENTIER ((NTT + 1)/Ncont));
  240.   dep1 = RECO TRESU FR ((&bo3 - 1 )*DT*Ncont) 'DEPL';
  241.   con1 = SIGMA MOD1 MAT1 dep1;
  242.   con2 = SIGMA MOD2 MAT2 dep1;
  243.   SI (&bo3 EGA 1);
  244.     time = PROG ((&bo3 - 1 )*DT*Ncont);
  245.     pfyp1 = prog (extr con1 1 1 2 EFFY);
  246.     pmzp1 = prog (extr con1 1 1 2 MOMZ);
  247.     deft = defo meshT dep1 1.;
  248.   SINON;
  249.     time = time et (PROG ((&bo3 - 1 )*DT*Ncont));
  250.     pfyp1 = pfyp1 et (prog (extr con1 1 1 2 EFFY));
  251.     pmzp1 = pmzp1 et (prog (extr con1 1 1 2 MOMZ));
  252.     deft = deft et (defo meshT dep1 1.);
  253.   FINSI;
  254. FIN bo3;    
  255. tifyp1 = evol manu Time pfyp1;
  256. timzp1 = evol manu Time pmzp1;
  257. *
  258. SI GRAPH;
  259.   TRAC oeil DEFT ANIME;
  260.  TITRE 'Deplacement avec 20 modes';
  261.  dess (UXP2 et UXP3 et UXPB3) xbord 0. 0.10 ybord 0. 1.40;
  262.  Titre 'Force de choc';
  263.  DESS EVFchoA xbord 0. 0.10;
  264. FINSI;
  265. *
  266. *
  267. FIN;
  268. * 
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales