Télécharger back_proj_7.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : back_proj_7.dgibi
  2. **************** CAS TEST : back_proj_7.dgibi ********************
  3. *
  4. * Ce test permet de vérifier le bon fonctionnement des opérateurs
  5. * utilisés pour la résolution des équations de NAVIER_STOKES en EF
  6. * par un algorithme de projection.
  7. *
  8. * Le cas étudié est celui d'un écoulement laminaire dans un canal
  9. * en présence d'une marche descendante. On teste la position du
  10. * point de réattachement par rapport au pied de la marche.
  11. *
  12. * Référence : K. Morgan, J. Périaux anf F. Thomasset, editors,
  13. * Analysis of laminar flow over a backward facing step, Vol9 of
  14. * Notes on numerical Fluid Mechanics, Vieweg, 1984.
  15. *
  16. *-------------------------------------------------------------------
  17. * Auteur : F.Dabbene (LTMF) 03/03
  18. *-------------------------------------------------------------------
  19. *
  20. 'SAUT' 'PAGE' ;
  21. 'OPTION' 'DIME' 2 'ELEM' 'QUA8' 'ECHO' 0 ;
  22. *
  23. *- Pilotage du calcul
  24. *
  25. * DISCR : Element en vitesse (LINE/MACRO/QUAF)
  26. * KPRES : Element en pression (CENTRE/CENTREP2/MSOMMET)
  27. * KSUPG : Méthode de décentrement (CENTREE/SUPG/SUPGDC)
  28. * KMASS : Matrice masse lumpée ou non (EFM1/EF)
  29. *
  30. * DT : Valeur du pas de temps
  31. * (En cas de problème de convergence, augmenter DT et/ou
  32. * prendre KMASS en EFM1)
  33. * EPS0 : Test d'arret
  34. * RAF : Taille de maille définie par 0.1*raf
  35. *
  36. * FREQ0 : Fréquence d'évaluation du résidu
  37. * GRAPH : Booleen pour les tracés
  38. * COMPLET : Booleen volume de calcul
  39. *
  40. DISCR = 'QUAF' ;
  41. KPRES = 'MSOMMET' ;
  42. KSUPG = 'SUPG' ;
  43. KMASS = 'EFM1' ;
  44. GRAPH = FAUX ;
  45. COMPLET = FAUX ;
  46. 'SI' COMPLET ;
  47. DT = 3. ;
  48. FREQ0 = 20 ;
  49. EPS0 = 1.D-5 ;
  50. RAF = 1. ;
  51. 'SINO' ;
  52. DT = 3. ;
  53. FREQ0 = 20 ;
  54. EPS0 = 1.D-2 ;
  55. RAF = 3. ;
  56. 'FINSI' ;
  57. *
  58. *---------------------------------------------------------------------------
  59. * Recherche du point de réattachement (point où dUx/dy=0)
  60. *---------------------------------------------------------------------------
  61. * 1/ Après avoir calculé le gradient de Ux, on ne conserve que les valeurs
  62. * sur la frontière qui nous intéresse sous la forme d'une évolution.
  63. * 2/ On borne l'évolution au voisinage du point de réattachement afin
  64. * d'avoir une variation monotone sur l'intervale de dUx/dy.
  65. * 3/ On recherche par interpolation le zero de la fonction (dUx/dy(s),s)
  66. * La valeur obtenu est l'abscisse curviligne cherchée
  67. *
  68. * Remarques :
  69. * (i) 1/ permettrait de calculer le coeff de frottement à la paroi :
  70. * il suffirait de diviser EV1 par le bon coefficient (Re/2 ici)
  71. * (ii) Il est impératif que dUx/dy soit monotone sur l'intervale 2/ afin
  72. * qu'il y ait unicité du zero (principe des valeurs intermédiaires)
  73. *---------------------------------------------------------------------------
  74. *
  75. 'DEBPROC' attac ;
  76. * 1/
  77. Ux = 'KCHT' $DOMTOT 'SCAL' 'SOMMET' 'COMP' 'UX' 0. RV.'INCO'.'UN' ;
  78. DUxDY = 'EXCO' 'UY' ('KOPS' Ux 'GRADS' $DOMTOT) 'SCAL' ;
  79. EV1 = 'EVOL' 'CHPO' DUxDY BOTTOM ;
  80. * 2/
  81. EV2 = 'EXTR' EV1 'APRE' 5. ;
  82. EV3 = 'EXTR' EV2 'AVAN' 10. ;
  83. * 3/
  84. LX1 = 'EXTR' EV3 'ABSC' ;
  85. LY1 = 'EXTR' EV3 'ORDO' ;
  86. LY1 = 'ORDO' LY1 ;
  87. Ymin = 'MINI' LY1 ;
  88. Ymax = 'MAXI' LY1 ;
  89. Delta = Ymin * Ymax ;
  90. 'SI' (Delta < 0.) ;
  91. Y0 = 0. ;
  92. 'SINON' ;
  93. 'MESS' 'Fonction 'NON' monotone' ;
  94. Y0 = Ymin ;
  95. * 'ERRE''Fonction 'NON' monotone' ;
  96. 'FINSI' ;
  97. V1 = 'IPOL' Y0 LY1 LX1 ;
  98. 'FINP' V1 ;
  99. *
  100. *==================================================================
  101. * Calcul du résidu basé sur la composante horizontale de la vitesse
  102. * et arrêt suivant un critère transmis
  103. *==================================================================
  104. * E/ : RVX : TABLE : TABLE des données créées par EQEX
  105. * ARG1 : Fréquence d'impression
  106. * ARG2 : Critère d'arrêt
  107. * ARG3 : Booleen de tracé
  108. * /S : MAT1 : MATRIK : Objet vide
  109. * /S : CHP1 : CHPO : Objet vide
  110. *------------------------------------------------------------------
  111. * MAT1 et CHP1 permettent d'assurer la compatibilité des opérateurs
  112. * de discrétisation avec les procédures personnelles
  113. *------------------------------------------------------------------
  114. 'DEBPROC' residu rvx*table ;
  115. RV = RVX . 'EQEX' ;
  116. FREQ = RVX . 'ARG1' ;
  117. EPS0 = RVX . 'ARG2' ;
  118. GRAPH = RVX . 'ARG3' ;
  119. NITER = RV . 'NITER' ;
  120. DD = RV . 'PASDETPS' . 'NUPASDT' ;
  121. NN = DD '/' FREQ ;
  122. L0 = 'EGA' (DD '-' (FREQ*NN)) 0 ;
  123. 'SI' L0 ;
  124. RANG0 = RV . 'PASDETPS' . 'NUPASDT' ;
  125. TIME0 = RV . 'PASDETPS' . 'TPS' ;
  126. UN0 = 'EXCO' 'UX' RV . 'INCO' . 'UN' 'SCAL' ;
  127. UNM0 = 'EXCO' 'UX' RV . 'INCO' . 'UN2' 'SCAL' ;
  128. ERR0 = ('MAXIMUM' ('ABS' (UN0 '-' UNM0))) '+' 1.D-20 ;
  129. ERR10 = ('LOG' ERR0 ) '/' ('LOG' 10.) ;
  130. 'MESSAGE' 'Résidu en vitesse suivant X au pas'
  131. RANG0 '(t=' TIME0 ') :' ERR0 ':' ERR10 ;
  132. RV . 'INCO' . 'IT' = RV . 'INCO' . 'IT' 'ET' ('PROG' RANG0) ;
  133. RV . 'INCO' . 'TI' = RV . 'INCO' . 'TI' 'ET' ('PROG' TIME0) ;
  134. RV . 'INCO' . 'ER' = RV . 'INCO' . 'ER' 'ET' ('PROG' ERR10) ;
  135. V1 = attac ;
  136. RV . 'INCO' . 'POSI' = RV . 'INCO' . 'POSI' 'ET' ('PROG' V1) ;
  137. Y1 = ('LOG' EPS0) '/' ('LOG' 10) ; Y2 = 0. ;
  138. 'SI' GRAPH ;
  139. EV1 = 'EVOL' 'MANU' (RV . 'INCO' . 'IT')(RV . 'INCO' . 'ER') ;
  140. 'DESSIN' EV1 'YBOR' Y1 Y2 'NCLK' ;
  141. 'FINSI' ;
  142. 'SI' ((ERR10 < Y1) 'ET' (DD > ('MAXI' ('LECT' 10 FREQ)))) ;
  143. RV . 'TFINAL' = RV . 'PASDETPS' . 'TPS' ;
  144. 'FINSI' ;
  145. 'FINSI' ;
  146. RV . 'INCO' . 'UN2' = 'COPIER' RV . 'INCO' . 'UN' ;
  147. mat1 chp1 = 'KOPS' 'MATRIK' ;
  148. 'FINP' mat1 chp1 ;
  149.  
  150. *
  151. *==========
  152. * Maillage
  153. *==========
  154. *
  155. *
  156. *-----------------------------------------------------------------------
  157. *
  158. *
  159. * < L1 X L2 - L1 >
  160. *
  161. * 7___________6__________________________________________________5
  162. * ^ ^
  163. * INLET H1
  164. * v H2 OUTLET
  165. * 1___________2
  166. * | v
  167. * 3__________________________________________________4
  168. * BOTTOM
  169. *
  170. *
  171. *-----------------------------------------------------------------------
  172. *
  173. *
  174. * L1 : Longueur de la section d'entrée (avant la marche)
  175. * L2 : Longueur de la totalité du dispositif
  176. * H1 : Hauteur de la section d'entrée
  177. * H2 : Hauteur de la section de sortie
  178. * d1 : Dimension caractéristique d'une maille
  179. L1 = 3.0 ;
  180. L2 = 22.0 ;
  181. H1 = 1.0 ;
  182. H2 = 1.5 ;
  183. d1 = 0.1 * raf ;
  184. *
  185. * H2-H1 : Hauteur de la marche servant à l'adimensionnalisation
  186. HDIM = H2 - H1 ;
  187. L1 = L1 / HDIM ;
  188. L2 = L2 / HDIM ;
  189. H1 = H1 / HDIM ;
  190. H2 = H2 / HDIM ;
  191. d1 = d1 / HDIM ;
  192. *
  193. * Points du maillage
  194. p1 = 0. (H2-H1) ;
  195. p2 = L1 (H2-H1) ;
  196. p3 = L1 0. ;
  197. p4 = L2 0. ;
  198. p5 = L2 H2 ;
  199. p6 = L1 H2 ;
  200. p7 = 0. H2 ;
  201. p8 = L2 (H2-H1) ;
  202. *
  203. * Section d'éntrée
  204. p1p2 = p1 'DROIT' 'DINI' d1 'DFIN' d1 p2 ;
  205. p2p6 = p2 'DROIT' 'DINI' d1 'DFIN' d1 p6 ;
  206. p6p7 = p6 'DROIT' 'DINI' d1 'DFIN' d1 p7 ;
  207. p7p1 = p7 'DROIT' 'DINI' d1 'DFIN' d1 p1 ;
  208. mesh1 = 'DALL' p1p2 p2p6 p6p7 p7p1 'PLAN' ;
  209. *
  210. * Section de sortie
  211. p6p2 = 'INVE' p2p6 ;
  212. p2p3 = p2 'DROIT' 'DINI' d1 'DFIN' d1 p3 ;
  213. p3p4 = p3 'DROIT' 'DINI' d1 'DFIN' d1 p4 ;
  214. p4p8 = p4 'DROIT' 'DINI' d1 'DFIN' d1 p8 ;
  215. p8p5 = p8 'DROIT' 'DINI' d1 'DFIN' d1 p5 ;
  216. p5p6 = p5 'DROIT' 'DINI' d1 'DFIN' d1 p6 ;
  217. mesh2 = 'DALL' (p6p2 'ET' p2p3) p3p4 (p4p8 'ET' p8p5) p5p6 'PLAN' ;
  218. *
  219. *
  220. *=======================
  221. * Modèles NAVIER_STOKES
  222. *=======================
  223. *
  224. *
  225. * Définition des équations
  226. * $DOMTOT : Modèle volumique défini sur le maillage complet
  227. *
  228. * Conditions aux limites en vitesse :
  229. * $INLET : Modèle surfacique défini à l'entrée fluide (Poiseuille)
  230. * $WALL : Modèle surfacique défini sur les murs (adhérence en paroi)
  231. *
  232. * Conditions aux limites en pression :
  233. * $OUTLET : Modèle surfacique défini à la sortie fluide (sert à imposer
  234. * la pression de sortie en pression continue MSOMMET)
  235. *
  236. * Post-traitement
  237. * $BOTTOM : Modèle surfacique défini sur le plancher après la marche
  238. * (sert à évaluer la position du point de réattachement)
  239. *
  240. DOMTOT = 'CHAN' 'QUAF' (mesh1 ET mesh2) ;
  241. $DOMTOT = 'MODE' DOMTOT 'NAVIER_STOKES' DISCR ;
  242. $INLET = 'MODE' p7p1 'NAVIER_STOKES' DISCR ;
  243. $OUTLET = 'MODE' (p4p8 'ET' p8p5) 'NAVIER_STOKES' DISCR ;
  244. $BOTTOM = 'MODE' p3p4 'NAVIER_STOKES' DISCR ;
  245. $WALL = 'MODE' (p1p2 ET p2p3 ET p3p4 ET p5p6 ET p6p7)
  246. 'NAVIER_STOKES' DISCR ;
  247. *
  248. * Elimination ad hoc
  249. * (En 2D, il faut éliminer les points centres des modèles surfaciques
  250. * avec les points faces des modèles volumiques à cause des MACROs)
  251. FDOMTOT = 'DOMA' $DOMTOT 'FACE' ;
  252. CINLET = 'DOMA' $INLET 'CENTRE' ;
  253. COUTLET = 'DOMA' $OUTLET 'CENTRE' ;
  254. CBOTTOM = 'DOMA' $BOTTOM 'CENTRE' ;
  255. CWALL = 'DOMA' $WALL 'CENTRE' ;
  256. 'ELIM' (FDOMTOT 'ET' CINLET 'ET' COUTLET 'ET' CWALL 'ET' CBOTTOM) EPS0 ;
  257. *
  258. * On écrase les anciens maillages afin d'éviter toute ambiguitée
  259. DOMTOT = 'DOMA' $DOMTOT 'MAILLAGE' ;
  260. INLET = 'DOMA' $INLET 'MAILLAGE' ;
  261. OUTLET = 'DOMA' $OUTLET 'MAILLAGE' ;
  262. BOTTOM = 'DOMA' $BOTTOM 'MAILLAGE' ;
  263. WALL = 'DOMA' $WALL 'MAILLAGE' ;
  264. *
  265. * Maillage pour d'éventuelles conditions aux limites en pression
  266. 'SI' ('EGA' kpres 'MSOMMET') ;
  267. OUTLETP = 'DOMA' $outlet KPRES ;
  268. 'SINON' ;
  269. OUTLETP = 'DOMA' $domtot KPRES ;
  270. 'FINSI' ;
  271. *
  272. *===========================
  273. * Description des équations
  274. *===========================
  275. *
  276. * Grandeurs adimensionnées
  277. Umax = 1.0 ;
  278. Re = 150. ;
  279. *
  280. * Profil de vitesse parabolique à l'entrée
  281. YINLET = 'COOR' 2 INLET ;
  282. YMAX = 'MAXI' YINLET ;
  283. YMIN = 'MINI' YINLET ;
  284. UIN = (YINLET '-' YMAX) '*' (YINLET '-' YMIN) ;
  285. UIN = UIN '*' (-4.0*Umax/((YMAX-YMIN)*(YMAX-YMIN))) ;
  286. UIN = 'NOMC' 'UX' UIN 'NATU' 'DISCRET' ;
  287. VIN = 'KCHT' $INLET 'SCAL' 'SOMMET' 'COMP' 'UY' 0. ;
  288. *
  289. * Description du système en vitesse-pression
  290. RV = 'EQEX' $DOMTOT 'ITMA' 5000 'ALFA' 1. 'FIDT' 20000
  291. 'OPTI' 'EF' 'IMPL' KSUPG KPRES
  292. 'ZONE' $DOMTOT 'OPER' residu FREQ0 EPS0 GRAPH
  293. 'ZONE' $DOMTOT 'OPER' 'NS' 1. 'UN' (1./Re) 'INCO' 'UN'
  294. * Conditions aux limites par défaut
  295. * 'ZONE' $OUTLET 'OPER' 'TOIM' (0. 0.) 'INCO' 'UN'
  296. 'OPTI' KMASS KSUPG
  297. 'ZONE' $DOMTOT 'OPER' 'DFDT' 1. 'UN' DT 'UN' (1./Re) 'INCO' 'UN'
  298. ;
  299. 'SI' ('EGA' kpres 'MSOMMET') ;
  300. RVP = 'EQEX' 'OPTI' 'EF' KPRES 'IMPL'
  301. 'ZONE' $DOMTOT 'OPER' 'KBBT' -1. 'INCO' 'UN' 'PRES'
  302. 'CLIM' 'PRES' 'TIMP' OUTLETP 0.
  303. ;
  304. 'SINON' ;
  305. RVP = 'EQEX' 'OPTI' 'EF' KPRES 'IMPL'
  306. 'ZONE' $DOMTOT 'OPER' 'KBBT' -1. 'INCO' 'UN' 'PRES'
  307. * En milieu ouvert, pression discontinue il est inutile
  308. * d'imposer la pression en un point
  309. * 'CLIM' 'PRES' 'TIMP' (OUTLETP 'ELEM' 1) 0.
  310. ;
  311. 'FINSI' ;
  312. *
  313. * Description des conditions aux limites
  314. RV = 'EQEX' RV
  315. 'CLIM' 'UN' 'UIMP' WALL 0. 'UN' 'VIMP' WALL 0.
  316. 'UN' 'UIMP' INLET UIN 'UN' 'VIMP' INLET VIN
  317. ;
  318. *
  319. * Déclaration des inconnues et initialisations (table INCO)
  320. RV . 'INCO' = 'TABLE' 'INCO' ;
  321. RV . 'INCO' . 'UN' = 'KCHT' $DOMTOT 'VECT' 'SOMMET' (0. 0.) ;
  322. RV . 'INCO' . 'PRES' = 'KCHT' $DOMTOT 'SCAL' KPRES 0. ;
  323. *
  324. * Champs supplémentaires pour la procédure residu
  325. RV . 'INCO' . 'IT' = 'PROG' ;
  326. RV . 'INCO' . 'TI' = 'PROG' ;
  327. RV . 'INCO' . 'ER' = 'PROG' ;
  328. RV . 'INCO' . 'POSI' = 'PROG' ;
  329. RV . 'INCO' . 'UN2' = 'KCHT' $DOMTOT 'VECT' 'SOMMET' (1.D-3 1.D-3) ;
  330. *
  331. * Algorithme de résolution : méthode de projection
  332. RV . 'PROJ' = RVP ;
  333. *
  334. EXEC RV ;
  335. *
  336. *=================
  337. * Post-traitement
  338. *=================
  339. *
  340. * Localisation du point de réattachement
  341. * Tracés de la vitesse et de la pression
  342. *
  343. CNT1 = WALL ;
  344. NLI0 = 14 ;
  345. *
  346. * Point de réattachement (point où dUx/dy=0)
  347. V1 = attac ;
  348. 'SAUT' 10 'LIGNE' ;
  349. 'MESS' 'ABSCISSE DU POINT DE REATTACHEMENT :' V1 ;
  350. 'SI' GRAPH ;
  351. EV1 = 'EVOL' 'MANU' RV . 'INCO' . 'TI' RV . 'INCO' . 'POSI' ;
  352. 'DESS' EV1 'MIMA' 'GRIL' 'TITR' 'Localisation reattachement = f(t)' ;
  353. *
  354. * Vitesse
  355. un = RV . 'INCO' . 'UN' ;
  356. vun = 'VECT' UN 0.1 'UX' 'UY' 'JAUNE' ;
  357. trace vun DOMTOT CNT1 'TITR' 'Vitesse' ;
  358. *
  359. * Pression
  360. pe = 'EXCO' (RV . 'INCO' . 'PRESSION') 'PRES' 'SCAL' ;
  361. 'SI' ('EGA' kpres 'MSOMMET') ;
  362. mp = 'DOMA' $DOMTOT 'MMAIL' ;
  363. trace pe mp ('CONTOUR' mp) ;
  364. 'SINO' ;
  365. pn = 'ELNO' $DOMTOT ('KCHT' $DOMTOT 'SCAL' kpres 0. pe) kpres;
  366. trace pn domtot CNT1 NLI0 'TITR' 'Pression' ;
  367. 'FINSI' ;
  368. 'FINSI' ;
  369. *
  370. *========================
  371. * Test de non régression
  372. *========================
  373. *
  374. 'SI' COMPLET ;
  375. mess ' V1' V1 ;
  376. TEST = ('ABS' (V1 '-' 6.4541)) < 0.0005 ;
  377. 'SINON' ;
  378. TEST = ('ABS' (V1 '-' 6.3584)) < 0.0005 ;
  379. 'FINSI' ;
  380. 'MESSAGE' 'Element Vitesse : ' DISCR ;
  381. 'MESSAGE' 'Element Pression : ' KPRES ;
  382. 'MESSAGE' 'Décentrement : ' KSUPG ;
  383. 'MESSAGE' 'Matrice masse : ' KMASS ;
  384. 'SI' TEST ;
  385. 'ERREUR' 0 ;
  386. 'SINON' ;
  387. 'ERREUR' 5 ;
  388. 'FINSI' ;
  389. *
  390. 'FIN' ;
  391.  
  392.  
  393.  
  394.  
  395.  
  396.  
  397.  
  398.  
  399.  
  400.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales