Télécharger comp1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : comp1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. * CYLINDRE COMPOSITE BICOUCHE
  7. * FIBRES ENROULEES -45/+45 AUTOUR DE L'AXE
  8. * PRESSION INTERNE
  9. *
  10. *
  11. * Un cylindre bloqué à sa base en déplacement suivant
  12. * l'axe Z est soumis à une pression interne.
  13. * 3D element DKT
  14. * Ref : Rapport CEA , DEMT 85-482 , M. Hittinger, 1985
  15. * Remise a plat : BP, 2017-01-23
  16. *
  17. ************************************************************************
  18.  
  19. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  20. * SINON SI GRAPH DIFFERENT DE N TOUS
  21. * LES GRAPHIQUES SONT AFFICHES
  22.  
  23. GRAPH = 'N' ;
  24. * GRAPH = 'O';
  25.  
  26. SAUT PAGE;
  27. SI (NEG GRAPH 'N') ;
  28. OPTI ECHO 1 ;
  29. * OPTI TRAC X ;
  30. OPTI TRAC 'PSC' EPTR 5;
  31. SINO ;
  32. OPTI ECHO 0 ;
  33. FINSI ;
  34.  
  35. TITRE 'CYLINDRE COMPOSITE BICOUCHE SOUS PRESSION INTERNE';
  36. OPTION DIME 3 ELEM TRI3 MODE TRIDIM ;
  37.  
  38. TEMPS ;
  39. DENS 0.1 ;
  40.  
  41. NAX = 8; NCIRC = 16;
  42. NAX = 4; NCIRC = 8;
  43. * NAX = 1; NCIRC = 16;
  44.  
  45.  
  46. *______________________________________________________
  47. * GEOMETRIE
  48. *______________________________________________________
  49. R = 1.05 ; H = 1. ;
  50. PA = R 0. 0. ; PB = R 0. H ;
  51. O1 = 0. 0. 0. ; O2 = 0. 0. H ;
  52. NR1 = 1. 1. 0. ;
  53. LI1 = PA DROIT NAX PB ;
  54. CYLP = ROTA LI1 NCIRC 90 O1 O2 ;
  55. CYL1 = ORIE CYLP NR1 ;
  56. CYL2 LIB = TOUR CYL1 LI1 90 O1 O2 ;
  57. CYL3 LIC = TOUR CYL2 LIB 90 O1 O2 ;
  58. CYL4 LID = TOUR CYL3 LIC 90 O1 O2 ;
  59. CYL = CYL1 ET CYL2 ET CYL3 ET CYL4 ;
  60. ELIM CYL ;
  61. OEIL = 10. 10. 5. ;
  62. *
  63. SI (NEG GRAPH 'N') ;
  64. TRAC OEIL CACH CYL 'QUAL' ;
  65. FINSI ;
  66.  
  67. *______________________________________________________
  68. * DESCRIPTION DU MATERIAU ORTHOTROPE : COUCHE 1
  69. *______________________________________________________
  70.  
  71. MOD1 = MODE CYL MECANIQUE ELASTIQUE ORTHOTROPE DKT ;
  72. * MAT1 = MATE MOD1 DIRE O2 INCL 45 NR1 YG1 7E6 YG2
  73. MAT1 = MATE MOD1 DIRE O2 INCL 45 YG1 7E6 YG2
  74. 1.3E6 NU12 0.28 G12 5E5 ;
  75. CAR1 = CARA MOD1 EPAI 0.05 EXCENTREMENT 0.025 ;
  76. MAT1=MAT1 ET CAR1;
  77.  
  78. * verification graphique de l'orientation :
  79. * 3D coque => 3 vecteurs : V1, V2 et V3
  80. v123 = VLOC MOD1 MAT1;
  81. v123 = CHAN 'GRAVITE' v123 MOD1;
  82. mo123 = mots 'V1X' 'V1Y' 'V1Z' 'V2X' 'V2Y' 'V2Z' 'V3X' 'V3Y' 'V3Z';
  83. ve123 = VECT v123 MOD1 0.07 mo123 (mots 'AZUR' 'OR' 'POUR');
  84. SI (NEG GRAPH 'N');
  85. TITRE 'COMP1 couche 1 : V1(AZUR) V2 (JAUNE) V3(ROUG)';
  86. TRACE OEIL ve123 CYL 'CACH';
  87. FINSI ;
  88.  
  89. *______________________________________________________
  90. * DESCRIPTION DU MATERIAU ORTHOTROPE : COUCHE 2
  91. *______________________________________________________
  92. MOD2 = MODE CYL MECANIQUE ELASTIQUE ORTHOTROPE DKT ;
  93. * MAT2 = MATE MOD2 DIRE O2 INCL -45 NR1 YG1 7E6 YG2
  94. MAT2 = MATE MOD2 DIRE O2 INCL -45 YG1 7E6 YG2
  95. 1.3E6 NU12 0.28 G12 5E5 ;
  96. CAR2 = CARA MOD2 EPAI 0.05 EXCENTREMENT -0.025 ;
  97. MAT2=MAT2 ET CAR2;
  98.  
  99. * verification graphique de l'orientation :
  100. * 3D coque => 3 vecteurs : V1, V2 et V3
  101. v123 = VLOC MOD2 MAT2;
  102. v123 = CHAN 'GRAVITE' v123 MOD2;
  103. ve123 = VECT v123 MOD2 0.07 mo123 (mots 'AZUR' 'BRON' 'POUR');
  104. SI (NEG GRAPH 'N');
  105. TITRE 'COMP1 couche 2 : V1(AZUR) V2 (JAUNE) V3(ROUG)';
  106. TRACE OEIL ve123 CYL 'CACH';
  107. FINSI ;
  108.  
  109. * chargement
  110. MOP = 'MODE' CYL 'CHARGEMENT' 'PRESSION' DKT ;
  111. MAP = 'MATE' MOP 'PRES' 1. ;
  112.  
  113. *______________________________________________________
  114. * CREATION DE LA RIGIDITE
  115. *______________________________________________________
  116.  
  117.  
  118. MODORT = MOD1 ET MOD2 'ET' MOP ;
  119. MATORT = MAT1 ET MAT2 'ET' MAP ;
  120.  
  121. RIG12 = RIGI MODORT MATORT ;
  122.  
  123.  
  124. *______________________________________________________
  125. * CONDITIONS AUX LIMITES
  126. *______________________________________________________
  127.  
  128. CO1 = COTE 2 CYL1 ; CO2 = COTE 2 CYL2 ;
  129. CO3 = COTE 2 CYL3 ; CO4 = COTE 2 CYL4 ;
  130. COB = (CO1 ET CO2 ET CO3 ET CO4 ) coul BLEU;
  131. CO1 = COTE 4 CYL1 ; CO2 = COTE 4 CYL2 ;
  132. CO3 = COTE 4 CYL3 ; CO4 = COTE 4 CYL4 ;
  133. COA = (CO1 ET CO2 ET CO3 ET CO4 ) coul BOUT;
  134.  
  135. PB1 = CYL point proch (0. R H);
  136. PB2 = CYL point proch ((-1.*R) 0. H);
  137. PB3 = CYL point proch (0. (-1.*R) H);
  138.  
  139. CDL1 = BLOQ 'UZ' COB ;
  140. CDL2 = ( BLOQ 'UY' (PB et PB2) )
  141. et ( BLOQ 'UX' (PB1 et PB3) );
  142. CDL = CDL1 ET CDL2 ;
  143.  
  144. *______________________________________________________
  145. * CALCUL
  146. *______________________________________________________
  147. RIGITOT = RIG12 ET CDL ;
  148.  
  149. FP = 'PRES' MOP MAP ;
  150. *
  151. DEP1 = RESO RIGITOT FP ;
  152.  
  153. DEFO0= DEFO CYL 0.0 DEP1 GRIS;
  154. DEFO1= DEFO CYL DEP1 (EXCO DEP1 'UX');
  155.  
  156. SI (NEG GRAPH 'N') ;
  157. TRAC OEIL (DEFO1 et DEFO0) ;
  158. TRAC (0. 0. 100.) (DEFO1 et DEFO0) ;
  159. * deplacement UX et UY
  160. evux = EVOL 'BLEU' 'CHPO' DEP1 COB 'UX';
  161. evuy = EVOL 'VERT' 'CHPO' DEP1 COB 'UY';
  162. Tlege = tabl; Tlege . 'TITRE' = tabl;
  163. Tlege . 'TITRE' . 1 = mot 'UX'; Tlege . 'TITRE' . 2 = mot 'UY';
  164. DESS (evux ET evuy) LEGE SO Tlege MIMA 'TITRE' 'en z=H';
  165. evux = EVOL 'BLEU' 'CHPO' DEP1 COA 'UX';
  166. evuy = EVOL 'VERT' 'CHPO' DEP1 COA 'UY';
  167. Tlege = tabl; Tlege . 'TITRE' = tabl;
  168. Tlege . 'TITRE' . 1 = mot 'UX'; Tlege . 'TITRE' . 2 = mot 'UY';
  169. DESS (evux ET evuy) LEGE SO Tlege MIMA 'TITRE' 'en z=0';
  170. FINSI;
  171.  
  172. * ref = calcul element LC8 tire de [DEMT 85-482]
  173. uref = (0.63615E-5 + 0.64702E-5) /2.;
  174.  
  175. * VALEUR pour le TEST
  176. ur1A = EXTR DEP1 'UX' PA ;
  177. ur1B = EXTR DEP1 'UX' PB ;
  178. MESS '************************************************';
  179. MESS ' DEPLACEMENT RADIAL REFERENCE : ' uref;
  180. MESS ' DEPLACEMENT RADIAL EN PA CALCULE :' ur1A ur1B;
  181. RES1= ABS((ur1A - uref) / uref);
  182. MESS 'ECART RELATIF : ' RES1 ;
  183. MESS '************************************************';
  184. TEMPS ;
  185. *______________________________________________________
  186. * CODE BON FONCTIONNEMENT
  187. *______________________________________________________
  188.  
  189. SI (RES1 <EG 5.E-2);
  190. ERRE 0 ;
  191. SINO;
  192. ERRE 5 ;
  193. FINSI ;
  194. FIN;
  195.  
  196.  
  197.  
  198.  
  199.  
  200.  
  201.  
  202.  
  203.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales