Télécharger damage_tc_3d.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : damage_tc_3d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *******************************************************
  5. * Cas test de l'implantation numérique du modele
  6. * DAMAGE_TC 3D
  7. *******************************************************
  8. * Développé par :
  9. * Benjamin Richard
  10. * Contact :
  11. * Benjamin.Richard@lmt.ens-cachan.fr
  12. * Institution :
  13. * CEA\DEN\DANS\DM2S\SEMT\EMSI
  14. *******************************************************
  15. * Les cas de charges sont entrés :
  16. * - 1 : Traction monotone
  17. * - 2 : Compression monotone
  18. * - 3 : Traction cyclique
  19. * - 4 : Compression cyclique
  20. * - 5 : Traction/compression cyclique
  21. *******************************************************
  22. * Choix du cas de charge
  23. ncas = 1;
  24. graph=mot 'N';
  25.  
  26. *******************************************************
  27.  
  28. *
  29. *-------------- Options de calcul ---------------------
  30. *
  31. OPTION DIME 3 ELEM CUB8;
  32.  
  33. *
  34. *-------------- Definition de la geometrie ------------
  35. *
  36. P1 = 0. 0. 0.;
  37. P2 = 1. 0. 0.;
  38. P3 = 1. 1. 0.;
  39. P4 = 0. 1. 0.;
  40. P5 = 0. 0. 1. ;
  41.  
  42. L1 = P1 DROIT 1 P2 ;
  43. L2 = P2 DROIT 1 P3 ;
  44. L3 = P3 DROIT 1 P4 ;
  45. L4 = P4 DROIT 1 P1 ;
  46.  
  47. LTOT = L1 ET L2 ET L3 ET L4 ;
  48. SURF1 = SURF LTOT PLANE;
  49. VOLTO =VOLU SURF1 1 TRANS P5;
  50. SURF2= FACE VOLTO 2;
  51.  
  52. VOLTOT = VOLTO;
  53.  
  54. *
  55. *------- Définition des conditions aux limites --------
  56. *----------- et des déplacements imposés --------------
  57. *
  58. CL = BLOQ SURF1 UZ;
  59. CLL = BLOQ P1 'DEPL';
  60. CL1 = BLOQ SURF2 Uz;
  61.  
  62. D1 = DEPI CL1 1;
  63.  
  64. *
  65. *----- Définition du modèle ---------------------------
  66. *
  67. MOD1 = MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE
  68. ENDOMMAGEMENT DAMAGE_TC;
  69.  
  70. *
  71. *----- Paramètres matériaux ---------------------------
  72. *
  73.  
  74. * Young's modulus
  75. YG = 36.e9 ;
  76.  
  77. * Poisson ratio
  78. NUB = 0.20 ;
  79.  
  80. * Material density
  81. RHOM = 2210 ;
  82.  
  83. * Fracture energy
  84. Gvalm = 300. ;
  85.  
  86. * Tension limit strength
  87. ftulm = 3.3e6 ;
  88.  
  89. * Drop Factor for Peak Tensile Stress
  90. redcm = 1.7e6 ;
  91.  
  92. * Elastic Limit Compressive Stress
  93. fc01m = -25.e6 ;
  94.  
  95. * Equi-biaxial Compressive Ratio
  96. rt45m = 1.18 ;
  97.  
  98. * Compressive Peak Stress
  99. fcu1m = -42.5e6 ;
  100.  
  101. * Ultimate Limit Strain
  102. extum = -0.015;
  103.  
  104. * Reference Stress for Plastic Parameter
  105. strpm = -22.e6 ;
  106.  
  107. * Reference Strain for Plastic Parameter
  108. extpm = -0.001 ;
  109.  
  110. * Fitting Point 1 (Strain)
  111. ext1m = -0.006 ;
  112.  
  113. * Fitting Point 1 (Stress)
  114. str1m = -35.e6 ;
  115.  
  116. * Fitting Point 2 (Strain)
  117. ext2m = -0.008 ;
  118.  
  119. * Fitting Point 2 (Stress)
  120. str2m = -22.e6 ;
  121.  
  122. * NCRIT - 1 exponential softening
  123. * - 2 linear softening
  124. ncrim = 1 ;
  125.  
  126. * Computation of the element size field
  127. jaco1 = jaco mod1 ;
  128. jaco2 = chan 'RIGIDITE' mod1 jaco1 ;
  129. hlenm = jaco2**(1./3.) ;
  130.  
  131.  
  132. mat1 = mate mod1 YOUN yg NU nub RHO rhom HLEN hlenm
  133. GVAL Gvalm FTUL ftulm REDC redcm FC01 fc01m
  134. RT45 rt45m FCU1 fcu1m STRU extum EXTP extpm
  135. STRP strpm EXT1 ext1m STR1 str1m EXT2 ext2m
  136. STR2 str2m NCRI ncrim ;
  137. *
  138. *----- Définition des cas de charge -------------------
  139. *
  140.  
  141. SI (EGA ncas 1) ;
  142. LI1 = PROG 0. 1.;
  143. LI2 = PROG 0. 4.0e-4;
  144. LIS1 = PROG 0. PAS 0.02 1.;
  145. FINSI;
  146.  
  147. SI (EGA ncas 2) ;
  148. LI1 = PROG 0. 1.;
  149. LI2 = PROG 0. -8.0e-3;
  150. LIS1 = PROG 0. PAS 0.02 1.;
  151. FINSI;
  152.  
  153. SI (EGA ncas 3) ;
  154. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  155. LI2 = PROG 0. 1.5e-4 9.5e-6 2.0E-4 3.0E-5 2.5E-4;
  156. LIS1 = PROG 0. PAS 0.02 5.;
  157. FINSI;
  158.  
  159. SI (EGA ncas 4) ;
  160. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  161. LI2 = PROG 0. -3.0e-3 -1.5e-4 -5.0E-3 -3.5E-4 -8.0E-3;
  162. LIS1 = PROG 0. PAS 0.02 5.;
  163. FINSI;
  164.  
  165. SI (EGA ncas 5) ;
  166. LI1 = PROG 0. 1. 2. 3. 4. 5. 6.;
  167. LI2 = PROG 0. 5.0e-4 -3.0e-3 -1.5E-4 -5.0E-3 -3.5E-4 -8.0E-3;
  168. LIS1 = PROG 0. PAS 0.02 2;
  169. FINSI;
  170.  
  171. EV = EVOL MANU LI1 LI2 ;
  172. CHA1 = CHAR 'DIMP' D1 EV ;
  173.  
  174. *
  175. *----------- Calcul par l'operateur PASAPAS ------------
  176. *
  177.  
  178. TAB1 = TABLE ;
  179. TAB1.'BLOCAGES_MECANIQUES' = CL ET CLL ET CL1;
  180. TAB1.'MODELE' = MOD1;
  181. TAB1.'MOVA' = 'RIEN';
  182. TAB1.'CHARGEMENT' = CHA1;
  183. TAB1.'CARACTERISTIQUES' = MAT1;
  184. TAB1.'TEMPS_CALCULES' = LIS1;
  185. TAB1.'MAXITERATION' = 10;
  186.  
  187. PASAPAS TAB1 ;
  188.  
  189. *
  190. *----------- Courbe effort-deplacement -----------------
  191. *
  192.  
  193. Si (ega graph 'O');
  194. ev2=@global tab1 CL1 EV fz;
  195. DESS EV2;
  196. finsi;
  197.  
  198. nn=dime tab1.deplacements;
  199. nn=nn-1;
  200. ee=tab1.variables_internes.nn;
  201.  
  202. aa = extr ee 'DAMT' 1 1 1 ;
  203. list aa;
  204. err = abs (aa - 0.97626) / 0.97626 ;
  205. message ' erreur relative ';
  206. list err;
  207. si (err > 1.e-3);
  208. erreur (5);
  209. finsi;
  210.  
  211. fin;
  212.  
  213.  
  214.  
  215.  
  216.  
  217.  
  218.  
  219.  
  220.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales