Télécharger bidetract.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : bidetract.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE BIDERMAN INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION SELON LA DIRECTION Y *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. * *
  11. * *
  12. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2010) *
  13. *======================================================================*
  14. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  15. * du Club Cast3m 2009, disponible sur le site Web de Cast3m. *
  16. *======================================================================*
  17. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  18. * *
  19. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  20. * ne peut contenir que des modeles de type UMAT. On ne peut *
  21. * pas melanger les derivees objectives et les modeles de C3m. *
  22. *======================================================================*
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24. * Mettre VRAI si l'on souhaite divers traces.
  25. GRAPH = VRAI ;
  26. GRAPH = FAUX ;
  27. title = 'CHAINE' 'BIDERMAN - ' 'TRACTION UNIAXIALE Y' ;
  28. *======================================================================*
  29. * Geometrie - Maillage *
  30. *======================================================================*
  31. * Longueur (direction x) de la plaque/membrane :
  32. Lg_x = 1. ;
  33. * Largeur (direction y) de la plaque/membrane :
  34. Lg_y = 1. ;
  35. * Nombre d'elements selon les directions x et y :
  36. Nel_x = 2;
  37. Nel_y = 2 ;
  38. * 'TRI6' 'TRI3' 'QUA8'
  39. 'OPTION' 'ELEM' 'QUA4' ;
  40. *
  41. P1 = 0. 0. ;
  42. P2 = Lg_x 0. ;
  43. P3 = Lg_x Lg_y ;
  44. P4 = 0. Lg_y ;
  45. *
  46. L1 = 'DROITE' Nel_x P1 P2 ;
  47. L2 = 'DROITE' Nel_y P2 P3 ;
  48. L3 = 'DROITE' Nel_x P3 P4 ;
  49. L4 = 'DROITE' Nel_y P4 P1 ;
  50. *
  51. SU = 'DALLER' L1 L2 L3 L4 ;
  52. 'SI' GRAPH ;
  53. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  54. 'FINSI' ;
  55.  
  56. *======================================================================*
  57. * Modele - Materiau - Caracteristiques (en Pa) *
  58. *======================================================================*
  59. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'OU'
  60. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  61. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  62. 'ERREUR' 5 ;
  63. 'FINSI' ;
  64. * Calcul du Module d'Young
  65. * Ne pas oublier de definir les parametres lies a l'elasticite.
  66. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  67. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  68. *
  69. LCMAT =MOTS 'YOUN' 'NU ' 'C01' 'C10' 'C20' 'C30' ;
  70. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  71. 'NON_LINEAIRE' 'UTILISATEUR'
  72. 'NUME_LOI' 35 'C_MATERIAU' LCMAT ;
  73. *
  74. * Pour calculer le module d'Young, on utilise les
  75. * Coefficients du modele de Biderman (en MPa) : Pourquoi Pas !
  76. *
  77. C1 = 0.183 ; C2 = 0.0034 ;
  78. *
  79. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  80. * du fait de l'incompressibilite inherente au modele.
  81. * Le module de Young YOU est alors connu, car, pour ce modele, le
  82. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  83. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  84. * de la traction. En fonction du niveau de deformation atteinte en
  85. * traction, il faut augmenter cette valeur afin de pouvoir faire
  86. * converger les calculs (module tangent en fin de calculs).
  87. * Prendre des valeurs superieures n'entraine pas de modification des
  88. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  89. *
  90. XNU = 0.499 ;
  91. YOUini = 3.*(2.*(C1+C2)) ; YOU = 1000. * YOUini ;
  92. *
  93. *Parametres du modèle Bidermann : essais Treloar/Kawabata MPa
  94. C01 = 0.0233;
  95. C10 = 0.208 ;
  96. C20 = -0.0024 ;
  97. C30 = 0.0005 ;
  98. *
  99. MA = MATE MO 'YOUN' YOU 'NU ' XNU 'C01' C01 'C10' C10
  100. 'C20' C20 'C30' C30 ;
  101. *
  102. *
  103. *======================================================================*
  104. * Conditions aux limites - Traction suivant UY *
  105. *======================================================================*
  106. BL1 = 'BLOQUER' 'UY ' L1 ;
  107. BL2 = 'BLOQUER' 'UY ' L3 ;
  108. BL4 = 'BLOQUER' 'UX ' P1 ;
  109. BLTOT = BL1 'ET' BL2 'ET' BL4 ;
  110. *
  111. * Definition des instants du chargement :
  112. t_deb = 0. ; t_fin = 10. ;
  113. L_tps = 'PROG' t_deb t_fin ;
  114. * Deplacement suivant Y :
  115. L_UY = 'PROG' 0. ( 3. * Lg_y) ;
  116. FF_y = 'DEPIMP' BL2 1. ;
  117. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMY' L_UY ;
  118. *
  119. CHARTOT = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  120. *
  121. *======================================================================*
  122. * Initialisation de la table pour appel a PASAPAS *
  123. *======================================================================*
  124. TAB1 = 'TABLE' ;
  125. TAB1.'MODELE' = MO ;
  126. TAB1.'CARACTERISTIQUES' = MA ;
  127. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  128. TAB1.'CHARGEMENT' = CHARTOT ;
  129. ***** LG
  130. *TAB1 . 'DELTAITER' = 150;
  131. *TAB1.'PRECISION' = 1.E-5 ;
  132. *TAB1.'FTOL' = 1.E-5 ;
  133. *TAB1.'MTOL' = 1.E-5 ;
  134. *****
  135. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  136. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  137. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  138. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  139. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  140. *
  141. L_abs = TAB1.'TEMPS_SAUVES' ;
  142. n_abs = 'DIMENSION' L_abs ;
  143. *
  144. PASAPAS TAB1 ;
  145. *
  146. * Quelques traces de controle apres calculs
  147. 'SI' GRAPH ;
  148. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  149. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  150. 'TRACER' (Defo_0 'ET' Defo_1)
  151. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  152. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  153. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  154. 'FINSI' ;
  155. *
  156. *======================================================================*
  157. * Construction de la solution analytique *
  158. *======================================================================*
  159. * Definitions :
  160. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  161. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  162. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  163. * Dans le cas du modele de Biderman :
  164. * dW/dI1 = C10+2*C20*(i1-3)+3*C30*(i1-3)**2
  165. * dW/dI2 = C01
  166. *
  167. * Les contraintes de Cauchy sont calculables analytiquement :
  168. * - SCxx = 0.
  169. * - SCyy = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  170. * - SCxy = 0 (pas de cisaillement)
  171. * - SCzz = 0 (hypothese des contraintes planes)
  172. *
  173. L_Un = 'PROG' n_abs '*' 1. ;
  174. Lamy = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  175. *
  176. L_z1 = Lamy * Lamy ; L_z2 = L_Un / Lamy ;
  177. * LG modif hartsmith !! averifier
  178. L_tr = L_Un * 3.;
  179. I1 = L_z1 + (2. * L_z2);
  180. I2 = (2. * Lamy) + ( L_Un / L_z1 );
  181. ************************************************************************
  182. dWI1=(C10 * L_Un)+(2.*C20*(I1 - L_tr))+(3.*C30*((I1 - L_tr)**2.));
  183. dWI2=C01 ;
  184. ************************************************************************
  185. SCxx_th = 0. * L_Un ;
  186. SCyy_th =(L_z1 - L_z2) * ((2.*dWI1*L_Un) + (2.*dWI2*L_z2)) ;
  187. SCxy_th = 0. * L_Un ;
  188. *
  189. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' Lamy 'SCYY' SCyy_th ;
  190. *dess Evyy_th ;
  191. *======================================================================*
  192. * Comparaison des resultats avec la solution analytique *
  193. *======================================================================*
  194. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  195. * calculees et les solutions analytiques correspondantes.
  196. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  197. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  198. *
  199. TabD = TAB1.'DEPLACEMENTS' ;
  200. TabS = TAB1.'CONTRAINTES' ;
  201. Confini = 'FORM' ;
  202. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  203. *
  204. SCxx = 'PROG' 0. ;
  205. SCyy = 'PROG' 0. ;
  206. SCxy = 'PROG' 0. ;
  207. 'REPETER' Boucle (n_abs - 1) ;
  208. 'FORM' (TabD.&Boucle) ;
  209. VolSU = 'INTG' MO ChmUn ;
  210. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  211. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  212. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  213. 'FORM' Confini ;
  214. 'FIN' Boucle ;
  215. * LG lamb
  216. L_abs = Lamy;
  217. *
  218. 'SI' GRAPH ;
  219. tlege = 'TABLE' ;
  220. tlege. 1 = 'MARQ CROI' ;
  221. tlege.'TITRE' = 'TABLE' ;
  222. tlege.'TITRE'. 1 = 'Numerique' ;
  223. tlege.'TITRE'. 2 = 'Analytique' ;
  224. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  225. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  226. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  227. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (MPa)') ;
  228. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  229. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  230. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  231. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (MPa)') ;
  232. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  233. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  234. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  235. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (MPa)');
  236. 'FINSI' ;
  237. *
  238. * Tests de bon fonctionnement :
  239. r_z = 'MAXIMUM' ('ABS' SCyy_th) ;
  240. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / r_z ;
  241. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / r_z ;
  242. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / r_z ;
  243. *
  244. MESS ' RESULTATS : ' title ;
  245. MESS ' ------------------------------------------------- ';
  246. 'SAUTER' 1 'LIGNE' ;
  247. 'MESS' ' Tests de bon fonctionnement :' ;
  248. 'MESS' ' -------------------------------' ;
  249. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  250. 'MESS' ' Ecart relatif maximal entre la valeur moyenne '
  251. 'calculee' ;
  252. 'MESS' ' et la '
  253. 'solution analytique associee' ;
  254. 'MESS' ' Composante XX : ' r_xx ;
  255. 'MESS' ' Composante YY : ' r_yy ;
  256. 'MESS' ' Composante XY : ' r_xy ;
  257. 'SAUTER' 1 'LIGNE' ;
  258. * Ecart relatif maximal tolere
  259. Sigref = 1.E-3 ;
  260. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  261. 'MESS' ' ---------------------' ;
  262. 'MESS' ' ECHEC DU CAS-TEST !' ;
  263. 'MESS' ' ---------------------' ;
  264. 'ERREUR' 5 ;
  265. 'SINON' ;
  266. 'MESS' ' ----------------------' ;
  267. 'MESS' ' SUCCES DU CAS-TEST !' ;
  268. 'MESS' ' ----------------------' ;
  269. 'FINSI' ;
  270. 'SAUTER' 1 'LIGNE' ;
  271. 'FIN' ;
  272.  
  273.  
  274.  
  275.  
  276.  
  277.  
  278.  
  279.  
  280.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales