Télécharger aerosol3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : aerosol3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. GRAPH = FAUX ;
  6.  
  7. ************************************************************************
  8. * AEROSOL3.DGIBI *
  9. * *
  10. * Exemple d'utilisation des FONCTIONS DE PAROI AEROSOL LAMINAIRES. *
  11. * Ce jeu de données teste les operateurs TSCA, ECHI, KUET et FPAL. *
  12. * On résoud une équation de transport de particules dans un *
  13. * ecoulement 2D plan de Poiseuille donne, avec dépot en paroi. *
  14. * *
  15. * resolution semi-implicite d'une equation de concentration avec *
  16. * depot d'aérosols en paroi *
  17. * *
  18. *P. CORNET SEMT/TTMF DECEMBRE 1997 *
  19. ************************************************************************
  20.  
  21. *------------------------- maillage ------------------------------------
  22.  
  23. TITRE 'MAILLAGE POUR DEPOT PAR DIFFUSION' ;
  24. OPTIO DIME 2 ELEM QUA4 ;
  25.  
  26. L = 1. ;
  27. H = 0.1 ;
  28.  
  29. nx = 30 ;
  30. nz = 10 ;
  31. E = H/nx ;
  32.  
  33. * POINTS :
  34.  
  35. PA1 = 0. 0. ;
  36. PA2 = 0. (E-h) ;
  37. PA3 = 0. (0.-H);
  38.  
  39. PB1 = L 0. ;
  40. PB2 = L (e-h) ;
  41. PB3 = L (0.-H);
  42.  
  43. PC1 = (L/2.) 0. ;
  44. PC2 = (L/2.) (e-h) ;
  45. PC3 = (L/2.) (0.-H);
  46.  
  47. * SEGMENTS DE BASE :
  48.  
  49. DA1 = PA1 DROIT nz PA3 ;
  50. DB1 = PB1 DROIT nz PB3 ;
  51. DC1 = PC1 DROIT nz PC3 ;
  52.  
  53. DAC3 = PA3 DROIT (nx/2) PC3 ;
  54. DAC1 = PA1 DROIT (nx/2) PC1 ;
  55. DAC2 = PA2 DROIT (nx/2) PC2 ;
  56.  
  57. DCB3 = PC3 DROIT (nx/2) PB3 ;
  58. DCB1 = PC1 DROIT (nx/2) PB1 ;
  59. DCB2 = PC2 DROIT (nx/2) PB2 ;
  60.  
  61. DSOL = DAC3 ET DCB3 ;
  62. DAXE = DAC1 ET DCB1 ;
  63. DFLU = DAC2 ET DCB2 ;
  64. SOL2 = DSOL ELEM (LECT 2 PAS 1 NX) ;
  65.  
  66. DENT = DA1 ;
  67. DSOR = DB1 ;
  68. DMIL = DC1 ;
  69. ENT2 = DENT ELEM (LECT 1 PAS 1 (NZ-1)) ;
  70.  
  71. * DOMAINES
  72.  
  73. DOM1 = DA1 DAC3 (INVE DC1) (INVE DAC1) DALLER PLAN ;
  74. DOM2 = DC1 DCB3 (INVE DB1) (INVE DCB1) DALLER PLAN ;
  75.  
  76. DOMTOT = DOM1 ET DOM2 ;
  77.  
  78. BORTOT = CONTOUR DOMTOT ;
  79.  
  80. *---------------------- MODELES et normales aux faces -----------
  81.  
  82. MDOMTOT = CHAN DOMTOT QUAF ;
  83. Mdsor = CHAN dsor QUAF ;
  84. Mdmil = CHAN dmil QUAF ;
  85. Mdent = CHAN dent QUAF ;
  86. Mdsol = CHAN dsol QUAF ;
  87. Msol2 = CHAN sol2 QUAF ;
  88. ELIM (MDOMTOT et Mdsor et Mdmil et Mdent et Mdsol et Msol2) 1.e-5 ;
  89.  
  90. $domtot =mode MDOMTOT 'NAVIER_STOKES' LINE ;
  91. DOMA $domtot 'IMPR' ;
  92. $dsor =mode Mdsor 'NAVIER_STOKES' LINE ;
  93. $dmil =mode Mdmil 'NAVIER_STOKES' LINE ;
  94. $dent =mode Mdent 'NAVIER_STOKES' LINE ;
  95. $dsol =mode Mdsol 'NAVIER_STOKES' LINE ;
  96. $sol2 =mode Msol2 'NAVIER_STOKES' LINE ;
  97.  
  98. NOR = DOMA $DOMTOT 'NORMALE' ;
  99.  
  100. *------------------------ Donnees --------------------------------------*
  101. * *
  102. * ECOULEMENT : UM = vitesse debitante (m/s) *
  103. * NU = viscosite cinematique (m2/s) *
  104. * ROF = masse vomumique du gaz (kg/m3) *
  105. * *
  106. * PARTICULES : C0 = concentration initiale (part/m3) *
  107. * CP = concentration a la paroi (part/m3) *
  108. * ROG = gravite x masse volumique des particules (kg/m2s2) *
  109. * DP = diametre des particules (m) *
  110. * DIF = coefficient de diffusion brownienne (m2/s) *
  111. * *
  112. *-----------------------------------------------------------------------*
  113.  
  114. R0 = H ;
  115. L0 = L ;
  116.  
  117. UM = 7.5E-3 ;
  118. NU = 1.5E-5 ;
  119. ROF = 1.2 ;
  120.  
  121. ROG = 0. (-9810.) ;
  122. DP = 1.E-7 ;
  123. DIF = 6.8E-10 ;
  124. RAP = DP/2. ;
  125.  
  126. C0 = 1. ;
  127. CP = 0. ;
  128.  
  129. *----------------- INITIALISATION champ de vitesse ---------------------
  130.  
  131. cy=coor 2 domtot ;
  132. cy=nomc 'UX' cy ;
  133. cy=abs cy ;
  134. VX= kcht $domtot scal sommet comp 'UX' (1.5*UM*( 1.-((cy/R0)**2.)) ) ;
  135. VY= kcht $domtot scal sommet comp 'UY' 0. ;
  136.  
  137. VN= kcht $domtot vect sommet comp (mots 'UX' 'UY') (vx et vy) ;
  138.  
  139.  
  140. *-------------------- calcul vitesse de depot des aerosols -------------
  141.  
  142. UET = KUET NU VN NOR $DOMTOT $SOL2 ;
  143.  
  144. AK = FPAL NU ROF UET NOR ROG RAP $SOL2 ;
  145.  
  146.  
  147. *------------------------- Equation de CONCENTRATION -------------------
  148.  
  149. CALCUL = EQEX $domtot 'ITMA' 100 'ALFA' 0.9 'TFINAL' 50.
  150.  
  151. OPTI 'EFM1' 'EXPL' 'SUPGDC'
  152. ZONE $DOMTOT 'OPER' 'TSCA' DIF 'VN' 0. 'INCO' 'CN'
  153. ZONE $SOL2 'OPER' 'ECHI' AK CP 'INCO' 'CN'
  154. OPTI EFM1 'CENTREE'
  155. ZONE $DOMTOT 'OPER' 'DFDT' 1. 'CN' 'DELTAT' 'INCO' 'CN'
  156.  
  157. 'CLIM' 'CN' TIMP DENT C0 ;
  158.  
  159. *--------------------------- Initialisations et historiques ------------
  160.  
  161. calcul.'INCO' = table 'INCO' ;
  162. calcul.'INCO'.'VN'= vn ;
  163. calcul.'INCO'.'CN' = kcht $domtot scal sommet c0 ;
  164.  
  165. lh = PB1 et PB2 et PB3 et PC1 et PC2 et PC3 ;
  166. his = khis 'CN' lh ;
  167. calcul.'HIST'=his ;
  168.  
  169.  
  170. *--------------------------- EXECUTION ---------------------------------
  171.  
  172. EXEC CALCUL ;
  173.  
  174. *------------------------- DESSINS -------------------------------------
  175. SI GRAPH ;
  176.  
  177. VNCH = VECTEUR VN 10. UX UY VERT ;
  178. TITRE 'depot laminaire : VITESSES ';
  179. TRACE VNCH DOMTOT (BORTOT) ;
  180.  
  181. CN = calcul.'INCO'.'CN' ;
  182. opti isov ligne ;
  183. titre 'CONCENTRATION' ;
  184. trace cn domtot (bortot) ;
  185.  
  186. dessin his.'TABD' his.'CN' ;
  187.  
  188. CMIL = KCHT $DMIL scal sommet CN ;
  189. CSOR = KCHT $DSOR scal sommet CN ;
  190. CSOL = KCHT $DSOL scal sommet CN ;
  191.  
  192. TITRE ' CONCENTRATION MILIEU ';
  193. evoc1 = evol chpo CMIL DMIL ; dess evoc1 ;
  194.  
  195. TITRE ' CONCENTRATION SORTIE ';
  196. evoc2 = evol chpo CSOR DSOR ; dess evoc2 ;
  197.  
  198. TITRE ' CONCENTRATION PAROI ';
  199. evoc3 = evol chpo CSOL DSOL ; dess evoc3 ;
  200.  
  201. FINSI ;
  202.  
  203. *-------------------- test sur le flux deposé total --------------------
  204.  
  205. SUR = DOMA $SOL2 'VOLUME' ;
  206. KV = SUR*AK ;
  207. CN1 = KCHT $SOL2 scal sommet CALCUL.INCO.'CN' ;
  208. CE2 = NOEL $SOL2 CN1 ;
  209. CKS = CE2*KV ;
  210. CKS = SOMT CKS ;
  211. DEPREL = ( CKS - 1.26289E-06 ) / 1.26289E-06 ;
  212. mess 'FLUX DEPOSE =' CKS ;
  213.  
  214. SI ( (ABS DEPREL) > 0.05 ) ;
  215. ERREUR 5 ;
  216. FINSI ;
  217.  
  218. FIN ;
  219.  
  220.  
  221.  
  222.  
  223.  
  224.  
  225.  
  226.  
  227.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales