Télécharger la plaquette Cast3M


fr en

Télécharger basmachQ.dgibi

Retour à la liste

Numérotation des lignes : 

  1. *****************************************************
  2. * fichier :  basmachQ.dgibi                         *
  3. ** modifie le 15/06/2014 passage EQPR -> EQEX       *
  4. *****************************************************
  5.  
  6. *******************************************************************
  7. * JEU DE DONNEES POUR TESTER LE BON FONCTIONNEMENT DES OPERATEURS *
  8. * NSKE, PRESSION, TSCAL. INJECTION D'UN MELANGE DE GAZ DANS UN    *
  9. * VOLUME FERME ET PRESSURISATION. ALGORITHME 'FAIBLES MACH' POUR  *
  10. * LES EQUATIONS NAVIER-STOKES FAIBLEMENT COMPRESSIBLES + MODELE   *
  11. * DE TURBULENCE K-E. ON TESTE SUR LA CONSERVATION DE LA MASSE     *
  12. * H. PAILLERE SEMT/TTMF AVRIL 1997                                *
  13. * FORMULATION EF ELEMENTS QUA8                                    *
  14. *******************************************************************
  15.  
  16. *************************************************************
  17. * PROCEDURE PROCINJ                                         *
  18. *************************************************************
  19.  
  20. DEBPROC PROCINJ ;
  21. ARGU RVX*'TABLE' ;
  22.  
  23. RV = RVX.'EQEX' ;
  24.  
  25. * recuperation des anciennes conditions aux limites :
  26.  
  27. cl_YH2 = 'EXCO' 'YH2' RV.'CLIM' 'YH2' ;
  28. cl_YO2 = 'EXCO' 'YO2' RV.'CLIM' 'YO2' ;
  29. cl_YH2O = 'EXCO' 'YH2O' RV.'CLIM' 'YH2O' ;
  30. cl_GNX = 'EXCO' '1GN' RV.'CLIM' '1GN' ;
  31. cl_GNY = 'EXCO' '2GN' RV.'CLIM' '2GN' ;
  32. cl_KN = 'EXCO' 'KN' RV.'CLIM' 'KN' ;
  33. cl_EN = 'EXCO' 'EN' RV.'CLIM' 'EN' ;
  34. cl_PSI = 'EXCO' 'PSIN' RV.'CLIM' 'PSIN' ;
  35.  
  36. * modification des conditions aux limites :
  37.  
  38. RHOJet = RV.INCO.'PM'/PSIJET ;
  39. UJet = GJet/RHOJet ;
  40.  
  41. KJet = 0.05*UJet*UJet ;
  42. EJet = 0.02*(UJet**3.)/DINJ ;
  43.  
  44. cl_KN = 0.D0 * cl_KN + KJet ;
  45. cl_EN = 0.D0 * cl_EN + EJet ;
  46.  
  47. * reimposition des conditions aux limites :
  48.  
  49. RV.'CLIM' = cl_YH2 + cl_YO2 + cl_YH2O + cl_GNX + cl_GNY +
  50.         cl_KN + cl_EN + cl_PSI ;
  51.  
  52. detr cl_YH2 ;
  53. detr cl_YO2 ;
  54. detr cl_YH2O ;
  55. detr cl_GNX ;
  56. detr cl_GNY ;
  57. detr cl_KN ;
  58. detr cl_EN ;
  59. detr cl_PSI ;
  60. *tc mise en commentaire du finsi ci-dessous
  61. *FINSI ;
  62.  
  63.  as2 ama1  = 'KOPS' 'MATRIK' ;
  64.  'FINPROC' as2 ama1 ;
  65.  
  66. *********************************************************************
  67. * PROCEDURE CALCUL1
  68. *********************************************************************
  69. DEBPROC CALCUL1 ;
  70. ARGU RVX*'TABLE' ;
  71. RV = RVX.'EQEX' ;
  72.  
  73. RV.PASDETPS.'DELTAT' = 0.01 ;
  74.  
  75. * filtres sur fractions massiques et calcul de la fraction massique d'azote
  76.  
  77. YH2  = RV.INCO.'YH2' ;
  78. YO2  = RV.INCO.'YO2' ;
  79. YH2O = RV.INCO.'YH2O' ;
  80. YH2  = KOPS YH2 '|<' 0. ;
  81. YO2  = KOPS YO2 '|<' 0. ;
  82. YH2O = KOPS YH2O '|<' 0. ;
  83.  
  84. RV.INCO.'YH2' =  YH2 ;
  85. RV.INCO.'YO2'  = YO2 ;
  86. RV.INCO.'YH2O' = YH2O ;
  87. RV.INCO.'YN2'  = KOPS 1.0 '-' RV.INCO.'YH2O' ;
  88. RV.INCO.'YN2'  = KOPS RV.INCO.'YN2' '-' RV.INCO.'YH2' ;
  89. RV.INCO.'YN2'  = KOPS RV.INCO.'YN2' '-' RV.INCO.'YO2' ;
  90.  
  91. * calcul de rho à partir de la loi d'état des gaz parfaits
  92.  
  93. RV.INCO.'RHO' = KOPS (RV.INCO.'PM') '/' (RV.INCO.'PSIN') ;
  94. RV.INCO.'RHOC' = NOEL $MT RV.INCO.'RHO' ;
  95. RV.INCO.'RHOC' = KCHT $MT 'SCAL' 'CENTRE' (RV.INCO.'RHOC') ;
  96. RHOM = (SOMT (KOPS RV.INCO.'RHOC' '*' VOL))/VOLT ;
  97. RV.INCO.'RHOM' = RHOM ;
  98.  
  99. * calcul du terme (rho-rhom)*g de la QDM
  100.  
  101. DRHO = KOPS (RV.INCO.'RHOC') '-' (RV.INCO.'RHOM') ;
  102. rogx = KCHT $MT SCAL CENTRE 0. ;
  103. rogy = KCHT $MT SCAL CENTRE (-9.81*DRHO) ;
  104. rogx = nomc 'UX' rogx 'NATU' 'DISCRET' ;
  105. rogy = nomc 'UY' rogy 'NATU' 'DISCRET' ;
  106. RV.INCO.'ROG' = KCHT $MT VECT CENTRE (rogx ET rogy) ;
  107.  
  108. * calcul la vitesse à partir de la qdm
  109.  
  110. GN = RV.INCO.'GN' ;
  111. gnx= kcht $MT scal sommet (exco 'UX' gn) ;
  112. gny= kcht $MT scal sommet (exco 'UY' gn) ;
  113. unx = kops gnx '/' RV.INCO.'RHO' ;
  114. uny = kops gny '/' RV.INCO.'RHO' ;
  115. unx = nomc 'UX' unx 'NATU' 'DISCRET' ;
  116. uny = nomc 'UY' uny 'NATU' 'DISCRET' ;
  117. un = kcht $MT vect sommet (unx et uny) ;
  118. RV.INCO.'UN' = un ;
  119.  
  120. * calcul de nut à partir de mut et de rho
  121.  
  122. RV.INCO.'NUT' = KOPS (RV.INCO.'MUT') '/' (RV.INCO.'RHOC') ;
  123.  
  124.  as2 ama1  = 'KOPS' 'MATRIK' ;
  125.  'FINPROC' as2 ama1 ;
  126.  
  127. *********************************************************************
  128. * PROCEDURE CALCUL2
  129. *********************************************************************
  130. DEBPROC CALCUL2 ;
  131. ARGU RVX*'TABLE' ;
  132.  
  133. RV = RVX.'EQEX' ;
  134.  
  135. * on récupère le pas de temps
  136.  
  137. Dt = RV.PASDETPS.'DELTAT' ;
  138. Dt = Dt * RV.'ALFA' ;
  139.  
  140. * calcul l'intégrale se trouvant dans le terme Dp/Dt.
  141.  
  142. ZT = KOPS (RV.INCO.'PSIN') '-' (RV.INCO.'PSI1') ;
  143. ZT = KOPS ZT '/' Dt ;
  144. ZT = KOPS ZT '/' (RV.INCO.'PSIN') ;
  145.  
  146. ZZ = KOPS ZT '*' RV.INCO.'RHO' ;
  147. ZZ = NOEL $MT ZZ ;
  148. ZZ = KCHT $MT 'SCAL' 'CENTRE' ZZ ;
  149. ZZT = SOMT ( KOPS ZZ '*' VOL ) ;
  150.  
  151. RV.INCO.'PSI1' = KCHT $MT 'SCAL' 'SOMMET' (RV.INCO.'PSIN') ;
  152.  
  153. * calcul de dPdt
  154.  
  155. q0 = 'DBIT' RV.INCO.'GN' $INJ ;
  156. RV.INCO.'DEBIT' = q0 ;
  157. dPdt = ZZT + q0 ;
  158. dPdt = dPdt*(RV.INCO.'PM')/VOLT/RV.INCO.'RHOM' ;
  159.  
  160. * terme source de l'équation d'énergie
  161.  
  162. zuzu = (gamma-1.)/gamma ;
  163.  
  164. QC = NOEL $MT RV.INCO.'Q' ;
  165. QC = KCHT $MT 'SCAL' 'CENTRE' QC ;
  166. TOTO = KOPS QC '+' dPdt ;
  167. TOTO = KOPS TOTO '/' RV.INCO.'RHOC' ;
  168. TOTO = KOPS TOTO '*' zuzu ;
  169. RV.INCO.'S' = KCHT $MT 'SCAL' 'CENTRE' TOTO ;
  170.  
  171. * terme source équation de Poisson
  172.  
  173. Z1 = dPdt/RV.INCO.'PM' ;
  174. ZP = KOPS RV.INCO.'RHOC' '*' Z1 ;
  175. ZS = KOPS ZP '-' ZZ ;
  176. ZZS = KOPS ZS '*' VOL ;
  177. ZZS = ZZS * (-1.0) ;
  178. RV.INCO.'ZS' = KCHT $MT 'SCAL' 'CENTRE' ZZS ;
  179.  
  180. * calcul de l'évolution de la pression 
  181.  
  182. RV.INCO.'PM' = RV.INCO.'PM' + (dPdt*dt) ;
  183.  
  184. * affichage informations toutes les 5 iterations
  185.  
  186. DD = RV.PASDETPS.'NUPASDT' ;
  187. NN = DD/5 ;
  188. LO = (DD-(5*NN)) EGA 0 ;
  189. SI ( LO ) ;
  190. MESSAGE '==========================================================' ;
  191. MESSAGE 'TEMPS = ' RV.PASDETPS.'TPS' ' PRESSION = ' RV.INCO.'PM' ;
  192. MESSAGE 'MASSE INI =' MASINI ' MASSE TOTALE = ' (RV.INCO.'RHOM'*VOLT) ;
  193. PT = PROG RV.'PASDETPS'.'TPS' ;
  194. PP = PROG RV.INCO.'PM' ;
  195. PMTO = PROG (RV.INCO.'RHOM'*VOLT) ;
  196. RV.INCO.'TEMPS' = RV.INCO.'TEMPS' ET PT ;
  197. RV.INCO.'PRESS' = RV.INCO.'PRESS' ET PP ;
  198. RV.INCO.'MTOTA' = RV.INCO.'MTOTA' ET PMTO ;
  199. MESSAGE '==========================================================' ;
  200. FINSI ;
  201.  
  202.  as2 ama1  = 'KOPS' 'MATRIK' ;
  203.  'FINPROC' as2 ama1 ;
  204.  
  205. ***************************************************************
  206. * JEU DE DONNEES NURETH-8 : CALCUL DE DISTRIBUTION/COMBUSTION *
  207. * ALGORITHME 'COMPRESSIBLE FAIBLE MACH' SEMI-IMPLICITE        *
  208. *                    === DISTRIBUTION ===                     *
  209. ***************************************************************
  210.  
  212. opti elem qua8 ;
  213. opti isov suli ;
  214.  
  215. DISCR  = 'MACRO'  ;
  216. KPRES  = 'CENTRE' ;
  217. BETAP  = 1.       ;
  218.  
  219.  
  220. *========================================================*
  221. *               GENERATION DU MAILLAGE                   *
  222. *========================================================*
  223.  
  224. L_A = 4.0 ;
  225. H_A = 4.0 ;
  226. L_B = 4.0 ;
  227. H_B = H_A ;
  228.  
  229. HINJ = 1.0 ;
  230. DINJ = 1.0 ;
  231.  
  232. HAB = 1. ;
  233. DAB = 2.0 ;
  234. LAB = 1. ;
  235.  
  236. DX = 1. ;
  237. DY = 1. ;
  238.  
  239. epsi = (DX/10.) ;
  240.  
  241. ******************
  242. * COMPARTIMENT A *
  243. ******************
  244.  
  245. A7 = 0. 0. ;
  246. A8 = HINJ 0. ;
  247. A1 = (HINJ+DINJ) 0. ;
  248. A2 = L_A 0.0 ;
  249. A3 = L_A HAB ;
  250. A4 = L_A (HAB+DAB) ;
  251. A5 = L_A H_A ;
  252. A6 = 0. H_A ;
  253.  
  254. N78 = 'ENTIER' (HINJ/DX) ;
  255. N81 = 'ENTIER' (DINJ/DX) ;
  256. N12 = 'ENTIER' ((L_A-HINJ-DINJ)/DX) ;
  257. N23 = 'ENTIER' (HAB/DY) ;
  258. N34 = 'ENTIER' (DAB/DY) ;
  259. N45 = 'ENTIER' ((H_A-HAB-DAB)/DY) ;
  260. N56 = N78 + N81 + N12 ;
  261. N67 = N23 + N34 + N45 ;
  262.  
  263. A7A8 = A7 'DROI' N78 A8 ;
  264. A8A1 = A8 'DROI' N81 A1 ;
  265. A1A2 = A1 'DROI' N12 A2 ;
  266. A2A3 = A2 'DROI' N23 A3 ;
  267. A3A4 = A3 'DROI' N34 A4 ;
  268. A4A5 = A4 'DROI' N45 A5 ;
  269. A5A6 = A5 'DROI' N56 A6 ;
  270. A6A7 = A6 'DROI' N67 A7 ;
  271.  
  272. BAS_A = A7A8 ET A8A1 ET A1A2 ;
  273. DRO_A = A2A3 ET A3A4 ET A4A5 ;
  274. HAU_A = A5A6 ;
  275. GAU_A = A6A7 ;
  276.  
  277. COMP_A = 'DALLER' BAS_A DRO_A HAU_A GAU_A 'PLAN' ;
  278.  
  279. ******************
  280. * COMPARTIMENT B *
  281. ******************
  282.  
  283. B1 = (L_A+LAB) 0. ;
  284. B2 = (L_A+LAB+L_B) 0. ;
  285. B3 = (L_A+LAB+L_B) H_B ;
  286. B6 = (L_A+LAB) H_B ;
  287. B7 = (L_A+LAB) (HAB+DAB) ;
  288. B8 = (L_A+LAB) HAB ;
  289.  
  290. N23 = 'ENTIER' (H_B/DY) ;
  291. N36 = 'ENTIER' (L_B/DX) ;
  292. N67 = 'ENTIER' ((H_B-HAB-DAB)/DY) ;
  293. N78 = 'ENTIER' (DAB/DY) ;
  294. N81 = N23 - N67 - N78 ;
  295. N12 = N36 ;
  296.  
  297. B1B2 = B1 'DROI' N12 B2 ;
  298. B2B3 = B2 'DROI' N23 B3 ;
  299. B3B6 = B3 'DROI' N36 B6 ;
  300. B6B7 = B6 'DROI' N67 B7 ;
  301. B7B8 = B7 'DROI' N78 B8 ;
  302. B8B1 = B8 'DROI' N81 B1 ;
  303.  
  304. BAS_B = B1B2 ;
  305. DRO_B = B2B3 ;
  306. HAU_B = B3B6 ;
  307. GAU_B = B6B7 ET B7B8 ET B8B1 ;
  308.  
  309. COMP_B = 'DALLER' BAS_B DRO_B HAU_B GAU_B 'PLAN' ;
  310.  
  311. ***************
  312. * JONCTION AB *
  313. ***************
  314.  
  315. NX = 'ENTIER' (LAB/DX) ;
  316. NY = 'ENTIER' (DAB/DY) ;
  317.  
  318. BAS_AB = A3 'DROI' NX B8 ;
  319. DRO_AB = B8 'DROI' NY B7 ;
  320. HAU_AB = B7 'DROI' NX A4 ;
  321. GAU_AB = A4 'DROI' NY A3 ;
  322.  
  323. J_AB = 'DALLER' BAS_AB DRO_AB HAU_AB GAU_AB 'PLAN' ;
  324.  
  325. ********************
  326. * MAILLAGE COMPLET *
  327. ********************
  328.  
  329. COMP_A = COMP_A 'COUL' 'ROUG' ;
  330. COMP_B = COMP_B 'COUL' 'VERT' ;
  331.  
  332. J_AB = J_AB 'COUL' 'BLAN' ;
  333.  
  334. MT = COMP_A ET COMP_B ET J_AB ;
  335. 'ELIM' epsi MT ;
  336.  
  337. 'ORIE' MT ;
  338. CNT = 'CONT' MT ;
  339.  
  340. ******************
  341. * TABLES DOMAINE *
  342. ******************
  343.  
  344. Mmt     = 'CHAN' mt     'QUAF' ;
  345. Minj    = 'CHAN' BAS_A  'QUAF' ;
  346. MCOMP_A = 'CHAN' comp_A 'QUAF' ;
  347. MCOMP_B = 'CHAN' comp_B 'QUAF' ;
  348. MJ_AB   = 'CHAN' J_AB   'QUAF' ;
  349.  
  350. 'ELIM' (Mmt 'ET' Minj 'ET' MCOMP_A 'ET' MCOMP_B 'ET' MJ_AB) epsi;
  351.  
  352. $MT     = 'MODE' MMT     'NAVIER_STOKES' DISCR  ;
  353. $INJ    = 'MODE' Minj    'NAVIER_STOKES' DISCR  ;
  354. $COMP_A = 'MODE' MCOMP_A 'NAVIER_STOKES' DISCR  ;
  355. $COMP_B = 'MODE' MCOMP_B 'NAVIER_STOKES' DISCR  ;
  356. $J_AB   = 'MODE' MJ_AB   'NAVIER_STOKES' DISCR  ;
  357.  
  358. MT      = 'DOMA' $MT     'MAILLAGE' ;
  359. inj     = 'DOMA' $INJ    'MAILLAGE' ;
  360. comp_A  = 'DOMA' $COMP_A 'MAILLAGE' ;
  361. comp_B  = 'DOMA' $COMP_B 'MAILLAGE' ;
  362. j_AB    = 'DOMA' $J_AB   'MAILLAGE' ;
  363.  
  364. VOL = 'DOMA' $MT 'VOLUME' ;
  365. VOLT = 'SOMT' VOL ;
  366. VOL = KCHT $MT 'SCAL' 'CENTRE' VOL ;
  367.  
  368. 'MESSAGE' 'VOLUME TOTAL = ' VOLT ;
  369.  
  370. ******************************************
  371. * FRONTIERES POUR CONDITIONS AUX LIMITES *
  372. ******************************************
  373.  
  374. MUR_HOR = A7A8 ET A1A2 ET BAS_AB ET B1B2 ET B3B6 
  375.           ET HAU_AB ET A5A6 ;
  376. MUR_VER = A2A3 ET B8B1 ET B2B3 ET B6B7 ET A4A5 ET A6A7 ;
  377. BRECHE = A8A1 ;
  378.  
  379. MUR_HOR = MUR_HOR 'COUL' 'VERT' ;
  380. MUR_VER = MUR_VER 'COUL' 'ROUG' ;
  381. BRECHE = BRECHE 'COUL' 'JAUNE' ;
  382.  
  383. *========================================================*
  384. *               DONNEES DU CALCUL DE DISTRIBUTION        *
  385. *========================================================*
  386.  
  387. *--------------------------------------
  388. * masses molaires et constantes des gaz
  389. *--------------------------------------
  390. MH2 = 2.0E-3 ;
  391. MO2 = 32.0E-3 ;
  392. MN2 = 28.0E-3 ;
  393. MH2O = 18.0E-3 ;
  394.  
  395. Rg = 8.313 ;
  396.  
  397. RH2 = Rg/MH2 ;
  398. RO2 = Rg/MO2 ;
  399. RN2 = Rg/MN2 ;
  400. RH2O = Rg/MH2O ;
  401.  
  402. *----------------------------------------------------------
  403. * fractions molaires des differents constituants du melange
  404. *----------------------------------------------------------
  405. XH2 = 0.0 ;
  406. XH2O = 0.1 ;
  407. XO2 = 0.21*(1.0 - XH2 - XH2O) ;
  408. XN2 = 1.0 - XH2 - XH2O - XO2 ;
  409.  
  410. *---------------------------------------------
  411. * masse molaire du melange et constante du gaz
  412. *---------------------------------------------
  413. M = (XH2*MH2) + (XO2*MO2) + (XN2*MN2) + (XH2O*MH2O) ;
  414. R = Rg/M ;
  415.  
  416. *------------------------------------------------------------
  417. * pression, temperature et densite du melange (loi d'etat GP)
  418. *------------------------------------------------------------
  419. P = 1.0E5 ;
  420. T = 400.0 ;
  421. PSI = R*T ;
  422. RHO = P/PSI ;
  423.  
  424. *------------------------
  425. * Caractéristiques du jet
  426. *------------------------
  427.  
  428. XH2Jet = 0.1 ;
  429. XH2OJet = 0.3 ;
  430. XO2Jet = 0.21*( 1.0 - XH2Jet - XH2OJet ) ;
  431. XN2Jet = 1.0 - XH2Jet - XH2OJet - XO2Jet ;
  432. MJet = (XH2Jet*MH2) + (XH2OJet*MH2O) + (XO2Jet*MO2) +
  433.        (XN2Jet*MN2) ;
  434. RJet = Rg/MJet ;
  435. TJet = 650.0 ;
  436. PSIJet = Rjet*Tjet ;
  437. RhoJet = P/PSIJet ;
  438. GJet = 10.*DINJ/(DINJ+(DX*0.5)) ;
  439. UJet = GJet/RhoJet ;
  440. KJet = 0.05*UJet*UJet ;
  441. EJet = 0.02*(UJet**3.)/DINJ ;
  442.  
  443. *------------------------------------------------
  444. * fractions massiques des differents constituants
  445. *------------------------------------------------
  446. YH2 = XH2*MH2/M ;
  447. YO2 = XO2*MO2/M ;
  448. YN2 = XN2*MN2/M ;
  449. YH2O = XH2O*MH2O/M ;
  450. YH2Jet = XH2Jet*MH2/MJet ;
  451. YH2OJet =XH2OJet*MH2O/MJet ;
  452. YO2Jet = XO2Jet*MO2/MJet ;
  453. YN2Jet =XN2Jet*MN2/MJet ;
  454.  
  455. *------------------------------------------------------------------
  456. * Cp des différents constituants et du mélange (supposés constants)
  457. *------------------------------------------------------------------
  458. CPH2 = 13514.04 + (1.684537*T) ;
  459. CPH2O = 1715.632 + (0.552805*T) ;
  460. CPN2 = 1006.15 + (0.1387166*T) ;
  461. CPO2 = 907.580 + (0.1420522*T) ;
  462.  
  463. CP = (YH2*CPH2) + (YH2O*CPH2O) + (YO2*CPO2) + (YN2*CPN2) ;
  464.  
  465. gamma = CP/(CP-R) ;
  466.  
  467. *----------------------------------------------------
  468. * calcul d'une vitesse de référence (pour les tracés)
  469. *----------------------------------------------------
  470.  
  471. uref = gamma*R*T ;
  472. uref = uref**0.5 ;
  473. uref = 0.01*uref ;
  474. ampl = 1./uref ;
  475.  
  476. *------------------------------------------------------------------------
  477. * Prandtl, Schmidt, viscosité (loi de Sutherland), conductivité thermique
  478. * coefficients de diffusion moléculaire  
  479. *------------------------------------------------------------------------
  480. Pr = 0.7 ;
  481. Prt = 1.0 ;
  482. Sct = 1.0 ;
  483.  
  484. Mu = 1.716E-5*((T/273.0)**1.5)*(273.0+110.5)/(T+110.5) ;
  485. Nu = Mu/RHO ;
  486. Lambda = Mu*CP/Pr ;
  487.  
  488. alpha = Lambda/RHO/CP ;
  489.  
  490. DH2O = 2.55E-5 ;
  491. DH2 = 7.12E-5 ;
  492. DO2 = 2.06E-5 ;
  493.  
  494. *==============================================================
  495. * TABLE EQEX CONTENANT LES EQUATIONS A RESOUDRE :           
  496. *  0) FILTRE K-E
  497. *  1) QUANTITE DE MOUVEMENT     --- OPERATEUR NSKE
  498. *  2) EQUATION DE L'ENERGIE     --- OPERATEUR TSCAL
  499. *  3) TRANSPORT DES ESPECES     --- OPERATEUR TSCAL
  500. * AINSI QUE 2 PROCEDURES (CALCUL1 ET CALCUL2) POUR L'ALGORITHME
  501. * 'FAIBLE MACH'
  502. *  4) CONDITIONS AUX LIMITES
  503. *==============================================================
  504.  
  505. RV = 'EQEX' $MT 'ITMA' 30 'ALFA' 0.9
  506.  'ZONE' $MT 'OPER'      'PROCINJ'  
  507.  'ZONE' $MT 'OPER'      'CALCUL1'
  508.  'ZONE' $MT 'OPER'      'FILTREKE' UJet DINJ  'INCO' 'KN' 'EN'
  509.  'OPTI' 'CONS'
  510.  'ZONE' $MT 'OPER'      'NSKE' 'RHOC' MU 'MUT' 'UN' 'ROG'
  511.                                 'INCO' 'GN' 'KN' 'EN'
  512.  'OPTI' 'NOCONS'
  513.  'ZONE' $MT 'OPER'      'TSCAL' alpha 'UN' 'S' 'NUT' Prt 
  514.                                 'INCO' 'PSIN'  ;
  515.  
  516. RV = 'EQEX' RV
  517.  'ZONE' $MT 'OPER'      'TSCAL' DH2 'UN' 0.0 'NUT' SCT 
  518.                                 'INCO' 'YH2'
  519.  'ZONE' $MT 'OPER'      'TSCAL' DO2 'UN' 0.0 'NUT' SCT 
  520.                                 'INCO' 'YO2'
  521.  'ZONE' $MT 'OPER'      'TSCAL' DH2O 'UN' 0.0 'NUT' SCT 
  522.                                 'INCO' 'YH2O' 
  523.  'ZONE' $MT 'OPER'      'CALCUL2' ;
  524.  
  525. RV = 'EQEX' RV
  526.  'CLIM' 'GN' 'UIMP' MUR_VER 0.0 
  527.         'GN' 'VIMP' MUR_HOR 0.0
  528.         'GN' 'UIMP' BRECHE  0.0 
  529.         'GN' 'VIMP' BRECHE  GJet 
  530.         'KN' 'TIMP' BRECHE  KJet
  531.         'EN' 'TIMP' BRECHE  EJet ;
  532. RV = 'EQEX' RV
  533.  'CLIM' 'PSIN' 'TIMP' BRECHE  PSIJet 
  534.         'YH2' 'TIMP' BRECHE YH2Jet
  535.         'YO2' 'TIMP' BRECHE YO2Jet 
  536.         'YH2O' 'TIMP' BRECHE YH2OJet ;
  537.  
  538.   RV=EQEX RV OPTI EFM1 'CENTREE'
  539.   'ZONE' $MT      'OPER' 'DFDT' 1. 'GN' 'DELTAT' 'INCO' 'GN'
  540.   'ZONE' $MT      'OPER' 'DFDT' 1. 'KN' 'DELTAT' 'INCO' 'KN'
  541.   'ZONE' $MT      'OPER' 'DFDT' 1. 'EN' 'DELTAT' 'INCO' 'EN'
  542.   'ZONE' $MT      'OPER' 'DFDT' 1. 'PSIN' 'DELTAT' 'INCO' 'PSIN'
  543.   'ZONE' $MT      'OPER' 'DFDT' 1. 'YH2' 'DELTAT' 'INCO' 'YH2'
  544.   'ZONE' $MT      'OPER' 'DFDT' 1. 'YO2' 'DELTAT' 'INCO' 'YO2'
  545.   'ZONE' $MT      'OPER' 'DFDT' 1. 'YH2O' 'DELTAT' 'INCO' 'YH2O' ;
  546.  
  547. *===========================================================
  548. * TABLE EQEX POUR L'EQUATION DE POISSON (SOLVEUR ELLIPTIQUE)
  549. *===========================================================
  550.  
  551. PPI = 'POIN' ('DOMA' $mt KPRES) 'PROC' ('BARY' mt) ;
  552. MPI = 'MANU' 'POI1' PPI ;
  553. RVP = EQEX 'OPTI' 'EF' KPRES
  554.  'ZONE' $MT    OPER  KBBT  -1. betap  INCO 'GN' 'PRES'
  555.            'OPTI' 'EF' 'CENTREE' 'INCOD' KPRES
  556.  'ZONE' $MT    OPER  FIMP  'ZS'   'INCO' 'PRES'
  557.  'CLIM' 'PRES' 'TIMP' MPI 0.
  558. ;
  559.  
  560.     rvp.'METHINV'.TYPINV=1 ;
  561.     rvp.'METHINV'.IMPINV=0 ;
  562.     rvp.'METHINV'.NITMAX=300;
  563.     rvp.'METHINV'.PRECOND=3 ;
  564.     rvp.'METHINV'.RESID  =1.e-8 ;
  565.     rvp.'METHINV' . 'FCPRECT'=100 ;
  566.     rvp.'METHINV' . 'FCPRECI'=100 ;
  567.  
  568.   RV.'PROJ'     =RVP ;
  569.  
  570. *==========================================================
  571. * TABLE INCO CONTENANT LES INCONNUES ET DONNEES DU PROBLEME 
  572. *==========================================================
  573.  
  574.   RV.'NOMVI' = 'GN' ;
  575.  
  576.   RV.'INCO' = 'TABLE' 'INCO' ;
  577.   RVP.'INCO' = RV.'INCO' ;
  578.  
  579. * vitesse et quantité de mouvement
  580.   RV.INCO.'UN' = kcht $MT VECT SOMMET (0. 0.);
  581.   RV.INCO.'GN' = kcht $MT VECT SOMMET (0. 0.);
  582. * pression
  583.   RV.INCO.'PRES' = kcht $MT SCAL KPRES   0.   ;
  584. * température
  585.   RV.INCO.'PSIN' = kcht $MT SCAL SOMMET   PSI ;
  586.   RV.INCO.'PSI1' = kcht $MT SCAL SOMMET   PSI ;
  587. * variables modèle de turbulence
  588.   RV.INCO.'EN' = kcht $MT SCAL SOMMET   1.E-5 ;
  589.   RV.INCO.'KN' = kcht $MT SCAL SOMMET   1.E-5 ;
  590.   RV.INCO.'MUT' = kcht $MT SCAL CENTRE  Mu ;
  591.   RV.INCO.'NUT' = kcht $MT SCAL CENTRE  Nu ;
  592. * masse volumique
  593.   RV.INCO.'RHO' = kcht $MT SCAL SOMMET  RHO    ;
  594.   RV.INCO.'RHOC'= kcht $MT SCAL CENTRE  RHO    ;
  595.   RV.INCO.'RHOM'= RHO ;
  596. * fractions massiques
  597.   RV.INCO.'YH2' = kcht $MT SCAL SOMMET  YH2   ;
  598.   RV.INCO.'YO2' = kcht $MT SCAL SOMMET  YO2   ;
  599.   RV.INCO.'YN2' = kcht $MT SCAL SOMMET  YN2   ;
  600.   RV.INCO.'YH2O'= kcht $MT SCAL SOMMET  YH2O   ;
  601. * termes sources (Poisson/énergie/QDM)
  602.   RV.INCO.'S'=kcht $MT SCAL CENTRE   0.    ;
  603.   RV.INCO.'Q'=kcht $MT SCAL SOMMET   0.    ;
  604.   RV.INCO.'ROG'=kcht $MT VECT CENTRE   (0. 0.)     ;
  605.   RV.INCO.'ZS' = KCHT $MT SCAL CENTRE 0.0 ;
  606. * pression
  607.   RV.INCO.'PM' = P ;
  608. * progressions contenant certaines données
  609.   RV.INCO.'TEMPS' = PROG 0. ;
  610.   RV.INCO.'PRESS' = PROG P ;
  611.   RV.INCO.'MTOTA' = PROG (RHO*VOLT) ;
  612. * debit de masse
  613.   RV.INCO.'DEBIT' = 0. ;
  614.  
  615. MASINI = KOPS RV.INCO.'RHOC' '*' VOL ;
  616. MASINI = SOMT MASINI ;
  617.  
  618. exec rv ;
  619.  
  620. MTHEO = MASINI + (RV.INCO.'DEBIT' * RV.PASDETPS.'TPS') ;
  621. MESSAGE MTHEO ;
  622. SI ( (MAXI RV.INCO.'MTOTA') <  (0.95*MTHEO) ) ;
  623.         ERREUR 5 ;
  624. FINSI ; 
  625.  
  626.  FIN ;
  627.  
  628.  
  629.  
  630.  
  631.  
  632.  
  633.  
  634.  
  635.  
  636.  
  637.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales