Télécharger c3d93.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : c3d93.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. **************************************************************
  6. * 3D MAGNETIC FIELD COMPUTATION 2 POTENTIALS METHOD
  7. *
  8. * REDUCED POTENTIAL (VOLUME CONTAINING INDUCTORS)
  9. * TOTAL POTENTIAL (VOLUME WHITHOUT CURRENTS )
  10. *
  11. **************************************************************
  12. option echo 1 ;
  13. TYPEL = 2 ;
  14. GRAPH = N ;
  15. si ( ega typel 2 ) ;
  16. OPTION DIME 2 ELEM QUA8 COUL VERT echo 0 ;
  17. sinon ;
  18. OPTION DIME 2 ELEM QUA4 COUL VERT echo 0 ;
  19. finsi ;
  20. *---------------------------MESH -----------------------------------
  21. R1 =20. ; R2= 25. ; R3= 27. ; R4= 29. ; R5=39.;R6 = 130.;
  22. Z1= 2.5; Z2= 5. ; Z3= 20. ; Z4= 130.;Z31=30.;Z32=50.;
  23. DI1= 1.; DI2=5.;DI3=60. ;DI4= 10.;NET2= 6;
  24.  
  25. DENS DI1 ;
  26. OZ3= 0. Z3; OZ2= 0. Z2;OZ1= 0. Z1;OZ4=0. Z4;
  27. OO= 0. 0.;R0Z0= DI1 0 ;
  28. R1Z0= R1 0. ;R2Z0= R2 0. ;R3Z0 = R3 0. ;R4Z0 = R4 0.;
  29. R0Z2= DI1 Z2 ; R4Z2 = R4 Z2 ;
  30. DENS DI2 ;
  31. R5Z0= R5 0. ;R5Z3= R5 Z3 ;R0Z3 =DI2 Z3 ;OZ3 = 0. Z3 ;
  32. DENS DI3 ;
  33. R6Z0=R6 0.; R6Z4=R6 Z4 ;
  34. DENS 10 ;
  35. R2Z3= R2 Z3 ; R1Z3= R1 Z3; R4Z1 = R4 Z1;
  36. R3Z1= R3 Z1 ;
  37. DENSITE DI4 ;
  38. R0Z4 = DI4 Z4 ; OZ4 = 0. Z4 ;
  39. NTRA= 1;
  40. FLAN1 =( D OO R0Z0 D R1Z0 ) TRAN DINI DI1 DFIN DI1 ( OZ1 MOINS OO )
  41. TRAN DINI DI1 DFIN DI1 ( OZ2 MOINS OZ1) COUL VERT ;
  42. BOBI =( D R1Z0 R2Z0 ) TRAN DINI DI1 DFIN DI1 ( OZ1 MOINS OO )
  43. COUL BLEU ;
  44. FLAN2 =(INVE( BOBI COTE 3)) TRAN DINI DI1 DFIN DI1
  45. ( OZ2 MOINS OZ1) COUL VERT ;
  46. FLAN3 =( D R2Z0 R3Z0 ) TRAN DINI DI1 DFIN DI1 ( OZ1 MOINS OO )
  47. TRAN DINI DI1 DFIN DI1 ( OZ2 MOINS OZ1) COUL VERT ;
  48. FLAN4 =( D R3Z0 R4Z0 ) TRAN DINI DI1 DFIN DI1 ( OZ1 MOINS OO )
  49. TRAN DINI DI1 DFIN DI1 ( OZ2 MOINS OZ1) COUL VERT ;
  50. FER = (D OZ2 R0Z2 D R4Z2 D 6 R4Z0 D R5Z0 D R5Z3 D R0Z3 D OZ3 D OZ2 )
  51. SURF PLANE COUL ROUG ;
  52.  
  53. FLAN5 = ( D R5Z0 R5Z3 D R6Z4 D R6Z0 D R5Z0 ) SURF PLANE ;
  54. *
  55. FLAN6 =( D R0Z3 R5Z3 D R6Z4 D R0Z4 D R0Z3 ) SURF PLANE
  56. COUL VERT ;
  57. TUB6 = (D OZ3 R0Z3 D R0Z4 D OZ4 D OZ3) SURF PLANE COUL VERT ;
  58. AIREXT =( FLAN6 ET TUB6 ET FLAN5 ) coul blan ;
  59. AIRIN =(FLAN1 ET FLAN2 ET FLAN3 ET BOBI ET FLAN4) coul vert ;
  60. TFLAN = AIRIN ET FER ET AIREXT ;ELIM .1 TFLAN ;
  61. PTAX = TFLAN POINT DROITE OO ( 0 1. ) .01 ;
  62. TU1 = TFLAN ELEM APPU LARG PTAX ;
  63. TOUT = DIFF TFLAN TU1 ;
  64. *
  65. C1 = (TOUT CONT ) 'ELEM' 'COMP' R0Z4 R0Z0 ;
  66. C2 = C1 PROJETER (1 0 ) DROITE OO OZ4 ;
  67. OZ4 = C2 POINT PROCHE OZ4 ;
  68. OO = C2 POINT PROCHE OO ;
  69. TU1 = DALLER C1 ( D 1 R0Z0 OO ) C2 (D OZ4 R0Z4 ) PLAN ;
  70. TUA = (COOR 2 TU1) POINT SUPER Z3 ;
  71. TUA = (TU1 ELEM APPU LARG TUA ) COUL BLAN ;
  72. TUB = (COOR 2 TU1) POINT INFER Z2 ;
  73. TUB= (TU1 ELEM APPU LARG TUB ) COUL VERT ;
  74. TUF = DIFF TU1 ( TUA ET TUB ) COUL ROUG ;
  75. AIRIN = (TOUT ELEM VERT ) ET TUB ;
  76. FER = (TOUT ELEM ROUG ) ET TUF ;
  77. AIREXT = ( TOUT ELEM BLAN) ET TUA ;
  78. * TRAC (AIRIN ET FER ET AIREXT ) FACE ;
  79. *-----------
  80. *------------------ SHIFT TO 3D --------------------------------
  81. *------------
  82. OPTION ELEM CUB8 ;
  83. SI ( EGA TYPEL 2 )
  84. OPTION DIME 3 ELEM CU20 ;
  85. FINSI ;
  86. ANG = 20. ;
  87. *
  88. *------------- DEFINITION OF THE 2 DOMAINS -----------
  89.  
  90. *------ REDUCED POTENTIAL VOLUME --------------------------
  91. DPHI = AIRIN VOLU 1 ROTA ANG (0 0 0 ) (0 1 0 ) ;
  92.  
  93. **------ TOTAL POTENTIAL VOLUME --------------------------
  94. DPSI = (AIREXT ET FER) VOLU 1 ROTA ANG (0 0 0 ) (0 1 0 ) ;
  95. *
  96. ELIM .001 DPHI ; DPHI = REGE DPHI ;
  97. ELIM .001 DPSI ; DPSI = REGE DPSI ;
  98. ELIM .001 ( DPHI ET DPSI) ;
  99.  
  100. *---- ---------SEPARATION SURFACE IDENTIFICATION -------------
  101. * ---------- BELONGS TO REDUCED POTENTIAL VOLUME ---------------
  102. SEP_PHI = INTE ( DPSI ENVEL ) ( DPHI ENVEL ) ;
  103. *------------- SPLITTING OF THE 2 DOMAINS ------------------
  104. DPSI = DPSI PLUS ( 0 0 0 ) ;
  105. SEP_PSI = SEP_PHI PLUS ( 0 0 0 ) ; ELIM .01 DPSI SEP_PSI ;
  106. *--------------------IRON-------------------------------------
  107. DFER = DPSI ELEM ROUG ;
  108. *
  109. VOL1 = DPHI ET DPSI ;
  110. DAIR = DPSI ELEM BLAN ;
  111. AA = DPHI POINT PLAN (0 0 0 ) ( 10 0 0 ) (0 0 10 ) .00001 ;
  112. AB =( DPHI ENVEL ) ELEM APPU STRIC AA ;
  113. AA = (AB ENVEL ) POINT DROITE (0 0 0 ) ( 10 0 0 ) .00001 ;
  114. AA = ( (AB CONTOUR ) ELEM APPU STRIC AA );
  115. deplacer vol1 tourner 90 ( 0 0 0 ) ( 1 0 0 ) ;
  116. *
  117. ORIG= SEP_PHI POINT PROCHE (29. 0 0 ) ;
  118. BANTI= SEP_PHI POINT PLAN (0. 0. 0.) (10. 0. 0.) (0. 10. 0.) .1 ;
  119. geomed = (dpsi et dphi ) point plan (0 0 0) ( 1 0 0) (0 1 0 ) .1 ;
  120. MU0 = 4. * PI * 1.E-4 ;
  121. RINT = 20. ;REXT =25. ; HAUT = 5. ; J = 800. ;
  122. C1 = 0. 0. 0. ; ZP1 = 20. 0. 0. ;ZP2 = 0. 20. 0. ;
  123. E = Z1 * 4 ;
  124. UNIT = M ;
  125. si ( ega UNIT M) ;
  126. deplacer vol1 homo .001 (0. 0. 0.) ;
  127. MU0 = 4. * PI * 1.E-7 ;
  128. RINT = RINT/1000; REXT = REXT/1000 ; HAUT = HAUT/1000 ;
  129. ZP1 = ZP1/1000;ZP2 = ZP2 / 1000 ;J = J*1.E6 ;
  130. E = E /1000 ;
  131. finsi ;
  132. option echo 1 ;
  133. *-------
  134. *-- BIOT and SAVART COMPUTATION of Hs ON REDUCED POTENTIAL DOMAIN
  135. *-------
  136. BS = BIOT SEP_PHI CERC C1 ZP1 ZP2 RINT REXT HAUT J MU0 ;
  137. HS = BS / MU0 ;
  138.  
  139.  
  140. SI (NEG GRAPH 'N') ;
  141. OEIL = 1000 1000 500 ;
  142. TITRE ' HS ON SEPARATION SURFACE ' ;
  143. VVVV = VECTEUR BS 1.e-3 'BX' 'BY' 'BZ' ROUG ;
  144. TRAC OEIL SEP_PHI VVVV ;
  145. FINSI ;
  146. *---------------- FILLING OF A TABLE -----------------------------
  147. *-in this computation there is only one isotropic material but it
  148. * is shown how to coope with multi-material (even orthotropic )
  149. *------------------------------------------------------------------
  150. TABB= TABLE ;
  151. *
  152. FER1 = DFER ELEM CU20 ;
  153. FER2 = DFER ELEM PR15 ;
  154. *
  155. KEVOL1 = H_B MU0 ;
  156. KEVOL2 = H_B MU0 ;
  157. OBFER1 = FER1 MODE THERMIQUE ISOTROPE ;
  158. OBFER2 = FER2 MODE THERMIQUE ORTHOTROPE ;
  159. TABDEF = TABLE ;
  160. *----------------- isotropic material -----------------
  161. STN = TABLE ;
  162. STN.'EV1' = KEVOL1 ;
  163. TABDEF.OBFER1 = STN ;
  164. *------------- orthotropic material -------------------
  165. STN = TABLE ;
  166. DI1 = (0 1 0 ) ;DI2 = (1 0 1 ) ;
  167. STN.'EV1' = KEVOL1 ;STN.'DIR1' = DI1 ;
  168. STN.'EV2' = KEVOL2 ;STN.'DIR2' = DI2 ;
  169. TABDEF.OBFER2 = STN ;
  170. TABB.'TABNUSEC'= TABDEF;
  171. *----------------------------------------------------------------
  172. TABB.'BIOT'=HS ;
  173. *----------------- REDUCED POTENTIAL AREA ----------------
  174. *---
  175. TABB.'DPHI' = DPHI ;
  176. imet = 0 ;
  177. si (ega imet 1 ) ;
  178. MOD1 = DPHI MODE THERMIQUE ISOTROPE ;
  179. MAT1 = MATE MOD1 'K' MU0 ;
  180. RIGC1 = CONDUC MOD1 MAT1 ;
  181. TABB.'RIGCON' = RIGC1 ;
  182. finsi ;
  183. *
  184. TABB.'SEPPHI' = SEP_PHI ;
  185. TABB.'ORIG' = ORIG ;
  186. TABB.'MUAIR' = MU0;
  187. *
  188. *------------------- TOTAL POTENTIAL AREA --------------------
  189. *---------
  190. TABB.'DPSI' = DPSI ;
  191. TABB.'AIRPSI' = DPSI ELEM BLAN ;
  192. si ( ega imet 1 ) ;
  193. MOD2 = DAIR MODE THERMIQUE ISOTROPE ;
  194. MAT2 = MATE MOD2 'K' MU0 ;
  195. RIGC2 = CONDUC MOD2 MAT2 ;
  196. TABB.'RIGCPSI' = RIGC2 ;
  197. finsi ;
  198.  
  199. * TABB.'SEP_PSI' = SEP_PSI ;
  200. *------------------ GENERAL BOUBDARY CONDITIONS ---------
  201. TABB.'BLOQUE' = BLOQUER 'T' GEOMED ;
  202. *
  203. *------ BOUNDARY CONDITION LINKED TO POTENTIAL JUMP ------------
  204. *
  205. TABA = TABLE ;
  206. STN = TABLE ;TABA.1 = STN ;
  207. STN.'LGEO' = BANTI ;STN.'MTYP' = 'TBLOQ' ;
  208. TABB.'POTSYM'= TABA ;
  209. TABB.ISTEP = 1 ;
  210. *-------------------- FIRST STEP POTENTIALS COMPUTATION ----------
  211. POT_SCAL TABB 'SOLIN';
  212. *-------------------------------------------------------------------
  213. SOL1= TABB.'POTENTIEL';
  214. PREF= 0. 0. 0. ;
  215. *----------- FIELD COMPUTATION (B) -----------------------
  216. OBJM= MODE DPHI THERMIQUE ISOTROPE ;
  217. BA= CHAN CHPO ( GRAD OBJM SOL1 ) OBJM ;
  218. BA= BA * -1. * MU0 ;
  219. BM= EXTR BA 'T,Z' OO ;
  220. option echo 0 ;
  221. SAUTER 5 LIGNES ;
  222. MESS '***********************************************************';
  223. MESS ' CIRCULAR COIL INTERNAL RADIUS' RINT 'mm *';
  224. MESS '* CROSS SECTION ' ( REXT - RINT) '*' HAUT 'mm2';
  225. MESS '* CURRENT DENSITY ' J 'A/mm2 *';
  226. MESS '***********************************************************';
  227. BS = BIOT AA CERC C1 ZP1 ZP2 RINT REXT HAUT J MU0 ;
  228. MESS '* INDUCTION ON AXIS WITHOUT IRON (BIOT SAVART )';
  229. BS0= EXTR BS 'BZ' OO ;
  230.  
  231. MESS '**************************************************************';
  232. MESS '* AMPERE mufer >> muo ALL AMPERE*TURNS IN THE GAP ';
  233. MESS '* GAP = ' E 'mm ';
  234. MESS '* J * EP * HAUT = B/ MU0 * e ';
  235. MESS '**************************************************************';
  236. BTH = MU0 * J * (REXT - RINT ) * HAUT / E ; BCAL = BM + BS0 ;
  237. MESS '**************************************************************';
  238. MESS ' BIOT ET SAVART ' BS0 ;
  239. MESS ' TOTAL B on AXIS ( z=0 ) EXPECTED ' BTH ;
  240. MESS ' COMPUTED ' BCAL ;
  241. *******************************************************************
  242. SI (NEG GRAPH 'N' ) ;
  243. TABLEG= TABLE ;TATT = TABLE ;
  244. TABLEG.1 = 'MARQ CROI' ;TATT.1= 'B_COIL' ;
  245. TABLEG.2 = 'MARQ PLUS' ;TATT.2= 'B_IRON' ;
  246. TABLEG.3 = 'MARQ CARR' ;TATT.3= 'B_TOTAL ' ;
  247. TABLEG.TITRE = TATT ;
  248. BRBIO = ( EXCO BS 'BZ') NOMC 'SCAL' ;
  249. BMRAY = EXCO (REDU BA AA) 'T,Z';
  250. EVBI = EVOL ROUG CHPO BRBIO 'SCAL' AA ;
  251. EVBM = EVOL VERT CHPO BMRAY 'SCAL' AA ;
  252. EVBT = EVOL TURQ CHPO (BRBIO + BMRAY ) 'SCAL' AA ;
  253. TITRE ' BZ(R) for Z=0 ' ;
  254. DESS (EVBI ET EVBM ET EVBT ) LEGE TABLEG TITY TESLAS ;
  255. FINSI ;
  256. RAP = ABS ((BCAL - BTH ) / BTH );
  257. SI ( RAP > .01 ) ; ERREUR 5 ; FINSI ;
  258. *-----------------------------------------------------------------
  259. * NON LINEAR COMPUTATION
  260. *-----------------------------------------------------------------
  261. TABB.SOUSTYPE = THERMIQUE ;
  262. TABB.CRITERE =1.E-4 ;
  263. TABB.NITER =1;
  264. TABB.'OME'= .99 ;
  265. * ----------2 itérations only for the test ------------------------
  266. TABB.ITERMAX=2;
  267. TABB.NIVEAU =1;
  268. *-----------------------------------------------------------------
  269. MAG_NLIN TABB ;
  270. *-----------------------------------------------------------------
  271. SOL2 = TABB.'POTENTIEL';
  272. BA= CHAN CHPO ( GRAD OBJM SOL2 ) OBJM ;
  273. BA= BA * -1. * MU0 ;
  274. BM= EXTR BA 'T,Z' OO ;
  275. *---------------
  276. ITEST = 1 ;
  277. SI ( EGA ITEST 1 ) ;
  278. MESS '***********************************************************';
  279. MESS ' VERIFICATION AU CENTRE ';
  280. MESS ' CONTRIBUTION FER ATTENDUE 1.9496 CALCULEE ' BM ;
  281. *****************************************************************
  282. BAT = 1.9496 ;
  283. *******************************************************************
  284. RAP = ABS ((BM - BAT ) / BAT );
  285. SI ( RAP > .01 ) ; ERREUR 5 ; FINSI ;
  286. *******************************************************************
  287. FIN ;
  288. FINSI ;
  289. *------------
  290. *------ CONTINUATION TILL CONVERGENCE OR UP TO 100 ITERATION ---
  291. *----------
  292. TABB.ITERMAX=100 ;
  293. *------------------------------------------------------------------
  294. MAG_NLI3 TABB ;
  295. *------------------------------------------------------------------
  296. SOL2 = TABB.'POTENTIEL';
  297. BA= CHAN CHPO ( GRAD OBJM SOL2 ) OBJM ;
  298. BA= BA * -1. * MU0 ;
  299. BM= EXTR BA 'T,Z' OO ;
  300. BCAL = BM + BS0 ;
  301. MESS '***********************************************************';
  302. MESS ' CHECK AT CENTER OF THE DEVICE ';
  303. MESS ' EXPECTED IRON CONTRIBUTION 1.9059 COMPUTED ' BM ;
  304. MESS ' TOTAL BZ COMPUTED AT CENTER ' BCAL ;
  305. MESS '***********************************************************';
  306. FIN;
  307.  
  308.  
  309.  
  310.  
  311.  
  312.  
  313.  
  314.  
  315.  
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales