Exemples de jeux de données Cast3M

* fichier : calp2.dgibi
*
*----------------------------------------------------------------------*
* Cas-test du calcul de VMIS et des contraintes en peau des poutres    *
* avec CALP.                                                           *
*                                                                      *
* On soumet l'extremite d'une poutre orientee suivant l'axe Ox a un    *
* deplacement suivant Oy+Oz, l'autre extremite etant encastree.        *
*                                                                      *
* On verifie le calcul de la contrainte de von Mises et de la compo-   *
* -sante SMXX des contraintes de peau calculee avec CALP.              *
*                                                                      *
* Le calcul est realise en DIME 3 ELEM SEG2.                           *
*----------------------------------------------------------------------*
 
opti dime 3 elem seg2 ; 
opti trac PSC POTR HELVETICA_16 EPTR 8;
* ORIG  = VRAI;
GRAPH = FAUX;
 
* * Donnees numeriques
* * ------------------
* sec1 = 0.0025 ;
* dx1  = 1. ;
* dy1  = 0.03 ;
* dz1  = 0.05 ;
* iry1 = 1. ;
* irz1 = 1. ;
* tor1 = 1. ; L1=10.;
* BP, 2022-08-05, fiche #11422 : on utilise des valeurs raisonnables
* GEOMETRIE : longueur, diametre, epaisseur
  L1    =   2.    ;
  Dext1 =   2.E-3  ;
  Th1   =   1.E-3  ;
* MATERIAU : module d'Young, coefficient de Poisson, masse volumique
  Ey1   =   2.E11  ;
  nu1   =   0.3 ;
  rho1eq=   8000.;
* DEDUCTION :
  Rext1 = 0.5 * Dext1;
  Rint1 = Rext1 - Th1;
  Sec1  = pi * ((Rext1**2) - (Rint1**2));
  iry1  = (pi/4.) * ((Rext1**4) - (Rint1**4));
  irz1  = iry1;
  tor1   = (pi/2.) * ((Rext1**4) - (Rint1**4));
teta = 0.;
 dx1 =0.;
 dy1 = (cos teta) * Rext1;
 dz1 = (sin teta) * Rext1;
 
FMT1 = MOT '(1PE9.3)';
FMT2 = MOT '(F10.3)';
 
* Maillage :
* ----------
P1 =  0 0 0 ; 
P2 = L1 0 0;
Lig1 = P1 droi 10 P2 ; 
 
* CL / Chargement :
* -----------------
cl1 = bloq depl rota P1 ; 
cl2 = bloq uy uz P2 ; 
dcl2 = depi cl2 0.01 ; 
 
 
* ==================================================
* =====     BOUCLE SUR LES TYPE D'ELEMENTS     ===== 
* ==================================================
 
*LEF = MOTS 'POUT' 'TIMO' 'TUYA';
* --> on ne fait pas les TUYA pour l'instant !
LEF = MOTS 'POUT' 'TIMO';
NEF = DIME LEF;
* on prepare plein de post traitements
SI GRAPH;
  lcoco = @PALETTE NEF;
  TevSig1 = TABL;
  lSig1 = MOTS EFFX EFFY EFFZ MOMX MOMY MOMZ;
  nSig1 = DIME lSig1; 
  REPE BSig1 nSig1; 
    moSig1 = EXTR lSig1 &BSig1;
    TevSig1 . moSig1 = VIDE 'EVOLUTIO'; 
  FIN  BSig1;
  evVMi = VIDE 'EVOLUTIO';
  evSXX = VIDE 'EVOLUTIO';
  Tdess1 = TABL; Tdess1 . 'TITRE' = TABL;
FINSI;
prERR = PROG;
 
REPE BEF NEF; 
  moEF = EXTR LEF &BEF;
  MESS 'Analyse avec element de type' ' ' moEF;
 
 
* Modele / caracteristiques :
* ---------------------------
  mo1  = mode Lig1 mecanique moEF ;
  SI (EGA moEF 'TUYA');
  ma1  = mate mo1 youn 20.e9 nu 0.2 EPAI th1 RAYO Rext1 ; 
  SINON;
  ma1  = mate mo1 youn 20.e9 nu 0.2 sect sec1 dx dx1 dy dy1 dz dz1 inry iry1 inrz irz1 tors tor1 ; 
  FINSI;
 
 
* Resolution :
* ------------
  K1 = rigi mo1 ma1 ; 
  u1 = reso (K1 et cl1 et cl2) dcl2 ; 
 
* Post-traitements : calcul des Contraintes
* -----------------------------------------
  SI GRAPH;
    Tdess1 . 'TITRE' . &BEF = MOT moEF;
    coco = EXTR lcoco  &BEF;
  FINSI;
 
* Contraintes generalisees :
* °°°°°°°°°°°°°°°°°°°°°°°° 
  sig1 = sigm mo1 ma1 u1 ; 
  SI GRAPH;
    sig1chpo = CHAN 'CHPO' sig1 mo1;
    REPE BSig1 nSig1; 
      moSig1 = EXTR lSig1 &BSig1;
      TevSig1 . moSig1 = TevSig1 . moSig1 ET (EVOL coco 'CHPO' sig1chpo moSig1 Lig1);
    FIN  BSig1;
  FINSI;
 
* Contrainte de Von Mises (en dx dy) :
* °°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
* - via VMIS :
  vmi1 = vmis mo1 ma1 sig1 ; 
  SI GRAPH;
    evVMi = evVMi ET (EVOL coco 'CHPO' (CHAN 'CHPO' vmi1 mo1) Lig1);
  FINSI;
* - via la formule indiquee dans sa notice :
* Seq = ((EFFX / SECT)**2 + (MOMX * DX / TORS)**2 + (MOMY * DZ / INRY)**2 + (MOMZ * DY / INRZ)**2)**0.5
  vmi2 = ((exco sig1 effx scal) / sec1 ** 2)
       + ((exco sig1 momx scal) * dx1 / tor1 ** 2)
       + ((exco sig1 momy scal) * dz1 / iry1 ** 2)
       + ((exco sig1 momz scal) * dy1 / irz1 ** 2) ;
  vmi2 = vmi2 ** 0.5 ;
* --> Erreur calcul VMIS :
  err1 = maxi abs (vmi1 - vmi2) ;
  prERR = prERR ET err1;
*list err1 ;
  MESS (CHAI '\s_{Von Mises}~' FORMAT FMT1 (MAXI ABS vmi2) ' err=' FORMAT FMT2 err1);
 
* Contrainte de peau smxx :
* °°°°°°°°°°°°°°°°°°°°°°°
* sauf si CALP non implanté...
* SI (ORIG ET (EGA moEF 'TIMO')) ; ITER BEF; FINSI;
SI (EGA moEF 'TUYA'); ITER BEF; FINSI;
* - via CALP :
  smp1 = calp sig1 mo1 ma1 ;
  smp1 = exco smp1 smxx smxx ;
  SI GRAPH;
    evSXX = evSXX ET (EVOL coco 'CHPO'  (CHAN 'CHPO' smp1 mo1) Lig1);
  FINSI;
* - via formule :
* SMXX = ((EFFX / SECT) + (MOMY * DZ / INRY) - (MOMZ * DY / INRZ)
  smp2 = ((exco sig1 effx smxx) / sec1)
       + ((exco sig1 momy smxx) * dz1 / iry1)
       - ((exco sig1 momz smxx) * dy1 / irz1) ;
* --> Erreur calcul peau
  err2 = maxi abs (smp1 - smp2) ;
  prERR = prERR ET err2;
* list err2 ;
  MESS (CHAI '\s_{xx}(dy,dz)~' FORMAT FMT1 (MAXI ABS smp2) ' err=' FORMAT FMT2 err2);
 
FIN BEF;
 
* Test de validation :
ERR0 = maxi abs prERR ;
xpr1 = (vale prec) ** 0.5 ;
MESS ERR0 ' >? ' ' 'xpr1;
 
SI GRAPH;
  REPE BSig1 nSig1; 
    moSig1 = EXTR lSig1 &BSig1;
    DESS (TevSig1 . moSig1) 'LEGE' Tdess1 'TITRE' (CHAI moSig1 '(x)');
  FIN  BSig1;
  DESS evVMi 'LEGE' Tdess1 'TITRE' 'VonMises(x,dy=0.03,dz=0.05)';
  DESS evSXX 'LEGE' Tdess1 'TITRE' '\s_{xx}(x,dy=0.03,dz=0.05)';
FINSI;
 
 
si (err0 > xpr1) ;
  erre 5 ;
fins ;
 
fin ;