Télécharger adve1.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : adve1.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Cas-test de l'operateur ADVEction. *
  5. * *
  6. * Comparaison a une solution analytique. *
  7. * *
  8. * On calcule la temperature d'un fluide qui s'ecoule dans un tuyau *
  9. * chauffe sur toute sa longueur. *
  10. * On verifie la temperature du fluide en sortie du tuyau. *
  11. * *
  12. * La puissance lineique est de : 500 W/m *
  13. * La temperature en entree est de : 20°C *
  14. * La vitesse d'ecoulement est de : 25 cm/s *
  15. * La section du tuyau est de : 5.e-5 m2, soit environ 8 mm de diametre *
  16. * La longueur du tuyau est de : 5 m *
  17. * *
  18. * La temperature attendue en sortie est de : 70°C *
  19. * *
  20. * On utilise les elements lineaires et quadratiques (TUY2,TUY3) *
  21. * *
  22. *----------------------------------------------------------------------*
  23. 'OPTI' 'DIME' 3 'ELEM' 'SEG2' ;
  24. * *
  25. * Commentez cette ligne pour voir les traces : *
  26. 'OPTI' 'TRAC' 'PSC' ;
  27. * *
  28. O1 = 0 0 0 ;
  29. X1 = 1 0 0 ;
  30. P1 = 2.5 * X1 ;
  31. P2 = 5.0 * X1 ;
  32. Y1 = 0 1 0 ;
  33. Z1 = 0 0 1 ;
  34. * *
  35. L1 = O1 'DROI' 5 P1 'COUL' 'VERT' ;
  36. L2 = P1 'DROI' 5 P2 ;
  37. L2 = 'CHAN' 'QUAD' L2 'COUL' 'BLEU' ;
  38. 'TITR' ' Maillage du tuyau, longueur = 5 m (Vert=SEG2,Bleu=SEG3) ' ;
  39. 'TRAC' 'QUAL' (L1 'ET' L2) ;
  40. * *
  41. mo1 = 'MODE' L1 thermique advection 'TUY2' ;
  42. mo2 = 'MODE' L2 thermique advection 'TUY3' ;
  43. mo1 = mo1 'ET' mo2 ;
  44. * *
  45. L0 = L1 'ET' L2 ;
  46. * *
  47. * La veleur de la conductivite ne joue pas, on prend donc "1." : *
  48. ma1 = 'MATE' mo1 'K' 1. 'RHO' 1.e3 'C' 4.e3
  49. 'VITE' 0.25 'SECT' 5.e-5 ;
  50. * *
  51. sq1 = 'SOUR' mo1 ma1 L0 (5.e2 / 5.e-5) ;
  52. * *
  53. KA1 = 'ADVE' mo1 ma1 ;
  54. * *
  55. cl1 = 'BLOQ' T O1 ;
  56. dcl1 = 'DEPI' cl1 20. ;
  57. * *
  58. cht2 = 'RESO' (ka1 'ET' cl1) (sq1 'ET' dcl1);
  59. * *
  60. 'TITR' ' Evolution de la temperature le long du tuyau ' ;
  61. 'DESS' ('EVOL' 'VERT' 'CHPO' cht2 L0 T) ;
  62. * *
  63. * Test :
  64. tref1 = 70. ;
  65. tp1 = 'EXTR' cht2 T P2 ;
  66. err1 = 'ABS' (TREF1 - tp1) / tp1 ;
  67. * *
  68. 'OPTI' 'ECHO' 0 ;
  69. 'MESS' ;
  70. mot1 = 'CHAI' ' > Temperature calculee en sortie = '
  71. 'FORMAT' '(F3.0)' tp1 '°C pour 70°C attendu ' ;
  72. 'MESS' mot1 ;
  73. 'MESS' ' > Erreur relative = ' err1 ;
  74. 'MESS' ;
  75. 'OPTI' 'ECHO' 1 ;
  76. * *
  77. 'SI' (err1 > 1.e-5) ;
  78. 'ERRE' 5 ;
  79. 'SINO' ;
  80. 'OPTI' 'ECHO' 0 ;
  81. 'MESS' ;
  82. 'MESS' ' > Test reussi ' ;
  83. 'MESS' ;
  84. 'FINS' ;
  85. * *
  86. 'FIN' ;
  87.  
  88.  
  89.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales