Télécharger chaboche3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : chaboche3.dgibi
  2. * section : Mecanique Viscoplastique
  3. *----------------------------------------------------------------------*
  4. * CHABOCHE3.DGIBI *
  5. *----------------------------------------------------------------------*
  6. *
  7. * Objet :
  8. * -------
  9. *
  10. * Test de validation d'une loi de comportement de materiau.
  11. * Loi de comportement elastoviscoplastique de Chaboche.
  12. * Validation de la loi de comportement en condition anisotherme.
  13. *
  14. *
  15. * Description :
  16. * -------------
  17. * Test "Satoh" : dilatation thermique d'un element de volume empeche
  18. * suivant (O,z)
  19. *
  20. * Type de calcul : Thermomecanique
  21. * Mode de calcul : TRIDIMENSIONNEL
  22. * Type d'element : CUB8
  23. * Chargement : Temperature imposee
  24. * Reference : solution obtenue avec SiDoLo, elle-meme validee
  25. * par comparaison au logiciel Zebulon.
  26. * Objectif : Ecart relatif sur la contrainte SMZZ < 2%
  27. *
  28. * Remarque 1 :
  29. * ------------
  30. * Les instants de calcul et les valeurs imposees de la temperature
  31. * sont celles de la solution de reference.
  32. *
  33. * Remarque 2 :
  34. * ------------
  35. * Solution de reference aimablement communiquee par Philippe PILVIN,
  36. * Université de Bretagne Sud.
  37. *
  38. *----------------------------------------------------------------------*
  39. *
  40. * Pour afficher les traces, mettre IGRAPH a vrai :
  41. IGRAPH = faux ;
  42. *
  43. *----------------------- Resultats de reference -----------------------*
  44. *
  45. * Lecture de la solution de reference :
  46. ta2 = lire csv '/u2/castem/divers/chaboche3.txt' debu 3 sepa ' ' ;
  47.  
  48. * liste des temps de calcul ;
  49. ltps1 = ta2.1 ;
  50. * liste des valeurs de temeprature associee
  51. lt1 = ta2.5 ;
  52. * liste des valeurs de la contrainte SMZZ associee
  53. lszz1 = ta2.3 ;
  54. *
  55. * Courbes d'evolution :
  56. evtref = evol defa manu temps ltps1 'T' lt1 ;
  57. evsref = evol defa manu temps ltps1 smzz lszz1 ;
  58. evref = evol defa manu 'T' lt1 smzz lszz1 ;
  59.  
  60. *--------------------- Mise en donnees du calcul ----------------------*
  61. *
  62. opti dime 3 elem cub8 ;
  63.  
  64. * Maillage d'un "cube unite" :
  65. L1 = (0 0 0) droi 1 (1 0 0) ;
  66. S1 = L1 tran (0 1 0) 1 ;
  67. V1 = S1 volu tran 1 (0 0 1) ;
  68.  
  69. si IGRAPH ;
  70. trac noeud elem V1 titr ' Maillage ' ;
  71. fins ;
  72.  
  73. * Parametres de la loi de Chaboche :
  74. ym1 = evol manu 'T' (prog 20. 600.) 'YOUN' (prog 190.e9 140.e9) ;
  75. nu1 = 0.3 ;
  76. al1 = 20.e-6 ;
  77. Sy1 = evol manu 'T' (prog 20. 600.) 'SIGY' (prog 82.e6 6.e6) ;
  78. gK0 = evol manu 'T' (prog 20. 600.) 'K ' (prog 151.e6 150.e6) ;
  79. pn1 = evol manu 'T' (prog 20. 600.) 'N ' (prog 24. 12.) ;
  80. gA1 = evol manu 'T' (prog 20. 600.) 'A ' (prog 58.e6 82.7e6) ;
  81. gC1 = evol manu 'T' (prog 20. 600.) 'C ' (prog 2800. 300.) ;
  82. gQ1 = evol manu 'T' (prog 20. 600.) 'Q ' (prog 60.e6 80.e6) ;
  83. pb1 = evol manu 'T' (prog 20. 600.) 'B ' (prog 8. 10.) ;
  84.  
  85. * Modele / Caracteristiques :
  86. mo1 = 'MODE' V1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'VISCOPLASTIQUE' 'CHABOCHE' ;
  87. ma1 = 'MATE' mo1 'YOUN' ym1 'NU' nu1 'ALPH' al1 'SIGY' Sy1
  88. 'K' gK0 'N' pn1 'A' gA1 'C' gC1 'B' pb1 'Q' gQ1 ;
  89.  
  90. * Blocages mecaniques :
  91. ptx0 = V1 coor 1 poin infe 0.1 ;
  92. pty0 = V1 coor 2 poin infe 0.1 ;
  93. ptz0 = V1 coor 3 poin infe 0.1 ;
  94. ptz1 = V1 coor 3 poin supe 0.9 ;
  95.  
  96. CLX0 = bloq ux ptx0 ;
  97. CLY0 = bloq uy pty0 ;
  98. CLZ0 = bloq uz (ptz0 et ptz1) ;
  99.  
  100. * Conditions initiales / Chargement :
  101. * Evolution de la temperature :
  102. CHT0 = manu chpo V1 1 'T' 1. ;
  103. CGT0 = char T CHT0 evtref ;
  104.  
  105. * Pas de temps (si vrai, pas de temps / 2) :
  106. si faux ;
  107. nbx = dime ltps1 - 1 ;
  108. tps0 = extr ltps1 1 ;
  109. ltps2 = prog tps0 ;
  110. repe bx nbx ;
  111. tps1 = extr ltps1 (&bx + 1) ;
  112. dtps = tps1 - tps0 ;
  113. tps2 = tps1 ;
  114. tps1 = 0.5*dtps + tps0 ;
  115. ltps2 = ltps2 et (prog tps1 tps2) ;
  116. tps0 = tps2 ;
  117. fin bx ;
  118. sino ;
  119. ltps2 = ltps1 ;
  120. fins ;
  121. * Test discretisation plus grossiere :
  122. *tps1 = ltps1 extr (dime ltps1) ;
  123. *ltps2 = prog 0. pas (0.02*tps1) tps1 ;
  124.  
  125. * Resolution PASAPAS :
  126. ta1 = table ;
  127. ta1.modele = mo1 ;
  128. ta1.caracteristiques = ma1 ;
  129. ta1.blocages_mecaniques = clx0 et cly0 et clz0 ;
  130. ta1.chargement = cgt0 ;
  131. ta1.temps_calcules = ltps2 ;
  132.  
  133. opti epsi lineaire ;
  134.  
  135. PASAPAS ta1 ;
  136.  
  137. * Post-traitement de la courbe SMZZ vs T :
  138. nb1 = dime ta1.temps ;
  139. i1 = 0 ;
  140. lt2 = prog ;
  141. lszz2 = prog ;
  142. repe b1 nb1 ;
  143. tpsi1 = ta1.temps.i1 ;
  144. ti1 = (tire ta1.chargement T tpsi1) maxi ;
  145. szzi1 = ta1.contraintes.i1 maxi avec (mots smzz) ;
  146. lt2 = lt2 et (prog ti1) ;
  147. lszz2 = lszz2 et (prog szzi1) ;
  148. i1 = i1 + 1 ;
  149. fin b1 ;
  150. lszz2 = 1.e-6 * lszz2 ;
  151. evcal = evol roug manu 'T' lt2 smzz lszz2 ;
  152. evscal = evol roug manu temps ltps2 smzz lszz2 ;
  153.  
  154. * Affichages :
  155. si IGRAPH ;
  156. ta3 = table ;
  157. ta3 . 1 = chai 'TIRR MARQ ROND REGU' ;
  158. ta3 . 'TITRE' = table ;
  159. ta3 . 'TITRE' . 1 = mot 'Zebulon/SiDoLo' ;
  160. ta3 . 'TITRE' . 2 = mot 'Cast3M' ;
  161. dess (evsref et evscal) xbor -5. 65. ygra 5. ybor -250. 300. ygra 50. gril
  162. titr 'Essai Satoh : SMZZ (MPa) vs. temps (s) ' lege ta3 ;
  163. dess (evref et evcal) gril ybor -250. 300. ygra 50.
  164. titr 'Essai Satoh : SMZZ (MPa) vs. T (degC) ' lege ta3 ;
  165. fins ;
  166. *
  167. * Test de validation :
  168. lszz2 = ipol evscal ltps1 ;
  169. err0 = (maxi abs (lszz2 - lszz1)) / (maxi abs lszz1) ;
  170.  
  171. opti echo 0 ;
  172. mess ' Comparaison solution calculee / reference ' ;
  173. mess ' ----------------------------------------- ' ;
  174. mess ' Max.|SMZZ(cal.) - SMZZ(Ref.)| / Max.|SMZZ(cal.)| =' err0 ;
  175. opti echo 1 ;
  176. *
  177. si (err0 > 0.02) ;
  178. erre 5 ;
  179. fins ;
  180. *
  181. fin ;
  182.  
  183.  
  184.  
  185.  
  186.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales