Télécharger la plaquette Cast3M


fr en

Télécharger comp2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  comp2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. *******************************************************
  6. *           Test Comp2.dgibi: Jeux de données         *
  7. *           ---------------------------------         *
  8. *******************************************************
  9.  
  10. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  11. * SINON SI GRAPH DIFFERENT DE N TOUS
  12. * LES GRAPHIQUES SONT AFFICHES
  13.  
  14. GRAPH = 'N' ;
  15.  
  16. SAUT PAGE;
  17. SI (NEG GRAPH 'N') ;
  18.   OPTI ECHO 1   ;
  19.   OPTI TRAC PSC ;
  20. SINO ;
  21.   OPTI ECHO 1   ;
  22. FINSI ;
  23. *______________________________________________________
  24. *                 PLAQUE BI-COUCHE A +/- 45
  25. *                APPUYEE , PRESSION REPARTIE
  26. *                       ELEMENT DKT
  27. *
  28. *
  29. * Une plaque composite carrée est appuyée sur toute sa
  30. * périphérie (blocage en déplacement suivant Z et en
  31. * rotation suivant Z).
  32. *
  33. * Le noeud situé au centre de la plaque ne peut se
  34. * déplacer que suivant l'axe vertical Z (blocage en
  35. * déplacement et en rotation suivant Z).
  36. *
  37. * Une pression répartie est appliquée sur toute
  38. * la plaque.
  39. *
  40. * Le déplacement calculé au centre de la plaque est
  41. * comparé au résultat théorique : 23.25
  42. *______________________________________________________
  43. SAUT PAGE ;
  44. TITRE 'PLAQUE COMPOSITE APPUYEE - PRESSION REPARTIE';
  45. OPTI DIME 3 ELEM TRI3 ECHO 1 ;
  46. *______________________________________________________
  47. *  GEOMETRIE
  48. *______________________________________________________
  49.  
  50. TEMPS ;
  51.  
  52. A = 127. ; B = A ; AM = -127. ; BM = AM ;
  53. H = 5.08 ; ES = H/4 ; EI = H/-4 ; S = H/2 ;
  54. P = 0.6894 ;
  55. N = 12 ;
  56. P0 = 0. 0. 0. ;
  57. P1 = AM BM 0. ; P2 = A BM 0. ;
  58. P3 = A B 0.   ; P4 = AM B 0. ;
  59. V1 = 0. (2*B) 0. ; V2 = 0. 0. 1. ;
  60. L1 = DROI N P1 P2 ;
  61.  
  62. SI1=L1 TRAN V1 N;
  63. S1=ORIE SI1 V2;
  64. CONF (S1 POIN PROC P1) P1 ;
  65. CONF (S1 POIN PROC P2) P2 ;
  66. CONF (S1 POIN PROC P3) P3 ;
  67. CONF (S1 POIN PROC P4) P4 ;
  68. CONF (S1 POIN PROC P0) P0 ;
  69. *
  70. SI (NEG GRAPH 'N') ;
  71.   TRACE S1 V2 'QUAL';
  72. FINSI ;
  73. *______________________________________________________
  74. *  MATERIAUX
  75. *______________________________________________________
  76. MOD1 = MODE S1 MECANIQUE ELASTIQUE ORTHOTROPE DKT;
  77.  
  78. MOP = 'MODE' S1 'CHARGEMENT' 'PRESSION' DKT ;
  79. MAP = 'PRES' MOP 'PRES' P ;
  80.  
  81. CARS = CARA MOD1 EPAI S EXCE ES ;
  82. CARI = CARA MOD1 EPAI S EXCE EI ;
  83. E11 = 276E3 ; E22 = 6.9E3 ; N12 = 0.25 ; GX = 3.4E3 ;
  84. MATS = MATE MOD1 DIRE V1 INCLINE  45. V2 YG1 E11 YG2 E22
  85.            NU12 N12 G12 GX ;
  86. MATI = MATE MOD1 DIRE V1 INCLINE -45. V2 YG1 E11 YG2 E22
  87.           NU12 N12 G12 GX ;
  88. MATS=MATS ET CARS;
  89. MATI=MATI ET CARI;
  90. *______________________________________________________
  91. *  CONDITIONS AUX LIMITES ET RIGIDITE
  92. *______________________________________________________
  93. RIS = RIGI MOD1 MATS  ;
  94. RII = RIGI MOD1 MATI  ;
  95. CL=(BLOQ UZ (CONT S1)) ET (BLOQ RZ (CONT S1)) ET
  96.    (BLOQ UX UY RX RY P0);
  97. RIT = RIS ET RII ET CL ;
  98. *______________________________________________________
  99. *  CALCUL ET SORTIE
  100. *______________________________________________________
  101. FP  = BSIG MOP MAP ;
  102. DEP = RESO RIT  FP        ;
  103. FP1 = EXTR DEP  UZ P0     ;
  104. SAUT PAGE          ;
  105. SU1=DEFO S1 DEP    ;
  106. DZ=EXCO DEP UZ     ;
  107. OEIL= 0 1000 0     ;
  108. SI (NEG GRAPH 'N') ;
  109.   TRAC OEIL CACH SU1 DZ;
  110. FINSI ;
  111. *
  112. MESS 'FLECHE THEORIQUE      23.25' ;
  114. MESS 'FLECHE CALCULEE           ' FP1 ;
  116. TEMPS ;
  117. *______________________________________________________
  118. *            CODE FONCTIONNEMENT
  119. *______________________________________________________
  120. FLEREF = 23.25;
  121. RESI = ABS ((FP1-FLEREF)/FLEREF);
  122. SI (RESI <EG 1E-2);
  123.     ERRE 0 ;
  124. SINO;
  125.     ERRE 5 ;
  126. FINSI;
  127. FIN ;
  128.  
  129.  
  130.  
  131.  
  132.  
  133.  
  134.  
  135.  
  136.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales