Exemples de jeux de données Cast3M

* fichier ajout1.dgibi
*----------------------------------------------------------------------*
* Calcul du champ de temperature apres ajout de matiere.               *
*                                                                      *
* Une 1ere partie d'un maillage est a la temperature de 1000.          *
* On lui ajoute une 2e partie a la temperature de 20.                  *
* L'objectif est de calculer la temperature a leur interface, ou leurs *
* noeuds sont en commun.                                               *
* Le princicpe est de verifier la conservation de la quantite de       *
* chaleur.                                                             *
*                                                                      *
* Pour cela, on utilise 2 methodes :                                   *
*   - A l'aide des matrices de capacite, on calcule les quantites de   *
*     chaleur contenues dans chaque partie, les assemble, puis on      *
*     resout le systeme : C0.T0 = (C1*T1 + C2*T2),                    *
*     T0 etant le champ de temperature recherche.                      *
*   - La 2nd consiste a diviser le second membre ci-dessus par un      *
*     champ de flux de chaleur "unite", obtenu en multipliant la       *
*     matrice de capacite globale par une temperature unite.           *
*                                                                      *
* Il y a conservation de l'energie avec les deux methodes.             *
* La seconde donne resultat qui semble plus physique.                  *
*                                                                      *
* La taille des elements des deux parties est differente.              *
* Les capacites thermiques dependent de la temperature.                *
*                                                                      *
*----------------------------------------------------------------------*
opti dime 3 elem cub8 ; 
 
* Mettre IG1 a VRAI pour affichages :
ig1      = faux ;
 
*------------------------------ Geometrie -----------------------------*
 
* Dimensions :
lo1      = 10.e-3 ; 
la1      = 6.e-3 ; 
h1       = 3.e-3 ; 
lo2      = h1 ;
 
* Maillage :
S1       = (0 0 0) droi 6 (0 la1 0) tran 3 (0 0 h1) ; 
v1       = s1 volu tran 10 (lo1 0 0) ; 
s2       = v1 face 2 ; 
v2       = s2 volu tran 5 (3.e-3 0 0 ) ; 
v2       = v2 coul vert ; 
v0       = v1 et v2 ; 
 
P0       = v0 poin proc (0 0 0) ; 
P1       = V0 poin proc (1 0 0) ; 
lx1      = (aret v0) elem comp p0 P1 ; 
si ig1 ;
  trac cach qual V0 titr 'Maillage des deux parties.' ;
fins ;
 
*----------------------- Modelisation ---------------------------------*
 
* Capacite thermique :
cp1      = evol manu 'T' (prog 0. 1000.) 'C' (prog 250. 500.) ;
si ig1 ;
  dess cp1 titr 'Capacite thermique' ;
fins ;
 
* Modeles - Caracteristiques :
mo0      = mode v0 thermique ; 
ma0      = mate mo0 rho 7.6e3 'C' cp1 k 20. ; 
 
* Champs de temperature initiaux dans chaque partie :
cht1     = manu chpo v1 1 t 1000. nature diffus ; 
cht2     = manu chpo v2 1 t 20.   nature diffus ; 
 
* Instanciation des carateristiques de chaque partie :
ma1      = vari nuag (redu mo0 v1) ma0 cht1 rigidites ;
ma2      = vari nuag (redu mo0 v2) ma0 cht2 rigidites ;
 
* Matrices de capacite :
c1       = capa (redu mo0 v1) ma1 ; 
c2       = capa (redu mo0 v2) ma2 ; 
c0       = c1 et c2 ;
 
* Quantite de chaleur globale :
q0       = (c1*cht1) + (c2 * cht2) ; 
 
*---------------------- Temperature apres ajout -----------------------*
 
* 1ere methode :
* cht0   : champ T resultat 1ere methode
cht0     = reso c0 q0 ; 
 
* Affichages resultat :
evt0     = evol chpo cht0 T lx1 ; 
si ig1 ;
  trac cht0 v0 titr 'Temperature apres ajout : 1ere methode' ; 
  dess evt0 titr 'Evolution Temperature le long de (0,x)' ;
fins ;
 
* Ecart relatif Quantites de chaleur initiale-finale 1ere methode :
err0     = ((resu (c0*cht0) maxi abs) - (resu q0 maxi abs)) / (resu q0 maxi abs) ;
list err0 ;
 
* 2nd methode :
* chtx0  : champ T resultat 2nd methode
chtx1    = manu chpo v0 1 t 1. ; 
qx1      = c0 * chtx1 ; 
chtx0    = q0 * (inve qx1) (mots q) (mots q) (mots t) ; 
 
* Affichage resultat :
evtx0    = evol vert chpo chtx0 t lx1 ; 
si ig1 ;
  trac chtx0 v0 titr 'Temperature apres ajout : 2nd methode' ;
  tleg1    = table ;
  tleg1 . 1 = mot 'MARQ S ETOI TIRR' ;
  tleg1 . 2 = mot 'MARQ S TRIA POIN' ;
  tleg1 . titre = table ;
  tleg1 . titre . 1 = '1ere methode' ;
  tleg1 . titre . 2 = '2nd  methode' ;
  dess (evt0 et evtx0) titr 'Evolution Temperature le long de (0,x)' lege tleg1 ; 
fins ;
 
* Ecart relatif Quantites de chaleur initiale-finale 2nd methode :
errx0    = ((resu (c0*chtx0) maxi abs) - (resu q0 maxi abs)) / (resu q0 maxi abs) ;
list errx0 ;
 
* Affichages resultat :
opti echo 0 ;
saut 1 lign ;
mess '  ***** Resultats sur quantite de chaleur globale :' ;
mess '      - Quantite de chaleur initiale parties 1 et 2 :' (resu Q0 maxi abs) ;
mess '      - Quantite de chaleur resultat methode 1      :' (resu (c0*cht0) maxi abs) ;
mess '      - Quantite de chaleur resultat methode 2      :' (resu (c0*chtx0) maxi abs) ;
saut 1 lign ;
opti echo 1 ;
 
si ((err0+errx0) > 1.e-10) ; erre 5 ; fins ;
 
fin ;