Télécharger dyna_nl3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : dyna_nl3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * ajout de option epsilon lineaire pour la precision des test!
  5. OPTION epsilon lineaire;
  6.  
  7.  
  8. * Test Dyna_nl3.dgibi: Jeux de données *
  9. * ------------------------------------ *
  10. * *
  11. complet = vrai;
  12. *
  13. *************************************************
  14. * pour calcul complet mettre complet à : vrai;
  15. ***************************************************
  16. *======================================================
  17. * TEST DES LA PRESSION SUIVEUSE EN DYNAMIQUE
  18. *
  19. * FLOTTEMENT D'UNE POUTRE ENCASTREE-LIBRE
  20. *
  21. * On etudie la reponse de la poutre à un lacher quand
  22. * elle est soumise à une force de compression axiale
  23. * legerement superieure à la valeur theorique de la
  24. * force critique de flottement (Fcr = 20.05*E*I/l**2)
  25. * On doit obtenir une reponse d'amplitude croissante.
  26. *
  27. *******************************************************
  28. * ==
  29. * /|aa___________________bb ==
  30. * /|______________________|<----- F ==
  31. * /| cc ==
  32. * EQUIVALENT A /| ==
  33. * dd / | ==
  34. * /|aa_________________bb|<-- ==
  35. * /|_____________________|<-- PRESSION ==
  36. * /| |<-- ==
  37. * ee |/ ff ==
  38. * ==
  39. * ==
  40. *======================================================
  41. graph = faux;
  42. option dime 3 elem seg2 ;
  43. *tri3 ;
  44. *======================================================
  45. * definition de la geometrie
  46. * la force suiveuse est modelisee par une pression équi
  47. * valente appliquée sur une petite plaque fixée à l'ex
  48. * trémité de la poutre
  49. *======================================================
  50. aa = 0 0 0 ;
  51. bb = 12 0 0;
  52. cc = 12 0.01 0.01 ;
  53. dd = 12 0.01 -0.01 ;
  54. ee = 12 -0.01 -0.01 ;
  55. ff = 12 -0.01 0.01 ;
  56. dens1 = 10 ;
  57. lig1 = aa d dens1 bb ;
  58. lig2 = cc d 2 dd d 2 ee d 2 ff d 2 cc ;
  59. surf1 = surf plan lig2 ;
  60. geo = lig1 et surf1 ;
  61. elim 1.e-4 geo ;
  62. *=====================================================
  63. *definition des conditions aux limites
  64. * encastrement à la base de la poutre et mouvement
  65. * dans le plan xOy
  66. *=====================================================
  67. cl1 = bloq rota depla aa ;
  68. cl2 = bloq uz rx ry surf1 ;
  69. cl3 = bloq bb uy ;
  70. *======================================================
  71. * definition du modele, du materiau et
  72. * des caracteristiques
  73. *======================================================
  74. mo1 = mode lig1 mecanique pout ;
  75. mo2 = mode surf1 mecanique coq3 ;
  76. ma1 = mate mo1 youn 2.1e7 nu 0.3 rho 7.8e-3 ;
  77. ma2 = mate mo2 youn 2.1e10 nu 0.3 rho 7.8e-10 ;
  78. ca1 = cara mo1 sect 0.15 inry 2.8125e-4 inrz 2.8125e-4
  79. tors 1.e-5;
  80. ca2 = cara mo2 epai 0.01 ;
  81. mat1 = ma1 et ca1 ;
  82. mat2 = ma2 et ca2 ;
  83. *
  84. * Chargement de pression
  85. MOPRE = 'MODE' SURF1 'CHARGEMENT' 'PRESSION' 'COQ3' ;
  86. MAPRE = 'MATE' MOPRE 'PRES' 1. ;
  87. *
  88. CHPZ = 'MANU' 'CHPO' ('CHAN' 'POI1' ('EXTR' MOPRE 'MAIL')) 1
  89. 'PRES' (2050781.25*1.05) ;
  90. CHMZ = 'CHAN' 'CHAM' CHPZ MOPRE ;
  91. CHMZ = 'CHAN' 'COMP' CHMZ 'PRES' ;
  92. CHMZ = 'CHAN' 'TYPE' CHMZ 'CONTRAINTES' ;
  93. *
  94. TTPS = 'TABL' ;
  95. TTPS. 0 = 0. ; TTPS. 1 = 0.00001 ; TTPS. 2 = 100. ;
  96. TPRE = 'TABL' ;
  97. TPRE. 0 = 0.*CHMZ ; TPRE. 1 = 1.*CHMZ ; TPRE. 2 = TPRE. 1 ;
  98. CHAA = 'CHAR' 'PRES' TTPS TPRE ;
  99. *
  100. mattotal = mat1 et mat2 et mapre ;
  101. mototal = mo1 et mo2 et mopre ;
  102. *======================================================
  103. * calcul des matrices de rigidite et de masse
  104. *======================================================
  105. ri1 = rigi mototal mattotal ;
  106. ritotal = ri1 et cl1 et cl2 ;
  107. masst = masse mototal mattotal ;
  108. *======================================================
  109. * chargement par pression equivalente a la force
  110. * critique de flottement pondérée par un coefficient
  111. * de 1.05 pour se placer legerement au dessus de
  112. * l'instabilité.
  113. *
  114. * on impose un petit deplacement transverse pour
  115. * perturber le systeme.
  116. *======================================================
  117. fo2 = depi cl3 .01 ;
  118. fo0 = manu chpo surf1 1 p (2050781.25*1.05)
  119. nature discret ;
  120. *======================================================
  121. * calcul non lineaire
  122. * calcul statique sous la force de compression et la
  123. * force transversale de perturbation
  124. *======================================================
  125. dt = 0.00001 ;
  126. li1 = prog 0. dt ;
  127. li2 = prog 0. 1 ;
  128. ev = evol manu t (li1 ) f(t) (li2 ) ;
  129. fco = char dimp fo2 ev ;
  130. lis1a = prog 0. pas (dt/5) dt ;
  131.  
  132.  
  133. tab3 = table ;
  134. tab3.grands_deplacements = vrai ;
  135. tab3.chargement = fco et chaa ;
  136. tab3.blocages_mecaniques = cl1 et cl2 et cl3 ;
  137. tab3.modele = mototal ;
  138. tab3.caracteristiques = mattotal ;
  139. tab3.temps_calcules = lis1a ;
  140. tab3.precision = 1e-6 ;
  141. tab3.deltaiter = 20 ;
  142. tab3.maxdefor=1e-3;
  143. tab3.k_sigma=faux;
  144.  
  145.  
  146. *optio veri 1;
  147. pasapas tab3 ;
  148.  
  149. oeil = 0 0 10000 ;
  150. dim1 = dime (tab3.deplacements) ;
  151. lisx = prog ; lisy = prog ;
  152. repeter bou1 dim1 ;
  153. n = &bou1 - 1 ;
  154. uy1 = extr tab3.deplacements.n 'UY' bb ;
  155. lisy = lisy et (prog uy1) ;
  156. lisx = lisx et (prog tab3.temps. n);
  157. def1 = defo tab3.deplacements.n geo 100 ;
  158. si (&bou1 ega 1) ; deft = def1 ; sinon ;
  159. deft = deft et def1 ; finsi ;
  160. fin bou1 ;
  161. ev1 = evol manu 'temps' lisx 'depl' lisy ;
  162. si graph ; trac deft oeil cach anime ; finsi ;
  163.  
  164.  
  165. *======================================================
  166. * calcul non lineaire dynamique
  167. *======================================================
  168. * definition de l'évolution du chargement
  169. * durée de la phase de chargement statique :dt
  170.  
  171. ev2 = evol manu (prog dt 100) (prog 1 1 ) ;
  172. *
  173. *fncons = char psui fo0 ev2 ;
  174.  
  175. si complet;
  176. lis1c = prog dt pas .0003 .045 ;
  177. sinon;
  178. lis1c = prog dt pas .001 0.005;
  179. finsi;
  180. ffbi= force (0 0 0) dd;
  181. fbidon = 'CHAR' 'MECA' ffbi ev2;
  182. tab3.'CHARGEMENT'= fbidon et chaa ;
  183. vv = manu chpo ( surf1 et lig1 ) 1 'UX' 0.;
  184. tab3.'VITESSES' = table;
  185. nso= dime tab3.'TEMPS'; tab3.'VITESSES'. ( nso + 1 ) = vv;
  186. tab3. 'CONTINUATION' . 'VITESSES' = vv;
  187. tab3.'ACCELERATIONS' = table;
  188. tab3.'ACCELERATIONS'. ( nso + 1 ) = vv;
  189. tab3. 'CONTINUATION' . 'ACCELERATIONS' = vv;
  190. tab3.blocages_mecaniques = cl1 et cl2 ;
  191. tab3.dynamique = vrai ;
  192. tab3.temps_calcules = lis1c ;
  193.  
  194. pasapas tab3 ;
  195.  
  196. *====================================================
  197. * exploitation des resultats : deplacement de l'
  198. * extrémité de la poutre (point bb)
  199. *====================================================
  200.  
  201. dim1 = dime (tab3.deplacements) ;
  202. lisx = prog ; lisy = prog ;
  203. repeter bou1 dim1 ;
  204. n = &bou1 - 1 ;
  205. uy1 = extr tab3.deplacements.n 'UY' bb ;
  206. lisy = lisy et (prog uy1) ;
  207. lisx = lisx et (prog tab3.temps. n);
  208. fin bou1 ;
  209. ev1 = evol manu 'temps' lisx 'depl' lisy ;
  210. list lisy;
  211. si graph ; dess ev1 ; finsi ;
  212.  
  213. * la reference pour le test est le resultat d'une
  214. * certaine version de C2000
  215. dmax = maxi abs lisy ; list dmax ;
  216. si complet ;
  217. valtes = 1.1191;
  218. sinon;
  219. valtes = .082;
  220. finsi;
  221. err1 = abs ((dmax - valtes)/valtes);
  222. list err1 ;
  223. si (err1 > .05) ; erreur 5 ;
  224. sinon ; erre 0 ; finsi ;
  225. fin ;
  226.  
  227.  
  228.  
  229.  
  230.  
  231.  
  232.  
  233.  
  234.  
  235.  
  236.  
  237.  
  238.  
  239.  
  240.  
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  
  248.  
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257.  
  258.  
  259.  
  260.  
  261.  
  262.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales