Télécharger alonso.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : alonso.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ******************************************************************
  6. * *
  7. * Modèle d'ALONSO: argile *
  8. * *
  9. * Un cube d'argile de 50 cm de cote est soumis à des *
  10. * deplacements imposes de 10.cm sur 3 de ses faces. *
  11. * L'état de contraintes est volumique. *
  12. * *
  13. * Ce calcul est réalisé dans le domaine saturé de l'argile *
  14. * (succion nulle) *
  15. * *
  16. ******************************************************************
  17.  
  18. 'OPTION' 'ECHO' 0 'DIME' 3 'ELEM' cub8 'TRACER' psc ;
  19. * ajout de option epsilon lineaire pour la precision des test!
  20. OPTION epsilon lineaire;
  21. graph0 = vrai ;
  22. ecri0 = vrai ;
  23. elast0 = faux ;
  24. pb0 = faux ;
  25. xlim0 = 1.E-7 ;
  26. *
  27. * Maillage : un cube soumis à un déplacement
  28. * isotrope
  29. *
  30. n1 = 1 ;
  31. n2 = 1 ;
  32. n3 = 1 ;
  33. l1 = .5 ;
  34. l2 = .5 ;
  35. l3 = .5 ;
  36. p1 = 0. 0. 0. ;
  37. p2 = l1 0. 0. ;
  38. p3 = l1 l2 0. ;
  39. p4 = 0. l2 0. ;
  40. d1 = 'DROITE' p1 n1 p2 ;
  41. d2 = 'DROITE' p2 n2 p3 ;
  42. d3 = 'DROITE' p3 n1 p4 ;
  43. d4 = 'DROITE' p4 n2 p1 ;
  44. sur1 = 'DALLER' d1 d2 d3 d4 'PLAN' ;
  45. mail0 = sur1 'VOLU' n3 'TRAN' ( 0. 0. l3 ) ;
  46. *
  47. coo1 coo2 coo3 = 'COOR' mail0 ;
  48. *
  49. sur1 = coo3 'POIN' 'EGSUPE' l3 ;
  50. sur2 = coo2 'POIN' 'EGSUPE' l2 ;
  51. sur3 = coo1 'POIN' 'EGSUPE' l1 ;
  52. sur4 = coo1 'POIN' 'EGINFE' 0. ;
  53. sur5 = coo2 'POIN' 'EGINFE' 0. ;
  54. sur6 = coo3 'POIN' 'EGINFE' 0. ;
  55. *
  56. *mail0 = sur1 'ET' sur2 'ET' sur3 'ET' sur4 'ET'
  57. * sur5 'ET' sur6 'ET' mail0 ;
  58. 'ELIM' mail0 1.E-5 ;
  59. 'SI' graph0 ;
  60. 'TITR' ' Maillage ' ;
  61. 'TRAC' mail0 'CACH' ;
  62. 'FINSI' ;
  63. *
  64. * Initialisations diverses
  65. *
  66. * Longueur du déplacement imposé sur les côtés 1, 2 et 3 (m) :
  67. depm0 = -.1 ;
  68. tfin0 = 10. ;
  69. EV0 = 'EVOL' 'MANU' 'temps' ( 'PROG' 0. tfin0 ) 'y' ( 'PROG' 0. 1. ) ;
  70. * Liste des temps calculés
  71. dt0 = tfin0 / 10. ;
  72. tem0 = 'PROG' 0. 'PAS' dt0 tfin0 ;
  73. *
  74. * modèle et matériau
  75. * ==================
  76. * {Notation d'Alonso : "A constitutive model for partially saturated soils"
  77. * E. Alonso, A. Gens, A. Josa (1990), Géotechnique 40, n°3}
  78. * [notations de Gens : "Expertise de la problématique THM-Gaz dans le
  79. * cadre de l'étude de la faisabilité d'un stockage en
  80. * profondeur. UPC" Rapport ANDRA : C RP 0UPC 00-001.
  81. * p' = contrainte nette isostatique]
  82. *
  83. *-- Lois de comportement :
  84.  
  85. * module d'Young tangent équivalent initial [E] (Pa).
  86. * Il sert uniquement pour initialiser le premier pas de temps.
  87. * N'importe quelle valeur supérieure à la pente à l'origine convient.
  88. youn0 = 2.1E11 ;
  89. * module de cisaillement équivalent initial [G] {G} (Pa)
  90. * Alonso donne 10 MPa !
  91. gtan0 = 150.E6 ;
  92. * coefficient de Poisson [nu] (s.d.) :
  93. nu0 = .3 ;
  94.  
  95. * Coef. d'écrouissage de traction en succion [k de P_s = - k s] {idem} (s.d.)
  96. * Alonso donne 0.6 !
  97. kk0 = 1.E-2 ;
  98.  
  99. * Pente q/p à l'état critique [M] {M} (s.d.) :
  100. * Alonso donne 1 !
  101. m0 = 1.2 ;
  102.  
  103. * paramètres de la loi lambda(s) = lambda(0) x [(1-r) exp (-beta s) + r]
  104. * Compressibilité en pression isostatique sur un chemin plastique :
  105. * charge d'un ech. normalement consolidé
  106. * [lambda(0)] {idem} (s.d.) :
  107. xlam1 = 5. / 111. ;
  108. * [r] {r} :
  109. * Alonso donne 0.75 !
  110. xt0 = .5 ;
  111. * [beta] {beta} (Pa-1) :
  112. tau0 = 1.E-6 ;
  113.  
  114. * Compressibilité élastique initiale en p' à saturation [k_i^0] {kapa} :
  115. * Il manque alpha_is pour définir k_i [Gens] {Alonso donne kapa constant}.
  116. ktan0 = 1. / 111. ;
  117.  
  118. * Pente d'écrouissage en succion [lambda_s] {lambda_s} (s.d.)
  119. * charge d'un ech. normalement consolidé
  120. * [variable chez Gens] {constant chez Alonso}
  121. lams0 = 5. / 111. ;
  122.  
  123. * Compressibilité élastique en succion [k_s] (s.d.)
  124. * charge d'un ech. surconsolidé ou décharge
  125. * Alonso donne 0.008 au lieu de 0.009. Gens le fait varier
  126. ks0 = 1. / 111. ;
  127.  
  128. * pression de référence pour l'évolution de P0(s) [P^c] {P^c} (Pa)
  129. xp0 = .1E6 ;
  130.  
  131. *-- Etat initial de l'échantillon
  132. * Contrainte de compression isostatique initiale [p] {sigma_m} (Pa)
  133. xp1 = 1.E6 ;
  134. * succion initiale [s(t=0)] {s(t=0)} (Pa)
  135. succ0 = 0. ;
  136. * indice des vides initial [e(t=0)] {e(t=0)} (s.d.)
  137. e00 = 0. ;
  138. * pression de consolidation fictive (à saturation) initiale [P0 ou Pc(t=0)] {idem} (Pa)
  139. xpc0 = 20.E6 ;
  140. * limite initiale de plasticité en succion (Succion Increase) [s_0] {s_0} (Pa) ?
  141. s00 = 1.E7 ;
  142.  
  143. *
  144. 'SI' elast0 ;
  145. * Calcul élastique
  146.  
  147. 'MESS' ' Calcul élastique' ;
  148. mod0 = 'MODE' mail0 'MECANIQUE' 'ELASTIQUE' ;
  149. mat0 = 'MATE' mod0 'YOUN' youn0 'NU' nu0 ;
  150.  
  151. 'SINON' ;
  152. * Calcul sur le modèle argileux ALONSO
  153.  
  154. 'MESS' ' Calcul sur le modèle argileux ALONSO ' ;
  155. mod0 = 'MODE' mail0 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'ALONSO' ;
  156. mat0 = 'MATE' mod0 'YOUN' youn0 'NU' nu0 'KS' ks0
  157. 'LAMS' lams0 'M' m0 'KK' kk0 'PC0' xpc0
  158. 'P0' xp0 'LAM1' xlam1 'T0' xt0 'TAU' tau0
  159. 'GTAN' gtan0 'KTAN' ktan0 'E0' e00 ;
  160. *
  161. * Volumes élémentaires de la structure
  162. *
  163. chel0 = 'MANU' 'CHML' mail0 'SCAL' 1. ;
  164. vol0 = 'INTG' 'ELEM' mod0 chel0 ;
  165. *
  166. * Variables internes initiales
  167. *
  168. q01 = 'MANU' 'CHML' mod0
  169. * 'VOLU' vol0 'PC0' xpc0 'SLIM' s00 'SUCC' succ0
  170. 'VOLU' vol0 'SLIM' s00 'SUCC' succ0
  171. 'TYPE' 'VARINTER' 'STRESSES' ;
  172. q00 = 'ZERO' mod0 'VARINTER' ;
  173. qq00 = q00 + q01 ;
  174. *
  175. * Contraintes initiales
  176. *
  177. p01 = 'MANU' 'CHML' mod0
  178. 'SMXX' (-1. * xp1) 'SMYY' (-1. * xp1) 'SMZZ' (-1. * xp1)
  179. 'SMXY' 0. 'SMXZ' 0. 'SMYZ' 0.
  180. 'TYPE' 'CONTRAINTES' 'STRESSES' ;
  181. *
  182. 'FINSI' ;
  183. *
  184. * Conditions aux limites
  185. *
  186. cl1 = 'BLOQ' sur1 'UZ' ;
  187. cl2 = 'BLOQ' sur2 'UY' ;
  188. cl3 = 'BLOQ' sur3 'UX' ;
  189. cl4 = 'BLOQ' sur4 'UX' ;
  190. cl5 = 'BLOQ' sur5 'UY' ;
  191. cl6 = 'BLOQ' sur6 'UZ' ;
  192. cl0 = cl1 'ET' cl2 'ET' cl3 'ET' cl4 'ET' cl5 'ET' cl6 ;
  193. *
  194. * Chargement
  195. *
  196. dep1 = 'DEPI' cl1 depm0 ;
  197. dep2 = 'DEPI' cl2 depm0 ;
  198. dep3 = 'DEPI' cl3 depm0 ;
  199. cha1 = 'CHAR' 'DIMP' dep1 EV0 ;
  200. cha2 = 'CHAR' 'DIMP' dep2 EV0 ;
  201. cha3 = 'CHAR' 'DIMP' dep3 EV0 ;
  202. cha0 = cha1 'ET' cha2 'ET' cha3 ;
  203. *
  204. * Appel à PASAPAS
  205. *
  206. ta1 = 'TABLE' ;
  207. ta1 .'MODELE' = mod0 ;
  208. ta1 .'CARACTERISTIQUES' = mat0 ;
  209. ta1 .'CHARGEMENT' = cha0 ;
  210. ta1 .'BLOCAGES_MECANIQUES' = cl0 ;
  211. 'SI' ( 'NON' elast0 ) ;
  212. ta1 .'VARIABLES_INTERNES' = 'TABLE' ;
  213. ta1 .'VARIABLES_INTERNES'. 0 = qq00 ;
  214. ta1 .'CONTRAINTES' = 'TABLE' ;
  215. ta1 .'CONTRAINTES'. 0 = p01 ;
  216. 'FINSI' ;
  217. ta1 .'TEMPS_CALCULES' = tem0 ;
  218. *
  219. TMASAU=table;
  220. ta1 . 'MES_SAUVEGARDES'=TMASAU;
  221. TMASAU .'DEFTO'=VRAI;
  222. TMASAU .'DEFIN'=VRAI;
  223. TMASAU .'DEFLO'=VRAI;
  224.  
  225. PASAPAS ta1 ;
  226. *
  227. 'SI' elast0 ;
  228. *
  229. * Post traitement
  230. *
  231. dim0 = 'DIME' ta1 .'TEMPS' - 1 ;
  232. sigm0 = ta1 .'CONTRAINTES'. dim0 ;
  233. depl0 = ta1 .'DEPLACEMENTS'. dim0 ;
  234. *
  235. sigxx = 'EXCO' sigm0 'SMXX' 'SCAL' ;
  236. sigyy = 'EXCO' sigm0 'SMYY' 'SCAL' ;
  237. sigzz = 'EXCO' sigm0 'SMZZ' 'SCAL' ;
  238. pres0 = -1. * ( sigxx + sigyy + sigzz ) / 3. ;
  239. *
  240. def1 = 'DEFO' mail0 depl0 1. 'ROUG' ;
  241. def0 = 'DEFO' mail0 depl0 0. ;
  242. *
  243. 'SI' graph0 ;
  244. 'TITR' ' Deformee ' ;
  245. 'TRAC' ( def1 'ET' def0 ) ;
  246. 'FINSI' ;
  247. *
  248. 'SI' ecri0 ;
  249. 'MESS' ' sigxx = ' ( 'MAXI' sigxx ) ;
  250. 'MESS' ' sigyy = ' ( 'MAXI' sigyy ) ;
  251. 'MESS' ' sigzz = ' ( 'MAXI' sigzz ) ;
  252. 'MESS' ' pres0 = ' ( 'MAXI' pres0 ) ;
  253. 'FINSI' ;
  254. *
  255. 'SINON' ;
  256. *
  257. dim0 = ( 'DIME' ta1 .'TEMPS' ) - 1 ;
  258. *
  259. ktan0 = 'MAXI' ( 'EXCO' mat0 'KTAN' 'SCAL' ) ;
  260. xlam1 = 'MAXI' ( 'EXCO' mat0 'LAM1' 'SCAL' ) ;
  261. xks0 = 'MAXI' ( 'EXCO' mat0 'KS' 'SCAL' ) ;
  262. lams0 = 'MAXI' ( 'EXCO' mat0 'LAMS' 'SCAL' ) ;
  263. xt0 = 'MAXI' ( 'EXCO' mat0 'T0' 'SCAL' ) ;
  264. tau0 = 'MAXI' ( 'EXCO' mat0 'TAU' 'SCAL' ) ;
  265. p00 = 'MAXI' ( 'EXCO' mat0 'P0' 'SCAL' ) ;
  266. *
  267. depl0 = ta1 .'DEPLACEMENTS'. dim0 ;
  268. sigm0 = ta1 .'CONTRAINTES'. dim0 ;
  269. var0 = ta1 .'VARIABLES_INTERNES'. dim0 ;
  270. *
  271. sigxx = 'EXCO' sigm0 'SMXX' 'SCAL' ;
  272. sigyy = 'EXCO' sigm0 'SMYY' 'SCAL' ;
  273. sigzz = 'EXCO' sigm0 'SMZZ' 'SCAL' ;
  274. pres0 = -1. * ( sigxx + sigyy + sigzz ) / 3. ;
  275. *
  276. def1 = 'DEFO' depl0 mail0 1. 'ROUG' ;
  277. def0 = 'DEFO' depl0 mail0 0. ;
  278. 'SI' graph0 ;
  279. 'TITR' ' Deformee ' ;
  280. 'TRAC' ( def1 'ET' def0 ) ;
  281. 'FINSI' ;
  282. *
  283. err_t1 = 'PROG' 0. ;
  284. err_p1 = 'PROG' 0. ;
  285. pres1 = 'PROG' xp1 ;
  286. treps1 = 'PROG' 0. ;
  287. pc1 = 'PROG' xpc0 ;
  288. trepp1 = 'PROG' 0. ;
  289. pres2 = 'PROG' xp1 ;
  290. trepp2 = 'PROG' 0. ;
  291. succ1 = 'PROG' succ0 ;
  292. slim1 = 'PROG' s00 ;
  293. succ00 = succ0 ;
  294. xlam2 = xlam1 * ((1. - xt0) *
  295. ( 'EXP' ( -1.* tau0 * succ0)) + xt0) ;
  296. exp0 = ( xlam1 - ktan0 ) / ( xlam2 - ktan0 ) ;
  297. pcs0 = p00 * ( ( xpc0 / p00 ) ** exp0 ) ;
  298. pcs1 = 'PROG' pcs0 ;
  299. *
  300. 'REPETER' bloc0 dim0 ;
  301. i0 = &bloc0 ;
  302. 'SI' ecri0 ;
  303. 'MESS' ' Calcul de restitution au pas ' i0 ;
  304. 'FINSI' ;
  305. *
  306. depl0 = ta1 .'DEPLACEMENTS'. i0 ;
  307. sigm0 = ta1 .'CONTRAINTES'. i0 ;
  308. var0 = ta1 .'VARIABLES_INTERNES'. i0 ;
  309. def0 = ta1 .'DEFORMATIONS_INELASTIQUES'. i0 ;
  310. *
  311. sigxx = 'EXCO' sigm0 'SMXX' 'SCAL' ;
  312. sigyy = 'EXCO' sigm0 'SMYY' 'SCAL' ;
  313. sigzz = 'EXCO' sigm0 'SMZZ' 'SCAL' ;
  314. pres0 = 'MAXI' ( -1. * ( sigxx + sigyy + sigzz ) / 3. ) ;
  315. *
  316. eps0 = 'EPSI' mod0 depl0 ;
  317. epxx = 'EXCO' eps0 'EPXX' 'SCAL' ;
  318. epyy = 'EXCO' eps0 'EPYY' 'SCAL' ;
  319. epzz = 'EXCO' eps0 'EPZZ' 'SCAL' ;
  320. treps0 = 'MAXI' ( -1. * ( epxx + epyy + epzz ) ) ;
  321. *
  322. pc0 = 'MAXI' ( 'EXCO' var0 'VPC0' 'SCAL' ) ;
  323. *
  324. defxx = 'EXCO' def0 'EIXX' 'SCAL' ;
  325. defyy = 'EXCO' def0 'EIYY' 'SCAL' ;
  326. defzz = 'EXCO' def0 'EIZZ' 'SCAL' ;
  327. trepp0 = 'MAXI' ( -1. * ( defxx + defyy + defzz ) ) ;
  328. *
  329. pres1 = pres1 'ET' ( 'PROG' pres0 ) ;
  330. pres01 = pres0 ;
  331. treps1 = treps1 'ET' ( 'PROG' treps0 ) ;
  332. pc1 = pc1 'ET' ( 'PROG' pc0 ) ;
  333. trepp1 = trepp1 'ET' ( 'PROG' trepp0 ) ;
  334. trepp01 = trepp0 ;
  335. *
  336. succ0 = 'MAXI' ( 'EXCO' var0 'SUCC' 'SCAL' ) ;
  337. slim0 = 'MAXI' ( 'EXCO' var0 'SLIM' 'SCAL' ) ;
  338. pc0 = 'MAXI' ( 'EXCO' var0 'VPC0' 'SCAL' ) ;
  339. xlam2 = xlam1 * ((1. - xt0) *
  340. ( 'EXP' ( -1.* tau0 * succ0)) + xt0) ;
  341. exp0 = ( xlam1 - ktan0 ) / ( xlam2 - ktan0 ) ;
  342. pcs0 = p00 * ( ( pc0 / p00 ) ** exp0 ) ;
  343. succ1 = succ1 'ET' ( 'PROG' succ0 ) ;
  344. slim1 = slim1 'ET' ( 'PROG' slim0 ) ;
  345. pcs1 = pcs1 'ET' ( 'PROG' pcs0 ) ;
  346. *
  347. * Solution analytique
  348. *
  349. treps0 = -1. * treps0 ;
  350. p_test0 = xp1 * ( 'EXP' ( -1. / ktan0 * treps0 ) ) ;
  351. xlam2 = xlam1 * ((1. - xt0) *
  352. ( 'EXP' ( -1.* tau0 * succ0)) + xt0) ;
  353. rapp0 = ( xpc0 / p00 )
  354. ** ( ( xlam1 - ktan0 ) / ( xlam2 - ktan0 ) );
  355. rapp0 = rapp0 * p00 / xp1 ;
  356. 'SI' ( p_test0 '>' xpc0 ) ;
  357. trepp0 = ( ( treps0 / ktan0 ) + ( 'LOG' rapp0 ) ) ;
  358. trepp0 = trepp0 * ( xlam2 - ktan0 ) * ktan0 / xlam2 ;
  359. p_th0 = xp1 * ( 'EXP' ( -1. / ktan0 * ( treps0 - trepp0 ) ) ) ;
  360. 'SINON' ;
  361. trepp0 = 0. ;
  362. p_th0 = p_test0 ;
  363. 'FINSI' ;
  364. trepp0 = -1. * trepp0 ;
  365. trepp02 = trepp0 ;
  366. *
  367. trepp2 = trepp2 'ET' ( 'PROG' trepp0 ) ;
  368. pres2 = pres2 'ET' ( 'PROG' p_th0 ) ;
  369. *
  370. * Calcul des erreurs
  371. *
  372. 'SI' ( trepp01 '>' 1.E-6 ) ;
  373. err_t0 = ( 'ABS' ( trepp01 - trepp02 ) ) / ( 'ABS' trepp01 ) ;
  374. err_t0 = err_t0 * 100. ;
  375. 'SINON' ;
  376. err_t0 = 0. ;
  377. 'FINSI' ;
  378. err_p0 = ( 'ABS' ( pres01 - p_th0 ) ) / ( 'ABS' pres01 ) ;
  379. err_p0 = err_p0 * 100. ;
  380. 'SI' ecri0 ;
  381. 'MESS' ' Erreur sur la deformation en % ' err_t0 ;
  382. 'MESS' ' Erreur sur la pression en % ' err_p0 ;
  383. 'FINSI' ;
  384. err_t1 = err_t1 'ET' ( 'PROG' err_t0 ) ;
  385. err_p1 = err_p1 'ET' ( 'PROG' err_p0 ) ;
  386. *
  387. 'SI' ((err_t0 '>' xlim0) 'OU' (err_p0 '>' xlim0)) ;
  388. pb0 = vrai ;
  389. 'FINSI' ;
  390. *
  391. 'FIN' bloc0 ;
  392. *
  393. * Traces
  394. *
  395. 'SI' graph0 ;
  396. evol1 = 'EVOL' 'MANU' 'trace' treps1 'pression' pres1 ;
  397. evol2 = 'EVOL' 'MANU' 'trace' treps1 'PC0' pc1 ;
  398. evol21 = 'EVOL' 'MANU' 'trace' treps1 'PCS' pcs1 ;
  399. evol3 = 'EVOL' 'MANU' 'trace' trepp1 'pression' pres1 ;
  400. evol4 = 'EVOL' 'MANU' 'trace' trepp2 'pression' pres2 ;
  401. evol5 = 'EVOL' 'MANU' 'trace' treps1 'succion' succ1 ;
  402. evol6 = 'EVOL' 'MANU' 'trace' treps1 'succion' slim1 ;
  403. evol7 = 'EVOL' 'MANU' 'trace' treps1 'erreur' err_t1 ;
  404. evol8 = 'EVOL' 'MANU' 'trace' treps1 'erreur' err_p1 ;
  405.  
  406. TAB = 'TABLE' ;
  407. TAB. 1 = 'MARQ PLUS ' ;
  408. TAB. 2 = 'MARQ CROI ' ;
  409. TAB. 3 = 'MARQ TRIA ' ;
  410. TAB.'TITRE' = 'TABLE' ;
  411. TAB.'TITRE'. 1 = MOT 'PRESSION' ;
  412. TAB.'TITRE'. 2 = MOT 'PC' ;
  413. TAB.'TITRE'. 3 = MOT 'PCS' ;
  414. 'DESS' ( evol1 'ET' evol2 'ET' evol21 )
  415. 'TITR' ' Trace de la deformation, pression ' 'LEGE' TAB ;
  416.  
  417. TAB = 'TABLE' ;
  418. TAB. 1 = 'MARQ PLUS ' ;
  419. TAB. 2 = 'MARQ CROI ' ;
  420. TAB.'TITRE'= 'TABLE' ;
  421. TAB.'TITRE'. 1 = MOT 'CALCUL' ;
  422. TAB.'TITRE'. 2 =MOT 'THEORIE' ;
  423. 'DESS' ( evol3 'ET' evol4 )
  424. 'TITR' ' Comparaison calcul-theorie ' 'LEGE' TAB ;
  425.  
  426. TAB = 'TABLE' ;
  427. TAB. 1 = 'MARQ PLUS' ;
  428. TAB. 2 = 'MARQ CROI' ;
  429. TAB.'TITRE'='TABLE' ;
  430. TAB.'TITRE'. 1 =MOT 'SUCCION' ;
  431. TAB.'TITRE'. 2 = MOT'LIMITE' ;
  432. 'DESS' ( evol5 'ET' evol6 )
  433. 'TITR' ' Succion ' 'LEGE' TAB ;
  434.  
  435. TAB = 'TABLE' ;
  436. TAB. 1 = 'MARQ PLUS' ;
  437. TAB. 2 = 'MARQ CROI' ;
  438. TAB.'TITRE' = 'TABLE' ;
  439. TAB.'TITRE'. 1 = MOT 'DEFORMATION' ;
  440. TAB.'TITRE'. 2 = MOT 'PRESSION' ;
  441. 'DESS' ( evol7 'ET' evol8 )
  442. 'TITR' ' Erreur en % ' 'LEGE' TAB ;
  443. 'FINSI' ;
  444. *
  445. 'FINSI' ;
  446.  
  447. *
  448. 'SI' pb0 ;
  449. 'ERRE' 5 ;
  450. 'SINON' ;
  451. 'ERRE' 0 ;
  452. 'FINSI' ;
  453.  
  454. 'FIN' ;
  455.  
  456.  
  457.  
  458.  
  459.  
  460.  
  461.  
  462.  
  463.  
  464.  
  465.  
  466.  
  467.  
  468.  
  469.  
  470.  
  471.  
  472.  
  473.  
  474.  
  475.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales