Télécharger concyc.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : concyc.dgibi
  2. *
  3. *******************************************************
  4. ************************************************************************
  5. ************************************************************************
  6. * Cas test de l'implantation numérique du modele
  7. * RICRAG 3D LOCAL/NON LOCAL
  8. *******************************************************
  9. * Développé par :
  10. * Maxime VASSAUX
  11. * Benjamin RICHARD
  12. *
  13. *******************************************************
  14. * Les cas de charges sont entrés :
  15. * - 1 : Traction monotone
  16. * - 2 : Compression monotone
  17. * - 3 : Traction cyclique
  18. * - 4 : Compression cyclique
  19. * - 5 : Traction/compression
  20. *******************************************************
  21. * Choix du cas de charge
  22. ncas = 1;
  23. graph=mot 'N';
  24. * Test du fichier compatible avec le non local
  25. * nloc0 = 0; Cas local
  26. * nloc0 = 1; Cas non local
  27.  
  28. nloc0 = 0;
  29. *******************************************************
  30.  
  31. *
  32. *-------------- Options de calcul ---------------------
  33. *
  34. OPTION DIME 3 ELEM CUB8;
  35.  
  36. *
  37. *-------------- Definition de la geometrie ------------
  38. *
  39. dim1 = 1.0;
  40. dim2 = 1.0;
  41. dim3 = 1.0;
  42. P1 = 0. 0. 0.;
  43. P2 = dim1 0. 0.;
  44. P3 = dim1 dim2 0.;
  45. P4 = 0. dim2 0.;
  46. P5 = 0. 0. dim3;
  47. P6 = dim1 0. dim3;
  48. P7 = dim1 dim2 dim3;
  49. P8 = 0. dim2 dim3;
  50.  
  51. nelem1 = 1;
  52. nelem2 = 1;
  53. nelem3 = 1;
  54.  
  55. L1 = P1 DROIT nelem1 P2 ;
  56. L2 = P2 DROIT nelem2 P3 ;
  57. L3 = P3 DROIT nelem1 P4 ;
  58. L4 = P4 DROIT nelem2 P1 ;
  59.  
  60. L5 = P5 DROIT nelem1 P6 ;
  61. L6 = P6 DROIT nelem2 P7 ;
  62. L7 = P7 DROIT nelem1 P8 ;
  63. L8 = P8 DROIT nelem2 P5 ;
  64.  
  65. L9 = P1 DROIT nelem3 P5 ;
  66. L10 = P2 DROIT nelem3 P6 ;
  67. L11 = P3 DROIT nelem3 P7 ;
  68. L12 = P4 DROIT nelem3 P8 ;
  69.  
  70. LTOT1 = L1 ET L2 ET L3 ET L4 ;
  71. SURF1 = SURF LTOT1 PLANE;
  72.  
  73. LTOT2 = L5 ET L6 ET L7 ET L8 ;
  74. SURF2 = SURF LTOT2 PLANE;
  75.  
  76. LTOT3 = L1 ET L5 ET L10 ET L9 ;
  77. SURF3 = SURF LTOT3 PLANE;
  78.  
  79. LTOT4 = L2 ET L11 ET L6 ET L10 ;
  80. SURF4 = SURF LTOT4 PLANE;
  81.  
  82. LTOT5 = L3 ET L12 ET L7 ET L11 ;
  83. SURF5 = SURF LTOT5 PLANE;
  84.  
  85. LTOT6 = L4 ET L9 ET L8 ET L12 ;
  86. SURF6 = SURF LTOT6 PLANE coul 'ROUG';
  87.  
  88. STOT = SURF1 et SURF2 et SURF3 et SURF4 et SURF5 et SURF6;
  89.  
  90. VOLTO = surf1 volu nelem3 tran (P5);
  91.  
  92. VOLTOT = VOLTO;
  93.  
  94. elim stot voltot 0.0001;
  95.  
  96. *
  97. *------- Définition des conditions aux limites --------
  98. *----------- et des déplacements imposés --------------
  99. *
  100. CL1 = BLOQ 'UZ' SURF1;
  101. CL3 = BLOQ 'UY' SURF3;
  102. CL6 = BLOQ 'UX' SURF6;
  103.  
  104. BCL = CL1 ET CL3 ET CL6;
  105. CL2 = BLOQ SURF2 UZ;
  106.  
  107. D1 = DEPI CL2 1;
  108.  
  109. *
  110. *----- Définition du modèle ---------------------------
  111. *
  112. SI (EGA nloc0 1);
  113. MOD1 = MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE
  114. ENDOMMAGEMENT CONCYC
  115. 'NON_LOCAL' 'MOYE' 'V_MOYENNE' (MOTS 'EPTI') ;
  116. SINON ;
  117. MOD1 = MODE VOLTOT MECANIQUE ELASTIQUE ISOTROPE
  118. ENDOMMAGEMENT CONCYC;
  119. FINSI;
  120. *
  121. *----- Paramètres matériaux ---------------------------
  122. *
  123. * Module de Young
  124. youngn = 30.0E9;
  125.  
  126. * Coefficient de Poisson
  127. nun = 0.2;
  128.  
  129. * Choix du modèle d'endommagement pour 'CONCYC' : Ricrag (1) - consolidation modifiee (2) - critere modifie (3)
  130. nendn = 2;
  131.  
  132. * Contrainte limite elastique
  133. sigtn = 3.00E6;
  134.  
  135. * Parametre controlant l'energie de fissuration
  136. atran = 0.004;
  137.  
  138. * RicRag classique *
  139. SI (EGA nendn 1);
  140. btran = 0.0;
  141. FINSI;
  142.  
  143. * RicRag avec consolidation modifiee *
  144. SI (EGA nendn 2);
  145. btran = 4.5;
  146. FINSI;
  147.  
  148. * RicRag avec critere modifie *
  149. SI (EGA nendn 3);
  150. btran = 0.31;
  151. FINSI;
  152.  
  153. * "Vitesse" de refermeture de fissure
  154. qpn = 6.5;
  155.  
  156. * Coefficient de frottement des fissures
  157. cfn = 2.89;
  158.  
  159. MAT1 = MATE MOD1 'YOUN' youngn 'NU ' nun
  160. 'NEND' nendn 'SIGT' sigtn
  161. 'ATRA' atran 'BTRA' btran
  162. 'QP ' qpn 'CF ' cfn ;
  163.  
  164. *
  165. *----- Définition des cas de charge -------------------
  166. *
  167.  
  168. SI (EGA ncas 1) ;
  169. LI1 = PROG 0. 1.;
  170. LI2 = PROG 0. 4.0e-4;
  171. LIS1 = PROG 0. PAS 0.0025 1.;
  172. FINSI;
  173.  
  174. SI (EGA ncas 2) ;
  175. LI1 = PROG 0. 1.;
  176. LI2 = PROG 0. -8.0e-3;
  177. LIS1 = PROG 0. PAS 0.0025 1.;
  178. FINSI;
  179.  
  180. SI (EGA ncas 3) ;
  181. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  182. LI2 = PROG 0. 1.5e-4 -2.0e-4 2.0E-4 -2.0e-4 2.5E-4;
  183. LIS1 = PROG 0. PAS 0.0025 5.;
  184. FINSI;
  185.  
  186. SI (EGA ncas 4) ;
  187. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  188. LI2 = PROG 0. -3.0e-3 -1.5e-4 -5.0E-3 -3.5E-4 -8.0E-3;
  189. LIS1 = PROG 0. PAS 0.0025 5.;
  190. FINSI;
  191.  
  192. SI (EGA ncas 5) ;
  193. LI1 = PROG 0. 1. 2.;
  194. LI2 = PROG 0. 2.0e-4 -4.0e-3;
  195. LIS1 = PROG 0. PAS 0.0025 2;
  196. FINSI;
  197.  
  198. EV = EVOL MANU LI1 LI2 ;
  199. CHA1 = CHAR 'DIMP' D1 EV ;
  200.  
  201. *
  202. *----------- Calcul par l'operateur PASAPAS ------------
  203. *
  204. LC = 1.0e-10;
  205. CO1 = CONNEC mod1 LC NORMAL;
  206.  
  207. TAB1 = TABLE ;
  208. TAB1.'BLOCAGES_MECANIQUES' = BCL ET CL2;
  209. TAB1.'MODELE' = MOD1;
  210. TAB1.'MOVA' = 'D ';
  211. TAB1.'CHARGEMENT' = CHA1;
  212. TAB1.'TEMPS_CALCULES' = LIS1;
  213. TAB1.'MAXITERATION' = 10;
  214.  
  215. SI (EGA nloc0 1);
  216. TAB1.CONN = CO1;
  217. MAT1 = MAT1 ET ( MATE MOD1 'LCAR' LC) ;
  218. FINSI;
  219.  
  220. TAB1.'CARACTERISTIQUES' = MAT1;
  221. PASAPAS TAB1 ;
  222.  
  223. *
  224. *----------- Courbe effort-deplacement -----------------
  225. *
  226. ev2=@global tab1 CL2 EV fz;
  227. ee = extr ev2 ordo 1;
  228. aa = extr ee ( dime ee);
  229. list aa;
  230. err = abs (((aa) - (5.14929E+05)) / (5.14929E+05)) ;
  231. message ' erreur relative ' err;
  232. si (err > 1.e-3);
  233. erreur (5);
  234. finsi;
  235.  
  236. si ( ega graph 'O');
  237. DESS EV2;
  238. finsi;
  239. list ev2;
  240. fin;
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  
  248.  
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales