Télécharger dyna16.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : dyna16.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. ***************************************
  5. *
  6. * Portique soumis à un déplacement différentiel des appuis
  7. *
  8. * Calcul sur un mode dynamique et les modes statiques
  9. *
  10. * D. Combescure aout 2006
  11. *
  12. ***************************************
  13. *GRAPH = VRAI;
  14. GRAPH = FAUX;
  15. *COMPLET = VRAI;
  16. COMPLET = FAUX;
  17. *
  18. opti dime 2 elem seg2 mode plan cont;
  19. OPTI EPSI LINEAIRE;
  20. H = 3.;
  21. L = 4.;
  22. p1 = ((-0.5)*L) 0.;
  23. vv = 0. H;
  24. p1h = p1 plus vv;
  25. p2 = (0.5*L) 0.;
  26. p2h = p2 plus vv;
  27. n1 = 10;
  28. n2 = 20;
  29. a = 0.25;
  30. b = a;
  31. e1 = 30000.D6;
  32. ro1 = 2400.;
  33. nu1 = 0.30;
  34. sec1 = a*b;
  35. in1 = (1./12.)*(b*(a**3));
  36. lig1 = (d n1 p1 p1h) et (d n1 p2 p2h) et (d n2 p1h p2h);
  37. mod1 = MODE lig1 mecanique elastique TIMO;
  38. mat1 = MATE mod1 YOUN E1 NU nu1 RHO ro1
  39. SECT sec1 INRZ in1;
  40. KK1 = rigi mod1 mat1;
  41. CC1 = 0.001*KK1;
  42. MM1 = mass mod1 mat1;
  43. bl1 = BLOQ UY RZ p1;
  44. bl2 = BLOQ UY RZ p2;
  45. bl1u = BLOQ UX p1;
  46. bl2u = BLOQ UX p2;
  47. bltot = bl1 et bl2 et bl1u et bl2u;
  48. fh1 = DEPI bl1u 1.;
  49. fh2 = DEPI bl2u 1.;
  50. *
  51. * mode propre
  52. *
  53. vib1 = vibr proche (prog 1.) (lect 1) (KK1 et bltot) MM1;
  54. vib1b= traduire vib1;
  55. nmod = (dime (vib1b) ) - 2;
  56. repeter lab1 nmod;
  57. dep1 = vib1b. &lab1 . DEFORMEE_MODALE;
  58. fr1 = vib1b. &lab1 . FREQUENCE;
  59. titre fr1;
  60. * trac (defo lig1 dep1);
  61. fin lab1;
  62. *
  63. * Définition du chargement
  64. *
  65. T1 = 0.02;
  66. SI COMPLET;
  67. tfin = 50.*T1;
  68. SINON;
  69. tfin = 2.*T1;
  70. FINSI;
  71. ltemps = prog 0. T1 (2.*T1) (3.*T1) (4.*T1) 10.;
  72. lpacc1 = prog 0 1. -1. 0. 0. 0.;
  73. lpacc2 = prog 0 0. 1. -1. 0. 0.;
  74. dt = T1/20.;
  75. ltime = prog 0 pas dt 10.;
  76. evacc1 = evol manu ltime (ipol ltime ltemps lpacc1);
  77. evdep1 evvit1 = insi evacc1;
  78. evacc2 = evol manu ltime (ipol ltime ltemps lpacc2);
  79. evdep2 evvit2 = insi evacc2;
  80. prtimeb = prog 0 pas dt tfin;
  81. prdep1 = extr evdep1 ordo;
  82. prdep2 = extr evdep2 ordo;
  83. *
  84. *--------------------------------------------------------
  85. *
  86. * Méthode 1 => on impose le déplacement (calcul direct)
  87. *
  88. *---------------------------------------------------------
  89. cha1 = (char fh1 evdep1) et (char fh2 evdep2);
  90. *
  91. tab1 = table;
  92. tab1.'DEPL' = manu chpo lig1 2 ux 0 uy 0;
  93. tab1.'VITE' = manu chpo lig1 2 ux 0 uy 0;
  94. tab1.'CHAR' = cha1;
  95. tab1.'RIGI' = (KK1 et bltot);
  96. tab1.'AMOR' = CC1;
  97. tab1.'MASS' = MM1;
  98. tab1.'FREQ' = (0.25/dt);
  99. tab1.'INST' = prtimeb;
  100. tab1.'SAUV' = VRAI;
  101. tab2 = dynamic tab1;
  102. nn = dime tab2;
  103. prp1h = prog;
  104. repeter lab1 nn;
  105. si (ega &lab1 1);
  106. deft = defo lig1 (tab2 . &lab1 . DEPL) 100;
  107. sinon;
  108. deft = deft et
  109. (defo lig1 (tab2 . &lab1 . DEPL) 100);
  110. finsi;
  111. prp1h = prp1h et
  112. (prog (extr (tab2 . &lab1 . DEPL) p1h UX));
  113. fin lab1;
  114. Ev1UX1 = evol rouge manu prtimeb prp1h;
  115. SI GRAPH;
  116. dess (evol manu prtimeb prp1h);
  117. trac deft anime;
  118. FINSI;
  119. *---------------------------------------------------------------
  120. *
  121. * Méthode 2 => superposition de solution statique et dynamique
  122. * sur base physique
  123. *
  124. *---------------------------------------------------------------
  125. *
  126. * mode statique (à la main)
  127. *
  128. depsta1 = reso (KK1 et bltot) fh1;
  129. depsta2 = reso (KK1 et bltot) fh2;
  130. *
  131. fh12 = (-1.)*MM1*depsta1;
  132. fh22 = (-1.)*MM1*depsta2;
  133. cha2 = (char fh12 evacc1) et (char fh22 evacc2);
  134. *
  135. tab1 = table;
  136. tab1.'DEPL' = manu chpo lig1 2 ux 0 uy 0;
  137. tab1.'VITE' = manu chpo lig1 2 ux 0 uy 0;
  138. tab1.'CHAR' = cha2;
  139. tab1.'RIGI' = (KK1 et bltot);
  140. tab1.'AMOR' = CC1;
  141. tab1.'MASS' = MM1;
  142. tab1.'FREQ' = (0.25/dt);
  143. tab1.'INST' = prtimeb;
  144. tab1.'SAUV' = VRAI;
  145. tab2 = dynamic tab1;
  146. nn = dime tab2;
  147. prp1h2 = prog;
  148. prp1h2t = prog;
  149. repeter lab2 nn;
  150. depj = (tab2 . &lab2 . DEPL);
  151. depjt = depj +
  152. ((extr prdep1 &lab2)*depsta1)
  153. + ((extr prdep2 &lab2)*depsta2);
  154. si (ega &lab2 1);
  155. def2 = defo lig1 depj 1000;
  156. deft2 = defo lig1 depjt 1000;
  157. sinon;
  158. deft2 = deft2 et
  159. (defo lig1 depjt 1000);
  160. finsi;
  161. prp1h2 = prp1h2 et
  162. (prog (extr depj p1h UX));
  163. prp1h2t = prp1h2t et
  164. (prog (extr depjt p1h UX));
  165. fin lab2;
  166. ta = table;
  167. ta.2 = 'TIRR';
  168. ta.3 = 'TIRL';
  169. ta.4 = 'TIRL';
  170. Ev2UX1 = evol rouge manu prtimeb prp1h2t;
  171. *------------------------------------------------------------------
  172. *
  173. *
  174. * Méthode 3=> superposition de solution statique et dynamique
  175. * sur base modale
  176. *
  177. *------------------------------------------------------------------
  178. vib1 = vibr proche (prog 1.) (lect 1)
  179. (KK1 et bl1 et bl2 et bl1u et bl2u) MM1;
  180. SPLA1=STRU (KK1 et bl1 et bl2 et bl1u et bl2u) MM1 ;
  181. ELM1=CLST SPLA1 BL1u;
  182. ELM2=CLST SPLA1 BL2u;
  183. PR1=PROG 1. ;
  184. LIUX=(RELA ELM1 LX PR1) et (RELA ELM2 LX PR1);
  185. SOL1 = SOLS LIUX SPLA1;
  186. BASE1 = BASE SPLA1 VIB1 LIUX SOL1;
  187. *
  188. MODYN1 = TRADUIRE (EXTR BASE1 MODE);
  189. MOSTA1 = TRADUIRE (EXTR BASE1 STAT);
  190. *
  191. depsta1 = MOSTA1. 1 . DEFORMEE_MODALE;
  192. fh12 = (-1.)*MM1*depsta1;
  193. depsta2 = MOSTA1. 2 . DEFORMEE_MODALE;
  194. fh22 = (-1.)*MM1*depsta2;
  195. cha3 = (char fh12 evacc1) et (char fh22 evacc2);
  196. *
  197. vib1c= traduire vib1;
  198. tbas1 = table 'BASE_MODALE';
  199. tbas1.'MODES' = vib1c;
  200. *
  201. TRIG = TABLE 'RAIDEUR_ET_MASSE';
  202. TRIG.'RAIDEUR' = pjba tbas1 (KK1 et bl1 et bl2 et bl1u et bl2u) ;
  203. TRIG.'MASSE' = pjba tbas1 MM1;
  204. TAMOR = TABLE 'AMORTISSEMENT';
  205. TAMOR . 'AMORTISSEMENT' = PJBA tbas1 CC1;
  206. TCHAR = TABLE 'CHARGEMENT' ;
  207. TCHAR.'BASE_A' = pjba tbas1 cha3;
  208. *
  209. TSORT = TABLE 'SORTIE' ;
  210. TSORV = TABLE 'VARIABLE' ;
  211. TSORT.'VARIABLE' = TSORV ;
  212. TSORV.'VITESSE' = VRAI;
  213. TSORV.'DEPLACEMENT' = VRAI ;
  214. TSORV.'ACCELERATION' = VRAI ;
  215. *
  216. DTEX = (pi/12.6)/100.;
  217. NTT = ENTIER (tfin/DTEX);
  218. *
  219. * Appel à DYNE
  220. *
  221. TRESU = DYNE DE_VOGELAERE TRIG TAMOR TCHAR
  222. NTT DTEX TSORT ;
  223. *
  224. * Post-traitement
  225. *
  226. Ev3UXD1 = EVOL VERT RECO TRESU tbas1 'DEPL' P1h UX ;
  227. EV3UXS1 = EVOL MANU (EXTR Ev3UXD1 ABSC)
  228. (ipol (EXTR Ev3UXD1 ABSC) (extr evdep1 absc)
  229. ((extr evdep1 ordo)*(extr depsta1 p1h ux)));
  230. EV3UXS2 = EVOL MANU (EXTR Ev3UXD1 ABSC)
  231. (ipol (EXTR Ev3UXD1 ABSC) (extr evdep2 absc)
  232. ((extr evdep2 ordo)*(extr depsta2 p1h ux)));
  233. Ev3UX1 = EVOL MANU (EXTR Ev3UXD1 ABSC)
  234. ((EXTR Ev3UXD1 ORDO) + (EXTR Ev3UXS1 ORDO)
  235. + (EXTR Ev3UXS2 ORDO));
  236. *
  237. SI GRAPH;
  238. TRAC (DEFO LIG1 (MODYN1. 1 . DEFORMEE_MODALE));
  239. TRAC ((DEFO LIG1 depsta1) et
  240. (DEFO LIG1 depsta1 0. ROUG));
  241. TRAC ((DEFO LIG1 depsta2) et
  242. (DEFO LIG1 depsta2 0. ROUG));;
  243. TRAC ((DEFO LIG1 (depsta1 + depsta2)) et
  244. (DEFO LIG1 depsta2 0. ROUG));;
  245. trac lig1 (vecteur fh12 fx fy);
  246. trac lig1 (vecteur fh22 fx fy);
  247. trac lig1 (vecteur (fh12 et fh22) fx fy);
  248. dess (evacc1 et (evacc2 coul rouge)) xbord 0. 0.20;
  249. dess (evdep1 et (evdep2 coul rouge)) xbord 0. 0.20;
  250. DESS (Ev3UXD1 et Ev3UXS1 et Ev3UXS2) xbord 0 0.2;
  251. DESS (Ev1UX1 et Ev2UX1 et Ev3UX1) xbord 0. 1.;
  252. FINSI;
  253. *
  254. TEST = MAXI (PROG
  255. ((MAXI (EXTR Ev2UX1 ORDO)) - (MAXI (EXTR Ev1UX1 ORDO)))
  256. ((MAXI (EXTR Ev3UX1 ORDO)) - (MAXI (EXTR Ev1UX1 ORDO)))) ABS;
  257. SI (TEST > 1.D-5);
  258. ERR 4;
  259. LIST TEST;
  260. FINSI;
  261. *
  262. FIN;
  263. *
  264.  
  265.  
  266.  
  267.  
  268.  
  269.  
  270.  
  271.  
  272.  
  273.  
  274.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales