Télécharger chaboche2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : chaboche2.dgibi
  2. * section : Mecanique Viscoplastique
  3. *----------------------------------------------------------------------*
  4. * CHABOCHE2.DGIBI *
  5. *----------------------------------------------------------------------*
  6. *
  7. * Objet :
  8. * -------
  9. *
  10. * Test de validation d'une loi de comportement de materiau.
  11. * Loi de comportement elastoviscoplastique de Chaboche.
  12. *
  13. *
  14. * Description :
  15. * -------------
  16. * Essai de traction-compression.
  17. *
  18. * Type de calcul : Mecanique
  19. * Mode de calcul : 2D axisymetrique
  20. * Type d'element : QUA4
  21. * Chargement : Deplacement impose
  22. * Reference : solution comparee a la loi ONERA
  23. * Objectif : Ecart relatif sur la contrainte SMZZ < 1.e-4
  24. *
  25. * Reference :
  26. * -----------
  27. * L&M : J. Lemaitre, J.-L. Chaboche, "Mecanique des materiaux solides",
  28. * Dunod, 2e edition, 1996.
  29. *
  30. *----------------------------------------------------------------------*
  31. *
  32. * Pour afficher les traces, mettre IGRAPH a vrai :
  33. IGRAPH = faux ;
  34. *
  35. *------------------------ Maillage (1 element) ------------------------*
  36. *
  37. opti dime 2 elem qua8 mode axis ;
  38.  
  39. ne1 = 1 ;
  40. l1 = (0 0) droi ne1 (1. 0.) ;
  41. S1 = l1 tran ne1 (0. 1.) ;
  42.  
  43. l2 = s1 cote 2 ;
  44. l3 = S1 cote 3 ;
  45. l4 = S1 cote 4 ;
  46.  
  47. si IGRAPH ;
  48. trac qual S1 titr ' Maillage ' ;
  49. fins ;
  50. *
  51. *---------------------- Modele & Carateristiques ----------------------*
  52. *
  53. * Par rapport aux parametres du modele presentes dans le L&M, p. 310 :
  54. * - CLM : coefficient C d'ecrouissage cinematique du L&M
  55. * - Gam : coefficient gamma d'ecrouissage cinematique du L&M
  56. * les coefficients d'ecrouissage du modele de Cast3M sont :
  57. * - C = Gam
  58. * - A = CLM / Gam
  59. * Valeurs des parametres du modele pour acier 316L a 20 degC (L&M, p. 319) :
  60. SIGY1 = 82.e6 ;
  61. N1 = 24. ;
  62. K1 = 151.e6 ;
  63. CLM = 162400.e6 ;
  64. Gam = 2800. ;
  65. A1 = CLM / Gam ;
  66. C1 = Gam ;
  67. Q1 = 142.e6 - SIGY1 ;
  68. B1 = 8. ;
  69.  
  70. * Module d'Young et coeff. de Poisson :
  71. YM1 = 200.e9 ;
  72. NU1 = 0.3 ;
  73.  
  74. * Modeles & Caracteristiques :
  75. mo1 = mode s1 mecanique elastique isotrope viscoplastique chaboche bbar ;
  76. ma1 = mate mo1 'YOUN' YM1 'NU' NU1 'SIGY' SIGY1
  77. 'K' K1 'N' N1 'A' A1 'C' C1 'B' B1 'Q' Q1 ;
  78.  
  79. mo2 = 'MODE' S1 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'VISCOPLASTIQUE' 'ONERA' 'BBAR' ;
  80. ma2 = 'MATE' mo2 'YOUN' YM1 'NU' NU1 'KK' SIGY1
  81. 'K0' K1 'N' N1 'B' B1
  82. 'ALFK' 0. 'ALFR' 1. 'ALF' 0.
  83. 'A1' A1 'C1' C1 'BET1' 0. 'R1' 0.
  84. 'A2' 0. 'C2' 0. 'BET2' 0. 'R2' 0.
  85. 'PHI' 1. 'GAMA' 0. 'M' 0.
  86. 'QMAX' 1. 'QSTA' 0. 'MU' 0. 'ETA' 0. ;
  87.  
  88. *-------------------------- CL & Chargement ---------------------------*
  89. *
  90. cl1 = bloq uz l1 ;
  91. cl2 = bloq ur l4 ;
  92. cl3 = bloq uz l3 ;
  93.  
  94. u1 = 0.002 ;
  95. f1 = depi cl3 u1 ;
  96.  
  97. xt1 = 100. ;
  98. ev1 = evol manu temp (xt1 * (prog 0. 1. 2. 3. 4. 6.))
  99. (prog 0. 1. 0. -1. 0. 2.) ;
  100. cgu1 = char dimp f1 ev1 ;
  101.  
  102. si IGRAPH ;
  103. trac qual (S1 et (l1 coul roug) et (l3 coul vert) et (l4 coul bleu))
  104. titr ' CL : Uz=0 en L1 (rouge), Ur=0 en L4 (bleu) et Uz impose sur L3 (vert)' ;
  105. dess (u1*ev1) titre ' Evolution temporelle du deplacement impose ';
  106. fins ;
  107.  
  108. *------------------------- Resolution PASAPAS -------------------------*
  109. *
  110. * Modele de Chaboche :
  111. ta1 = tabl ;
  112. ta1.modele = mo1 ;
  113. ta1.caracteristiques = ma1 ;
  114. ta1.blocages_mecaniques = cl1 et cl2 et cl3 ;
  115. ta1.chargement = cgu1 ;
  116. ta1.temps_calcules = (prog 0. pas 0.1 6.) * xt1 ;
  117.  
  118. ta1.mes_sauvegardes = tabl ;
  119. ta1.mes_sauvegardes.defin = vrai ;
  120.  
  121. pasapas ta1 ;
  122.  
  123. * Modele ONERA :
  124. ta2 = tabl ;
  125. ta2.modele = mo2 ;
  126. ta2.caracteristiques = ma2 ;
  127. ta2.blocages_mecaniques = cl1 et cl2 et cl3 ;
  128. ta2.chargement = cgu1 ;
  129. ta2.temps_calcules = ta1.temps_calcules ;
  130. ta2.hypothese_deformations = 'LINEAIRE' ;
  131.  
  132. ta2.mes_sauvegardes = tabl ;
  133. ta2.mes_sauvegardes.defin = vrai ;
  134.  
  135. chq0 = manu chml mo2 epse 0. qqq Q1 stresses ;
  136. ta2.variables_internes = tabl ;
  137. ta2.variables_internes.0 = chq0 ;
  138.  
  139. pasapas ta2 ;
  140.  
  141. *-------------------- Postraitement des resultats ---------------------*
  142.  
  143. nb1 = dime ta1.temps ;
  144. ltps1 = prog ;
  145. leps1 = prog ;
  146. lsig1 = prog ;
  147. lsig2 = prog ;
  148. i1 = 0 ;
  149. repe bo1 nb1 ;
  150. tpsi1 = ta1.temps.i1 ;
  151. depi1 = ta1.deplacements.i1 ;
  152. epsi1 = (epsi mo1 ma1 depi1) exco epzz scal maxi ;
  153. sigi1 = ta1.contraintes.i1 exco smzz scal maxi ;
  154. sigi2 = ta2.contraintes.i1 exco smzz scal maxi ;
  155. ltps1 = ltps1 et (prog tpsi1) ;
  156. leps1 = leps1 et (prog epsi1) ;
  157. lsig1 = lsig1 et (prog sigi1) ;
  158. lsig2 = lsig2 et (prog sigi2) ;
  159. i1 = i1 + 1 ;
  160. fin bo1 ;
  161. lsig1 = 1.e-6 * lsig1 ;
  162. lsig2 = 1.e-6 * lsig2 ;
  163. evezz1 = evol manu temps ltps1 epzz leps1 ;
  164. evszz1 = evol roug manu temps ltps1 smzz lsig1 ;
  165. evszz2 = evol vert manu temps ltps1 smzz lsig2 ;
  166. evsve1 = evol roug manu epzz leps1 smzz lsig1 ;
  167. evsve2 = evol vert manu epzz leps1 smzz lsig2 ;
  168.  
  169. * Affichages :
  170. si IGRAPH ;
  171. tl1 = table ;
  172. tl1 . 1 = 'NOLI MARQ CROI' ;
  173. tl1 . titre = table ;
  174. tl1 . titre . 1 = 'ONERA' ;
  175. tl1 . titre . 2 = 'CHABOCHE' ;
  176. dess (evszz1 et evszz2) lege tl1
  177. titre ' Evolution temporelle de la contrainte de traction ' ;
  178. dess (evsve1 et evsve2) lege tl1 titre ' Courbe de traction ' ;
  179. fins ;
  180.  
  181. *------------------------- Test de validation -------------------------*
  182. *
  183. err0 = (maxi abs (lsig2 - lsig1)) / (maxi abs lsig2) ;
  184.  
  185. opti echo 0 ;
  186. mess ' Comparaison solution calculee / reference ' ;
  187. mess ' ----------------------------------------- ' ;
  188. mess ' Max.|SMZZ(cal.) - SMZZ(Ref.)| / Max.|SMZZ(cal.)| =' err0 ;
  189. opti echo 1 ;
  190.  
  191. si (err0 > 1.e-4) ;
  192. erre 5 ;
  193. fins ;
  194.  
  195. fin ;
  196.  
  197.  
  198.  
  199.  
  200.  
  201.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales