Télécharger canalBu.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : canalBu.dgibi
  2. * Ce cas teste le modèle longueur de melange de Buleev
  3. * sur l'écoulement turbulent dans un canal plan.
  4. opti trace 'PSC';
  5. mess ' Configuration Courte ' ; COMPLET = FAUX ;
  6. mess ' Configuration SANS TRACE' ; GRAPH = FAUX ;
  7. *mess ' Configuration Complete ' ; COMPLET = VRAI ;
  8. *mess ' Configuration POST ' ; GRAPH = VRAI ;
  9. *-----------------------------------------------------------------------
  10. opti dime 2 elem TRI6;
  11. opti dime 2 elem QUA8;
  12. *-----------------------------------------------------------------------
  13. * |Triangles | Quadrangles
  14. * ---------------------------
  15. * LINE | | OK
  16. * LINB | |
  17. * MACRO| ? | OK
  18. * QUAF | | OK
  19. *-----------------------------------------------------------------------
  20.  
  21.  
  22. DISCR=QUAF;
  23. DISCR=MACRO;
  24. *DISCR=LINE;
  25. KPRES=CENTREP1;
  26. *KPRES=MSOMMET ;
  27. *KPRES=CENTRE ;
  28. KSUPG=SUPG;
  29. KSUPG=CENTREE;
  30. KSUPG=SUPG ;
  31. epsi = 1.e-5;
  32.  
  33. ******=================================================**********
  34. ******=================================================**********
  35. ******=================================================**********
  36. ******=================================================**********
  37. ******=================================================**********
  38. Si COMPLET;
  39. NBIT =250;
  40. DT = 0.05;
  41. H=1. ;
  42. L=30.*H;
  43. dcl=H/120;
  44. dm=H/20;
  45. dcl=H/160;
  46. dm=H/25;
  47. dcl=H/1200;
  48. dm=H/40;
  49. dcx=H/15.;
  50. dmx=H/10.;
  51. Sinon;
  52. NBIT =7;
  53. *NBIT =100;
  54. DT = 0.1;
  55. H=1. ;
  56. L=10.*H;
  57. dcl=H/20;
  58. dm=H/5;
  59. dcx=H/10.;
  60. dmx=H/5.;
  61. Finsi;
  62. *................................................................
  63. DEBPROC CALCUL;
  64. ARGU RVX*'TABLE';
  65. RV = RVX.'EQEX' ;
  66.  
  67. un = rv.'INCO'.'UN' ;
  68.  
  69. * Prt = PRODT UN $mt (GB T) ;
  70. * Prt = PRODT UN $mt ;
  71.  
  72. Prt = (exco (kops 'GRADS' (exco un 'UX') $mt) 'UY') abs;
  73. rv.'INCO'.'PRODT'=Prt;
  74. Si ( EGA LMEL 1) ;
  75. mut = Ro * lm1 * lm1 * (Prt**0.5);
  76. Finsi;
  77. Si ( EGA LMEL 2 ) ;
  78. mut = Ro * lm2 * lm2 * Prt ;
  79. Finsi;
  80. Si ( EGA LMEL 3 ) ;
  81. cm2 = 7.1*7.1;
  82. uaxe= exco un 'UX';
  83. rett= ro*uaxe*lm3*(inve rv.'INCO'.'MU');
  84. rett=rett - cm2;
  85. irett= masq rett 'SUPERIEUR' 0.;
  86. mut = rett * irett * (rv.inco.'MU' * (1./cm2));
  87. Finsi;
  88.  
  89. rv.'INCO'.'MUF'= mut + rv.'INCO'.'MU';
  90.  
  91. as2 ama1 = 'KOPS' 'MATRIK' ;
  92. * mess ' FIN CALCUL' ;
  93. 'FINPROC' as2 ama1 ;
  94.  
  95. ******=================================================**********
  96. ******=================================================**********
  97. ******=================================================**********
  98. ******=================================================**********
  99. ******=================================================**********
  100. P0 = 0. 0. ;
  101. P1 = L 0. ;
  102. P2 = L H ;
  103. P3 = 0. H ;
  104. PS3 = (P0 PLUS P3)*0.5;
  105.  
  106. entree= P0 d dini dcl dfin dm ps3 d dini dm dfin dcl P3;
  107. *entree= P0 d 12 P3;
  108. sortie=(entree plus (L 0.)) inve;
  109. par1 = p0 d dini dcx dfin dmx p1 ;
  110. *par1 = p0 d dini dcl dfin dcl p1 ;
  111. par2 = (par1 plus (0. H)) inve;
  112.  
  113. pc= 1. 1.;
  114. ang= 43.;
  115. ang= 60.;
  116. ang= 0. ;
  117. entree=entree TOUR ang pC;
  118. sortie=sortie TOUR ang pC;
  119. par1 =par1 TOUR ang pC;
  120. par2 =par2 TOUR ang pC;
  121.  
  122. elim (entree et par1 et par2 et sortie) epsi;
  123. mt = daller entree par2 sortie par1;
  124. v1=1. 0. ;
  125. v2=0. -1.;
  126. v3=-1. 0.;
  127. v4=0. 1. ;
  128. vt1= tour v1 ang p0;
  129. vt2= tour v2 ang p0;
  130. vt3= tour v3 ang p0;
  131. vt4= tour v4 ang p0;
  132. list vt1;
  133. list vt2;
  134. list vt3;
  135. list vt4;
  136.  
  137. Mmt = chan mt QUAF ;
  138. Mentree= chan entree QUAF ;
  139. Msortie= chan sortie QUAF ;
  140. Mpar1 = chan par1 QUAF ;
  141. Mpar2 = chan par2 QUAF ;
  142.  
  143. elim (Mmt et Mentree et Msortie et Mpar1 et Mpar2) epsi ;
  144.  
  145. $mt = model Mmt 'NAVIER_STOKES' DISCR;
  146. $entree = model Mentree 'NAVIER_STOKES' DISCR;
  147. $sortie = model Msortie 'NAVIER_STOKES' DISCR;
  148. $par1 = model Mpar1 'NAVIER_STOKES' DISCR;
  149. $par2 = model Mpar2 'NAVIER_STOKES' DISCR;
  150.  
  151. doma $mt 'IMPR';
  152. doma $entree 'IMPR';
  153. mt = doma $mt maillage;
  154. entree = doma $entree maillage;
  155. sortie = doma $sortie maillage;
  156. par1 = doma $par1 maillage;
  157. par2 = doma $par2 maillage;
  158. axe = par1 plus (0. (H/2.));
  159. elim (axe et mt) epsi;
  160. entre1= chan entree poi1;
  161. entre1= elem entre1 (lect 2 pas 1 ((nbel entre1) - 1 ));
  162.  
  163. *****************************************************************
  164. *** Création des longueurs de mélange
  165. * LMEL=1
  166. ck=0.41;
  167. lm1=0.41 *(coor 2 mt);
  168. ilm1= lm1 masq 'INFERIEUR' (0.4 *H/2.) ;
  169. lm2=0.41*(H - (coor 2 mt));
  170. ilm2= lm2 masq 'INFERIEUR' (0.4 *H/2.) ;
  171. lma=0.41 *(coor 2 axe);
  172. lm1= (lm1*ilm1)+(lm2*ilm2) + lma;
  173. Ef=H/2.;
  174.  
  175.  
  176. * LMEL=2
  177. yr = (coor 2 mt)*(1./Ef/2.);
  178. lm2 = 2.*Ef*(0.14 - (0.08*(1. - yr)**2.) - (0.06*(1. - yr)**4.));
  179.  
  180. * LMEL=3
  181. dparoi=(coor 2 mt);
  182. dparoi=dparoi*(H - dparoi);
  183. dparoi=dparoi+1.e-10;
  184.  
  185. zd = dparoi ;
  186. *lm3 = H *( (Zd / H) * (1. - (Zd/H)) ) ;
  187. lm3 = Zd ;
  188.  
  189. evlm1 = evol chpo lm1 sortie;
  190. evlm1 = evlm1 coul rouge;
  191. evlm2 = evol chpo lm2 sortie;
  192. evlm2 = evlm2 coul jaune;
  193. evlm3 = evol chpo lm3 sortie;
  194. evlm3 = evlm3 coul verte;
  195. evdpar=evol chpo dparoi sortie;
  196. evdpar= evdpar coul bleus;
  197.  
  198. TAB1 = TABLE ;
  199. tab1.1 = 'MOT' 'TIRR';
  200. *tab1.2 = 'MOT' 'TIRC';
  201. tab1.2 = 'MOT' 'TIRM';
  202. tab1.3 = 'MOT' '' ;
  203. tab1.'TITRE' = TABLE ;
  204. tab1.'TITRE'. 1 = 'MOT' 'Karman' ;
  205. *tab1.'TITRE'. 2 = 'MOT' 'lm2' ;
  206. tab1.'TITRE'. 2 = 'MOT' 'Buleev' ;
  207. tab1.'TITRE'. 3 = 'MOT' 'd paroi' ;
  208.  
  209. Si GRAPH ;
  210. trace mt TITR ' Maillage ';
  211. *dess (evlm1 et evlm2 et evlm3 et evdpar)
  212. dess (evlm1 et evlm3 et evdpar)
  213. TITR ' Longueurs de mélange' 'GRIL' lege TAB1;
  214. Finsi ;
  215.  
  216. *****************************************************************
  217.  
  218. ye= coor 2 entre1;
  219. U0 = 1. ;
  220. *U0 = 5. ;
  221. Ufr = U0 ;
  222. *Ufr = ye*(H - ye)*U0*1.5*4. ;
  223. uux=(cos ang) * U0;
  224. uuy=(sin ang) * U0;
  225.  
  226. MU = 3.14E-5;
  227. Ro = 1. ;
  228. YP = 1.e-2 ;
  229.  
  230. *Modèle de turbulence : Buleev
  231. LMEL=3;
  232.  
  233. Rey= Ro * Ufr *H * 2. / MU;
  234. mess ' Reynolds = ' Rey;
  235.  
  236. RV= EQEX 'OMEGA' 1. 'NITER' 1 ITMA NBIT 'FIDT' 1
  237. 'OPTI' 'EF' 'IMPL' KSUPG KPRES 'MUVARI'
  238. ZONE $mt 'OPER' 'CALCUL'
  239. ZONE $mt 'OPER' 'NS' 1. 'UN' 'MUF' 'INCO' 'UN'
  240. 'OPTI' 'EFM1' 'IMPL' 'CENTREE'
  241. ZONE $mt 'OPER' DFDT 1. 'UNM' DT INCO 'UN';
  242. ;
  243.  
  244. rv.'ALGO_KEPSILON'=mots 'KLbr';
  245.  
  246. RV= EQEX RV CLIM
  247. * UN UIMP entre1 Ufr UN VIMP entree 1.e-4
  248. UN UIMP entre1 uux UN VIMP entree (uuy + 1.e-4)
  249. UN UIMP (par1 et par2) 0. UN VIMP (par1 et par2) 0.
  250. ;
  251.  
  252. rv.'METHINV'.TYPINV=3 ;
  253. rv.'METHINV'.IMPINV=0 ;
  254. rv.'METHINV'.NITMAX=5000;
  255. rv.'METHINV'.PRECOND=3 ;
  256. *rv.'METHINV'.PRECOND=2 ;
  257. rv.'METHINV'.ILUTLFIL=4 ;
  258. rv.'METHINV'.ILUTDTOL=0.;
  259. rv.'METHINV'.RESID =1.e-8;
  260. rv.'METHINV' . 'FCPRECT'=1 ;
  261. rv.'METHINV' . 'FCPRECI'=1 ;
  262.  
  263. RVP= EQEX
  264. 'OPTI' 'EF' KPRES
  265. ZONE $mt 'OPER' KBBT (-1.) 'INCO' 'UN' 'PRES'
  266. ;
  267.  
  268. * rvp.'METHINV'.TYPINV=TYPINVPR ;
  269. rvp.'METHINV'.TYPINV=3 ;
  270. rvp.'METHINV'.IMPINV=0 ;
  271. rvp.'METHINV'.NITMAX=2500;
  272. rvp.'METHINV'.PRECOND=3 ;
  273. rvp.'METHINV'.ILUTLFIL=10;
  274. rvp.'METHINV'.ILUTDTOL=0.;
  275. rvp.'METHINV'.RESID =1.e-10 ;
  276. rvp.'METHINV' . 'FCPRECT'=50000 ;
  277. rvp.'METHINV' . 'FCPRECI'=50000 ;
  278.  
  279.  
  280. RV.'PROJ'= RVP ;
  281.  
  282. rv.'INCO'= table inco ;
  283. rv.'INCO'.'UN' = kcht $mt vect sommet (1.e-5 1.e-5) ;
  284. rv.'INCO'.'MUF' = kcht $mt scal sommet MU ;
  285. rv.'INCO'.'Echl'= kcht $mt scal sommet dparoi ;
  286. rv.'INCO'.'dparoi'= kcht $mt scal sommet dparoi ;
  287. rv.'INCO'.'EN' = kcht $mt scal sommet 1.e-5 ;
  288. rv.'INCO'.'UNM' = kcht $mt vect sommet (1.e-5 1.e-5) ;
  289. rv.'INCO'.'UNMM'= kcht $mt vect sommet (1.e-5 1.e-5) ;
  290. rv.'INCO'.'PRES'= kcht $mt scal kpres 0.;
  291. rv.'INCO'.'MU' = kcht $mt scal sommet MU;
  292.  
  293.  
  294. rv.'LTPS' = PROG ;
  295. rv.'Tps' = 1. ;
  296. rv.'DT' = DT;
  297. rv.'NUPAT' =1;
  298.  
  299. mess ' EXECUTION '; exec rv ;
  300.  
  301. *Si VRAI ; opti rest 'KBU'; rest ; Finsi;
  302.  
  303. un = rv.inco.'UN' ;
  304.  
  305. qs=dbit un $sortie IMPR;
  306. um=(1./H)*qs;
  307. unn=(1./um)*un;
  308.  
  309. *-----------------------------------------------------------------------
  310. *--- Edition d'un profil de vitesse asymptotique de Référence ----------
  311. *--- Modèle de Buleev
  312. Debproc ANABU H*'FLOTTANT' Rey*'FLOTTANT' UM*'FLOTTANT' ;
  313. H2=H*H;
  314. p0=0. 0. ; p1=0. H. ; Pm=0. (H/2.); dpar=H/Rey*0.05; dctr=H*0.05;
  315. de= p0 d dini dpar dfin dctr pm d dini dctr dfin dpar p1 ;
  316. z= coor 2 de;
  317. Dh=2.*H;
  318. Rho=1.;
  319. mu=um/Rey*Rho*Dh;
  320. m=7.1;
  321. nu=mu/rho;
  322.  
  323. uet=um;
  324. REPETER CCP 15 ;
  325. fp=(uet/Um)**2.*8. ;
  326. F=fp/2/Dh*rho*(um*um);
  327. xi = z*(1./H);
  328. xiet = (1. - ((1. - (nu*m/h/Uet*4))**0.5))/2.;
  329. u1=H2*F/2./mu*xi*(1. - xi);
  330. ax=xi*(1. - xi)/xiet/(1. - xiet) + 1.e-10;
  331. ax=m*m*F*H/Rho* (log ax);
  332. ax =(abs ax) + 1.e-10;
  333. ax0=(h*h*F/mu/2*xiet*(1. - xiet))**2.;
  334. u2=(ax0+ax)**0.5;
  335. iua=masq xi 'INFERIEUR' xiet;
  336. iub=masq xi 'SUPERIEUR' (1. - xiet);
  337. iu1=iua+iub;
  338.  
  339. uref = (iu1 * u1) + ((1. - iu1)*u2) ;
  340. evuref = evol chpo uref de ;
  341. umn=INTG evuref ;
  342. umn=(extr 1 umn)/H; Reyn=rho*umn*Dh/mu;
  343. w=0.9;
  344. uet=(w*(uet*um/umn)) + ((1. - w)*uet);
  345. dumn=abs ((umn - um)/um);
  346. mess 'Iteration ' &ccp ' Umn=' umn ' Reyn=' Reyn ' Uet=' Uet
  347. ' dumn=' dumn;
  348. *dess evuref ;
  349. Si (dumn < 1.e-4) ; quitter CCP; Finsi ;
  350. Fin CCP;
  351. * Calcul des u+g et u+d
  352. yplus= (extr evuref 'ABSC')*uet/nu;
  353. evuplus=evuref*(1./uet);
  354. yy=extr evuplus ORDO ;
  355. lyz=lect (dime yy) pas -1 1;
  356. yyz=extr yy lyz;
  357. evuplud = (evol manu yplus yyz) coul verte;
  358. evuplug = (evol manu yplus yy) coul rouge ;
  359.  
  360. Resproc evuplug evuplud evuref uet;
  361. Finproc ;
  362.  
  363. evupd1 evupg1 evuref1 uet1 = anabu 1. 2000. 1. ;
  364. evupd2 evupg2 evuref2 uet2 = anabu 1. 1.e4 1. ;
  365. evupd3 evupg3 evuref3 uet3 = anabu 1. 1.e5 1. ;
  366. evupd4 evupg4 evuref4 uet4 = anabu 1. 1.e6 1. ;
  367. evupd5 evupg5 evuref5 uet5 = anabu 1. 1.e7 1. ;
  368.  
  369. *--- Profil de Reichardt -----------------------------------------------
  370. Ka = 0.41;
  371. yplusr= prog 0.1 pas 0.1 30 pas 1. 100. pas 50. 1.e3
  372. pas 500. 1.e4 pas 1.e4 2.e5 ;
  373. unp = prog (dime yplusr)*1.;
  374.  
  375. E=9.5;
  376. uplusr=(1./Ka)*(Log (unp + (Ka*yplusr)));
  377. uplusr=uplusr + (7.8* (unp - (exp (yplusr*(-1./11))))
  378. - ( (yplusr*(-1./11)) * (exp (yplusr*(-1./3.))) ) );
  379.  
  380. evr1=evol manu yplusr uplusr;
  381. evr1=evr1 coul verte;
  382. *--- Profil de Reichardt -----------------------------------------------
  383.  
  384. *$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
  385. Si GRAPH;
  386.  
  387. TAB1 = TABLE ;
  388. tab1.1 = 'MOT' ' ';
  389. tab1.2 = 'MOT' 'MARQ CROI REGU';
  390. tab1.3 = 'MOT' 'MARQ CARR REGU';
  391. tab1.4 = 'MOT' 'MARQ LOSA REGU';
  392. tab1.5 = 'MOT' 'MARQ PLUS REGU';
  393. tab1.6 = 'MOT' 'MARQ TRIA REGU';
  394. tab1.'TITRE' = TABLE ;
  395. tab1.'TITRE'. 1 = 'MOT' 'Re 2.e3' ;
  396. tab1.'TITRE'. 2 = 'MOT' 'Re 1.e4' ;
  397. tab1.'TITRE'. 3 = 'MOT' 'Re 1.e5' ;
  398. tab1.'TITRE'. 4 = 'MOT' 'Re 1.e6' ;
  399. tab1.'TITRE'. 5 = 'MOT' 'Re 1.e7' ;
  400. tab1.'TITRE'. 6 = 'MOT' 'Reichardt' ;
  401.  
  402. tit1=chai 'Comparaison Profils de vitesse Buleev à différents Reynds';
  403. tit2=chai tit1 ' et Reichardt';
  404. dess (evupd1 et evupd2 et evupd3 et evupd4 et evupd5 et evr1)
  405. LOGX XBOR 0.1 5.e5 'GRIL' 'CARR' lege TAB1 titr tit2;
  406.  
  407. dess (evuref1 et evuref2 et evuref3 et evuref4 et evuref5)
  408. 'GRIL' 'CARR' lege TAB1 titr tit1;
  409. *-----------------------------------------------------------------------
  410.  
  411. unx =exco un 'UX';
  412. dudy=exco (kops 'GRADS' unx $mt) 'UY';
  413. uet=(mu*(abs (dudy + 1.e-5)))**0.5;
  414. uet1=redu uet par1;
  415. uet2=redu uet par2;
  416. evuet1= evol chpo uet1 par1;
  417. evuet2= evol chpo uet2 (inve par2);
  418.  
  419. dess (evuet1 et evuet2) TITR ' U* le long des deux parois'
  420. tity 'm/s' titx 'm';
  421.  
  422. mess ' Liste de U*';
  423. yevuet1=extr evuet1 'ORDO';
  424. yevuet2=extr evuet2 'ORDO';
  425. dl=(dime yevuet1) ;
  426. ll=lect (dl - 10) pas 1 dl;
  427. list (extr yevuet1 ll) ;
  428. list (extr yevuet2 ll) ;
  429.  
  430.  
  431. f1=8.*(((1./um)*uet1)**2.);
  432. f2=8.*(((1./um)*uet2)**2.);
  433. fiso = 0.202*(Rey**(-0.196));
  434. evf1=evol chpo f1 par1;
  435. evf1=evf1 coul rouge;
  436. evf2=evol chpo f2 (inve par2);
  437. evf2=evf2 coul verte;
  438. xx=extr evf1 'ABSC';
  439. yfiso= prog (dime xx)*fiso;
  440. evfiso=evol manu xx yfiso ;
  441. evfiso=evfiso coul bleue ;
  442.  
  443. TAB1 = TABLE ;
  444. tab1.1 = 'MOT' 'TIRR';
  445. tab1.2 = 'MOT' 'TIRC';
  446. tab1.3 = 'MOT' 'TIRM';
  447. tab1.'TITRE' = TABLE ;
  448. tab1.'TITRE'. 1 = 'MOT' 'Corr' ;
  449. tab1.'TITRE'. 2 = 'MOT' 'f paroi1' ;
  450. tab1.'TITRE'. 3 = 'MOT' 'f paroi2' ;
  451.  
  452. dess (evfiso et evf2 et evf1)
  453. TITR ' Coefficient de frottement' 'GRIL' lege TAB1;
  454.  
  455.  
  456. yp1=norm ((poin 2 entre1) moins (poin 1 entre1));
  457. yp2=norm ((poin entre1 final) moins (poin ((nbno entre1) - 1) entre1));
  458.  
  459. mess ' YP1=' YP1 ' YP2=' YP2;
  460.  
  461. yplus1= yp1*uet1*(rv.inco.'MU'**(-1.));
  462. yplus2= yp2*uet2*(rv.inco.'MU'**(-1.));
  463.  
  464. evyplus1=evol chpo yplus1 par1;
  465. evyplus2=evol chpo yplus2 (inve par2);
  466.  
  467. dess (evyplus1 et evyplus2) TITR ' Y+ le long des deux parois'
  468. tity ' ' titx 'm';
  469.  
  470. sort2=elem sortie (lect 1 pas 1 ((nbel sortie)/2));
  471. sort1= syme sort2 'DROIT' (point 1 axe) (axe poin final);
  472. elim (sort1 et sort2 et sortie) epsi;
  473.  
  474. uet1=extr (nbno par1) (extr evuet1 'ORDO');
  475. uet2=extr (nbno par1) (extr evuet2 'ORDO');
  476. mess ' uet1 et uet2=' uet1 uet2;
  477. ypls1= evol chpo ((1./mu) * uet1 * (coor 2 sort1)) (inve sort1);
  478. ypls2= evol chpo ((1./mu) * uet2 * (H - (coor 2 sort2))) ( sort2);
  479.  
  480. upl1=(evol chpo unx (inve sort1))*(1./uet1);
  481. upl2=(evol chpo unx sort2)*(1./uet2);
  482. xypls1= ORDO (extr ypls1 'ORDO');
  483. yypls1= ORDO (extr upl1 'ORDO');
  484.  
  485. xypls1=xypls1 enlev 1;
  486. yypls1=yypls1 enlev 1;
  487. evupl1=evol manu xypls1 yypls1;
  488.  
  489.  
  490. xypls2=extr ypls2 'ORDO';
  491. yypls2=extr upl2 'ORDO';
  492. xypls2=xypls2 enlev 1;
  493. yypls2=yypls2 enlev 1;
  494. evupl2=evol manu xypls2 yypls2 ;
  495. evupl1=evupl1 coul rouge;
  496. evupl2=evupl2 coul verte;
  497.  
  498. TAB1 = TABLE ;
  499. tab1.1 = 'MOT' ' ';
  500. tab1.2 = 'MOT' 'TIRC';
  501. tab1.3 = 'MOT' 'TIRM';
  502. tab1.'TITRE' = TABLE ;
  503. tab1.'TITRE'. 1 = 'MOT' 'Reichardt' ;
  504. tab1.'TITRE'. 2 = 'MOT' 'U+ paroi1' ;
  505. tab1.'TITRE'. 3 = 'MOT' 'U+ paroi2' ;
  506.  
  507. dess (evr1 et evupl2 et evupl1) 'LOGX' 'XBOR' 1. 500.
  508. TITR ' U+ en sortie' 'GRIL' lege TAB1
  509. tity ' ' titx 'm';
  510.  
  511. nutsnu=(rv.inco.'MUF')*(1./MU);
  512. trace nutsnu mt (cont mt) 'TITR' ' Nu effectif / nu ';
  513.  
  514. ung = vect un 0.5 'UX' 'UY' jaune;
  515. trace ung mt 'TITR' ' Vitesses ';
  516.  
  517. pn = elno $mt rv.inco.PRESSION kpres;
  518. trace pn mt (cont mt) TITR 'Pression';
  519. evpaxe= evol chpo pn axe;
  520. dess evpaxe TITR ' Pression sur l axe';
  521.  
  522. evax= evol chpo (exco un 'UX') axe ;
  523. dess evax TITR 'U sur l axe'
  524. tity 'm/s' titx 'm';
  525.  
  526. Finsi ;
  527. *$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
  528.  
  529. *profils de référence
  530. evupdr evupgr evusr uetr = anabu 1. Rey 1. ;
  531. mess '***************************************************************';
  532. mess '***************************************************************';
  533. mess ' UET1 = ' UET1 ' UET2 = ' UET2 ' UETR = ' UETR ;
  534. mess '***************************************************************';
  535. mess '***************************************************************';
  536.  
  537. evus= evol chpo (exco unn 'UX') sortie;
  538. usix = extr evusr 'ABSC';
  539. usi = ipol usix (extr evus 'ABSC') (extr evus 'ORDO');
  540. evusi = evol manu usix usi ;
  541. evdu = (evusi - evusr)*(evusi - evusr);
  542.  
  543. Si GRAPH ;
  544. tab1 = table;
  545. tab1.1 = 'MOT' 'TIRC';
  546. tab1.2 = 'MOT' ' ';
  547. tab1.'TITRE' = TABLE ;
  548. tab1.'TITRE'. 1 = 'MOT' 'Buleev' ;
  549. tab1.'TITRE'. 2 = 'MOT' 'Buleev analytique' ;
  550. evusr=evusr coul rouge;
  551.  
  552. dess (evusr et evus) TITR 'U en sortie' 'GRIL' LEGE TAB1
  553. tity 'm/s' titx 'm';
  554.  
  555. dess evdu TITR '|U - uref|**2';
  556. Finsi;
  557.  
  558. du = extr 1 (INTG evdu);
  559. errn = (abs (du - 4.06931E-03));
  560. mess ' delta u = ' du ' errn = ' errn;
  561. Si (NON COMPLET);
  562. Si(errn > 0.0001); erreur 5 ; Finsi ;
  563. Finsi;
  564.  
  565. FIN;
  566.  
  567.  
  568.  
  569.  
  570.  
  571.  
  572.  
  573.  
  574.  
  575.  
  576.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales