Télécharger dilthe.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier dilthe.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. 'OPTION' 'ECHO' 0 ;
  5. ************************************************************************
  6. * NOM : DILTHE
  7. * DESCRIPTION : Dilatation thermique d'un cube encastre sur deux faces
  8. * opposees
  9. *
  10. * Ce cas-test sortait en erreur de non-convergence dans
  11. * les iterations internes au refroidissement pour cause
  12. * de critere de convergence trop serre dans ccoin0.eso
  13. * (< precision machine).
  14. * Correction faite en fiche anomalie 9553
  15. *
  16. *
  17. *
  18. * LANGAGE : GIBIANE-CAST3M
  19. * AUTEURS : Harry POMMIER (CEA/DEN/DM2S/SEMT/LTA)
  20. * + modifs Stéphane GOUNAND (CEA/DEN/DM2S/SEMT/LTA)
  21. * mél : stephane.gounand@cea.fr
  22. **********************************************************************
  23. * VERSION : v1, 20/09/2017, version initiale
  24. * HISTORIQUE : v1, 20/09/2017, création
  25. * HISTORIQUE :
  26. * HISTORIQUE :
  27. ************************************************************************
  28. *
  29. interact = faux ;
  30. graph = faux ;
  31. *
  32. *Dilatation thermique d'un cube encastre sur deux faces opposees
  33. *
  34. 'OPTI' 'DIME' 3 ;
  35. 'OPTI' 'ELEM' 'CUB8' ;
  36. *
  37. *MAILLAGE
  38. ne = 2 ;
  39. P1 = 0. 0. 0. ;
  40. P2 = 0. 0.01 0. ;
  41. P3 = 0. 0.01 0.01 ;
  42. P4 = 0. 0. 0.01 ;
  43. L12 = 'DROI' ne P1 P2 ;
  44. L23 = 'DROI' ne P2 P3 ;
  45. L34 = 'DROI' ne P3 P4 ;
  46. L41 = 'DROI' ne P4 P1 ;
  47. S1 = 'DALL' L12 L23 L34 L41 ;
  48. MAILT = 'VOLU' 'TRAN' ne S1 (0.01 0. 0.) ;
  49. *TRAC MAILT ;
  50.  
  51. *MODELES
  52. MODTHER = 'MODE' MAILT 'THERMIQUE' 'CONDUCTION' ;
  53. MODMECA = 'MODE' MAILT 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  54. 'PLASTIQUE' 'CHABOCHE1' ;
  55.  
  56. *MATERIAUX
  57. *THER
  58. LTK = 'PROG' 20. 100. 200. 300. 400. 500. 600. 700.
  59. 800. 900. 1000. 1200. 1400. 10000. ;
  60. LK = 'PROG' 14.7 15.8 17.2 18.6 20. 21.1 22.2 23.2
  61. 24.1 24.8 25.5 26.9 28.3 28.3 ;
  62. LTRHO = 'PROG' 20. 200. 400. 600. 800.
  63. 1000. 1200. 1400. 1500. 10000. ;
  64. LRHO = 'PROG' 8000. 7930. 7840. 7750. 7650.
  65. 7550. 7450. 7350. 7300. 7300. ;
  66. LTCP = 'PROG' 20. 100. 200. 300. 400. 600. 800.
  67. 1000. 1200. 1500. 10000. ;
  68. LCP = 'PROG' 450. 490. 525. 545. 560. 580. 625. 660. 670. 690. 690. ;
  69. EVK = 'EVOL' 'MANU' 'T' LTK 'K' LK ;
  70. EVRHO = 'EVOL' 'MANU' 'T' LTRHO 'RHO' LRHO ;
  71. EVCP = 'EVOL' 'MANU' 'T' LTCP 'C' LCP ;
  72. *MECA
  73. LTSIGY = 'PROG' 20. 200. 300. 400. 500. 600. 700.
  74. 800. 900. 1000. 1500. 10000. ;
  75. LSIGY = 'PROG' 287.e6 198.e6 172.e6 157.e6 152.e6 145.e6 136.e6 127.e6
  76. 115.e6 79.e6 5.e6 1.e6 ;
  77. LTEMPER = 'PROG' 20. 200. 300. 400. 500. 600. 700. 800.
  78. 900. 1000. 1500. 10000. ;
  79. LRM = 'PROG' 900.e6 800.e6 725.e6 440.e6 400.e6 360.e6 260.e6
  80. 225.e6 60.e6 25.e6 5.e6 4.e6 ;
  81. EVRM = 'EVOL' 'MANU' 'T' LTEMPER 'RM' LRM ;
  82. LB = 'PROG' 2. 2. 2. 5. 5. 5. 5. 5. 20. 20. 2. 2. ;
  83. EVB = 'EVOL' 'MANU' 'T' LTEMPER 'B' LB ;
  84. EVSIGY = 'EVOL' 'MANU' 'T' LTSIGY 'R0' LSIGY ;
  85.  
  86. MATHE = 'MATE' MODTHER 'K' EVK 'RHO' EVRHO 'C' EVCP ;
  87. MAMEC = 'MATE' MODMECA 'YOUN' 200.e6 'NU' 0.3 'RHO' EVRHO 'ALPH' 20.e-6
  88. 'A' 0. 'C' 0. PSI 1. OMEG 0. 'R0' EVSIGY
  89. 'RM' EVRM 'B' EVB ;
  90.  
  91. *CLS
  92. PTFIX1 = MAILT 'POIN' 'PLAN' (0. 0. 0.)
  93. (1. 0. 0.) (0. 0. 1.) 1.e-5 ;
  94. PTFIX2 = MAILT 'POIN' 'PLAN' (0. 0.01 0.)
  95. (1. 0.01 0.) (0. 0.01 1.) 1.e-5 ;
  96. PTFIXT = PTFIX1 'ET' PTFIX2 ;
  97. BLOQM = 'BLOQ' PTFIXT 'UX' 'UY' 'UZ' ;
  98.  
  99. *CHARGEMENT THERMIQUE
  100. SRC1 = 'SOUR' MODTHER 2.e9 MAILT ;
  101. EVO1 = 'EVOL' 'MANU' 'TEMPS' (PROG 0. 5. 10. 10000.)
  102. 'Q' ('PROG' 0. 1. 0. 0.) ;
  103. CHA1 = 'CHAR' 'Q' SRC1 EVO1 ;
  104.  
  105. *PASAPAS
  106. LTCAL = 'PROG' 0.5 'PAS' 0.5 10. 'PAS' 10. 100. 'PAS' 1000. 10000. ;
  107. CHPTINI = 'MANU' 'CHPO' MAILT 1 'T' 20. 'NATU' 'DIFFUS' ;
  108. MODTOT = MODMECA 'ET' MODTHER ;
  109. MATTOT = MATHE 'ET' MAMEC ;
  110.  
  111. HTAB ='TABL' ;
  112. HTAB . 'MODELE' = MODTOT ;
  113. HTAB . 'CARACTERISTIQUES' = MATTOT ;
  114. HTAB . 'BLOCAGES_MECANIQUES' = BLOQM ;
  115. HTAB . 'CHARGEMENT' = CHA1 ;
  116. HTAB . 'TEMPS_CALCULES' = LTCAL ;
  117.  
  118. HTAB . 'TEMPERATURES' = 'TABL' ;
  119. HTAB . 'TEMPERATURES' . 0 = CHPTINI ;
  120. HTAB . 'CELSIUS' = VRAI ;
  121. HTAB . 'PRECISION' = 1e-6 ;
  122. HTAB . 'PROCESSEURS' = 'MOT' 'MONOPROCESSEUR' ;
  123. HTAB . 'PROCEDURE_CHARTHER' = VRAI ;
  124.  
  125. PASAPAS HTAB ;
  126. *
  127. * Tests
  128. * (pas de test pertinent pour l'instant, on ctrole juste
  129. * l'execution sans erreur)
  130. *
  131. lok = vrai ;
  132. *
  133. * Test final
  134. *
  135. 'SI' ('NON' lok) ;
  136. 'ERREUR' 5 ;
  137. 'SINON' ;
  138. 'SAUT' 1 'LIGN' ;
  139. 'MESSAGE' ('CHAINE' 'Tout sest bien passe !') ;
  140. 'FINSI' ;
  141. *
  142. 'SI' interact ;
  143. 'OPTION' 'ECHO' 1 ;
  144. 'OPTION' 'DONN' 5 ;
  145. 'FINSI' ;
  146.  
  147. 'FIN' ;
  148.  
  149.  
  150.  
  151.  
  152.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales