Télécharger dyna5.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : dyna5.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Dyna5.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. * CAS TEST DU 01/07/92 PROVENANCE : PHIL
  8. * MODIFICATION D. COMBESCURE 30/09/2005
  9. OPTI ECHO 1;
  10. *GRAPH='O';
  11. GRAPH='N';
  12. SAUT PAGE ;
  13. *******************************************************
  14. *
  15. * DYNA5 - Test de sous-structuration par 3 méthodes
  16. *
  17. * La fréquence propre d'une poutre est égale à 65 Hz.
  18. * On se propose de retrouver cette fréquence par trois
  19. * méthodes de sous-structuration.
  20. *
  21. * Pour cela on décompose la poutre en deux morceaux
  22. * de meme longueur.
  23. *
  24. *
  25. * Q1 poutre 1 Q2
  26. * .--------------..------------.
  27. * Q3 poutre 2 Q4
  28. *
  29. *
  30. * Les trois méthodes de sous-structuration correspon-
  31. * dent aux conditions aux limites de l'extrémité
  32. * commune Q2 et Q3 des deux morceaux de poutres :
  33. * * Q2 libre - Q3 libre
  34. * * Q2 bloque - Q3 bloque
  35. * * Q2 bloque - Q3 libre
  36. *
  37. * A ces trois méthodes correspondent trois manières de
  38. * décrire les liaisons entre sous-structures
  39. * (opérateur RELA).
  40. *
  41. *******************************************************
  42. *
  43. TITRE 'DYNA5 - METHODES DE SOUS-STRUCTURATION' ;
  44. OPTIO DIME 3 ELEM SEG2 MODE TRID IMPI 0;
  45. OPTI EPSI LINEAIRE;
  46. *OPTION TRAC BENS;
  47. SOL=TABLE;
  48. TEMPS ;
  49. *
  50. *______________________________________________________
  51. * PREMIERE METHODE LIBRE-LIBRE
  52. *______________________________________________________
  53. *
  54. *---- Définition de la géométrie de la 1ère poutre ----
  55. *
  56. Q1 = 0. 0. 0.; Q2 =2. 0. 0.;
  57. LIG1= D 12 Q1 Q2;
  58. OEIL1 = 5 5 5 ;
  59. * TRACE OEIL1 LIG1 ;
  60. *
  61. *---- Type de calcul, matériau et caractéristiques ----
  62. *---------------- de la 1ère poutre -------------------
  63. *
  64. MO1= MODE LIG1 MECANIQUE ELASTIQUE POUT ;
  65.  
  66. MATPL1=MATE MO1 YOUNG 2.E11 NU 0.3 RHO 7800;
  67. CARPL1= 'CARA' MO1 SECT 0.1 INRY 2.08E-7 INRZ 3.33E-8
  68. TORS 2.41E-7;
  69. MATPL1=MATPL1 ET CARPL1;
  70. *
  71. *------ Rigidité, masse et conditions aux limites -----
  72. *----------------- de la 1ère poutre ------------------
  73. *
  74. RIGPL1 =RIGI MATPL1 MO1 ;
  75. MASPLA1=MASS MATPL1 MO1 ;
  76. BLOQ1=BLOQ DEPL ROTA Q1 ;
  77. RIGPLA1=RIGPL1 ET BLOQ1 ;
  78. *
  79. *---- Recherche des modes propres de la 1ère poutre ---
  80. *
  81. PR=PROG 0.4 ;
  82. MODPLA1=VIBR PROC PR RIGPLA1 MASPLA1;
  83. *
  84. *---- Définition de la géométrie de la 2ème poutre ----
  85. *
  86. Q3 =2. 0. 0.; Q4 =4. 0. 0.;
  87. LIG2= D 12 Q3 Q4;
  88. * TRAC OEIL1 LIG2 ;
  89. *
  90. POUTRE=LIG1 ET LIG2 ;
  91. SI(NEG GRAPH 'N');
  92. TRAC OEIL1 POUTRE;
  93. FINSI;
  94. *
  95. *---- Type de calcul, matériau et caractéristiques ----
  96. *---------------- de la 2ème poutre -------------------
  97. *
  98. MO2= MODE LIG2 MECANIQUE ELASTIQUE POUT ;
  99. MATPL2=MATE MO2 YOUNG 2.E11 NU 0.3 RHO 7800;
  100. CARPL2= 'CARA' MO2 SECT 0.1 INRY 2.08E-7 INRZ 3.33E-8
  101. TORS 2.41E-7;
  102. MATPL2=MATPL2 ET CARPL2;
  103. *
  104. *----- Rigidité, masse et conditions aux limites ------
  105. *---------------- de la 2ème poutre -------------------
  106. *
  107. RIGPL2 =RIGI MATPL2 MO2 ;
  108. MASPLA2=MASS MATPL2 MO2 ;
  109. BLOQ4=BLOQ DEPL ROTA Q4;
  110. RIGPLA2=RIGPL2 ET BLOQ4 ;
  111. *
  112. *---- Recherche des modes propres de la 2ème poutre ---
  113. *
  114. MODPLA2=VIBR PROC PR RIGPLA2 MASPLA2;
  115. *
  116. * Création des sous-structures associées aux 2 poutres
  117. *
  118. SPLA1=STRU RIGPLA1 MASPLA1 ;
  119. SPLA2=STRU RIGPLA2 MASPLA2 ;
  120. ELM2=ELST Q2 SPLA1;
  121. ELM3=ELST Q3 SPLA2;
  122. PR2=PROG 1. ;PR3=PROG -1. ;
  123. *
  124. *--- Description des liaisons entre sous-structures ---
  125. *
  126. LIUX=RELA ELM2 UX PR2 ELM3 UX PR3;
  127. LIUY=RELA ELM2 UY PR2 ELM3 UY PR3;
  128. LIUZ=RELA ELM2 UZ PR2 ELM3 UZ PR3;
  129. LIRX=RELA ELM2 RX PR2 ELM3 RX PR3;
  130. LIRY=RELA ELM2 RY PR2 ELM3 RY PR3;
  131. LIRZ=RELA ELM2 RZ PR2 ELM3 RZ PR3;
  132. ENCL=LIUY ET LIRX ET LIRY ET LIRZ ET LIUX ET LIUZ;
  133. *
  134. * -Création des bases modales associées aux 2 poutres -
  135. *
  136. SOL1 = SOLS ENCL SPLA1;
  137. SOL2 = SOLS ENCL SPLA2;
  138. BASE1=BASE SPLA1 MODPLA1 ENCL SOL1;
  139. BASE2=BASE SPLA2 MODPLA2 ENCL SOL2;
  140. *
  141. *------------------ Base modale totale ----------------
  142. *---------------- correspondant à la réunion des ------
  143. *------------------- deux bases élémentaires ----------
  144. *
  145. BASET= BASE1 ET BASE2 ;
  146. RIGMO = RIGI BASET ;
  147. MASMO = MASS BASET ;
  148. *
  149. *------------ Recherche de la 1ère fréquence ----------
  150. *------------ propre de la structure totale -----------
  151. *
  152. SOL.1= VIBR PROC (PROG 0.65) MASMO RIGMO ;
  153. FREQ1=TIRE (SOL.1) FREQ RANG 1;
  154. *
  155. SOLL = SYNT (SOL.1) BASET;
  156. SOLB = TRADUIRE SOLL;
  157. DEFMOD1 = SOLB. 1 . DEFORMEE_MODALE;
  158. SI (EGA GRAPH 'O');
  159. TRAC (DEFO (LIG1 ET LIG2) DEFMOD1);
  160. FINSI;
  161. *
  162. *
  163. *______________________________________________________
  164. * DEUXIEME METHODE BLOQUE-BLOQUE
  165. *______________________________________________________
  166. *
  167. *
  168. *-------------------- Conditions aux limites ----------
  169. *--------------- sur l'extrémité de la 1ère poutre ----
  170. *
  171. BLOQUX2=BLOQ UX Q2;
  172. BLOQUY2=BLOQ UY Q2;
  173. BLOQUZ2=BLOQ UZ Q2;
  174. BLOQRX2=BLOQ RX Q2;
  175. BLOQRY2=BLOQ RY Q2;
  176. BLOQRZ2=BLOQ RZ Q2;
  177. *
  178. *------------ Rigidité de la 1ère poutre --------------
  179. *
  180. RIGPLA1=RIGPL1 ET BLOQ1
  181. ET BLOQUX2 ET BLOQUY2 ET BLOQUZ2 ET BLOQRX2 ET
  182. BLOQRY2 ET BLOQRZ2;
  183. *
  184. *---- Recherche des modes propres de la 1ère poutre ---
  185. *
  186. PR1=PROG 2.6 ;
  187. MODPLA1=VIBR PROC PR1 RIGPLA1 MASPLA1;
  188. *
  189. *---------------- Conditions aux limites --------------
  190. *------------ sur l'extrémité de la 2ème poutre -------
  191. *
  192. *- Le point Q2 de la 1ère poutre et le point Q3 de la -
  193. *-------- 2ème poutre ont les memes coordonnées -------
  194. *
  195. BLOQUX3=BLOQ UX Q3;
  196. BLOQUY3=BLOQ UY Q3;
  197. BLOQUZ3=BLOQ UZ Q3;
  198. BLOQRX3=BLOQ RX Q3;
  199. BLOQRY3=BLOQ RY Q3;
  200. BLOQRZ3=BLOQ RZ Q3;
  201. *
  202. *------------ Rigidité de la 2ème poutre --------------
  203. *
  204. RIGPLA2=RIGPL2 ET BLOQ4
  205. ET BLOQUX3 ET BLOQUY3 ET BLOQUZ3 ET BLOQRX3 ET
  206. BLOQRY3 ET BLOQRZ3;
  207. *
  208. *---- Recherche des modes propres de la 2ème poutre ---
  209. *
  210. MODPLA2=VIBR PROC PR1 RIGPLA2 MASPLA2;
  211. *
  212. * Création des sous structures associées aux 2 poutres
  213. *
  214. SPLA1=STRU RIGPLA1 MASPLA1 ;
  215. SPLA2=STRU RIGPLA2 MASPLA2 ;
  216. CLUX2=CLST SPLA1 BLOQUX2;
  217. CLUY2=CLST SPLA1 BLOQUY2;
  218. CLUZ2=CLST SPLA1 BLOQUZ2;
  219. CLRX2=CLST SPLA1 BLOQRX2;
  220. CLRY2=CLST SPLA1 BLOQRY2;
  221. CLRZ2=CLST SPLA1 BLOQRZ2;
  222. CLUX3=CLST SPLA2 BLOQUX3;
  223. CLUY3=CLST SPLA2 BLOQUY3;
  224. CLUZ3=CLST SPLA2 BLOQUZ3;
  225. CLRX3=CLST SPLA2 BLOQRX3;
  226. CLRY3=CLST SPLA2 BLOQRY3;
  227. CLRZ3=CLST SPLA2 BLOQRZ3;
  228. *
  229. *--- Description des liaisons entre sous-structures ---
  230. *
  231. PR2=PROG 1.;PR3=PROG 1.;
  232. LIUX=RELA CLUX2 LX PR2 CLUX3 LX PR3;
  233. LIUY=RELA CLUY2 LX PR2 CLUY3 LX PR3;
  234. LIUZ=RELA CLUZ2 LX PR2 CLUZ3 LX PR3;
  235. LIRX=RELA CLRX2 LX PR2 CLRX3 LX PR3;
  236. LIRY=RELA CLRY2 LX PR2 CLRY3 LX PR3;
  237. LIRZ=RELA CLRZ2 LX PR2 CLRZ3 LX PR3;
  238. ENCL=LIUY ET LIRX ET LIRY ET LIRZ ET LIUX ET LIUZ;
  239. *
  240. *--------- Création des bases modales élémentaires ----
  241. *------------- associées aux deux poutres -------------
  242. *
  243. SOL1 = SOLS ENCL SPLA1;
  244. SOL2 = SOLS ENCL SPLA2;
  245. BASE1=BASE SPLA1 MODPLA1 ENCL SOL1;
  246. BASE2=BASE SPLA2 MODPLA2 ENCL SOL2;
  247. *
  248. *------------------ Base modale totale ----------------
  249. *------------- correspondant à la réunion des ---------
  250. *---------------- deux bases élémentaires -------------
  251. *
  252. BASET= BASE1 ET BASE2 ;
  253. RIGMO = RIGI BASET ;
  254. MASMO = MASS BASET ;
  255. *
  256. *------------- Recherche de la 1ère fréquence ---------
  257. *-------------- propre de la structure totale ---------
  258. *
  259. SOL.2= VIBR PROC (PROG 0.65) MASMO RIGMO ;
  260. FREQ2=TIRE SOL.2 FREQ RANG 1;
  261. *
  262. SOLL = SYNT (SOL.2) BASET;
  263. SOLB = TRADUIRE SOLL;
  264. DEFMOD2 = SOLB. 1 . DEFORMEE_MODALE;
  265. SI (EGA GRAPH 'O');
  266. TRAC (DEFO (LIG1 ET LIG2) DEFMOD2);
  267. FINSI;
  268. *
  269. *
  270. *______________________________________________________
  271. * TROISIEME METHODE LIBRE-BLOQUE
  272. *______________________________________________________
  273. *
  274. *
  275. *------------ Rigidité et conditions aux limites ------
  276. *----------------- de la 1ère poutre ------------------
  277. *
  278. RIGPLA1=RIGPL1 ET BLOQ1
  279. ET BLOQUX2 ET BLOQUY2 ET BLOQUZ2 ET BLOQRX2 ET BLOQRY2
  280. ET BLOQRZ2;
  281. *
  282. *---- Recherche des modes propres de la 1ère poutre ---
  283. *
  284. PR1=PROG 2.6;
  285. MODPLA1=VIBR PROC PR1 RIGPLA1 MASPLA1;
  286. *
  287. *-------- Rigidité et conditions aux limites ----------
  288. *--------------- de la 2ème poutre --------------------
  289. *
  290. RIGPLA2=RIGPL2 ET BLOQ4;
  291. *
  292. *---- Recherche des modes propres de la 2ème poutre ---
  293. *
  294. PR2=PROG 0.41 ;
  295. MODPLA2=VIBR PROC PR2 RIGPLA2 MASPLA2;
  296. *
  297. *------------ Définition des sous-structures ----------
  298. *
  299. SPLA2=STRU RIGPLA2 MASPLA2 ;
  300. CL3=ELST SPLA2 Q3;
  301. *
  302. *---- Définition des liaisons entre sous-structures ---
  303. *
  304. PR=PROG 1;
  305. REL1=RELA CL3 UX 1 CLUX2 LX PR ;
  306. REL2=RELA CL3 UY 1 CLUY2 LX PR ;
  307. REL3=RELA CL3 UZ 1 CLUZ2 LX PR ;
  308. REL4=RELA CL3 RX 1 CLRX2 LX PR ;
  309. REL5=RELA CL3 RY 1 CLRY2 LX PR ;
  310. REL6=RELA CL3 RZ 1 CLRZ2 LX PR ;
  311. ENCL=REL1 ET REL2 ET REL3 ET REL4 ET REL5 ET REL6;
  312. *
  313. *--------- Création des bases modales élèmentaires ----
  314. *
  315. *SOL1 = SOLS ENCL SPLA1;
  316. *SOL2 = SOLS ENCL SPLA2;
  317. BASE1=BASE SPLA1 MODPLA1 ENCL;
  318. BASE2=BASE SPLA2 MODPLA2 ENCL;
  319. *
  320. *------------------ Base modale totale ----------------
  321. *------------- correspondant à la réunion des ---------
  322. *----------------- deux bases élémentaires ------------
  323. *
  324. BASET= BASE1 ET BASE2 ;
  325. RIGMO = RIGI BASET ;
  326. MASMO = MASS BASET ;
  327. *
  328. *---------- Recherche de la 1ère fréquence ------------
  329. *---------- propre de la structure totale -------------
  330. *
  331. SOL.3= VIBR PROC (PROG 0.65) MASMO RIGMO ;
  332. FREQ3=TIRE SOL.3 FREQ RANG 1;
  333. *______________________________________________________
  334. * RESULTATS
  335. *______________________________________________________
  336. SAUT PAGE ; SAUT 4 LIGNE ;
  337. MESS 'ON DOIT TROUVER UNE FREQUENCE DE 0.65 HZ';
  338. SAUT 2 LIGNE ;
  339. MESS 'PAR LA PREMIERE METHODE ON TROUVE : ' FREQ1;
  340. MESS 'PAR LA DEUXIEME METHODE ON TROUVE : ' FREQ2;
  341. MESS 'PAR LA TROISIEME METHODE ON TROUVE : ' FREQ3;
  342. TEMPS ;
  343. * CODE FONCTIONNEMENT
  344. SOLL = SYNT (sol.3) BASET;
  345. SOLB = TRADUIRE SOLL;
  346. DEFMOD3 = SOLB. 1 . DEFORMEE_MODALE;
  347. SI (EGA GRAPH 'O');
  348. TRAC (DEFO (LIG1 ET LIG2) DEFMOD3);
  349. FINSI;
  350. *
  351. *
  352. REF=0.65;
  353. RESI1=ABS((FREQ1-REF)/REF);
  354. RESI2=ABS((FREQ2-REF)/REF);
  355. RESI3=ABS((FREQ3-REF)/REF);
  356. SI((RESI1 <EG 5E-2) ET (RESI2 <EG 5E-2) ET
  357. (RESI3 <EG 5E-2));
  358. ERRE 0;
  359. SINO;
  360. ERRE 5;
  361. FINSI;
  362. FIN;
  363. *
  364. *
  365.  
  366.  
  367.  
  368.  
  369.  
  370.  
  371.  
  372.  
  373.  
  374.  
  375.  
  376.  
  377.  
  378.  
  379.  
  380.  
  381.  
  382.  
  383.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales