Télécharger dyna6.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : dyna6.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Dyna6.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7.  
  8. *******************************************************
  9. * Test dyna6.dgibi: jeux de données *
  10. * --------------------------------- *
  11. *******************************************************
  12.  
  13. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  14. * SINON SI GRAPH DIFFERENT DE N TOUS
  15. * LES GRAPHIQUES SONT AFFICHES
  16.  
  17. GRAPH = 'N' ;
  18.  
  19. SAUT PAGE;
  20. SI (NEG GRAPH 'N') ;
  21. OPTI ECHO 1 ;
  22. OPTI TRAC X ;
  23. SINO ;
  24. OPTI ECHO 0 ;
  25. FINSI ;
  26.  
  27. SAUT PAGE;
  28. *******************************************************
  29. * DYNA6
  30. *
  31. * CAS TEST OPERATEUR VIBRATION
  32. * MODES DE FLEXION D'UNE POUTRE
  33. * ENCASTREE-LIBRE
  34. *
  35. * Cet exemple permet de tester les trois options
  36. * de l'opérateur VIBR :
  37. *
  38. * - par intervalle (INTERVALLE) ou on sépare les
  39. * modes par dichotomie sur un intervalle donné
  40. * - par proximité (PROCHE) ou on recherche les
  41. * modes proches de valeurs données
  42. * - par la méthode de Lanczos (SIMULTANE) ou on
  43. * projette sur un sous-espace
  44. * - par la méthode d Arnoldi (IRAM) ou on
  45. * projette sur un sous-espace
  46. *
  47. *
  48. * Le problème consiste à trouver les fréquences pour
  49. * le premier et le deuxième mode, d'une poutre
  50. * encastrée à une extrémité et libre à l'autre.
  51. *
  52. * Les valeurs obtenues par les trois méthodes sont
  53. * comparées aux valeurs théoriques.
  54. *
  55. *******************************************************
  56. TITR 'FLEXION D UNE POUTRE ENCASTREE-LIBRE';
  57. OPTI DIME 3 ELEM SEG2 MODE TRID IMPI 0;
  58. OPTI EPSI LINEAIRE;
  59. TEMPS ;
  60. DENSITE 0.1;
  61.  
  62. *---------------------- MAILLAGE ----------------------
  63. *----------- Q2 EST UN NOEUD POUR LE MODE NUMERO 2 ----
  64. Q1 = 0. 0. 0.;Q2 = (2.*0.783) 0. 0. ;Q3 = 2. 0. 0. ;
  65. LIG= Q1 D Q2 D Q3 ;
  66. OEIL1 = 5 5 5 ;
  67.  
  68. SI(NEG GRAPH 'N');
  69. TRAC OEIL1 LIG ;
  70. FINSI;
  71.  
  72. STAN= MODE LIG MECANIQUE POUT ;
  73.  
  74. *------------ MATERIAU ET CARATERISTIQUES -------------
  75. MATPL1=MATE STAN YOUNG 2.E11 NU 0.3 RHO 7800;
  76. CARPL1=CARA STAN SECT 0.01 INRY 6.25E-6 INRZ 1.E-3 TORS 1.E-2;
  77. MATPL1=MATPL1 ET CARPL1;
  78.  
  79. *------------------ RIGIDITE ET MASSE -----------------
  80. RIGPL1 =RIGI STAN MATPL1;
  81. MASPLA1=MASS STAN MATPL1 ;
  82.  
  83. *------------------ ON BLOQUE Q1 ----------------------
  84. BLOQ1 =BLOQ DEPL ROTA Q1 ;
  85. RIGPLA1=RIGPL1 ET BLOQ1 ;
  86.  
  87. *______________________________________________________
  88. * PREMIERE OPTION (INTERVALLE)
  89. * ON SEPARE LES MODES PAR DICHOTOMIE
  90. * PUIS ON LANCE LES ITERATIONS INVERSES
  91. *______________________________________________________
  92. MODPLA1=VIBR INTE 10. 120. RIGPLA1 MASPLA1 ;
  93.  
  94. *______________________________________________________
  95. * DEUXIEME OPTION (PROCHE)
  96. * ON LANCE LES ITERATIONS INVERSES
  97. * A PARTIR DES FREQUENCES CONTENUES
  98. * DANS LE LISTREEL
  99. *______________________________________________________
  100. PR=PROG 17. 110.;
  101. MODPLA2=VIBR PROC PR RIGPLA1 MASPLA1 ;
  102.  
  103. *______________________________________________________
  104. * TROISIEME OPTION (SIMULTANE)
  105. * ON UTILISE LA METHODE DE LANCZOS
  106. * (PROJECTION SUR UN SOUS-ESPACE)
  107. *______________________________________________________
  108. MODPLA3=VIBR SIMU 1. 2 RIGPLA1 MASPLA1 ;
  109. *______________________________________________________
  110. * 4EME OPTION (IRAM)
  111. *______________________________________________________
  112. MODPLA4=VIBR IRAM 1. 2 RIGPLA1 MASPLA1 ;
  113. *
  114. *---------------------- Resultats ---------------------
  115. *
  116. OPTI ECHO 0;
  117. SAUTER PAGE;
  118. F1= MODPLA1 . 'MODES' . 1 . 'FREQUENCE';
  119. G1= MODPLA1 . 'MODES' . 2 . 'FREQUENCE' ;
  120. F2= MODPLA2 . 'MODES' . 1 . 'FREQUENCE' ;
  121. G2= MODPLA2 . 'MODES' . 2 . 'FREQUENCE' ;
  122. F3= MODPLA3 . 'MODES' . 1 . 'FREQUENCE' ;
  123. G3= MODPLA3 . 'MODES' . 2 . 'FREQUENCE' ;
  124. F4= MODPLA4 . 'MODES' . 1 . 'FREQUENCE' ;
  125. G4= MODPLA4 . 'MODES' . 2 . 'FREQUENCE' ;
  126. *
  127. MESS '*';
  128. MESS '******** ON VERIFIE LES FREQUENCES';
  129. MESS '*';
  130. MESS ' ANALYTIQUE * INTERVALLE * PROCHE * SIMULTANE * IRAM ';
  131. MESS ' -------------*-----------------*----------- -----*-------------';
  132. MESS ' MODE 1 17.71 * ' F1 ' * ' F2 ' * ' F3 ' * ' F4;
  133. MESS ' MODE 2 110.98 * ' G1 ' * ' G2 ' * ' G3 ' * ' G4;
  134. MESS ' ';
  135. MESS ' ';
  136. MESS '*';
  137. MESS '******** ON VERIFIE LA DEFORMEE DU DEUXIEME MODE';
  138. MESS '*';
  139. MESS ' ';
  140. X1=EXTR (MODPLA1 . 'MODES' . 2 . 'DEFORMEE_MODALE') UZ Q2;
  141. X2=EXTR (MODPLA2 . 'MODES' . 2 . 'DEFORMEE_MODALE') UZ Q2;
  142. X3=EXTR (MODPLA3 . 'MODES' . 2 . 'DEFORMEE_MODALE') UZ Q2;
  143. X4=EXTR (MODPLA4 . 'MODES' . 2 . 'DEFORMEE_MODALE') UZ Q2;
  144. MESS ' ANALYTIQUE * INTERVALLE * PROCHE * SIMULTANE * IRAM';
  145. MESS ' -------------*-----------------*----------- -----*-------------';
  146. MESS 'MODE 2 0.00 * ' X1 ' * ' X2 ' * ' X3 ' *' X4;
  147. TEMPS ;
  148. * CODE FONCTIONNEMENT
  149. FREF=17.71;
  150. GREF=110.98;
  151. * le point Q2 est proche du "noeud" du 2eme mode
  152. XREF= 0.;
  153. F = prog F1 F2 F3 F4;
  154. G = prog G1 G2 G3 G4;
  155. X = prog X1 X2 X3 X4;
  156. RES_F = 100 * (MAXI 'ABS' ((F-FREF)/FREF));
  157. RES_G = 100 * (MAXI 'ABS' ((G-GREF)/GREF));
  158. RES_X = 100 * (MAXI 'ABS' X);
  159.  
  160. SI((RES_F <EG 1.) ET (RES_G <EG 1.) ET (RES_X <EG 1.));
  161. ERRE 0;
  162. SINO;
  163. ERRE 5;
  164. FINSI;
  165.  
  166. FIN;
  167.  
  168.  
  169.  
  170.  
  171.  
  172.  
  173.  
  174.  
  175.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales