Télécharger dpressupp.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : dpressupp.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *---------------------------------------------------------
  5. * Cas test de recette de TONUS multiD version 1.0
  6. *
  7. * Depressurisation d'une enceinte type Phébus
  8. *
  9. * Le maillage correspond à une enceinte cylindrique
  10. * d'environ 10 m3 avec un mur en contact avec la
  11. * paroi verticale (10 cm d'acier)
  12. * Tout le volume est initialement a 1.86bar et 90oC
  13. * et la température du mur est mise à 40oC
  14. * au début du calcul. On calcule la depressurisation
  15. * de cette enceinte sur 50 secondes en n'injectant pas de
  16. * vapeur. La temperature d injection est de 90oC.
  17. * Ce test (un peu long)
  18. * verifie le demarrage de la condensation "
  19. * verifie l'evolution moyenne de la temprature gaz
  20. * verifie la pression max a 50"
  21. * verifie la vitesse max a 50" (Convection naturelle)
  22. * Auteurs : E. Studer, J.P. Magnaud Novembre 1999
  23. * revisite Avril 2002
  24. * Ce test peut utiliser la procedure enceinte
  25. * 1/ il faut l'avoir (ce n'est pas donne a tout le monde)
  26. * 2/ faire enceinte = mot 'ENCEINTE' ;
  27. *--------------------------------------------------------
  28. COMPLET = FAUX ;
  29. *COMPLET = VRAI ;
  30. GRAPH = VRAI ;
  31. GRAPH = FAUX ;
  32.  
  33. TCPT = FAUX;
  34. TKPR = VRAI;
  35. TRESOU = FAUX;
  36. IMPARA = VRAI;
  37.  
  38. 'SI' COMPLET ;
  39.  
  40. nbit=100;
  41. DT0 = 1. ;
  42. n1 = 1 ; n2 = 4 ; n3 = 4 ;
  43. n4 = 8 ; nn = 2 ;
  44.  
  45. 'SINON' ;
  46.  
  47. nbit= 5 ;
  48. DT0 = 10. ;
  49. n1 = 1 ; n2 = 2 ; n3 = 4 ;
  50. n4 = 4 ; nn = 1 ;
  51.  
  52. 'FINSI' ;
  53.  
  54. *--------------------------------------------------------
  55. * Definition du maillage de l'enceinte cylindrique
  56. *
  57. 'OPTI' 'DIME' 3 'ELEM' 'CU20' ;
  58.  
  59. ri = 1.052 ; sp = 0.10 ; hc = 4.163 ;
  60.  
  61.  
  62.  
  63. epsi = 1.000e-2 ; ;
  64.  
  65. p0 = 0.000 0.000 0.000 ;
  66. px = -1000.000 0.000 0.000 ;
  67. py = 0.000 -1000.000 0.000 ;
  68. pz = 0.000 0.000 1000.000 ;
  69. cd = 0.000 0.000 -20.000 ;
  70. ph0 = 0.000 0.000 hc ;
  71. phx = ri 0.000 hc ;
  72. phy = 0.000 ri hc ;
  73.  
  74. fg1 = 0.25 ;
  75. fg2 = fg1 * (2.0 ** 0.5) / 2. ;
  76.  
  77. p1 = (ri*fg1) 0.000 0.000 ;
  78. p2 = (ri*fg2) (ri*fg2) 0.000 ;
  79. p3 = 0.000 (ri*fg1) 0.000 ;
  80. p4 = ri 0.000 0.000 ;
  81. p5 = 0.000 ri 0.000 ;
  82. p6 = (ri+sp) 0.000 0.000 ;
  83. p7 = 0.000 (ri+sp) 0.000 ;
  84.  
  85. * Hauteur de l'enceinte
  86. h1 = 4.163 ;
  87. * Vecteur de translation
  88. v1 = 0. 0. h1 ;
  89.  
  90. l1 = 'DROI' p0 p1 n1 ;
  91. l2 = 'DROI' p1 p2 n1 ;
  92. l3 = 'DROI' p2 p3 n1 ;
  93. l4 = 'DROI' p3 p0 n1 ;
  94. l5 = 'CERC' p4 p0 p5 (2*n1) ;
  95. l6 = 'CERC' p6 p0 p7 (2*n1) ;
  96.  
  97. basf0= 'DALL' l1 l2 l3 l4 'PLAN' ;
  98. basf1=('REGL' (l2 'ET' l3) l5 n2) ;
  99. l44= cote 2 basf1;
  100. ax4= (inve l4) et l44 ;
  101. l11= cote 4 basf1;
  102. ax1= l11 et (inve l1) ;
  103.  
  104. basf = basf0 'ET' ('REGL' (l2 'ET' l3) l5 n2) ;
  105. 'ELIM' basf epsi ;
  106. basf = basf 'ET' ('SYME' basf 'DROI' p0 p3) ;
  107. ax11 = ('SYME' ax1 'DROI' p0 p3) 'ET' (inve ax1) ;
  108. 'ELIM' basf epsi ;
  109. basf = basf 'ET' ('SYME' basf 'DROI' p0 p1) ;
  110. ax44 = (inve ax4) 'ET' ('SYME' ax4 'DROI' p0 p4) ;
  111. 'ELIM' basf epsi ;
  112.  
  113. basm = 'REGL' l5 l6 n3 ;
  114. basm = basm 'ET' ('SYME' basm 'DROI' p0 p3) ;
  115. 'ELIM' basm epsi ;
  116. basm = basm 'ET' ('SYME' basm 'DROI' p0 p1) ;
  117. 'ELIM' basm epsi ;
  118.  
  119. * Creation du volume
  120.  
  121. dx = ri / 2. ;
  122. nz1 = ('ENTIER' ( h1 / dx ))*nn ;
  123.  
  124. bas = basf 'VOLU' nz1 'TRAN' v1 ;
  125. mbas = basm 'VOLU' nz1 'TRAN' v1 ;
  126. mbas = mbas 'COUL' 'ROUG' ;
  127. plan1 = ax11 'TRAN' nz1 v1 ;
  128. plan4 = ax44 'TRAN' nz1 v1 ;
  129. 'ELIM' (bas et plan1 et plan4) epsi ;
  130.  
  131. mt = bas ;
  132. wall = mbas ;
  133. elim (mt et wall) epsi ;
  134.  
  135. * Localisation d'une brèche éventuelle au bas de l'enceinte
  136.  
  137. pjg = 'POIN' basf 'PROC' (0.000 0.000 0.000) ;
  138. jg = ('ELEM' basf 'APPUIE' 'LARGEMENT' pjg) 'COUL' 'VERT' ;
  139.  
  140. *--------------------------------------------------------------------
  141. * Fin de la définition du maillage
  142. *--------------------------------------------------------------------
  143.  
  144. *--------------------------------------------------------------------
  145. * Début de l'initialisation de la procédure ENCEINTE : table RXT
  146. *--------------------------------------------------------------------
  147.  
  148. rxt = 'TABLE' ;
  149. rxt.'VERSION'= 'V0' ;
  150. rxt.'TCPT' = TCPT ;
  151. rxt.'TKPR' = TKPR ;
  152. rxt.'TRESOU' = TRESOU ;
  153. rxt.'IMPARA' = IMPARA ;
  154.  
  155. *-- Nom du volume fluide
  156. rxt.'vtf' = mt ;
  157. rxt.'epsi' = epsi ;
  158.  
  159. *-- Definition des murs de l'enceinte : ici un seul mur
  160. *-- en ACIER dont on traitera la thermique dans l'épaisseur
  161. *-- et que l'on initialise a 40oC
  162.  
  163. *-- On definit d'abort la matériau ACIER avec sa conductivite
  164. *-- thermique LAMBDA (W/m/K) et le produit ro*Cp (J/m3/K)
  165. rxt.'THERMP' = VRAI ;
  166. rxt.'vtp' = wall ;
  167. rxt.'LAMBDA' = 15. ;
  168. rxt.'ROCP' = 3.9E6 ;
  169. rxt.'Tp0' = 40. ;
  170. rxt.'ECHAN' = 10. ;
  171.  
  172. *-- Conditions initiales dans l'enceinte de test
  173. rxt.'TF0' = 90.0 ;
  174. rxt.'PT0' = 1.86076e5 ;
  175. rxt.'Yvap0' = 0.2728 ;
  176.  
  177. *-- On positionne une brèche
  178. * rxt.'breche' = jg ;
  179. * rxt.'diru1' = 0 0 1 ;
  180.  
  181. *-- On definit un point interne au maillage pour imposer la valeur de
  182. *-- la pression
  183. rxt.'pi' = (0.0 0.0 0.5) ;
  184.  
  185. *-- On indique que le calcul comporte de la vapeur d'eau
  186. rxt.'VAPEUR' = VRAI ;
  187.  
  188. *-- On active le recalcul automatique du préconditionnement
  189. *-- toutes les 5 itérations
  190. rxt.'FRPREC' = 5 ;
  191. rxt.'DETMAT' = VRAI ;
  192.  
  193. *-- Definition du scenario thermohydraulique
  194. * rxt.'scenario' = table ;
  195.  
  196. *-- Conditions a la breche (Obligatoire pour l'instant)
  197. * rxt.'scenario'.'t' = prog 0.0 1000.0 ;
  198. * rxt.'scenario'.'qeau' = prog 0.000 0.000 ;
  199. * rxt.'scenario'.'qair' = prog 0.000 0.000 ;
  200. * rxt.'scenario'.'tinj' = prog 90.0 90.0 ;
  201.  
  202. *-- On impose le pas de temps (s)
  203. rxt.'DT0' = DT0 ;
  204.  
  205. *-- On impose la viscosite turbulente (m2/s)
  206. rxt.'MODTURB'='NUTURB' ;
  207. rxt.'NUT' = 1.e-2 ;
  208.  
  209. *-- On lance le calcul sur 20 itérations d'une seconde
  210. rxt.'GRAPH'=GRAPH ;
  211.  
  212. EXECRXT 2 rxt ;
  213. EXECRXT (nbit - 2) rxt ;
  214.  
  215.  
  216. list rxt.TIC.'Tfm' ;
  217. list rxt.TIC.'PT' ;
  218. list rxt.TIC.'Qc' ;
  219. list rxt.TIC.'LMAXU';
  220.  
  221. 'SI' (NON COMPLET) ;
  222.  
  223.  
  224. ltfm=Prog
  225. *90.000 82.759 65.078 60.601 56.047 51.777 ;
  226. 90.000 82.759 68.655 63.051 58.082 53.682 ;
  227.  
  228. lPT =Prog
  229. *1.86076E+05 1.83833E+05 1.73114E+05 1.55674E+05 1.49937E+05 1.47211E+05 ;
  230. 1.86076E+05 1.83833E+05 1.74918E+05 1.61022E+05 1.54803E+05 1.51174E+05 ;
  231. Lqc =Prog
  232. *0.0000 7.74979E-02 4.99805E-02 3.61752E-02 3.16373E-02 2.90635E-02 ;
  233. 0.0000 5.58061E-02 4.29392E-02 3.41083E-02 3.01362E-02 2.76068E-02 ;
  234.  
  235. Lmaxu=Prog
  236. *0.0000 0.0000 0.30666 0.45360 0.55440 0.30930 ;
  237. 0.0000 0.0000 0.30666 0.45360 0.49687 0.29288 ;
  238.  
  239. tic=rxt.'TIC' ;
  240. ERtf=SOMM( abs (ltfm - tic.'Tfm') )/ 80. ;
  241. ERPT=SOMM( abs (lPT - tic.'PT' ) ) /1.e5 ;
  242. ERQc=SOMM( abs (lqc - tic.'Qc' ) ) ;
  243. ERum=SOMM( abs (Lmaxu - tic.'LMAXU' ) )/2. ;
  244.  
  245. Mess 'ERtf=' ERtf 'ERPT=' ERPT 'ERQc=' ERQc 'ERum=' ERum ;
  246.  
  247. Si (ERtf '>' 1.e-4) ; erreur 5 ; Finsi ;
  248. Si (ERPT '>' 1.e-4) ; erreur 5 ; Finsi ;
  249. Si (ERQc '>' 1.e-4) ; erreur 5 ; Finsi ;
  250. Si (ERum '>' 1.e-3) ; erreur 5 ; Finsi ;
  251.  
  252. 'FINSI' ;
  253.  
  254. Si GRAPH ;
  255.  
  256. $vtf=rxt.'GEO'.'$vtf' ;
  257. mt =doma $vtf maillage ;
  258. Mpl1=chan 'QUAF' plan1 ;
  259. Mpl4=chan 'QUAF' plan4 ;
  260. ELIM (mt et Mpl1 et Mpl4) epsi ;
  261. $mpl1= mode Mpl1 'NAVIER_STOKES' MACRO ;
  262. $mpl4= mode Mpl4 'NAVIER_STOKES' MACRO ;
  263. plan1= doma $mpl1 maillage ;
  264. plan4= doma $mpl4 maillage ;
  265. plan=plan1 et plan4 ;
  266.  
  267. paroif = rxt.'GEO'.'paroif';
  268. rho=rxt.'TIC'.'RHO';
  269. rvp=rxt.'TIC'.'RVP';
  270. tf=rxt.'TIC'.'TF';
  271. un=rxt.'TIC'.'UN' ;
  272. un1=redu un plan ;
  273. ung= vect un1 1. ux uy uz jaune ;
  274. trace ung plan ;
  275. opti isov suli ;
  276. trace rho plan 'TITRE'' Rho' ;
  277. trace rvp plan 'TITRE'' Rvp' ;
  278. trace tf plan 'TITRE'' Tf ' ;
  279.  
  280. trace rho paroif 'TITRE'' Rho' ;
  281. trace rvp paroif 'TITRE'' Rvp' ;
  282. trace Tf paroif 'TITRE'' Tf ' ;
  283. Fcond = tic.'Fcondw';
  284. trace Fcond paroif 'TITRE' ' Flux de condensation Kg / m**2 ' ;
  285.  
  286. axe = p0 d nz1 (p0 plus v1) ;
  287. axe = chan axe 'QUAF' ;
  288. elim (axe et mt) epsi ;
  289.  
  290. evr= evol 'CHPO' rho axe ;
  291. dess evr 'TITRE' ' Rho axe ';
  292.  
  293. evt = evol 'CHPO' Tf axe ;
  294. dess evt 'TITRE' ' Température axe ';
  295.  
  296. evvp= evol 'CHPO' rvp axe ;
  297. dess evvp 'TITRE' ' rvp axe ';
  298.  
  299.  
  300. 'FINSI' ;
  301.  
  302.  
  303. 'FIN' ;
  304.  
  305.  
  306.  
  307.  
  308.  
  309.  
  310.  
  311.  
  312.  
  313.  
  314.  
  315.  
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales