Télécharger beton.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : beton.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Test Beton.dgibi: Jeux de données *
  5. * --------------------------------- *
  6. * *
  7. * CAS TEST DU 93/01/19 PROVENANCE : NAH
  8. OPTION ECHO 1;
  9. GRAPH='N';
  10. SAUT PAGE ;
  11. *
  12. *-----------------------------------------------------*
  13. * *
  14. * Exemple simple de calcul mécanique élastique *
  15. * plastique beton fonctionnant avec les nouvelles *
  16. * structures MMODEL et MCHAMELEM *
  17. * *
  18. * Un cube en béton soumis à un chargement de *
  19. * traction uniaxial suivant l'axe OZ *
  20. * *
  21. * La limite en traction simple du béton LTR1 est *
  22. * égale à 4 MPa *
  23. * *
  24. *-----------------------------------------------------*
  25. * Définition des options
  26. *
  27. OPTI DIME 3 ELEM CUB8 MODEL TRIDIM ;
  28. * ajout de option epsilon lineaire pour la precision des test!
  29. OPTION epsilon lineaire;
  30. *opti impi 9 ;
  31. N = 1 ;
  32. *
  33. * Maillage d'un cube de N*N*N éléments CUB8
  34. *
  35. DENS N ;
  36. *
  37. A1 = 0 0 0 ;
  38. A2 = N 0 0 ;
  39. A3 = N N 0 ;
  40. A4 = 0 N 0 ;
  41. B1 = 0 0 N ;
  42. B2 = N 0 N ;
  43. B3 = N N N ;
  44. B4 = 0 N N ;
  45. *
  46. A1A2 = A1 D N A2 ;
  47. A2A3 = A2 D N A3 ;
  48. A3A4 = A3 D N A4 ;
  49. A4A1 = A4 D N A1 ;
  50. B1B2 = B1 D N B2 ;
  51. B2B3 = B2 D N B3 ;
  52. B3B4 = B3 D N B4 ;
  53. B4B1 = B4 D N B1 ;
  54. A1B1 = A1 D N B1 ;
  55. A2B2 = A2 D N B2 ;
  56. A3B3 = A3 D N B3 ;
  57. A4B4 = A4 D N B4 ;
  58. *
  59. A1A2A3A4 = A1A2 A2A3 A3A4 A4A1 DALLE PLAN ;
  60. B1B2B3B4 = B1B2 B2B3 B3B4 B4B1 DALLE PLAN ;
  61. *
  62. A1A2B2B1 = A1A2 A2B2 (INVE B1B2) (INVE A1B1)
  63. DALLE PLAN ;
  64. A4A3B3B4 = (INVE A3A4) A3B3 B3B4 (INVE A4B4)
  65. DALLE PLAN ;
  66. *
  67. A2A3B3B2 = A2A3 A3B3 B2B3 (INVE A2B2)
  68. DALLE PLAN ;
  69. A1A4B4B1 = (INVE A4A1) A4B4 B4B1 (INVE A1B1)
  70. DALLE PLAN ;
  71. *
  72. TOTAL = PAVE A1A2A3A4 B1B2B3B4 A1A2B2B1 A4A3B3B4
  73. A2A3B3B2 A1A4B4B1 ;
  74. *
  75. *TRAC TOTAL CACH (1000 -2000 1000) ;
  76. *
  77. *
  78. * Formulation, matériau défini à l'aide des
  79. * opérateurs MODE et MATR
  80. *
  81. MO = MODE TOTAL MECANIQUE ELASTIQUE PLASTIQUE
  82. BETON CUB8 ;
  83. MA = MATE MO YOUN 40000 NU 0.20 ALPH 1E-5
  84. LTR1 4 ;
  85. *
  86. * Conditions de blocages
  87. *
  88. ENC1 = BLOQ UX A1A4B4B1 ;
  89. ENC2 = BLOQ UY A1A2B2B1 ;
  90. ENC3 = BLOQ UZ A1A2A3A4 ;
  91. ENC = ENC1 ET ENC2 ET ENC3 ;
  92. *
  93. * Blocage pour déplacements imposés
  94. *
  95. * END1 = BLOQ UX A2A3B3B2 ;
  96. * END2 = BLOQ UY A4A3B3B4 ;
  97. END3 = BLOQ UZ B1B2B3B4 ;
  98. * END = END1 ET END2 ET END3 ;
  99. END = END3 ;
  100. EN = ENC ET END ;
  101. *
  102. *
  103. * Valeur des déplacements imposés
  104. *
  105. * FEXT1 = DEPI END1 1E-4 ;
  106. * FEXT2 = DEPI END2 1E-4 ;
  107. FEXT3 = DEPI END3 1E-4 ;
  108. * FEXT = FEXT1 ET FEXT2 ET FEXT3 ;
  109. FEXT = FEXT3 ;
  110. *
  111. * Force en fonction du temps
  112. *
  113. lt1 = prog 0. 10. ;
  114. lt2 = prog 0. 10. ;
  115. ev = evol rouge manu temps lt1 force lt2 ;
  116. chat = char DIMP fext ev ;
  117.  
  118. *
  119. * Préparation à nonlin
  120. *
  121. ltt = prog 0 1 2 ;
  122. tab1 = table;
  123. tab1.blocages_mecaniques = EN;
  124. tab1.caracteristiques = ma;
  125. tab1.modele = mo;
  126. tab1.chargement = chat;
  127. tab1.temps_calcules = ltt;
  128. pasapas tab1;
  129. *
  130. * Traitement des résultats
  131. *
  132. ptt = prog 0 ;
  133. psz = prog 0 ;
  134. ic = 0 ;
  135. repeter mabou 2 ;
  136. ic = ic + 1 ;
  137. dd = tab1 . deplacements . ic;
  138. ptt = ptt et ( prog ( extr dd uz b3 ) ) ;
  139. ss = tab1.contraintes.ic ;
  140. sz = extr ( chan chpo mo ss ) smzz b3 ;
  141. psz = psz et ( prog sz ) ;
  142. fin mabou ;
  143. *
  144. evsz = evol vert manu deplacement ptt contrainte psz ;
  145. *dess evsz ;
  146. *
  147. * Code de fonctionnement
  148. *
  149. si ( (abs ( sz - 2. )) < 1.E-6 ) ;
  150. erre 0 ;
  151. sino ;
  152. erre 5 ;
  153. finsi ;
  154. *
  155. fin ;
  156.  
  157.  
  158.  
  159.  
  160.  
  161.  
  162.  
  163.  
  164.  
  165.  
  166.  
  167.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales