Télécharger Th1D-T3D-Ebul.dgibi

Retour à la liste

Numérotation des lignes :

  1. * NOM DE FICHIER : Th1D-T3D-Ebul.dgibi
  2.  
  3. *******************************************
  4. *******************************************
  5.  
  6. ************************************************************************
  7. * DESCRIPTION : Modelisation thermique 3D - thermohydraulique 1D avec possibilite
  8. * d'ebullition nucleee sur la paroi chauffante en contact avec le
  9. * fluide caloporteur (voir ci-dessous le domaine de calcul et les
  10. * phenomenes physiques modelises).
  11. *
  12. **********************************************************************************************
  13. * A U T E U R S
  14. **********************************************************************************************
  15. *
  16. * Julien BIGNALET Stagiaire ENSEEIHT - Genie Atomique 2006 - mel : julien.bignalet@alumni.enseeiht.fr
  17. * Jean-Louis LASZLO - CEA/DEN/DANS/DRSN/SIREN/LASPI - mel : jean-louis.laszlo@cea.fr
  18. * Stephane GOUNAND - CEA/DEN/DANS/DM2S/SFME/LTMF - mel : gounand@semt2.smts.cea.fr
  19. *
  20. **********************************************************************************************
  21. **********************************************************************************************
  22. *
  23. *
  24. * TEST RAPIDE : la variable logique complet = FAUX;
  25. * TEST NOMINAL : la variable logique complet = VRAI;
  26. *
  27. **********************************************************************************************
  28. **********************************************************************************************
  29. * Exemple de resultats *
  30. **********************************************************************************************
  31. * Variable logique COMPLET VRAI FAUX
  32. * ******* **** ****
  33. * Pas d'algorithme
  34. * "diphasique", donc
  35. * pas de seuillage
  36. * de la face externe
  37. * du crayon chauffant
  38. *
  39. * Pression 146.4 bar 146.4 bar
  40. * Diametre externe crayon chauffant 9.5 mm 9.5 mm
  41. * Longueur chauffante 360.0 mm 360.0 mm
  42. * Debit massique commun jambes chaude et froide 0.196 kg/s 0.196 kg/s
  43. * Puissance lineique maximale crayon chauffant 480.0 W/cm 480.0 W/cm
  44. * Flux critique (BOWRING) a mi-longueur chauffante 379.9 W/cm2 379.9 W/cm2
  45. * Flux critique (BOWRING) a mi-longueur chauffante 1133.8 W/cm 1133.8 W/cm
  46. * Puissance incidente crayon chauffant 16094.0 W 16094.0 W
  47. *
  48. * Sources internes prises en compte
  49. * Sources internes dans les structures
  50. * Sources internes dans les fluides
  51. * Sources internes structures 15809.8 W 15791.8 W
  52. * Sources internes fluides 912.0 W 909.8 W
  53. * Sources internes totales 16721.8 W 16701.6 W
  54.  
  55. * Puissance interface
  56. * jambe chaude & parois separant les 2 ecoulements -370.4 W 581.1 W
  57. * Puissance interface
  58. * jambe froide & parois separant les 2 ecoulements 1589.8 W 638.4 W
  59. * Puissance interface
  60. * jambe froide & tubes de force 2700.4 W 2083.3 W
  61. * Pertes vers eau statique de la piscine 11600.8 W 13150.1 W
  62.  
  63. * Fluide caloporteur :
  64. * ------------------
  65. * Temperature entree fluide chaud (imposee) 252.0 degres C 252.0 degres C
  66. * Temperature sortie fluide chaud 269.5 degres C 270.6 degres C
  67. * Gradient de temperature fluide chaud 17.5 degres 18.6 degres
  68. * Temperature entree fluide froid 245.5 degres C 247.2 degres C
  69. * Temperature sortie fluide froid (imposee) 251.0 degres C 251.0 degres C
  70. * Gradient de temperature fluide froid 5.5 degres 3.8 degres
  71.  
  72. * Temperature structures solides :
  73. * ------------------------------
  74. * Temperature de saturation 340.2 degres C
  75. * Temperature ebullition nucleee maximale (JENS & LOTTE) 342.9 degres C PAS DE TRAITEMENT
  76. * Temperature maximale paroi externe crayon chauffant 342.9 degres C EBULLITION NUCLEEE
  77. * Temperature maximale paroi externe en contact piscine 99.5 degres C 72.4 degres C
  78. **********************************************************************************************
  79. **********************************************************************************************
  80. *
  81. ************************************************************************
  82. * PARAMETRES PRINCIPAUX
  83. ************************************************************************
  84. * discr = |LINE : discretisation lineaire (suffisante)
  85. * |QUAF : discretisation quadratique
  86. * graph = VRAI : pour tracer des choses
  87. * interact = |VRAI : pour une utilisation interactive avec traces a l'ecran
  88. * |FAUX : execution sans arret et sans traces
  89. * rayo = |VRAI : rayonnement (face a face) dans la cavite de gaz
  90. * |FAUX : non prise en compte du rayonnement
  91. * verbose = FAUX : moins de messages dans le recapitulatif
  92.  
  93. * precis | = |VRAI : represente seulement les bonnes puissances
  94. * | |FAUX : permet de comparer les differentes puissances aux
  95. * | meme interfaces afin de choisir la plus precise
  96.  
  97. * egasol = |VRAI : prise en compte sources internes reparties dans les structures
  98. * |FAUX : pas de prise en compte sources internes reparties dans les structures
  99. * egaliq = |VRAI : prise en compte sources internes reparties dans les fluides
  100. * |FAUX : pas de prise en compte sources internes reparties dans les fluides
  101. * varcna = |VRAI : convection naturelle avec la piscine
  102. * |FAUX : echange constant avec la piscine (valeur HCNCST)
  103.  
  104. * complet = |VRAI : calcul avec toutes les iterations
  105. * |FAUX : calcul rapide, avec nombre reduit d'iterations
  106. ************************************************************************
  107. ************************************************************************
  108. *
  109. *
  110. ***********************
  111. * DOMAINE DE CALCUL : *
  112. ************************************************************************
  113. * PISCINE remplie d'eau statique |--|----|------|---|
  114. * -------- / |
  115. * / |
  116. * "mtef_t" ->|----------|----|--------|----|-----| |
  117. * | |--|----|------|---|
  118. * | tube force externe : "mt_tfe" / |
  119. * | / |
  120. * "mten_t" ->|----------|----|--------|----|-----| |
  121. * | |----|------|---|
  122. * | lame de gaz (N2) : "mt_gaz" / |
  123. * | / |
  124. * "mtif_t" ->|----------|----|--------|----|-----|--| |
  125. * | |
  126. * | |----|------|---|
  127. * | tube de force interne : "mt_tfi" / |
  128. * | / |
  129. * "mtin_t" ->|----------|----|--------|----|-----|--| |
  130. * | <== |
  131. * |<-"bahe_p" <== "hahe_p"->|
  132. * | fluide froid : "mthe_p" <== |
  133. * | <== |
  134. * "mtif_pe"->|----------|----|--------|----|-----|--|--|-----|-----|---|
  135. * | panier externe : "mt_pe" |
  136. * "mtin_pe"->|----------|----|--------|----|-----|--|--|-----|-----|---|
  137. * | lame d'eau stagnante : "mt_lam" |
  138. * "mtif_p" ->|----------|----|--------|----|-----|--|--|-----|-----|---|
  139. * | panier interne : "mtcb_p" |
  140. * "mtin_p" ->|----------|----|--------|----|-----|--|--|-----|-----|---|
  141. * | ==> |
  142. * |<-"bahe" fluide chaud : "mthe" ==> |
  143. * | ==> |
  144. * "mtif" ->|----------|----|--------|----|-----|--|--|-----| "hahe"->|
  145. * | gaine : "mtcb" |\ |
  146. * "mtin" ->|----------|----|--------|----|-----|--|--|-----| \ |
  147. * ->| rallonge |bou | zone |bou | rallonge sup : | \ |
  148. * | inf : |chon| chauf. |chon| | \ |
  149. * | "mtcbAr" | | | | "mtcbEr" | \ |
  150. * Axe --------------------------------------------------------|---|->
  151. * symetrie -------------------------------------------------------------->
  152. * | | | | | | | | | | |
  153. *
  154. * Parties : | A | B | C | D | E |F |G | H,I | J | K |
  155. * | | | | | | | | | | |
  156. * z1 z2 z3 z4 z5 z6 z7 z8 z9 z10 z11 zM
  157. *
  158. *
  159. *--------------------------------|
  160. * PHENOMENES PHYSIQUES MODELISES |
  161. *--------------------------------|
  162. *
  163. *
  164. * PISCINE : Temperature fixe |------------------|
  165. * / |
  166. * / |
  167. * |--------Convection naturelle-------| |
  168. * | |------------------|
  169. * | tube force externe : Conduction / |
  170. * | / |
  171. * |-----------------------------------| |
  172. * | |---------------|
  173. * | lame de gaz (N2) : / |
  174. * | Rayonnement + Conduction / |
  175. * |--------------------------------------| |
  176. * | |
  177. * | |----|------|---|
  178. * | tube de force interne : Conduction / |
  179. * | / |
  180. * |---- Convection forcee ---------------| |
  181. * | <== |
  182. * Temp | <== |
  183. * imposee | <== fluide froid |
  184. * | <== |
  185. * |---- Convection forcee ----------------------------------|
  186. * | panier externe : Conduction |
  187. * |---------------------------------------------------------|
  188. * | lame d'eau : Conduction |
  189. * |---------------------------------------------------------|
  190. * | panier interne : Conduction |
  191. * |---- Convection forcee ----------------------------------|
  192. * Temp | ==> |
  193. * imposee | fluide chaud ==> |
  194. * | ==> |
  195. * |---- Convection forcee ------------------------| |
  196. * | gaine : Conduction |\ |
  197. * |-----------------------------------------------| \ |
  198. * | rallonge |bou | crayon |bou | rallonge sup : | \ |
  199. * | inf : |chon| |chon| | \ |
  200. * |Conduction|vide| chauff.|vide| Conduction | \ |
  201. * Axe --------------------------------------------------------|---|->
  202. * symetrie -------------------------------------------------------------->
  203.  
  204. ************************************************************************
  205. *****************DECLARATIONS DES PROCEDURES****************************
  206. ************************************************************************
  207.  
  208. debproc ecform c1*MOT c2*MOT c3*MOT v0*FLOTTANT ;
  209. c1 = et c1 ' = ' ;
  210. c3 = et ' ' c3 ;
  211. c20 = ( chaine 'FORMAT' c2 v0) ;
  212. mess (et (et c1 c20 ) c3) ;
  213. finproc ;
  214.  
  215. debproc recal coul0*mot dhp0*chpoint mod0/MMODEL m0*maillage
  216. pt1*point pt2*point npt1*entier
  217. pt3/point npt2/entier ;
  218. si ( non ( existe mod0)) ;
  219. chp0 = dhp0 ;
  220. sinon ;
  221. chp0 = ELNO mod0 dhp0 ;
  222. sele0 = DOMA mod0 'XXVOLUM' ; comm surface elements ;
  223. densf0 = KOPS '/' dhp0 sele0 ; comm chpo scal centre ;
  224. densf1 = ELNO mod0 densf0 ; comm chpo scal sommet ;
  225. finsi ;
  226. qt1 = m0 poin proc pt1 ;
  227. qt2 = m0 poin proc pt2 ;
  228. opti elem seg2 ;
  229. si (existe pt3 );
  230. qt3 = m0 poin proc pt3 ;
  231. drt0 = droi npt1 qt1 ( droi npt2 qt2 qt3 ) ;
  232. sinon ;
  233. drt0 = droi npt1 qt1 qt2 ;
  234. finsi ;
  235. * * castem13 et avant
  236. * si ( non ( existe mod0)) ;
  237. * tdrt0 = INT_COMP m0 chp0 drt0 ;
  238. * sinon ;
  239. * tdrt0 = INT_COMP m0 densf1 drt0 ;
  240. * finsi ;
  241. ***** modif bp du 03/09/2013 suite a l'evolution #7817 *****
  242. si ( non ( existe mod0)) ;
  243. chp0ok = chp0 ;
  244. sinon ;
  245. chp0ok = densf1;
  246. finsi ;
  247. * normale aux elements (d'amplitude=0.1*taille des elements)
  248. modcoq4 = mode m0 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'COQ4';
  249. vcoq4 = VSUR modcoq4;
  250. vcoq4x = exco vcoq4 'VX' 'SCAL';
  251. vcoq4y = exco vcoq4 'VY' 'SCAL';
  252. vcoq4z = exco vcoq4 'VZ' 'SCAL';
  253. nvcoq4 = ((vcoq4x**2) + (vcoq4y**2) + (vcoq4z**2))**0.5;
  254. vcoq4 = 0.1 * (nvcoq4**-0.5) *
  255. (vcoq4 exco (mots VX VY VZ) (mots UX UY UZ));
  256. *trac (vect 1. modcoq4 vcoq4 (mots UX UY UZ)) m0;
  257. vcoq4 = chan vcoq4 'CHPO' modcoq4 'MOYENNE';
  258. * extrusion pour creation elements massifs
  259. * (seuls acceptes par PROI qui est appele par INT_COMP)
  260. m0pp chp0pp = m0 chp0ok plus vcoq4;
  261. m0mm chp0mm = m0 chp0ok moin vcoq4;
  262. opti elem CUB8;
  263. m0ok = (volu m0mm m0) et (volu m0 m0pp);
  264. chp0ok = chp0mm et chp0ok et chp0pp;
  265. *trac chp0ok m0ok;
  266. tdrt0 = INT_COMP m0ok chp0ok drt0 ;
  267. ***** fin modif bp du 03/09/2013 suite a l'evolution #7817 *****
  268. ev0 = evol coul0 'CHPO' tdrt0 drt0 ;
  269. si ( non ( existe mod0)) ;
  270. respro ev0 ;
  271. sinon ;
  272. respro ev0 densf1 ;
  273. finsi ;
  274. finproc ;
  275.  
  276. DEBPROC BOWRING TAB_1*TABLE chlat/flottant ;
  277. *
  278. *
  279. * CALCUL DU FLUX CRITIQUE SUIVANT LA CORRELATION DE BOWRING
  280. * --- entrees
  281. *
  282. INIVEAU1 = TAB_1.'NIVEAU' ;
  283. D_DIAM1 = TAB_1.'D_DIAM' ;
  284. L_LONG1 = TAB_1.'L_HEATED' ;
  285. P_PRES1 = TAB_1.'P_IN' ;
  286. G_VITE1 = TAB_1.'G_IN' ;
  287. T_TEMP1 = TAB_1.'T_IN' ;
  288.  
  289.  
  290. * - test sur la vitesse de l'eau
  291. SI ((G_VITE1 < 136.) OU ( G_VITE1 > 18600.)) ;
  292. MESS 'Vitesse massique : ' G_VITE1;
  293. ERRE '@BOWRING -> Vitesse massique hors [136. , 18600.] (Kg/M2/S)';
  294. FINSI ;
  295.  
  296. * - test sur le diametre
  297. SI ((D_DIAM1 < 2.E-3) OU (D_DIAM1 > 450.E-3)) ;
  298. MESS 'Diametre : ' D_DIAM1;
  299. ERRE '@BOWRING -> Diametre hors [0.002 0.45] (M)' ;
  300. FINSI ;
  301.  
  302. * - test sur la Pression
  303. SI ((P_PRES1 < 1.E5) OU (P_PRES1 > 200.E5)) ;
  304. MESS 'Pression : ' P_PRES1;
  305. ERRE '@BOWRING -> Pression hors de [1.E5, 200.E5] (Pa) ' ;
  306. FINSI ;
  307.  
  308. * - test sur la longueur chauffee
  309. SI ((L_LONG1 < 0.15) OU (L_LONG1 > 3.7)) ;
  310. MESS 'Longueur : ' L_LONG1;
  311. ERRE '@BOWRING --> Longueur hors de [0.15,3.7](M) ' ;
  312. FINSI ;
  313.  
  314. P1 = P_PRES1 / 6900000. ;
  315.  
  316. SI (P1 &lt;EG 1.) ;
  317. F1 = (((P1 ** 18.942) * (EXP (20.8 * (1. - P1)))) + 0.917) / 1.917;
  318. F2 = (F1 * 1.309)/(((P1 ** 1.316)*(EXP(2.444*(1. - P1)))) + 0.309);
  319. F3 = (((P1 ** 17.023)*(EXP(16.658*(1. - P1)))) + 0.667)/1.667;
  320. F4 = F3 * (P1 ** 1.649) ;
  321. SINON ;
  322. F1 = (P1 ** (-0.368))*(EXP(0.648*(1. - P1)));
  323. F2 = (P1 ** (-0.448))*(EXP(0.245*(1. - P1)));
  324. F3 = P1 ** 0.219;
  325. F4 = F3 * (P1 ** 1.649) ;
  326. FINSI ;
  327.  
  328.  
  329. si (existe chlat) ;
  330. L_VAP = chlat ;
  331. sinon ;
  332. L_VAP = 'VARI' 'LATENT' P_PRES1 ;
  333. finsi ;
  334.  
  335. S_SAT = hlsat - ( 'VARI' 'HLS' P_PRES1 ( T_TEMP1 + ck ) ) ;
  336.  
  337. A__1 = 0.5793 * L_VAP * D_DIAM1 * G_VITE1 * F1 /
  338. (1. + (0.0143 * F2 * (D_DIAM1 ** .5) * G_VITE1 )) ;
  339.  
  340. B__1 = .25 * D_DIAM1 * G_VITE1 ;
  341.  
  342. C__1 = 0.077 * D_DIAM1 * G_VITE1 * F3 /
  343. (1. + (0.347 * F4 * ((G_VITE1/1356.) ** (2. - (.5 * P1))))) ;
  344.  
  345. QCHFW = (A__1 + (B__1 * S_SAT)) / (C__1 + L_LONG1) ;
  346.  
  347. G1 = G_VITE1 * PI * D_DIAM1 * D_DIAM1 / 4. ;
  348. *
  349. FINPROC QCHFW ;
  350.  
  351.  
  352.  
  353. debproc loupe m0*maillage c0*chpoint gross0*flottant
  354. tjt0*mot tipiso*mot cnt0/entier ;
  355. opti isov tipiso ;
  356. eye = 1.e30 1.e30 1.e30 ;
  357. * 1 pour UX - 2 pour UY - 3 pour UZ
  358. xmt = 'COORDONNEE' 1 m0 ;
  359. ymt = 'COORDONNEE' 2 m0 ;
  360. dxmt = 'NOMC' 'UX' ('*' xmt gross0) 'NATURE' 'DISCRET' ;
  361. dymt = 'NOMC' 'UY' ('*' ymt gross0) 'NATURE' 'DISCRET' ;
  362. orig0 = 'FORME' ;
  363. 'FORME' dxmt ;
  364. 'FORME' dymt ;
  365. si (existe cnt0) ;
  366. si ( cnt0 < 0 );
  367. trac cach eye c0 m0 (cont m0 )
  368. coupe (0. 0. 0.) (0. 1. 0.) (0. 0. 1.) titr tjt0 ;
  369. sinon ;
  370. * trac cach eye c0 m0 (cont m0 ) titr tjt0 ;
  371. trac cach eye c0 m0 titr tjt0 ;
  372. finsi ;
  373. sinon ;
  374. trac cach eye c0 m0 titr tjt0 ;
  375. finsi ;
  376. 'FORME' orig0 ;
  377. finproc ;
  378.  
  379.  
  380. DEBPROC h2o_psat t*'FLOTTANT' ;
  381. * H2O_PSAT Saturation pressure at a given temperature in kPa
  382. * H2O_PSAT(T) Returns the saturation pressure at a given
  383. * temperature. Based on the correlation (K function) given in the
  384. * ASME STEAM TABLES - SIXTH EDITION
  385. * Temperature range from 0.0�C to 374.15�C
  386. * Called function: NONE
  387. * Required Inputs are: T - temperature in �C
  388. * ---------------------------------------------------------------
  389. * The MATLAB function was created by Tibor Balint, December 1998
  390. * TBoreal Research Corporation, Toronto, Ont. Canada
  391. * (tibor@netcom.ca) and also, University of Warwick, UK
  392. * ---------------------------------------------------------------
  393.  
  394.  
  395. SI ( T > 374.15 ) ;
  396. MESS 'Temperature out of range (above 374.15�C)' ;
  397. FINSI ;
  398. SI ( T < 0.0 ) ;
  399. MESS 'Temperature out of range (below 0.0�C)' ;
  400. FINSI ;
  401.  
  402.  
  403. T1=T+273.15;
  404. * set up the constants
  405. * the reduced temperature is calculated from theta=T/Tc1
  406. * temperature constants used in the reduced temperature Tc1=647.3K
  407. TC1=647.3;
  408. *the reduced saturation pressure is calculated from
  409. * betaK(theta)=ps/pc1, where ps=ps(T)
  410. *pc1=22120000 N/m^2
  411. pc1=22120000;
  412.  
  413. *Saturation line constants from k1 to k9
  414. k = TABLE ;
  415. s = TABLE ;
  416. k . 1 = -7.691234564e0 ;
  417. k . 2 = -2.608023696e1 ;
  418. k . 3 = -1.681706546e2 ;
  419. k . 4 = 6.423285504e1 ;
  420. k . 5 = -1.189646225e2 ;
  421. k . 6 = 4.167117320e0 ;
  422. k . 7 = 2.097506760e1 ;
  423. k . 8 = ( 10 ** 9. ) ;
  424. k . 9 = 6. ;
  425.  
  426. * build up the correlation
  427. a1 = 0. ;
  428.  
  429. REPE v 5 ;
  430. s . &v = ( k . &v ) * ((1.-(T1/TC1)) ** &v ) ;
  431. a1 = a1 + (s . &v) ;
  432. FIN v ;
  433.  
  434. a2 = 1. / (T1/TC1) ;
  435. a3 = (1. - (T1/TC1));
  436. a4 = 1. + ((k . 6) * a3) + ((k . 7) * (a3 ** 2.)) ;
  437. a5 = (k . 8) * (a3 ** 2.) + (k . 9) ;
  438.  
  439. *the reduced saturation pressure is
  440. betaK = exp(a2*(a1/a4)-(a3/a5));
  441.  
  442. PSAT = betaK * pc1 ; comm saturation pressure in Pa ;
  443.  
  444. FINPROC psat ;
  445.  
  446. DEBPROC h2o_tsat p*'FLOTTANT' ;
  447. * H2O_TSAT Saturation temperature at a given pressure in �C
  448. * H2O_TSAT(P) Returns the saturation temperature at a given
  449. * pressure. Based on the correlation (K function) given in the
  450. * ASME STEAM TABLES - SIXTH EDITION
  451. * Pressure range from 0.6108kPa to 22120kPa
  452. * Called function: h2o_psat
  453. * Required Inputs are: P - pressure in Pa
  454. * ---------------------------------------------------------------
  455. * The MATLAB function was created by Tibor Balint, December 1998
  456. * TBoreal Research Corporation, Toronto, Ont. Canada
  457. * (tibor@netcom.ca) and also, University of Warwick, UK
  458. * ---------------------------------------------------------------
  459.  
  460.  
  461. SI ( P > 22120.e3 ) ;
  462. MESS 'Pressure out of range (above 22120 kPa)' ;
  463. FINSI ;
  464. SI ( P < 0.61080062637844 ) ;
  465. MESS 'Pressure out of range (below 0.6108 kPa)' ;
  466. FINSI;
  467.  
  468. PIN=P;
  469. *set the minimum temperature to the lower range of the h2o_psat function
  470. TMIN=0;
  471. *set the maximum temperature to the lower range of the h2o_psat function
  472. TMAX=374.15;
  473. tm = 0.5 * ( tmin + tmax ) ;
  474. pm =( h2o_psat tm);
  475.  
  476. * Iterate for the pressure by guessing the temperature and
  477. * compare the result to the requested pressure input
  478. REPE fb ;
  479.  
  480. SI (( abs (PIN - Pm)) > 0.1 ) ;
  481. *SI ( &fb < 10 ) ;
  482.  
  483. SI ( PIN &lt;EG pm ) ;
  484. TMAX = tm ;
  485.  
  486. SINON ;
  487. TMIN = tm ;
  488. FINSI ;
  489. tm = 0.5 * ( tmin + tmax ) ;
  490.  
  491. Pm = ( h2o_psat tm) ;
  492.  
  493. SINON ;
  494. QUITTER fb ;
  495. FINSI ;
  496.  
  497. FIN fb ;
  498.  
  499. * Assign the last iteration value to the saturation temperature
  500. TSAT=Tm ;
  501.  
  502. FINPROC tsat ;
  503.  
  504. DEBPROC h2o_cplq t*'FLOTTANT' p*'FLOTTANT' ;
  505.  
  506. TS = ( h2o_tsat p ) ; comm calculate the saturation temperature ;
  507. PS = ( h2o_psat T ) ; comm calculate the saturation pressure ;
  508.  
  509. SI ( T > TS ) ;
  510. MESS 'Cp : Temperature is above saturation for the given pressure' ;
  511. FINSI ;
  512. SI ( PS > P ) ;
  513. MESS 'Cp : Pressure is above saturation for the given temperature' ;
  514. FINSI ;
  515.  
  516. hl2 = ((((0.3654e-12 * p ) - 0.30413e-5 ) * p ) + 0.40047e4 ) ;
  517. hl3 = ((((-0.95261e-8 * p ) - 0.25785 ) * p ) + 0.20641e8 ) ;
  518. hl4 = 399.98;
  519. CPLIQ = hl2 + ( hl3 / ((hl4 - t ) ** 2.0)) ;
  520. FINPROC cpliq ;
  521.  
  522. DEBPROC h2o_mu9 t*'FLOTTANT' p*'FLOTTANT' ;
  523.  
  524. * H2O_MU Dynamic viscosity at a given temperature and density
  525. * H2O_MU(T,RHO) Returns the dynamic viscosity at a given temperature and density.
  526. * Dynamic viscosity in (Pa s) i.e., (kg/ms)
  527. * Based on the correlation given in Appendix 6 of the
  528. * ASME STEAM TABLES - SIXTH EDITION
  529. * Range of validity of equation:
  530. * P<=500MPa for 0�C <= T <= 150�C
  531. * P<=350MPa for 150�C <= T <= 600�C
  532. * P<=300MPa for 600�C <= T <= 900�C
  533. * Called function: none
  534. * Required Inputs are: T - temperature in �C
  535. *
  536. *
  537. * ---------------------------------------------------------------
  538. * The MATLAB function was created by Tibor Balint, December 1998
  539. * TBoreal Research Corporation, Toronto, Ont. Canada
  540. * (tibor@netcom.ca) and also, University of Warwick, UK
  541. * ---------------------------------------------------------------
  542.  
  543. *check the pressure and temperature ranges
  544. TS = ( h2o_tsat p ) ; comm calculate the saturation temperature ;
  545. PS = ( h2o_psat T ) ; comm calculate the saturation pressure ;
  546.  
  547.  
  548. SI ( T > TS ) ;
  549. MESS 'MU : Temperature is above saturation for the given pressure' ;
  550. FINSI ;
  551. SI ( PS > P ) ;
  552. MESS 'MU : Pressure is above saturation for the given temperature' ;
  553. FINSI ;
  554.  
  555. * Get the saturated fluid density
  556. RHO = ( h2o_rhol T P ) ;
  557.  
  558.  
  559. *Reference temperature 647.27K
  560. Tstar=647.27;
  561. *Reference density 317.763 kg/m^3
  562. RHOstar=317.763;
  563. *Reference pressure 22.115x10^6 Pa
  564. Pstar=22.115e6;
  565. *Reference viscosity 55.071x10^-6 Pa s (or kg/ms)
  566. mustar=55.071e-6;
  567.  
  568. tab = TABLE ;
  569. tab . 1 = TABLE ;
  570. tab . 2 = TABLE ;
  571. tab . 3 = TABLE ;
  572. tab . 4 = TABLE ;
  573. tab . 5 = TABLE ;
  574. tab . 6 = TABLE ;
  575. tab . 7 = TABLE ;
  576.  
  577.  
  578. *Coefficients H_i for mu_0
  579. HI = TABLE ;
  580. HI . 1 = 1. ;
  581. HI . 2 = 0.978197 ;
  582. HI . 3 = 0.579829 ;
  583. HI . 4 = -0.202354 ;
  584. *list HI ;
  585. *HI=[1 0.978197 0.579829 -0.202354];
  586.  
  587. *Coefficients H_ij for mu_1
  588. *The coefficients not listed are all 0, so first set the matrix elements to 0
  589. REPE i 6 ;
  590. REPE j 7 ;
  591. tab . &i . &j = 0. ;
  592. FIN j ;
  593. FIN i ;
  594. *list tab ;
  595. *list ( tab . 1 ) ;
  596. *HIJ(1:6,1:7)=0;
  597.  
  598. H00=0.5132047; comm ;
  599. tab . 1 . 1 = H00;
  600. H10=0.3205656; comm ;
  601. tab . 2 . 1 = H10;
  602.  
  603.  
  604.  
  605. H40=-0.7782567; comm ;
  606. tab . 5 . 1 =H40;
  607. H50=0.1885447; comm ;
  608. tab . 6 . 1 =H50;
  609. H01=0.2151778; comm ;
  610. tab . 1 . 2 =H01;
  611. H11=0.7317883; comm ;
  612. tab . 2 . 2 =H11;
  613. H21=1.241044; comm ;
  614. tab . 3 . 2 =H21;
  615. H31=1.476783; comm ;
  616. tab . 4 . 2 =H31;
  617. H02=-0.2818107; comm ;
  618. tab . 1 . 3 =H02;
  619. H12=-1.070786; comm ;
  620. tab . 2 . 3 =H12;
  621. H22=-1.263184; comm ;
  622. tab . 3 . 3 =H22;
  623. H03=0.1778064; comm ;
  624. tab . 1 . 4 =H03;
  625. H13=0.4605040; comm ;
  626. tab . 2 . 4 =H13;
  627. H23=0.2340379; comm ;
  628. tab . 3 . 4 =H23;
  629. H33=-0.4924179; comm ;
  630. tab . 4 . 4 =H33;
  631. H04=-0.04176610; comm ;
  632. tab . 1 . 5 =H04;
  633. H34=0.1600435; comm ;
  634. tab . 4 . 5 =H34;
  635. H15=-0.01578386; comm ;
  636. tab . 2 . 6 =H15;
  637. H36=-0.003629481; comm ;
  638. tab . 4 . 7 =H36;
  639. *list tab ;
  640.  
  641. T1 = T + 273.15 ; comm Celsius to K ;
  642. Tbar = T1 / Tstar ;
  643. * In the viscosity equation the firs (mu0) term of the product gives the viscosity
  644. * of the steam in the ideal-gas limit and calculated from:
  645. comp1=0;
  646. REPE i 4 ;
  647. comp1 = comp1 + ( ( hi . &i ) / (Tbar ** (&i-1)) );
  648. FIN i ;
  649. mu0 = (((Tbar) ** 0.5 ) / comp1 ) ;
  650. * The second multiplicative factor is
  651. RHObar = RHO / RHOstar ;
  652. comp2=0;
  653. REPE i 6 ;
  654. REPE j 7 ;
  655.  
  656. comp2 = comp2 + ( ( tab . &i . &j )
  657. * ( ((1. / Tbar ) - 1. ) ** ( &i - 1. ) )
  658. * ((RHObar - 1.) ** ( &j - 1. )) ) ;
  659. FIN j ;
  660. FIN i ;
  661.  
  662. mu1 = exp ( RHObar * comp2 );
  663.  
  664. * The reduced viscosity is
  665. mubar = mu0 * mu1 ;
  666.  
  667. * The dynamic viscosity is calculated from the reduced and reference viscosities
  668. MU = mubar * mustar ;
  669.  
  670.  
  671.  
  672. FINPRO mu ;
  673.  
  674. DEBPROC h2o_lmda t*'FLOTTANT' p*'FLOTTANT' ;
  675. hl = VARI 'HLS' p ( t + 273.15 ) ;
  676. ak0=5.73738622e-1;
  677. ak1=2.536103551e-1;
  678. ak2=-1.45468269e-1;
  679. ak3=1.387472485e-2;
  680. xk = ( hl*1.7196904e-6 ) ;
  681. lmda = (((((ak3*xk)+ak2)*xk)+ak1)*xk)+ak0;
  682.  
  683.  
  684. FINPROC lmda ;
  685.  
  686.  
  687. DEBPROC h2o_rhol ;
  688. ARGU t*'FLOTTANT' ; comm temperature in �C ;
  689. ARGU p*'FLOTTANT' ; comm pressure in Pa ;
  690.  
  691. * ---------------------------------------------------------------
  692. * H2O_RHOL Subcooled density at a given temperature and pressure
  693. * H2O_RHOL(T,P) Returns the subcooled density a given temperature
  694. * and pressure. Based on the correlation (Subsection 1) given in the
  695. * ASME STEAM TABLES - SIXTH EDITION
  696. * Temperature range from 0.0�C to 374.15�C
  697. * Pressure range from 0.6108kPa to 22120kPa
  698. * Called function: h2o_psat(T), h2o_tsat(P)
  699. * The MATLAB function was created by Tibor Balint, December 1998
  700. * TBoreal Research Corporation, Toronto, Ont. Canada
  701. * (tibor@netcom.ca) and also, University of Warwick, UK
  702. * ---------------------------------------------------------------
  703.  
  704.  
  705. *check the pressure and temperature ranges
  706. TS=h2o_tsat P ; comm calculate the saturation temperature ;
  707. PS=h2o_psat T ; comm calculate the saturation pressure ;
  708.  
  709. si ( T > TS ) ;
  710. mess 'RHOL : Temperature is above saturation for the given pressure' ;
  711. SINON;
  712. mess'RHOL : Pressure is above saturation for the given temperature' ;
  713. finsi;
  714.  
  715. T1=T+273.15; comm convert the temperature from �C to K ;
  716.  
  717. * set up the constants
  718. * the reduced temperature is calculated from theta=T/Tc1
  719. * temperature constants used in the reduced temperature Tc1=647.3K
  720. TC1=647.3; comm the reduced temperature ;
  721. theta=T1/TC1;
  722.  
  723. * The reduced pressure is: beta=ps/pc1
  724. *where: pc1=22120000 N/m^2
  725. pc1=22120000.D0; comm reduced pressure i;
  726. beta=P/pc1;
  727.  
  728. * Primary constants for Subregion 1
  729. A11=7.982692717e0;
  730. A12=-2.616571843e-2;
  731. A13=1.522411790e-3;
  732. A14=2.284279054e-2;
  733. A15=2.421647003e2;
  734. A16=1.269716088e-10;
  735. A17=2.074838328e-7;
  736. A18=2.174020350e-8;
  737. A19=1.105710498e-9;
  738. A20=1.293441934e1;
  739. A21=1.308119072e-5;
  740. A22=6.047626338e-14;
  741. a1=8.438375405e-1;
  742. a2=5.362162162e-4;
  743. a3=1.72e0;
  744. a4=7.342278489e-2;
  745. a5=4.975858870e-2;
  746. a6=6.5371543e-1;
  747. a7=1.15e-6;
  748. a8=1.1508e-5;
  749. a9=1.4188e-1;
  750. ab10=7.002753165e0;
  751. ab11=2.995284926e-4;
  752. ab12=2.04e-1;
  753.  
  754. Y=1 - (a1*(theta**2.)) - (a2*(theta**(-6.)));
  755. Z=Y + (((a3*(Y**2.)) - (2.*a4*theta) + (2.*a5*beta))**0.5) ;
  756.  
  757. f1 = (A11*a5*(Z**(-5./17.))) ;
  758. f2 = ( A12 + (A13*theta) + (A14*(theta**2.)) + (A15*((a6-theta)**10.))
  759. + ( A16*((a7 + (theta**19.))**(-1.)) ) );
  760. f3 = (-1.) * ((a8 + (theta**11.))**(-1.))*(A17 + (2.*A18*beta) +
  761. (3.*A19*(beta**2.))) ;
  762. f4 = (-1. ) * (A20*(theta**18.)*(a9 + (theta**2.))*
  763. ((-3.*((ab10+beta)**(-4.))) + ab11)) ;
  764. f5 = (3.*A21*(ab12-theta)*(beta**2.));
  765. f6 = (4.*A22*(theta**(-20.))*(beta**3.)) ;
  766. * The reduced volume is
  767. x1 = f1 + f2 + f3 + f4 + f5 + f6 ;
  768.  
  769. * The reduced volume for subcooled fluid in Subregin 1 is
  770. * calculated from x1=v/vc1 where vc1=0.00317 m^3/kg
  771. vc1=0.00317;
  772. vl=x1*vc1;
  773. RHOL=1/vl;
  774. FINPROC rhol ;
  775.  
  776.  
  777.  
  778. DEBPROC PRPN2 TS/'FLOTTANT' T/'CHPOINT' ;
  779.  
  780. *** Description
  781. *** ***********
  782.  
  783. * Procedure donnant les proprietes du diazote dans la cavite de gaz :
  784. * - la masse volumique en approximant N2 a un gaz parfait
  785. * - la conductivite a partir des tables des Techniques de l'Ingenieur
  786. * Loi des GP : PV = nRT donne P/rho = rT <=> rho = P/rT
  787. * On est a une presssion de 5 bars, soit 0.5 MPa.
  788. * P_N2 : pression de N2 en bars
  789. * P : pression en Pa
  790. * R1 : constante des GP
  791. * M : masse molaire de N2 en kg/mol
  792. * rho : masse volumique en kg/m3
  793. * pres : pression de la table en MPa
  794. * temp : temperature de la table en K
  795. * ld_i : conductivite thermique de 200 a 1000 K a la pression i,
  796. * en mW/m/K
  797. *
  798. * T : temperature, parametre d'entree en Kelvin
  799. *
  800.  
  801.  
  802. P_N2 = 5. ;
  803. P_MPa = P_N2 / 10. ;
  804.  
  805. **Masse volumique AZOTE
  806. P = P_N2 * 1.e5 ;
  807. R1 = 8.314 ;
  808. M = 28.0134 * 1.e-3 ;
  809. r = R1/M ;
  810.  
  811. **Conductivite AZOTE
  812. pres = prog 0.1 1. 2. ;
  813. temp = prog 200. 250. 300. 350. 400. 450. 500. 600. 700. 800. 1000. ;
  814. ld_01 = prog 18.6 22.5 26.1 29.4 32.7 35.8 38.9 44.8 50.7 56.4 67.6 ;
  815. ld_1 = prog 19.2 23.4 26.9 30.1 33.3 36.4 39.4 45.3 51.1 56.8 67.9 ;
  816. ld_2 = prog 19.9 23.4 26.9 30.1 33.3 36.4 39.4 45.3 51.1 56.8 67.9 ;
  817.  
  818. nb1 = 11 ;
  819. ld_05 = prog ;
  820.  
  821. REPETER bouc1 nb1 ;
  822. ldb_01 = EXTR ld_01 &bouc1 ;
  823. ldb_1 = EXTR ld_1 &bouc1 ;
  824. ldb_2 = EXTR ld_2 &bouc1 ;
  825. ld_T = prog ldb_01 ldb_1 ldb_2 ;
  826. ldb_05 = IPOL P_MPa pres ld_T ;
  827. ld_05 = ld_05 ET (prog ldb_05) ;
  828. FIN bouc1 ;
  829.  
  830. ld_05 = ld_05 * 1e-3 ;
  831.  
  832. **Resultats :
  833. SI (EXISTE TS) ;
  834. rho = P / (r*TS) ;
  835. ld_CH = IPOL TS temp ld_05 ;
  836. FINSI ;
  837.  
  838. SI (EXISTE T) ;
  839. rho = KOPS P / (KOPS r * T) ;
  840. ld_CH = IPOL T temp ld_05 ;
  841. FINSI ;
  842.  
  843. RESPROC rho ld_CH ;
  844.  
  845. FINPROC ;
  846.  
  847.  
  848.  
  849. ************************************************************************
  850. * NOM : PRPEAU
  851. *-----------------------------------------------------------------------
  852. * Proprietes thermiques de l'eau a 150 bars
  853. *-----------------------------------------------------------------------
  854. * Input : PTOT : pression en Pa ou en bars
  855. * T ou TS : temperature sous forme de CHPOINT ou LISTREEL ou
  856. * FLOTTANT (en K)
  857. *
  858. * Output : RHOEAU : densite de l helium (USI) de meme type que T ou TS
  859. * MUEAU : viscosite
  860. * LEAU : conductivite thermique
  861. * CPEAU : capacite calorifique a pression constante
  862. *-----------------------------------------------------------------------
  863. 'DEBPROC' PRPEAU prt7*'LISTREEL' roo*'LISTREEL' muo*'LISTREEL'
  864. cpo*'LISTREEL' lambo*'LISTREEL' T/'CHPOINT'
  865. TL/'LISTREEL' TS/'FLOTTANT' ;
  866.  
  867. 'SI' ('EXISTE' T) ;
  868. rhoeau = 'IPOL' T prt7 roo ;
  869. mueau = 'IPOL' T prt7 muo ;
  870. leau = 'IPOL' T prt7 lambo ;
  871. cpeau = 'IPOL' T prt7 cpo ;
  872. 'RESPRO' rhoeau mueau leau cpeau ;
  873. 'FINSI' ;
  874. 'SI' ('EXISTE' TL) ;
  875. rhoeau = 'IPOL' TL prt7 roo ;
  876. mueau = 'IPOL' TL prt7 muo ;
  877. leau = 'IPOL' TL prt7 lambo ;
  878. cpeau = 'IPOL' TL prt7 cpo ;
  879. 'RESPRO' rhoeau mueau leau cpeau ;
  880. 'FINSI' ;
  881. 'SI' ('EXISTE' TS) ;
  882. rhoeau = 'IPOL' TS prt7 roo ;
  883. mueau = 'IPOL' TS prt7 muo ;
  884. leau = 'IPOL' TS prt7 lambo ;
  885. cpeau = 'IPOL' TS prt7 cpo ;
  886. 'RESPRO' rhoeau mueau leau cpeau ;
  887. 'FINSI' ;
  888. *tc mise en commentaire du finsi ci dessous
  889. *'FINSI';
  890. *
  891. * End of procedure file PRPEAU
  892. *
  893. 'FINPROC' ;
  894.  
  895.  
  896.  
  897. 'DEBPROC' PRPZIRC T/'CHPOINT' TL/'LISTREEL' TS/'FLOTTANT' ;
  898.  
  899. * Permet de donner la conductivite thermique du Zircaloy 4
  900. * et la masse volumique.
  901. * rho20 : masse volumique du zirconium a 20 degres C
  902. * dil20 : coefficient de dilatation lineique
  903. * Domaine de validite :| 0 a 1200 degres C pour la conductivite
  904. * | 20 a 700 degres C pour la masse volumique
  905. *
  906. * X.2. Arguments d'entree et de sortie
  907. * Input = T : temperature sous forme de CHPOINT ou FLOTTANT (en K)
  908. * Output = LZIRC : conductivite thermique du Zircalloy (W.m-1.K-1)
  909. * RHOZIRC : masse volumique (kg/m3)
  910.  
  911. * X.3. Ecriture ==> voir isa4reb.procedur
  912.  
  913. ***Pour la conductivite
  914. prt = 'PROG' 273.15 'PAS' 100. 'NPAS' 12 ;
  915. prk_zy4 = PROG 12.650 13.478 14.443 15.545 16.784 18.160
  916. 19.673 21.324 23.111 25.036 27.098 29.297 31.633 ;
  917. ***Pour la masse volumique
  918. rho20 = 6550. ;
  919. dil20 = 6.e-6 ;
  920. T20 = 293. ;
  921.  
  922. ***
  923. 'SI' ('EXISTE' T) ;
  924. lzirc = 'IPOL' T prt prk_zy4 ;
  925. DT = T - T20 ;
  926. rhozirc = KOPS rho20 / ((1. + (DT * dil20)) ** 3.) ;
  927. 'RESPRO' rhozirc lzirc ;
  928. 'FINSI' ;
  929. 'SI' ('EXISTE' TL) ;
  930. lzirc = 'IPOL' TL prt prk_zy4 ;
  931. DT = TL - T20 ;
  932. rhozirc = rho20 / ((1. + (DT * dil20)) ** 3.) ;
  933. 'RESPRO' rhozirc lzirc ;
  934. 'FINSI' ;
  935. 'SI' ('EXISTE' TS) ;
  936. lzirc = 'IPOL' TS prt prk_zy4 ;
  937. DT = TS - T20 ;
  938. rhozirc = rho20 / ((1. + (DT * dil20)) ** 3.) ;
  939. 'RESPRO' rhozirc lzirc ;
  940. 'FINSI' ;
  941. *'FINSI' ;
  942. 'FINPROC' ;
  943.  
  944.  
  945.  
  946. ************************************************************************
  947. * NOM : TRACCHPO
  948. * DESCRIPTION : Trace d'un chpoint avec titre optionnel.
  949. *
  950. *
  951. *
  952. * LANGAGE : GIBIANE-CAST3M
  953. * AUTEUR : Stephane GOUNAND (CEA/DEN/DM2S/SFME/LTMF)
  954. * mel : gounand@semt2.smts.cea.fr
  955. **********************************************************************
  956. * VERSION : v1, 14/10/2002, version initiale
  957. * HISTORIQUE : v1, 14/10/2002, creation
  958. * HISTORIQUE :
  959. * HISTORIQUE :
  960. ************************************************************************
  961. * Priere de PRENDRE LE TEMPS de completer les commentaires
  962. * en cas de modification de ce sous-programme afin de faciliter
  963. * la maintenance !
  964. ************************************************************************
  965. *
  966. *
  967. 'DEBPROC' TRACCHPO ;
  968. 'ARGUMENT' pn*'CHPOINT ' ;
  969. 'ARGUMENT' mt*'MAILLAGE' ;
  970. 'ARGUMENT' mt2/'MAILLAGE' ;
  971. 'ARGUMENT' oeil/'POINT ' ;
  972. 'ARGUMENT' tit/'MOT ' ;
  973. 'SI' ('EXISTE' tit) ;
  974. titpn = 'CHAINE' 'FORMAT' formflot tit titglob ;
  975. 'SINON' ;
  976. titpn = 'CHAINE' 'FORMAT' formflot titglob ;
  977. 'FINSI' ;
  978. rescal = pn ;
  979. 'SI' ('NON' ('EXISTE' mt2)) ;
  980. mt2 = mt ;
  981. 'FINSI' ;
  982. 'SI' ('EXISTE' oeil) ;
  983. 'TRACER' 'CACH' oeil rescal mt mt2 'TITR' titpn nbisov ;
  984. 'SINON' ;
  985. 'TRACER' 'CACH' rescal mt mt2 'TITR' titpn nbisov ;
  986. 'FINSI' ;
  987. *
  988. * End of procedure file TRACCHPO
  989. *
  990. 'FINPROC' ;
  991.  
  992.  
  993. debproc rayon0 m*maillage ;
  994. x = coor 1 m ;
  995. y = coor 2 m ;
  996. r = ((x * x ) + ( y * y )) ** 0.5 ;
  997. finproc r ;
  998.  
  999.  
  1000. DEBPROC VOLUJU sfluc*'MAILLAGE' sfluf*'MAILLAGE'
  1001. licb*'MAILLAGE' lecb*'MAILLAGE' scb*'MAILLAGE'
  1002. lipa*'MAILLAGE' lepa*'MAILLAGE' spa*'MAILLAGE'
  1003. lipe*'MAILLAGE' lepe*'MAILLAGE' spe*'MAILLAGE'
  1004. litf*'MAILLAGE' letf*'MAILLAGE' stf*'MAILLAGE'
  1005. zn*'FLOTTANT' zn1*'FLOTTANT' nmail*'ENTIER'
  1006. tabcb*'TABLE' tabpa*'TABLE' tabpe*'TABLE' tabtf*'TABLE'
  1007. tabfluc*'TABLE' tabfluf*'TABLE' itab*'ENTIER' ;
  1008.  
  1009. ** Description :
  1010. ** ***********
  1011. * Procedure permettant de construire les maillages (volume) de chaque
  1012. * partie axiale du dispositif ainsi que les tables de connectivite
  1013. * entre fluide et solides.
  1014. * Les volumes 3D sont extrudees a partir des surfaces et des lignes 2D
  1015. * perpendiculaires a l'axe z.
  1016. *
  1017. * sfluc : surface du fluide chaud
  1018. * sfluf : surface du fluide froid
  1019. * licb : ligne inteieure du crayon chauffant
  1020. * lecb : ligne exteieure du crayon chauffant
  1021. * scb : surface du crayon chauffant
  1022. * lipa lepa spa : lignes interieure, exterieure et surface du panier
  1023. * lipe lepe spe : lignes interieure, exterieure et surface du PE
  1024. * litf letf stf : lignes interieure, exterieure et surface du tdf interne
  1025. * zn : cote axiale de la delimitation en amont de la partie construite
  1026. * zn1(n+1) : cote axiale de la delimitation en aval de la partie construite
  1027. * nmail : nombre de maille de la tranche construite
  1028. * tabX : tables de connectivite contenant les elements de surface
  1029. * solides et de volume fluides.
  1030. * itab : indice des tables
  1031. *
  1032.  
  1033.  
  1034. *** A. Objet utiles :
  1035. hnh = (zn1 - zn) / ('FLOTTANT' nmail) ;
  1036. vechau = 0. 0. hnh ;
  1037.  
  1038. *** B. Definition des elements pour une hauteur elementaire
  1039. mtfluc0 = 'VOLUME' sfluc 1 'TRAN' vechau ;
  1040. mticb0 = 'TRANSLATION' licb 1 vechau ;
  1041. mtecb0 = 'TRANSLATION' lecb 1 vechau ;
  1042. mtcb0 = 'VOLUME' scb 1 'TRAN' vechau ;
  1043. mtipa0 = 'TRANSLATION' lipa 1 vechau ;
  1044. mtepa0 = 'TRANSLATION' lepa 1 vechau ;
  1045. mtpa0 = 'VOLUME' spa 1 'TRAN' vechau ;
  1046.  
  1047. mtfluf0 = 'VOLUME' sfluf 1 'TRAN' vechau ;
  1048. mtipe0 = 'TRANSLATION' lipe 1 vechau ;
  1049. mtepe0 = 'TRANSLATION' lepe 1 vechau ;
  1050. mtpe0 = 'VOLUME' spe 1 'TRAN' vechau ;
  1051. mtitf0 = 'TRANSLATION' litf 1 vechau ;
  1052. mtetf0 = 'TRANSLATION' letf 1 vechau ;
  1053. mttf0 = 'VOLUME' stf 1 'TRAN' vechau ;
  1054.  
  1055.  
  1056. *** C. Initialisation du maillage :
  1057. mtfluc = mtfluc0 ;
  1058. mticb = mticb0 ;
  1059. mtecb = mtecb0 ;
  1060. mtcb = mtcb0 ;
  1061. mtipa = mtipa0 ;
  1062. mtepa = mtepa0 ;
  1063. mtpa = mtpa0 ;
  1064. mtfluf = mtfluf0 ;
  1065. mtipe = mtipe0 ;
  1066. mtepe = mtepe0 ;
  1067. mtpe = mtpe0 ;
  1068. mtitf = mtitf0 ;
  1069. mtetf = mtetf0 ;
  1070. mttf = mttf0 ;
  1071.  
  1072. *** D. Ecriture des tables de correspondances :
  1073.  
  1074. ** 1ere maille :
  1075. nmtif1 = 'NBEL' mtipa ;
  1076. 'REPETER' imtif1 nmtif1 ;
  1077. lmtif1 = 'ELEM' mtecb &imtif1 ;
  1078. lmtif3 = 'ELEM' mtipa &imtif1 ;
  1079. lmtif5 = 'ELEM' mtepe &imtif1 ;
  1080. lmtif7 = 'ELEM' mtitf &imtif1 ;
  1081. tabcb . itab = lmtif1 ;
  1082. tabpa . itab = lmtif3 ;
  1083. tabfluc . itab = mtfluc ;
  1084. tabpe . itab = lmtif5 ;
  1085. tabtf . itab = lmtif7 ;
  1086. tabfluf . itab = mtfluf ;
  1087. itab = '+' itab 1 ;
  1088. 'FIN' imtif1 ;
  1089.  
  1090.  
  1091. SI (nmail NEG 1) ;
  1092.  
  1093. 'REPETER' ihaut ('-' nmail 1) ;
  1094. vectran = 0. 0. ('*' hnh ('FLOTTANT' &ihaut)) ;
  1095. mthe2 mtin2 mtif2 mtcb2 = PLUS mtfluc0 mticb0 mtecb0 mtcb0 vectran ;
  1096. mtin2_p mtif2_p mtcb2_p = PLUS mtipa0 mtepa0 mtpa0 vectran ;
  1097. mthe4 mtin4 mtif4 mtcb4 = PLUS mtfluf0 mtipe0 mtepe0 mtpe0 vectran ;
  1098. mtin4_p mtif4_p mtcb4_p = PLUS mtitf0 mtetf0 mttf0 vectran ;
  1099. nmtif2 = 'NBEL' mtif2_p ; comm changeju essai52 ;
  1100. 'REPETER' imtif2 nmtif2 ;
  1101. lmtif2 = 'ELEM' mtif2 &imtif2 ;
  1102. lmtif4 = 'ELEM' mtin2_p &imtif2 ;
  1103. lmtif6 = 'ELEM' mtif4 &imtif2 ;
  1104. lmtif8 = 'ELEM' mtin4_p &imtif2 ;
  1105. tabcb . itab = lmtif2 ;
  1106. tabpa . itab = lmtif4 ;
  1107. tabfluc . itab = mthe2 ;
  1108. tabpe . itab = lmtif6 ;
  1109. tabtf . itab = lmtif8 ;
  1110. tabfluf . itab = mthe4 ;
  1111. itab = '+' itab 1 ;
  1112. 'FIN' imtif2 ;
  1113. mtfluc = 'ET' mthe2 mtfluc ;
  1114. mticb = 'ET' mtin2 mticb ;
  1115. mtecb = 'ET' mtif2 mtecb ;
  1116. mtcb = 'ET' mtcb2 mtcb ;
  1117. mtipa = 'ET' mtin2_p mtipa ;
  1118. mtepa = 'ET' mtif2_p mtepa ;
  1119. mtpa = 'ET' mtcb2_p mtpa ;
  1120. mtfluf = 'ET' mthe4 mtfluf ;
  1121. mtipe = 'ET' mtin4 mtipe ;
  1122. mtepe = 'ET' mtif4 mtepe ;
  1123. mtpe = 'ET' mtcb4 mtpe ;
  1124. mtitf = 'ET' mtin4_p mtitf ;
  1125. mtetf = 'ET' mtif4_p mtetf ;
  1126. mttf = 'ET' mtcb4_p mttf ;
  1127.  
  1128. 'FIN' ihaut ;
  1129.  
  1130. FINSI ;
  1131.  
  1132. RESPRO mtfluc mtfluf
  1133. mticb mtecb mtcb
  1134. mtipa mtepa mtpa
  1135. mtipe mtepe mtpe
  1136. mtitf mtetf mttf
  1137. tabcb tabpa tabpe tabtf
  1138. tabfluc tabfluf itab ;
  1139.  
  1140. FINPRO ;
  1141.  
  1142.  
  1143. DEBPROC PLUSJU geo1*'MAILLAGE' ;
  1144. ** Description
  1145. ** ***********
  1146. *
  1147. * Procedure permettant de construire les maillages (lignes ou surfaces)
  1148. * a toutes les interfaces entre les parties axiales en utilisant la
  1149. * procedure 'PLUS' et la geometrie en z1:
  1150. *
  1151.  
  1152. geo2 = PLUS geo1 (0. 0. (z2 - z1)) ;
  1153. geo3 = PLUS geo1 (0. 0. (z3 - z1)) ;
  1154. geo4 = PLUS geo1 (0. 0. (z4 - z1)) ;
  1155. geo5 = PLUS geo1 (0. 0. (z5 - z1)) ;
  1156. geo6 = PLUS geo1 (0. 0. (z6 - z1)) ;
  1157. geo7 = PLUS geo1 (0. 0. (z7 - z1)) ;
  1158. geo8 = PLUS geo1 (0. 0. (z8 - z1)) ;
  1159. geo9 = PLUS geo1 (0. 0. (z9 - z1)) ;
  1160. geo10 = PLUS geo1 (0. 0. (z10 - z1)) ;
  1161. geo11 = PLUS geo1 (0. 0. (z11 -z1)) ;
  1162. geoM = PLUS geo1 (0. 0. (zM - z1)) ;
  1163.  
  1164. RESPRO geo2 geo3 geo4 geo5 geo6 geo7 geo8 geo9 geo10 geo11 geoM ;
  1165.  
  1166. FINPRO ;
  1167.  
  1168. debproc resex c*chpoint m*maillage ;
  1169. * Trace d'un sur les faces des tubes de force
  1170. * *******************************************
  1171.  
  1172. ttt = redu c m ;
  1173. mttt = extr ttt mail ;
  1174. x = prog ;
  1175. y = prog ;
  1176. z = prog ;
  1177. t = prog ;
  1178. z2 = prog ;
  1179. t2 = prog ;
  1180. n = nbno m ;
  1181. repe w n ;
  1182. pt = mttt 'POINT' &w ;
  1183. ptx = coor 1 pt ;
  1184. pty = coor 2 pt ;
  1185. ptz = coor 3 pt ;
  1186. x = x et (prog ptx );
  1187. y = y et (prog pty ) ;
  1188. z = z et (prog ptz ) ;
  1189. t9 = extr ttt scal pt ;
  1190. t = t et (prog t9 );
  1191. si ( et ( EGA pty 0. ) ( ptx > 0. )) ;
  1192. z2 = z2 et ( prog ptz ) ;
  1193. t2 = t2 et ( prog t9 ) ;
  1194. finsi ;
  1195. fin w ;
  1196. evtnew = ORDONNER (evol manu 'Z' z2 t2) ;
  1197. finpro evtnew ;
  1198.  
  1199.  
  1200.  
  1201.  
  1202.  
  1203. DEBPROC HNAT Ttdf*'CHPOINT' Teau*'FLOTTANT' long*'FLOTTANT' ;
  1204. * Procedure permettant de calculer le coefficient d'ehange naturel
  1205. * entre le tube de force externe et la piscine
  1206. * On utilise les formules suivantes :
  1207. * - Nu = h_nat*D/ld
  1208. * - Nu = 0.13(Gr*Pr)**(1/3)
  1209. * Nu : nombre de Nusselt
  1210. * long : longueur caracteristique de la convection naturelle
  1211. * ld : conductivite de l'eau
  1212. * Gr : nombre de Grashof
  1213. * Pr : nombre de Prandl
  1214. * Ra : nombre de Raileigh
  1215. * beteau : coefficient de dilatation thermique des liquides au environ
  1216. * de 300K
  1217. * g0 : gravite* h_nat : coefficient d'ehange de convection naturelle
  1218.  
  1219.  
  1220. *Donnes du probleme :
  1221. deltaT = Ttdf - Teau ;
  1222. cnat1 = 0.13 ;
  1223. cnat2 = 1. / 3. ;
  1224. beteau = 2.E-4 ;
  1225. g0 = 9.81 ;
  1226.  
  1227. *Proprietes de l'eau :
  1228. Tfilm = KOPS (Ttdf + Teau) / 2. ;
  1229. rhoeau mueau leau cpeau = PRPEAU prt ro_o mu_o cp_o lamb_o Tfilm ;
  1230. nueau = KOPS mueau / rhoeau ;
  1231.  
  1232. *Nombres adimensionnels :
  1233. Pr = KOPS (KOPS mueau * cpeau) / leau ;
  1234. Gr0 = g0 * beteau * ( long ** 3. ) ;
  1235. Gr = KOPS deltaT * (KOPS Gr0 / ( KOPS nueau ** 2. )) ;
  1236. Ra = KOPS Pr * Gr ;
  1237. Nu = KOPS cnat1 * ( KOPS Ra ** cnat2 ) ;
  1238.  
  1239. *Cacul du h_nat :
  1240. h_nat = KOPS Nu * (KOPS leau / long) ;
  1241.  
  1242. 'RESPRO' h_nat ;
  1243.  
  1244. FINPROC ;
  1245.  
  1246.  
  1247. DEBPROC GAMMA mat*'MOT' cotx1*'FLOTTANT' $solide*'MMODEL' ;
  1248. * Procedure permettant de donner le profil axial des sources internes.
  1249. * Les parametres sont :
  1250. * a. La composition du milieu
  1251. * b. La position du dispositif par rapport au caisson afin de
  1252. * deerminer l'echauffement au plan median.
  1253. * c. Ensuite on determine le profil de l'echauffement
  1254. *
  1255. * 2. Valeur des parametres d'entree :
  1256. * - "mat" deigne la nature du milieu. Il prend les valeurs :
  1257. * -> "eau" pour l'eau
  1258. * -> "alu" pour l'aluminium
  1259. * -> "zir" pour le zirconium
  1260. * -> "hel" pour l'heium
  1261. * -> "azo" pour l'azote
  1262. * - "cotx1" est la position du dispositif par rapport au caisson lors
  1263. * de l'experience
  1264. * - "$solide" est le modele dans lequel on calcule les sources internes dans les solides
  1265. *
  1266. * 3. Valeur des variables locales
  1267. * Eg0(x1) : sources internes au plan median a la cote x (W/g)
  1268. * c la radioprotection qui m'a donne les mesures
  1269. * x1 : position du chariot lue sur les reglages de la manip
  1270. * z1 : position verticale en mm
  1271. * z2 : position verticale utilise par castem correspondant a z1
  1272. * Egnom : Sources internes nominal
  1273. * Egmax : Sources internes au plan median a z=0m
  1274. * Egcoef2 : coefficient du profil Sources internes, c un champoint
  1275. * Egch : CHPOINT donnant l'echauffemnt dans chaque maille en W/g
  1276. * Eg_SI : CHPOINT donnant l'echauffemnt dans chaque maille en W/kg
  1277.  
  1278. **Definition du facteur de Fadile :
  1279. log1 = EGA mat eau ;
  1280. log2 = EGA mat alu ;
  1281. log3 = EGA mat zir ;
  1282. log4 = EGA mat hel ;
  1283. log5 = EGA mat azo ;
  1284.  
  1285. SI (log1 OU log2 OU log4 OU log5) ;
  1286. fad = 1. ;
  1287. FINSI ;
  1288. SI log3 ;
  1289. fad = 1.3 ;
  1290. FINSI ;
  1291.  
  1292. Eg0 = 2.1281 * (EXP(-0.0072 * (291. - cotx1))) ;
  1293.  
  1294.  
  1295. z1 = prog -870. -700. -550. -400 -250 -175 -140 -120. -100. -80. -60.
  1296. -40. -20. 0. 20. 40. 60. 80. 100. 120. 140. 175. 250. 400. 550. 700.
  1297. 860. ;
  1298. z1m = z1 * 1.e-3 ;
  1299. Egnom = prog 0. 0.065 0.13 0.25 0.675 0.84 0.861 0.895 0.925 0.948 0.97
  1300. 0.985 0.995 1. 0.995 0.985 0.97 0.948 0.925 0.895 0.861 0.84 0.675 0.25
  1301. 0.13 0.065 0. ;
  1302.  
  1303.  
  1304. *Changements et Interpolation :
  1305. Egcoef = Egnom * Egmax ;
  1306.  
  1307. d_soli = DOMA $solide 'MAILLAGE' ;
  1308. cotz1 = COOR 3 d_soli ; comm en m ;
  1309.  
  1310. Egcoef2 = IPOL cotz1 z1m Egcoef ; comm comparaison REFLET ;
  1311.  
  1312. **Final
  1313. Egch = KOPS (fad * Eg0) * Egcoef2 ;
  1314. Egch = NOEL $solide Egch ;
  1315. Eg_SI = Egch * 1.e3 ;
  1316.  
  1317. RESPRO Eg_SI ;
  1318.  
  1319. FINPROC ;
  1320. ************************************************************************
  1321.  
  1322.  
  1323.  
  1324.  
  1325. DEBPROC FLUXNS choix*'ENTIER' lambda*'CHPOINT' T*'CHPOINT'
  1326. $surface*'MMODEL' $solide*'MMODEL' ;
  1327. **Procedure permettant de :
  1328. ** - calculer la puissance totale traversant une interface
  1329. ** - construire un chpoint du flux (W/m2) sur cet interface
  1330. ** - choisir entre trois procedures ressemblantes
  1331. **On procede par :
  1332. ** - construction du flux avec loi de Fourrier
  1333. ** - integration sur la surface orientee par la normale sortante
  1334.  
  1335. * T est la variable temperature de la matiere du modele NS
  1336. * lambda = conductivite apparaissant dans l'equation, en argument
  1337. * d'entree de la procedure :
  1338. * gaine : rvcb . inco . 'LCB'
  1339. * panier : rvcb . inco . 'LCB_p'
  1340. * tube force interne : rvcb . inco . 'LCB_tfi'
  1341. * tube force externe : rvcb . inco . 'LCB_tfe'
  1342. * gaz : rvcb . inco . 'LCB_gaz'
  1343. * RQ : lambda doit etre un CHPOINT scal centre !!!!!!!!!!
  1344. *
  1345. * solide = maillage du solide
  1346. * surface = maillage de la frontiere du solide sur laquelle
  1347. * on veut calculer le flux (Watt)
  1348. * $solide et $surface modeles s'appuyant sur ces maillages
  1349.  
  1350. **Construction des maillages a partir des modeles
  1351. d_soli = DOMA $solide 'MAILLAGE' ;
  1352. d_surf = DOMA $surface 'MAILLAGE' ;
  1353.  
  1354. SI (choix EGA 1) ;
  1355.  
  1356. * Definition des champoints utiles a la resolution
  1357. X Y Z = COOR d_soli ;
  1358. R = KOPS ( KOPS X * X ) + ( KOPS Y * Y ) ;
  1359. R = KOPS R ** 0.5 ;
  1360. lambda = ELNO $solide lambda;
  1361.  
  1362. * Construction du flux
  1363. Grad_T = KOPS T 'GRADS' $solide ;
  1364. Sn_Pmail = doma $surface 'XXDIAGSI' ;
  1365. * Selon X
  1366. Grad_Tx = exco Grad_T Ux ;
  1367. Flux = KOPS Grad_Tx '*' (-1. * lambda) ;
  1368. Fluxr = KOPS Flux * ( KOPS X / R) ;
  1369. Fluxr = REDU Fluxr d_surf ;
  1370. * Selon Y
  1371. Grad_Ty = exco Grad_T Uy ;
  1372. Fluy = KOPS Grad_Ty '*' (-1. * lambda) ;
  1373. Fluyr = KOPS Fluy * ( Y / R) ;
  1374. Fluyr = REDU Fluyr d_surf ;
  1375.  
  1376. * Resultats :
  1377. FluR = KOPS Fluxr + Fluyr ;
  1378. Wunit = KOPS FluR * Sn_Pmail ;
  1379. Wtot = SOMT Wunit ;
  1380.  
  1381. FINSI ;
  1382.  
  1383.  
  1384. SI (choix EGA 2) ;
  1385.  
  1386. * Definition des champoints utiles a la resolution :
  1387. lambda = ELNO $solide lambda; comm a evaluer en direct ;
  1388. lambda = REDU d_surf lambda ;
  1389. Mot1 = MOTS 'UX' 'UY' ;
  1390. Sn_mail = DOMA $surface 'VOLUME' ;
  1391.  
  1392. * Normale a la paroi :
  1393. Norm0 = DOMA $solide 'NORMALEV' ;
  1394. Norm1 = KCHT $surface VECT SOMMET Norm0 ;
  1395.  
  1396. * Construction du flux :
  1397. Grad_T = KOPS T 'GRADS' $solide ;
  1398. Grad_TS = KCHT $surface VECT SOMMET Grad_T ;
  1399. Grad_TR = PSCA Grad_TS Norm1 Mot1 Mot1 ;
  1400. FluR = KOPS Grad_TR '*' (-1. * lambda) ;
  1401. FluR = NOEL $surface FluR ;
  1402.  
  1403. * Resultats :
  1404. Wunit = KOPS FluR * Sn_mail ;
  1405. Wtot = SOMT Wunit;
  1406.  
  1407. FINSI ;
  1408.  
  1409. SI (choix EGA 3) ;
  1410.  
  1411.  
  1412. * Definition des champoints utiles a la resolution
  1413. n_surf = DOMA $surface 'MAILLAGE' ;
  1414. lambda = ELNO $solide lambda ;
  1415. lambda = REDU d_surf lambda ;
  1416. lambda = NOEL $surface lambda ;
  1417. SS1 = 'DOMA' $surface 'VOLUME' ;
  1418.  
  1419. * Construction du flux :
  1420. GRADC0 = 'KOPS' T 'GRAD' $solide ;
  1421. GRADS0 = 'ELNO' $solide GRADC0 ;
  1422. GS0 = 'KCHT' $surface 'VECT' 'SOMMET' GRADS0 ;
  1423. GC0 = 'NOEL' $surface GS0 ;
  1424. NORM1 = 'DOMA' $solide 'NORMALEV' ;
  1425. NCOTE = 'KCHT' $surface 'VECT' 'SOMMET' NORM1 ;
  1426. NCOTE = 'NOEL' $surface NCOTE ;
  1427. MOT1 = 'MOTS' 'UX' 'UY' ;
  1428.  
  1429. FLUX = 'PSCA' GC0 NCOTE MOT1 MOT1 ;
  1430.  
  1431. FLUX = KOPS FLUX * lambda ;
  1432. FluR = KOPS (-1.) * FLUX ;
  1433.  
  1434.  
  1435. * Resultats :
  1436. Wunit = KOPS FluR * SS1 ;
  1437. Wtot = SOMT Wunit ;
  1438.  
  1439. FINSI ;
  1440.  
  1441. FINPROC Wtot Wunit FluR;
  1442.  
  1443.  
  1444.  
  1445. 'DEBPROC' chpobor mess1/'MOT' T*'CHPOINT' ;
  1446. *Elle permet d'afficher les valeurs minimales et maximales d'un
  1447. *champoint avec message optionnel
  1448.  
  1449. SI ( EXISTE mess1 ) ;
  1450. mess mess1 ' : ' ( MINI T ) ( MAXI T) ;
  1451. SINON ;
  1452. mess ( MINI T ) ( MAXI T) ;
  1453. FINSI ;
  1454. FINPROC ;
  1455.  
  1456. ** IV.tcpu9
  1457. DEBPROC tcpu9 ;
  1458. TABTPS = TEMP 'NOEC';
  1459. tcpu = TABTPS.'TEMPS_CPU'.'INITIAL';
  1460. tcpus = '/' ('FLOTTANT' tcpu) 100.D0 ;
  1461. 'MESSAGE' ('CHAINE' 'tcpus=' tcpus) ;
  1462. FINPROC ;
  1463.  
  1464. 'DEBP' FRAY ;
  1465. 'ARGU' RVX*'TABLE' ;
  1466.  
  1467. *OPERATEUR DE RAYONNEMENT
  1468.  
  1469. RV = RVX.'EQEX' ;
  1470. * recuperation du champ de temperature
  1471. T = RV.INCO.'TCB' ;
  1472. * recuperation de la table TABR associee a l'operateur
  1473. TABR = RVX.'ARG1' ;
  1474. MAILR = TABR.'MAILLAGE' ;
  1475. * TSU : temperature de surface
  1476. TSU = 'REDU' T MAILR ;
  1477. TSU = 'EXCO' TSU 'SCAL' 'T' ;
  1478. TR = 'CHAN' 'CHAM' TSU TABR.'MODELE' 'GRAVITE' ;
  1479. * MRS : matrice de rayonnement
  1480. MRS = 'RAYN' TABR.'MODELE' TABR.'MATRICE' TR ;
  1481. MAILR = 'DOMA' TABR.'MODELENS' 'SOMMET' ;
  1482. * MRS : transformation Rigidite/Matrik
  1483. MRS = 'KOPS' 'RIMA' MRS MAILR ('MOTS' 'TCB') ;
  1484.  
  1485. AS AF = 'KOPS' 'MATRIK' ;
  1486. 'FINP' AS MRS ;
  1487.  
  1488.  
  1489.  
  1490.  
  1491.  
  1492. 'DEBPROC' COEFLU ma*'MAILLAGE' lch/'ENTIER' ;
  1493. * Procedure permettant de determiner les coefficients de flux lorsqu'on
  1494. * choisit d'etre a puissance lineique variable selon l'axe.
  1495.  
  1496. si ( non ( exis lch ) ) ;
  1497. cote1 = prog -700. -180.1
  1498. -180.00 -162.86 -145.71 -128.57 -111.43 -94.29 -77.14
  1499. -60.00 -42.86 -25.71 -8.57 8.57 25.71 42.86
  1500. 60.00 77.14 94.29 111.43 128.57 145.71 162.86 180.00
  1501. 180.1 850. ;
  1502.  
  1503. rapP1 = prog 1.e-8 1.e-8
  1504. 0.864 0.897 0.935 0.955 0.973 0.989 0.997
  1505. 1.000 0.999 0.995 0.990 0.975 0.969 0.960
  1506. 0.946 0.932 0.910 0.880 0.850 0.823 0.777 0.744
  1507. 1.e-8 1.e-8 ;
  1508. sinon ;
  1509.  
  1510. cote1 = prog -700. -250.1
  1511. -250.00 -226.19 -202.38 -178.57 -154.76 -130.95
  1512. -107.14 -83.33 -59.52 -35.71 -11.90 11.90 35.71
  1513. 59.52 83.33 107.14 130.95 154.76 178.57 202.38
  1514. 226.19 250.00 250.1 850. ;
  1515. rapP1 = prog 1.e-8 1.e-8
  1516. 0.722 0.747 0.812 0.867 0.914 0.952 0.977
  1517. 0.996 1.000 0.997 0.992 0.972 0.966 0.947 0.924
  1518. 0.888 0.847 0.801 0.748 0.689 0.622 0.548
  1519. 1.e-8 1.e-8 ;
  1520.  
  1521.  
  1522. finsi ;
  1523. *Changement d'unite : on passe en metre
  1524. cote3 = cote1 * 1e-3 ;
  1525.  
  1526.  
  1527. ** yyv1 est un CHAMPOINT representant le profil de flux
  1528. xv1 = ( COOR 3 ma ) ;
  1529. yyv1 = IPOL xv1 cote3 rapP1 ;
  1530.  
  1531. 'RESPRO' yyv1 ;
  1532. 'FINPROC' ;
  1533.  
  1534.  
  1535. DEBPROC EBULL ;
  1536. * Procedure permettant de determiner si il y a ou non ebullition locale
  1537. * sur la gaine du crayon chauffant. Si oui, cette procedure donne
  1538. * numeriquement et graphiquement la zone exacte ou apparait l'ebullition
  1539. * nuclee.
  1540. * Les reultats obtenues dependent fortement du maillage, en particulier
  1541. * du nombre de maille selon z : nhaut.
  1542. * On procede de la maniere suivante
  1543. * - Determination de la temperature de paroi a saturation :
  1544. * a l'aide de la formule de Jens et Lottes
  1545. * - Determination des coefficiant indiquant la zone d'ebullition :
  1546. * c_mono : coefficient d'echange monophasique =| 0 si ebullition nuclee
  1547. * | 1 sinon
  1548. * c_di : coefficient d'echange diphasique =| 1 si ebullition nuclee
  1549. * | 0 sinon
  1550. * - Determination de la cote d'ebullition
  1551. * ebull1 =| VRAI si il y a ebullition
  1552. * | FAUX si on reste en monophasique
  1553. *
  1554. * L'indice "_N" deigne le champoint correspondant aux noeuds du
  1555. * maillage
  1556.  
  1557. ***Remise a niveau de f0 ;
  1558. cf0 = f0 MASQ 'SUPERIEUR' 0. ;
  1559. f0 = KOPS f0 * cf0 ;
  1560. ***Determination de la temperature de paroi a saturation :
  1561. Volif = DOMA $mtif 'VOLUME' ;
  1562. phi0 = KOPS f0 / Volif;
  1563. phi0 = 1.e-4 * phi0 ;
  1564.  
  1565. expo1 = EXP ( -1. * PsatB / 62.) ;
  1566. DTsat = 7.91 * expo1 *(phi0 ** 0.25) ;
  1567. Tpsat = Tsat + DTsat ;
  1568. DTsat_N = ELNO $mtif DTsat ; comm modif essai14 ;
  1569. Tpsat_N = Tsat + DTsat_N ; comm modif essai14 ;
  1570.  
  1571. ***Determination des coeff indiquant la zone d'ebullition
  1572. Tparoi = NOEL $mtif (rvi . 'TCB') ;
  1573. c_mono = Tparoi MASQ 'INFERIEUR' Tpsat ;
  1574. c_diph = Tparoi MASQ 'SUPERIEUR' Tpsat ;
  1575. c_app = Tparoi MASQ 'SUPERIEUR' 'SOMME' Tpsat ;
  1576.  
  1577. Tparoi_N = REDU (rvi . 'TCB') mtif ; comm modif essai14 ;
  1578. c_mono_N = Tparoi_N MASQ 'INFERIEUR' Tpsat_N ; comm modif essai14 ;
  1579. c_diph_N = Tparoi_N MASQ 'SUPERIEUR' Tpsat_N ; comm modif essai14 ;
  1580.  
  1581. SI (c_app EGA 0) ;
  1582. ebulli = FAUX ;
  1583. RESPRO ebulli c_mono c_diph c_mono_N c_diph_N ;
  1584.  
  1585. SINON ;
  1586. ebulli = VRAI ;
  1587. ***Determination de la cote d'ebullition
  1588.  
  1589. * 1. Numeriquement :
  1590. Z = COOR 3 mtif ;
  1591. Zeb = Z * c_diph_N ; comm modif essai14 ;
  1592. mtif_pt = CHAN POI1 mtif ;
  1593. nbno1 = nbno mtif ;
  1594. listZeb = prog ;
  1595.  
  1596. 'REPETER' boucju nbno1 ;
  1597. pt1 = mtif_pt point &boucju ;
  1598. valZeb = extr Zeb 'SCAL' pt1 ;
  1599. SI (valZeb > 0) ;
  1600. listZeb = listZeb ET (prog valZeb) ;
  1601. FINSI ;
  1602. FIN boucju ;
  1603.  
  1604. ZebMin = MINI listZeb ;
  1605. ZebMax = MAXI listZeb ;
  1606. MESS 'ebullition nuclee apparait entre :' ZebMin 'et' ZebMax 'm' ;
  1607.  
  1608. ***Hauteur des mailles dans les differentes parties :
  1609. hautmA = (z2 - z1) / nhautA ;
  1610. hautmB = (z3 - z2) / nhautB ;
  1611. hautmC = (z4 - z3) / nhautC ;
  1612. hautmD = (z5 - z4) / nhautD ;
  1613. hautmE = (zM - z5) / nhautE ;
  1614.  
  1615. Mess 'taille d une maille partie A' hautmA ;
  1616. Mess 'taille d une maille partie B' hautmB ;
  1617. Mess 'taille d une maille partie C' hautmC ;
  1618. Mess 'taille d une maille partie D' hautmD ;
  1619. Mess 'taille d une maille partie E' hautmE ;
  1620.  
  1621. * 2. Graphiquement
  1622. * Evc_diph = EVOL ROUG CHPO c_diph_N ligif; comm modif essai14 ;
  1623. * DESS Evc_diph 'TITR' 'Zone ebullition nuclee' 'TITX' 'Hauteur' ;
  1624.  
  1625. RESPRO ebulli c_mono c_diph c_mono_N c_diph_N ;
  1626. FINSI ;
  1627. FINPROC ;
  1628.  
  1629. ************************************************************************
  1630. **************************FIN DES PROCEDURES****************************
  1631. ************************************************************************
  1632. *opti debu 1;
  1633.  
  1634.  
  1635.  
  1636. discr = 'LINE' ;
  1637.  
  1638. ***graffic = vrai ; comm trace fichier ;
  1639. graffic = faux ; comm trace ecran ;
  1640.  
  1641. interact = VRAI ;
  1642. interact = faux ; comm execution sans arret ;
  1643.  
  1644. rayo = VRAI ;
  1645.  
  1646. egasol = VRAI ;
  1647. egaliq = VRAI ;
  1648.  
  1649. verbose = VRAI ;
  1650. precis = VRAI ;
  1651.  
  1652. complet = vrai ;
  1653. complet = faux ;
  1654.  
  1655. si ( non complet ) ;
  1656. rayo = faux ;
  1657. finsi ;
  1658.  
  1659.  
  1660. si interact ;
  1661. graph = vrai ;
  1662. sinon ;
  1663. graph = faux ;
  1664. finsi ;
  1665. * graph = vrai ; opti 'TRAC' 'PSC' 'EPTR' 6 'POTR' 'HELVETICA_16';
  1666.  
  1667. graph0 = graph;
  1668. graffic0 = graffic ;
  1669. interac0 = interact ;
  1670. rayo0 = rayo ;
  1671. egasol0 = egasol ;
  1672. egaliq0 = egaliq ;
  1673.  
  1674. verbose0 = verbose ;
  1675. precis0 = precis ;
  1676. comple0 = complet ;
  1677.  
  1678.  
  1679. ** II.Parametres geometriques et numeriques
  1680. * II.1.Description
  1681. *
  1682. * nb_bouc : nombre maximal d'iterations de la boucle
  1683. * ne : nombre de maille selon r
  1684. * np : nombre de maiile selon theta
  1685. *
  1686. * prhe : pression de l'helium dans la cavite du tube de force, en bars
  1687. * qmhe : debit massique des fluides chaud et froid, en kg/s
  1688. * theec : |temperature, en Celsius,|d'entree du fluide chaud
  1689. * |de sortie du fluide froid
  1690. * |imposee en realite par les systemes de regulation d'ISA1
  1691. * tpisci : temperature de la piscine, en Celsius
  1692. * plin1 : |puissance lineique delivree par le crayon chauffant
  1693. * |en W.cm-1
  1694. * PsatB : pression constante des fluides et donc de saturation, en Bars
  1695. * CK : permet de passer des degre Celsius en Kelvin.
  1696. * posix : position du dispositif par rapport au caisson
  1697. * : valeur que l'on lit, sur les ecrans de controle de la manip
  1698. * ISA1, en mm
  1699.  
  1700.  
  1701. * II.2.Valeurs
  1702. nb_bouc = 40 ;
  1703. SI rayo ;
  1704. ne = 3 ;
  1705. np = 22 ; comm suffisamment grands sinon rayo marche pas ;
  1706. nral = 10 ; comm discretisation radiale des rallonges ;
  1707. SINON ;
  1708. ne = 3 ;
  1709. np = 10;
  1710. nral = 10 ; comm discretisation radiale des rallonges ;
  1711. FINSI ;
  1712.  
  1713. * Loi de convection forcee
  1714. A_colb = 0.023 ;
  1715. B_colb = 0.8D0 ;
  1716. C_colb = ('/' 1.D0 3.D0) ;
  1717.  
  1718. prhe = 5.D0 ;
  1719.  
  1720. **Donnees variables du calcul
  1721. **--------------------------
  1722.  
  1723. qmhe = 0.1956 ;
  1724. theec = 252. ;
  1725. tpisci = 40. ;
  1726. plin1 = 480. ;
  1727. PsatB = 146.4 ;
  1728. Posix = 198. ;
  1729. Egmax = 1.089 ;
  1730. ***Coefficient echange externe piscine
  1731. ***valeur positive�: coeff constant sur la hauteur
  1732. ***valeur negative�: convection naturelle et calcul auto
  1733. Hcnczt = -1000. ;
  1734. diamex0 = 9.5D-3 ;
  1735. epai0 = 1.D-3 ;
  1736.  
  1737. lat00 = 1045713.55 ; comm pression au dela des tables Cast3M ;
  1738.  
  1739. mess 'valeurs lues : ' ;
  1740. mess num0 qmhe theec plin1 Egmax
  1741. posix psatb diamex0 epai0 hcnczt ;
  1742.  
  1743. si ( hcnczt &lt;EG 0 ) ;
  1744. varcna = vrai ;
  1745. sinon ;
  1746. varcna = faux ;
  1747. hcncst = hcnczt ;
  1748. finsi ;
  1749.  
  1750. SI varcna ;
  1751. mess 'Convection naturelle avec la piscine' ;
  1752. SINON ;
  1753. mess 'Echange constant avec la piscine : ' hcncst ' W/m2.K' ;
  1754. FINSI ;
  1755.  
  1756. varcna0 = varcna ;
  1757. hcncst0 = hcncst ;
  1758.  
  1759. ppa = PsatB * 1.e5 ; comm pression en Pascal ;
  1760. CK = 273.15 ;
  1761.  
  1762.  
  1763. prhe0 = prhe ;
  1764. qmhe0 = qmhe ;
  1765. theec0 = theec ;
  1766. theeK0 = theeK ;
  1767. tpisci0 = tpisci ;
  1768. plin10 = plin1 ;
  1769. psatb0 = psatb ;
  1770. ppa0 = ppa ;
  1771. posix0 = posix ;
  1772. Egmax0 = Egmax ;
  1773.  
  1774. choiju = 2 ; comm choix de la procedure calculant les flux ;
  1775.  
  1776. * PARAMETRAGE
  1777. ************************************************************************
  1778. 'TEMPS' 'ZERO' ;
  1779. 'OPTION' 'DIME' 3 ;
  1780. 'OPTION' 'ISOV' 'SULI' ;
  1781. nbisov = 15 ;
  1782. si graffic ;
  1783. 'OPTION' 'TRAC' 'PSC' ;
  1784. * 'OPTION' 'ECHO' 0 ;
  1785. 'SINON' ;
  1786. 'OPTION' 'TRAC' 'X' ;
  1787. 'FINSI' ;
  1788.  
  1789. titglob = 'CHAINE' ' Isabelle1' ;
  1790.  
  1791. **ESSAI30:**
  1792. 'SI' ('EGA' discr 'LINE') ;
  1793. 'OPTION' 'DIME' 3 'ELEM' 'CUB8' ;
  1794. 'SINON' ;
  1795. 'OPTION' 'DIME' 3 'ELEM' 'CU20' ;
  1796. 'FINSI' ;
  1797. **
  1798.  
  1799. ************************************************************************
  1800.  
  1801.  
  1802. * MAILLAGE
  1803. ************************************************************************
  1804. ** I.Geometrie
  1805. * I.1.Parametres initiaux
  1806. *
  1807. * I.1.1.Description
  1808. *
  1809. * partie A => rallonge infeieure, entre z1 et z2 ;
  1810. * partie B => bouchon infeieur , entre z2 et z3 ;
  1811. * partie C => crayon , entre z3 et z4 ;
  1812. * partie D => bouchon supeieur , entre z4 et z5 ;
  1813. * partie E => rallonge superieure, entre z5 et z6 ;
  1814. * partie F => changement section tdf ext, entre z6 et z7 ;
  1815. * partie G => changement section tdf int, entre z7 et z8 ;
  1816. * partie H => jusqu'au fin du panier, entre z8 et z9 ;
  1817. * partie I => depuis la fin du panier, entre z9 et z10 ;
  1818. * partie J => changement section fluid ch,entre z10 et z11 ;
  1819. * partie K => plus de rallonge sup, entre z11 zt zM ;
  1820. *
  1821. *
  1822. * I.1.1.Valeurs numeriques
  1823. ** COTES INVARIANTES
  1824. * z1 : coordonne axiale du bas du dispositif modelise, (m).
  1825. * zM : coordonne axiale du haut du dispositif modelise, (m).
  1826. * o : point origine
  1827. * o1 : point de l'axe
  1828.  
  1829. z1 = -695D-3 ;
  1830. z6 = 539.D-3 ;
  1831. z7 = 569.D-3 ;
  1832. z8 = 597.D-3 ;
  1833. z9 = 630.D-3 ;;
  1834. zM = 850D-3 ;
  1835. o = 0. 0. 0. ;
  1836. o1 = 0. 0. 1. ;
  1837.  
  1838. ** COTES VARIANTES
  1839. z2 = -197.4D-3 ;
  1840. *** Cotes du crayon
  1841. z3 = -180.D-3 ;
  1842. z4 = 180.D-3 ;
  1843. z5 = 248.1D-3 ;
  1844. z10 = 743.D-3 ;
  1845. z11 = z10 + 27.D-3 ;
  1846.  
  1847. ** Nombre de maille selon la hauteur
  1848. nhautB = 1 ;
  1849. nhautD = 1 ;
  1850. nhautF = 1 ;
  1851. nhautG = 1 ;
  1852. nhautH = 1 ;
  1853. nhautJ = 1 ;
  1854. nhautK = 1 ;
  1855. si complet ;
  1856. nhautA = 6 ;
  1857. nhautE = 4 ;
  1858. nhautC = 20 ;
  1859. nhautI = 2 ;
  1860. sinon ;
  1861. nhautA = 3 ;
  1862. nhautE = 2 ;
  1863. nhautC = 5 ;
  1864. nhautI = 1 ;
  1865. finsi ;
  1866.  
  1867.  
  1868.  
  1869.  
  1870. *** LE CRAYON :
  1871. * partie A => rallonge inferieure (Zircaloy4)
  1872. * partie B => bouchon inferieur (vide)
  1873. * partie C => longueur chauffante du crayon
  1874. * partie D => bouchon superieur (vide)
  1875. * parties E,F,G,H,I => rallonge superieure (Zircaloy4)
  1876. * diamext : diametre exterieur de la gaine entourant le crayon chauffant
  1877. * epai : epaisseur de la gaine entourant le crayon chauffant
  1878. diamext = diamex0 ;
  1879. epai = epai0 ;
  1880. ****diamext = 9.5D-3 ;
  1881. ****epai = 1.D-3 ;
  1882.  
  1883. *** LE PANIER :
  1884. * pani : diametre interieur du panier (m)
  1885. * pane : diametre exterieur du panier (m)
  1886. pani = 19.6D-3 ;
  1887. pane = 21.0D-3 ;
  1888.  
  1889. *** LE FLUIDE CHAUD ASCENDANT:
  1890. * spass : surface de passage du fluide chaud, i-e l'ecoulement interne
  1891. * cotp : cote du carre representant la base du maillage du fluide chaud
  1892. * dhy : diametre hydraulique du fluide chaud
  1893. * qhenom : vitesse massique du fluide chaud (kg.m-2.s-1)
  1894.  
  1895. spass = (pi * ((pani / 2.) ** 2.)) - (pi * ((diamext / 2.) ** 2.)) ;
  1896. cotp = '**' spass 0.5D0 ;
  1897. dhy = 4 * spass / (( pi * diamext ) + ( pi * pani)) ;
  1898. qhenom = qmhe / spass ;
  1899.  
  1900. spassK = (pi * ((pani / 2.) ** 2.)) ;
  1901. cotpK = '**' spassK 0.5D0 ;
  1902. dhyK = 4 * spassK / ( pi * pani) ;
  1903. qhenomK = qmhe / spassK ;
  1904.  
  1905.  
  1906. *** LE PORTE ECHANTILLON (PE) :
  1907. * pei : diametre interieur du PE (m)
  1908. * pee : diametre exterieur du PE (m)
  1909. *****pei = 23.0D-3 ;
  1910. pei = 22.0D-3 ; comm DRSN/SIREN/LECSI/DO 16 du 11/02/08 ;
  1911. pee = 25.0D-3 ;
  1912.  
  1913. *** LE TUBE DE FORCE INTERNE :
  1914. * partie A,B,C,D,E => 1ere partie tdf interne (Zircaloy4)
  1915. * partie F => changement de section du tdf externe (Zircaloy4)
  1916. * partie G => changement de section du tdf interne (Zircaloy4)
  1917. * partie H,I,J,K => 2eme partie tdf interne et externe (Zircaloy4)
  1918. * tfintiA : diametre interne du tube de force interne partie A -> E
  1919. * tfinteA : diametre externe du tube de force interne partie A -> E
  1920. * tfintiH : diametre interne du tube de force interne partie H -> J
  1921. * tfinteH : diametre externe du tube de force interne partie H -> J
  1922.  
  1923. tfintiA = 46.D-3 ;
  1924. tfinteA = 59.0D-3 ;
  1925. tfintiH = 53.05D-3 ;
  1926. tfinteH = 66.50D-3 ;
  1927.  
  1928. *** LE FLUIDE FROID DESCENDANT:
  1929. * spassN : surface de passage dans la partie N
  1930. * cotpN : cote du carre representant la base du maillage partie N
  1931. * dhyN : diametre hydraulique de la partie N
  1932. * qhenomN : vitesse massique de la partie N (kg.m-2.s-1)
  1933.  
  1934. spassA = (pi * ((tfintiA / 2.) ** 2.)) - (pi * ((pee / 2.) ** 2.)) ;
  1935. cotpA = '**' spassA 0.5D0 ;
  1936. dhyA = 4 * spassA / (( pi * pee ) + ( pi * tfintiA)) ;
  1937. qhenomA = qmhe / spassA ;
  1938.  
  1939. spassH = (pi * ((tfintiH / 2.) ** 2.)) - (pi * ((pee / 2.) ** 2.)) ;
  1940. cotpH = '**' spassH 0.5D0 ;
  1941. dhyH = 4 * spassH / (( pi * pee ) + ( pi * tfintiH)) ;
  1942. qhenomH = qmhe / spassH ;
  1943.  
  1944.  
  1945. *** LE TUBE DE FORCE EXTERNE :
  1946. * parties A,B,C,D,E => 1ere partie tdf externe (Zircaloy4)
  1947. * partie F => changement de section du tdf externe (Zircaloy4)
  1948. * partie G => changement de section du tdf interne (Zircaloy4)
  1949. * partie H,I,J,K => 2eme partie tdf externe (Zircaloy4)
  1950. * tfextiA : diametre interne du tube de force externe partie A -> E
  1951. * tfexteA : diametre externe du tube de force externe partie A -> E
  1952. * tfextiG : diametre interne du tube de force externe partie G -> J
  1953. * tfexteG : diametre externe du tube de force externe partie G -> J
  1954.  
  1955. *****tfextiA = 59.9D-3 ;
  1956. *****tfexteA = 70.1D-3 ;
  1957. tfextiA = 59.8D-3 ; comm DRSN/SIREN/LECSI/DO 16 du 11/02/08 ;
  1958. tfexteA = 70.D-3 ; comm DRSN/SIREN/LECSI/DO 16 du 11/02/08 ;
  1959. tfextiG = 67.5D-3 ;
  1960. tfexteG = 78.5D-3 ;
  1961.  
  1962.  
  1963. * I.2.Parametres calcules
  1964. * I.2.1.Description
  1965. * theek : conversion en Kelvin de theec
  1966. * tpiscik : conversion en Kelvin de tpisci
  1967. * plin1 : conversion en W/m.
  1968. * Psat : conversion en Pascals de PsatB
  1969. * Tsat : temperature de saturation a la pression Psat
  1970.  
  1971. * I.2.2.Valeurs
  1972.  
  1973. theek = theec + CK ;
  1974. tpiscik = tpisci + CK ;
  1975. plin1 = '*' plin1 100.D0 ;
  1976. Psat = PsatB * 1.e5 ;
  1977. Tsat = CK + ( h2o_tsat Psat );
  1978. ** IV.Points, lignes, surfaces
  1979. * IV.1. Crayon Chauffant
  1980.  
  1981. * A. GAINE :
  1982. rext = diamext / 2. ;
  1983. rint = rext - epai ;
  1984. mrext = -1. * rext ;
  1985. mrint = -1. * rint ;
  1986.  
  1987. **Points de l'interface 1 :
  1988. p11e = rext 0. z1 ;
  1989. p12e = 0. rext z1 ;
  1990. p13e = mrext 0. z1 ;
  1991. p14e = 0. mrext z1 ;
  1992. p11i = rint 0. z1 ;
  1993. p12i = 0. rint z1 ;
  1994. p13i = mrint 0. z1 ;
  1995. p14i = 0. mrint z1 ;
  1996.  
  1997. *** Lignes de toutes les interfaces :
  1998. l11e = 'CER3' np p11e p12e p13e ;
  1999. l12e = 'CER3' np p13e p14e p11e ;
  2000. lt1e = 'ET' l11e l12e ;
  2001. l11i = 'CER3' np p11i p12i p13i ;
  2002. l12i = 'CER3' np p13i p14i p11i ;
  2003. lt1i = 'ET' l11i l12i ;
  2004.  
  2005. lt2e lt3e lt4e lt5e lt6e lt7e lt8e lt9e lt10e lt11e noMe = PLUSJU lt1e ;
  2006. lt2i lt3i lt4i lt5i lt6i lt7i lt8i lt9i lt10i lt11i noMi = PLUSJU lt1i ;
  2007.  
  2008. *** Bases des volumes :
  2009. stcb1 = 'REGLER' lt1i ne lt1e ;
  2010. stcb2 stcb3 stcb4 stcb5 stcb6 stcb7 stcb8 stcb9 stcb10 stcb11 noM
  2011. = PLUSJU stcb1 ; comm meme si stcb11 n existe pas ;
  2012.  
  2013. ELIM 1.e-8 (lt2e ET lt3e ET lt4e ET lt5e ET lt6e ET lt7e ET lt8e ET
  2014. lt9e ET lt10e ET stcb1 ET stcb2 ET stcb3 ET stcb4
  2015. ET stcb5 ET stcb6 ET stcb7 ET stcb8 ET stcb9 ET stcb10) ;
  2016.  
  2017. * B. LES RALLONGES :
  2018. rintr = rint / 10. ;
  2019. mrintr = -1. * rintr ;
  2020.  
  2021. **Points :
  2022. p11r = rintr 0. z1 ;
  2023. p12r = 0. rintr z1 ;
  2024. p13r = mrintr 0. z1 ;
  2025. p14r = 0. mrintr z1 ;
  2026.  
  2027. *** Lignes et Surfaces : interfaces 1->10 :
  2028. l11r = 'CER3' np p11r p12r p13r ;
  2029. l12r = 'CER3' np p13r p14r p11r ;
  2030. lt1r = 'ET' l11r l12r ;
  2031.  
  2032. stcb11r = 'REGLER' lt1r nral lt1i ;
  2033. stcb12r = SURF lt1r 'PLANE' ;
  2034. stcb1r = stcb11r et stcb12r ;
  2035. stcb2r stcb3r stcb4r stcb5r stcb6r stcb7r stcb8r stcb9r stcb10r no11 noM
  2036. = PLUSJU stcb1r ;
  2037.  
  2038.  
  2039. * IV.2. Fluide chaud ESSAI30 :
  2040.  
  2041. * 1. Section 1 : A->I
  2042. *RQ : La geometrie est un carre de surface egale a spass
  2043. * Au lieu de centrer le canal du fluide chaud en (0;0) on va le
  2044. * centrer en (0.07;0).
  2045.  
  2046. *** Points de l'interface 1 :
  2047. cotp2 = '/' cotp 2.D0 ;
  2048. mcotp2 = '*' cotp2 -1.D0 ;
  2049. p11 = (70.e-3 + cotp2) cotp2 z1 ;
  2050. p12 = (70.e-3 + mcotp2) cotp2 z1 ;
  2051. p13 = (70.e-3 + mcotp2) mcotp2 z1 ;
  2052. p14 = (70.e-3 +cotp2) mcotp2 z1 ;
  2053.  
  2054. *** Surfaces :
  2055. sthe1 = 'MANUEL' 'QUA4' p11 p12 p13 p14;
  2056. sthe2 sthe3 sthe4 sthe5 sthe6 sthe7 sthe8 sthe9 sthe10 no11 noM
  2057. = PLUSJU sthe1 ;
  2058.  
  2059. * 2. Section 2 :
  2060. *La geometrie est un carre de surface egale a spassK
  2061. cotp2K = '/' cotpK 2.D0 ;
  2062. mcotp2K = '*' cotp2K -1.D0 ;
  2063. p111 = (70.e-3 + cotp2K) cotp2K z11 ;
  2064. p112 = (70.e-3 + mcotp2K) cotp2K z11 ;
  2065. p113 = (70.e-3 + mcotp2K) mcotp2K z11 ;
  2066. p114 = (70.e-3 +cotp2K) mcotp2K z11 ;
  2067. sthe11 = 'MANUEL' 'QUA4' p111 p112 p113 p114 ;
  2068. stheM = PLUS sthe11 (0. 0. (zM - z11)) ;
  2069.  
  2070. 'SI' ('NON' ('EGA' discr 'LINE')) ;
  2071. sthe1 = 'CHANGER' 'QUADRATIQUE' sthe1 ;
  2072. sthe2 = 'CHANGER' 'QUADRATIQUE' sthe2 ;
  2073. sthe3 = 'CHANGER' 'QUADRATIQUE' sthe3 ;
  2074. sthe4 = 'CHANGER' 'QUADRATIQUE' sthe4 ;
  2075. sthe5 = 'CHANGER' 'QUADRATIQUE' sthe5 ;
  2076. sthe6 = 'CHANGER' 'QUADRATIQUE' sthe6 ;
  2077. sthe7 = 'CHANGER' 'QUADRATIQUE' sthe7 ;
  2078. sthe8 = 'CHANGER' 'QUADRATIQUE' sthe8 ;
  2079. sthe9 = 'CHANGER' 'QUADRATIQUE' sthe9 ;
  2080. sthe10 = 'CHANGER' 'QUADRATIQUE' sthe10 ;
  2081. sthe11 = 'CHANGER' 'QUADRATIQUE' sthe11 ;
  2082. stheM = 'CHANGER' 'QUADRATIQUE' stheM ;
  2083. 'FINSI' ;
  2084.  
  2085. * IV.3. Panier(interne) ESSAI30 :
  2086.  
  2087. rint1 = ( pani / 2.D0 ) ;
  2088. rext1 = ( pane / 2.D0 ) ;
  2089. mrext1 = '*' rext1 -1.D0 ;
  2090. mrint1 = '*' rint1 -1.D0 ;
  2091.  
  2092. **Points de l'interface 1 :
  2093. q11e = rext1 0. z1 ;
  2094. q12e = 0. rext1 z1 ;
  2095. q13e = mrext1 0. z1 ;
  2096. q14e = 0. mrext1 z1 ;
  2097. q11i = rint1 0. z1 ;
  2098. q12i = 0. rint1 z1 ;
  2099. q13i = mrint1 0. z1 ;
  2100. q14i = 0. mrint1 z1 ;
  2101.  
  2102. *** Lignes de toutes les interfaces :
  2103. l11e_p = 'CER3' np q11e q12e q13e ;
  2104. l12e_p = 'CER3' np q13e q14e q11e ;
  2105. lt1e_p = 'ET' l11e_p l12e_p ;
  2106. l11i_p = 'CER3' np q11i q12i q13i ;
  2107. l12i_p = 'CER3' np q13i q14i q11i ;
  2108. lt1i_p = 'ET' l11i_p l12i_p ;
  2109.  
  2110. lt2e_p lt3e_p lt4e_p lt5e_p lt6e_p lt7e_p lt8e_p lt9e_p lt10e_p lt11e_p
  2111. ltMe_p = PLUSJU lt1e_p ;
  2112. lt2i_p lt3i_p lt4i_p lt5i_p lt6i_p lt7i_p lt8i_p lt9i_p lt10i_p lt11i_p
  2113. ltMi_p = PLUSJU lt1i_p ;
  2114.  
  2115. *** Surfaces de toutes les interfaces :
  2116. stcb_p1 = 'REGLER' lt1i_p ne lt1e_p ;
  2117. stcb_p2 stcb_p3 stcb_p4 stcb_p5 stcb_p6 stcb_p7 stcb_p8 stcb_p9
  2118. stcb_p10 stcb_p11 stcb_pM = PLUSJU stcb_p1 ;
  2119.  
  2120. ELIM 1.e-8 (lt2e_p ET lt3e_p ET lt4e_p ET lt5e_p ET lt6e_p ET lt7e_p ET
  2121. lt8e_p ET lt9e_p ET lt10e_p ET lt11e_p ET ltMe_p ET lt2i_p
  2122. ET lt3i_p ET lt4i_p ET lt5i_p ET lt6i_p ET lt7i_p ET lt8i_p
  2123. ET lt9i_p ET lt10i_p ET lt11i_p ET ltMi_p ET stcb_p1
  2124. ET stcb_p2 ET stcb_p3 ET stcb_p4 ET stcb_p5 ET stcb_p6 ET
  2125. stcb_p7 ET stcb_p8 ET stcb_p9 ET stcb_p10 ET stcb_p11 ET
  2126. stcb_pM) ;
  2127.  
  2128.  
  2129. * IV.4. Porte echantillon ESSAI32 :
  2130.  
  2131. rpeint = (pei / 2.D0 ) ;
  2132. rpeext = ( pee / 2.D0 ) ;
  2133. mrpeint = '*' rpeint -1.D0 ;
  2134. mrpeext = '*' rpeext -1.D0 ;
  2135.  
  2136. **Points de l'interface 1 :
  2137. qpe11e = rpeext 0. z1 ;
  2138. qpe12e = 0. rpeext z1 ;
  2139. qpe13e = mrpeext 0. z1 ;
  2140. qpe14e = 0. mrpeext z1 ;
  2141. qpe11i = rpeint 0. z1 ;
  2142. qpe12i = 0. rpeint z1 ;
  2143. qpe13i = mrpeint 0. z1 ;
  2144. qpe14i = 0. mrpeint z1 ;
  2145.  
  2146. *** Lignes de toutes les interfaces :
  2147. lpe11e = 'CER3' np qpe11e qpe12e qpe13e ;
  2148. lpe12e = 'CER3' np qpe13e qpe14e qpe11e ;
  2149. lpet1e = 'ET' lpe11e lpe12e ;
  2150. lpe11i = 'CER3' np qpe11i qpe12i qpe13i ;
  2151. lpe12i = 'CER3' np qpe13i qpe14i qpe11i ;
  2152. lpet1i = 'ET' lpe11i lpe12i ;
  2153.  
  2154. lpet2e lpet3e lpet4e lpet5e lpet6e lpet7e lpet8e lpet9e lpet10e lpet11e
  2155. lpetMe = PLUSJU lpet1e ;
  2156. lpet2i lpet3i lpet4i lpet5i lpet6i lpet7i lpet8i lpet9i lpet10i lpet11i
  2157. lpetMi = PLUSJU lpet1i ;
  2158.  
  2159. *** Surfaces de toutes les interfaces :
  2160. stpe1 = 'REGLER' lpet1i ne lpet1e ;
  2161. stpe2 stpe3 stpe4 stpe5 stpe6 stpe7 stpe8 stpe9 stpe10 stpe11 stpeM
  2162. = PLUSJU stpe1 ;
  2163.  
  2164. ELIM 1.e-8 (lpet2e ET lpet3e ET lpet4e ET lpet5e ET lpet6e ET lpet7e ET
  2165. lpet8e ET lpet9e ET lpet10e ET lpet11e ET lpetMe ET stpe1
  2166. ET stpe2 ET stpe3 ET stpe4 ET stpe5 ET stpe6 ET stpe7 ET
  2167. stpe8 ET stpe9 ET stpe10 ET stpe11 ET stpeM) ;
  2168.  
  2169.  
  2170. * IV.5. Lame d'eau stagnante : ESSAI51 :
  2171.  
  2172. st_lam1 = 'REGLER' lt1e_p ne lpet1i ;
  2173. st_lam2 st_lam3 st_lam4 st_lam5 st_lam6 st_lam7 st_lam8 st_lam9 st_lam10
  2174. st_lam11 st_lamM = PLUSJU st_lam1 ;
  2175.  
  2176.  
  2177. * IV.6. Fluide froid ESSAI32 :
  2178.  
  2179. * 1. Section 1 :
  2180. *La geometrie est un carre de surface egale a spassA
  2181. * Au lieu de centrer le canal du fluide chaud en (0;0) on va le
  2182. * centrer en (0.;0.08).
  2183.  
  2184. cotp12 = cotpA / 2. ;
  2185. mcotp12 = -1.D0 * cotp12 ;
  2186. q11 = cotp12 (80.e-3 + cotp12) z1 ;
  2187. q12 = mcotp12 (80.e-3 + cotp12) z1 ;
  2188. q13 = mcotp12 (80.e-3 + mcotp12) z1 ;
  2189. q14 = cotp12 (80.e-3 + mcotp12) z1 ;
  2190.  
  2191. sthe_p1 = 'MANUEL' 'QUA4' q11 q12 q13 q14 ;
  2192. sthe_p2 sthe_p3 sthe_p4 sthe_p5 sthe_p6 sthe_p7 no8 no9 no10 no11 noM
  2193. = PLUSJU sthe_p1 ;
  2194.  
  2195.  
  2196. * 2. Section 2 :
  2197. *La geometrie est un carre de surface egale a spassH
  2198. cotp22 = cotpH / 2. ;
  2199. mcotp22 = -1.D0 * cotp22 ;
  2200. q81 = cotp22 (80.e-3 + cotp22) z8 ;
  2201. q82 = mcotp22 (80.e-3 + cotp22) z8 ;
  2202. q83 = mcotp22 (80.e-3 + mcotp22) z8 ;
  2203. q84 = cotp22 (80.e-3 + mcotp22) z8 ;
  2204. sthe_p8 = 'MANUEL' 'QUA4' q81 q82 q83 q84 ;
  2205. sthe_p9 = PLUS sthe_p8 (0. 0. (z9 - z8)) ;
  2206. sthe_p10 = PLUS sthe_p8 (0. 0. (z10 - z8)) ;
  2207. sthe_p11 = PLUS sthe_p8 (0. 0. (z11 - z8)) ;
  2208. sthe_pM = PLUS sthe_p8 (0. 0. (zM - z8)) ;
  2209.  
  2210. 'SI' ('NON' ('EGA' discr 'LINE')) ;
  2211. sthe_p1 = 'CHANGER' 'QUADRATIQUE' sthe_p1 ;
  2212. sthe_p2 = 'CHANGER' 'QUADRATIQUE' sthe_p2 ;
  2213. sthe_p3 = 'CHANGER' 'QUADRATIQUE' sthe_p3 ;
  2214. sthe_p4 = 'CHANGER' 'QUADRATIQUE' sthe_p4 ;
  2215. sthe_p5 = 'CHANGER' 'QUADRATIQUE' sthe_p5 ;
  2216. sthe_p6 = 'CHANGER' 'QUADRATIQUE' sthe_p6 ;
  2217. sthe_p7 = 'CHANGER' 'QUADRATIQUE' sthe_p7 ;
  2218. sthe_p8 = 'CHANGER' 'QUADRATIQUE' sthe_p8 ;
  2219. sthe_p9 = 'CHANGER' 'QUADRATIQUE' sthe_p9 ;
  2220. sthe_p10 = 'CHANGER' 'QUADRATIQUE' sthe_p10 ;
  2221. sthe_p11 = 'CHANGER' 'QUADRATIQUE' sthe_p11 ;
  2222. sthe_pM = 'CHANGER' 'QUADRATIQUE' sthe_pM ;
  2223. 'FINSI' ;
  2224.  
  2225.  
  2226. * IV.7. Tube de force interne ESSAI34 :
  2227.  
  2228. rtiinA = (tfintiA / 2.D0) ;
  2229. rtiexA = (tfinteA / 2.D0) ;
  2230. mrtiexA = '*' rtiexA -1.D0 ;
  2231. mrtiinA = '*' rtiinA -1.D0 ;
  2232. rtiinH = (tfintiH / 2.D0) ;
  2233. rtiexH = (tfinteH / 2.D0) ;
  2234. mrtiexH = '*' rtiexH -1.D0 ;
  2235. mrtiinH = '*' rtiinH -1.D0 ;
  2236.  
  2237. **Points de l'interface 1 :
  2238. qti11e = rtiexA 0. z1 ;
  2239. qti12e = 0. rtiexA z1 ;
  2240. qti13e = mrtiexA 0. z1 ;
  2241. qti14e = 0. mrtiexA z1 ;
  2242. qti11i = rtiinA 0. z1 ;
  2243. qti12i = 0. rtiinA z1 ;
  2244. qti13i = mrtiinA 0. z1 ;
  2245. qti14i = 0. mrtiinA z1 ;
  2246.  
  2247. ** Points de l'interface 7 :
  2248. qti71e = rtiexA 0. z7 ;
  2249. qti71i = rtiinA 0. z7 ;
  2250.  
  2251. **Points de l'interface 8 :
  2252. qti81e = rtiexH 0. z8 ;
  2253. qti82e = 0. rtiexH z8 ;
  2254. qti83e = mrtiexH 0. z8 ;
  2255. qti84e = 0. mrtiexH z8 ;
  2256. qti81i = rtiinH 0. z8 ;
  2257. qti82i = 0. rtiinH z8 ;
  2258. qti83i = mrtiinH 0. z8 ;
  2259. qti84i = 0. mrtiinH z8 ;
  2260.  
  2261. * Points supplementaires pour la cavite de gaz :
  2262. qti21e = rtiexA 0. z2 ;
  2263. qti31e = rtiexA 0. z3 ;
  2264. qti41e = rtiexA 0. z4 ;
  2265. qti51e = rtiexA 0. z5 ;
  2266. qti61e = rtiexA 0. z6 ;
  2267. qti91e = rtiexH 0. z9 ;
  2268. qti101e = rtiexH 0. z10 ;
  2269. qti111e = rtiexH 0. z11 ;
  2270. qtiM1e = rtiexH 0. zM ;
  2271.  
  2272. *** Lignes des interfaces 1 -> 7 :
  2273. lti11e_p = 'CER3' np qti11e qti12e qti13e ;
  2274. lti12e_p = 'CER3' np qti13e qti14e qti11e ;
  2275. ltit1e_p = 'ET' lti11e_p lti12e_p ;
  2276. lti11i_p = 'CER3' np qti11i qti12i qti13i ;
  2277. lti12i_p = 'CER3' np qti13i qti14i qti11i ;
  2278. ltit1i_p = 'ET' lti11i_p lti12i_p ;
  2279.  
  2280. ltit2e_p ltit3e_p ltit4e_p ltit5e_p ltit6e_p ltit7e_p no8 no9 no10 no11
  2281. noM = PLUSJU ltit1e_p ;
  2282. ltit2i_p ltit3i_p ltit4i_p ltit5i_p ltit6i_p ltit7i_p no8 no9 no10 no11
  2283. noM = PLUSJU ltit1i_p ;
  2284.  
  2285. *** Lignes des interfaces 8 -> 11 :
  2286. lti81e_p = 'CER3' np qti81e qti82e qti83e ;
  2287. lti82e_p = 'CER3' np qti83e qti84e qti81e ;
  2288. ltit8e_p = 'ET' lti81e_p lti82e_p ;
  2289. lti81i_p = 'CER3' np qti81i qti82i qti83i ;
  2290. lti82i_p = 'CER3' np qti83i qti84i qti81i ;
  2291. ltit8i_p = 'ET' lti81i_p lti82i_p ;
  2292.  
  2293. ltit9e_p = PLUS ltit8e_p (0. 0. (z9 - z8)) ;
  2294. ltit10e_ = PLUS ltit8e_p (0. 0. (z10 - z8)) ;
  2295. ltit11e_ = PLUS ltit8e_p (0. 0. (z11 - z8)) ;
  2296. ltit9i_p = PLUS ltit8i_p (0. 0. (z9 - z8)) ;
  2297. ltit10i_ = PLUS ltit8i_p (0. 0. (z10 - z8)) ;
  2298. ltit11i_ = PLUS ltit8i_p (0. 0. (z11 - z8)) ;
  2299.  
  2300. *** Surfaces de toutes les interfaces :
  2301. stfint1 = 'REGLER' ltit1i_p ne ltit1e_p ;
  2302. stfint2 = 'REGLER' ltit2i_p ne ltit2e_p ;
  2303. stfint3 = 'REGLER' ltit3i_p ne ltit3e_p ;
  2304. stfint4 = 'REGLER' ltit4i_p ne ltit4e_p ;
  2305. stfint5 = 'REGLER' ltit5i_p ne ltit5e_p ;
  2306. stfint6 = 'REGLER' ltit6i_p ne ltit6e_p ;
  2307. stfint7 = 'REGLER' ltit7i_p ne ltit7e_p ;
  2308. stfint8 = 'REGLER' ltit8i_p ne ltit8e_p ;
  2309. stfint9 = 'REGLER' ltit9i_p ne ltit9e_p ;
  2310. stfint10 = 'REGLER' ltit10i_ ne ltit10e_ ;
  2311. stfint11 = 'REGLER' ltit11i_ ne ltit11e_ ;
  2312. stfintM = PLUS stfint11 (0. 0. (zM - z11)) ;
  2313.  
  2314. elim 1.e-8 (stfint2 ET stfint3 ET stfint4 ET stfint5 ET stfint6 ET
  2315. stfint7 ET stfint9 ET stfint10 ET stfint11 ET stfintM ET
  2316. qti21e ET qti31e ET qti41e ET qti51e ET qti61e ET qti71e ET
  2317. qti91e ET qti101e ET qti111e ET qtiM1e) ;
  2318.  
  2319.  
  2320. * IV.8. Tube de force externe
  2321.  
  2322. rteinA = ( tfextiA / 2.D0 ) ;
  2323. rteexA = ( tfexteA / 2.D0 ) ;
  2324. mrteexA = '*' rteexA -1.D0 ;
  2325. mrteinA = '*' rteinA -1.D0 ;
  2326. rteinG = ( tfextiG / 2.D0 ) ;
  2327. rteexG = ( tfexteG / 2.D0 ) ;
  2328. mrteexG = '*' rteexG -1.D0 ;
  2329. mrteinG = '*' rteinG -1.D0 ;
  2330.  
  2331. **Points de l'interface 1 :
  2332. qte11e = rteexA 0. z1 ;
  2333. qte12e = 0. rteexA z1 ;
  2334. qte13e = mrteexA 0. z1 ;
  2335. qte14e = 0. mrteexA z1 ;
  2336. qte11i = rteinA 0. z1 ;
  2337. qte12i = 0. rteinA z1 ;
  2338. qte13i = mrteinA 0. z1 ;
  2339. qte14i = 0. mrteinA z1 ;
  2340.  
  2341. **Points de l'interface 6 :
  2342. qte61e = rteexA 0. z6 ;
  2343. qte61i = rteinA 0. z6 ;
  2344.  
  2345. **Points de l'interface 7 :
  2346. qte71e = rteexG 0. z7 ;
  2347. qte72e = 0. rteexG z7 ;
  2348. qte73e = mrteexG 0. z7 ;
  2349. qte74e = 0. mrteexG z7 ;
  2350. qte71i = rteinG 0. z7 ;
  2351. qte72i = 0. rteinG z7 ;
  2352. qte73i = mrteinG 0. z7 ;
  2353. qte74i = 0. mrteinG z7 ;
  2354.  
  2355. * Points supplementaires pour la cavite de gaz :
  2356. qte21i = rteinA 0. z2 ;
  2357. qte31i = rteinA 0. z3 ;
  2358. qte41i = rteinA 0. z4 ;
  2359. qte51i = rteinA 0. z5 ;
  2360. qte81i = rteinG 0. z8 ;
  2361. qte91i = rteinG 0. z9 ;
  2362. qte101i = rteinG 0. z10 ;
  2363. qte111i = rteinG 0. z11 ;
  2364. qteM1i = rteinG 0. zM ;
  2365.  
  2366. *** Lignes des interfaces 1 -> 6 :
  2367. lte11e_p = 'CER3' np qte11e qte12e qte13e ;
  2368. lte12e_p = 'CER3' np qte13e qte14e qte11e ;
  2369. ltet1e_p = 'ET' lte11e_p lte12e_p ;
  2370. lte11i_p = 'CER3' np qte11i qte12i qte13i ;
  2371. lte12i_p = 'CER3' np qte13i qte14i qte11i ;
  2372. ltet1i_p = 'ET' lte11i_p lte12i_p ;
  2373.  
  2374. ltet2e_p ltet3e_p ltet4e_p ltet5e_p ltet6e_p no7 no8 no9 no10 no11 noM
  2375. = PLUSJU ltet1e_p ;
  2376. ltet2i_p ltet3i_p ltet4i_p ltet5i_p ltet6i_p no7 no8 no9 no10 no11 noM
  2377. = PLUSJU ltet1i_p ;
  2378.  
  2379. *** Lignes des interfaces 7 -> 11 :
  2380. lte71e_p = 'CER3' np qte71e qte72e qte73e ;
  2381. lte72e_p = 'CER3' np qte73e qte74e qte71e ;
  2382. ltet7e_p = 'ET' lte71e_p lte72e_p ;
  2383. lte71i_p = 'CER3' np qte71i qte72i qte73i ;
  2384. lte72i_p = 'CER3' np qte73i qte74i qte71i ;
  2385. ltet7i_p = 'ET' lte71i_p lte72i_p ;
  2386.  
  2387. ltet8e_p = PLUS ltet7e_p (0. 0. (z8 - z7)) ;
  2388. ltet8i_p = PLUS ltet7i_p (0. 0. (z8 - z7)) ;
  2389. ltet9e_p = PLUS ltet7e_p (0. 0. (z9 - z7)) ;
  2390. ltet9i_p = PLUS ltet7i_p (0. 0. (z9 - z7)) ;
  2391. ltet10e_ = PLUS ltet7e_p (0. 0. (z10 - z7)) ;
  2392. ltet10i_ = PLUS ltet7i_p (0. 0. (z10 - z7)) ;
  2393. ltet11e_ = PLUS ltet7e_p (0. 0. (z11 - z7)) ;
  2394. ltet11i_ = PLUS ltet7i_p (0. 0. (z11 - z7)) ;
  2395.  
  2396. *** Surfaces de toute les interfaces du tube de force externe
  2397. stfext1 = ( 'REGLER' ltet1i_p ne ltet1e_p ) ;
  2398. stfext2 = ( 'REGLER' ltet2i_p ne ltet2e_p ) ;
  2399. stfext3 = ( 'REGLER' ltet3i_p ne ltet3e_p ) ;
  2400. stfext4 = ( 'REGLER' ltet4i_p ne ltet4e_p ) ;
  2401. stfext5 = ( 'REGLER' ltet5i_p ne ltet5e_p ) ;
  2402. stfext6 = ( 'REGLER' ltet6i_p ne ltet6e_p ) ;
  2403. stfext7 = ( 'REGLER' ltet7i_p ne ltet7e_p ) ;
  2404. stfext8 = ( 'REGLER' ltet8i_p ne ltet8e_p ) ;
  2405. stfext9 = ( 'REGLER' ltet9i_p ne ltet9e_p ) ;
  2406. stfext10 = ( 'REGLER' ltet10i_ ne ltet10e_ ) ;
  2407. stfext11 = ( 'REGLER' ltet11i_ ne ltet11e_ ) ;
  2408. stfextM = PLUS stfext11 (0. 0. (zM - z11)) ;
  2409.  
  2410. elim 1.e-8 (qte21i ET qte31i ET qte41i ET qte51i ET qte61e ET qte61i ET
  2411. qte81i ET qte91i ET qte101i ET qte111i ET qteM1i ET stfext2
  2412. ET stfext3 ET stfext4 ET stfext5 ET stfext6 ET stfext8 ET
  2413. stfext9 ET stfext10 ET stfext11 ET stfextM) ;
  2414.  
  2415.  
  2416. * IV.9. Lame de gaz statique : ESSAI51 :
  2417.  
  2418. * Contrairement au autres maillages la lame de gaz se construit par
  2419. * rotation autour de l'axe plutot que par translation selon z.
  2420.  
  2421. ltiA = qti11e DROI qti21e nhautA ;
  2422. lteA = qte21i DROI qte11i nhautA ;
  2423. lsouA = qte11i DROI qti11e 1 ;
  2424. lsurA = qti21e DROI qte21i 1 ;
  2425. SgazA = DALL lsouA ltiA lsurA lteA 'PLAN' ;
  2426.  
  2427. ltiB = qti21e DROI qti31e nhautB ;
  2428. lteB = qte31i DROI qte21i nhautB ;
  2429. lsouB = qte21i DROI qti21e 1 ;
  2430. lsurB = qti31e DROI qte31i 1 ;
  2431. SgazB = DALL lsouB ltiB lsurB lteB 'PLAN' ;
  2432.  
  2433. ltiC = qti31e DROI qti41e nhautC ;
  2434. lteC = qte41i DROI qte31i nhautC ;
  2435. lsouC = qte31i DROI qti31e 1 ;
  2436. lsurC = qti41e DROI qte41i 1 ;
  2437. SgazC = DALL lsouC ltiC lsurC lteC 'PLAN' ;
  2438.  
  2439. ltiD = qti41e DROI qti51e nhautD ;
  2440. lteD = qte51i DROI qte41i nhautD ;
  2441. lsouD = qte41i DROI qti41e 1 ;
  2442. lsurD = qti51e DROI qte51i 1 ;
  2443. SgazD = DALL lsouD ltiD lsurD lteD 'PLAN' ;
  2444.  
  2445. ltiE = qti51e DROI qti61e nhautE ;
  2446. lteE = qte61i DROI qte51i nhautE ;
  2447. lsouE = qte51i DROI qti51e 1 ;
  2448. lsurE = qti61e DROI qte61i 1 ;
  2449. SgazE = DALL lsouE ltiE lsurE lteE 'PLAN' ;
  2450.  
  2451. ltiF = qti61e DROI qti71e nhautF ;
  2452. lteF = qte71i DROI qte61i nhautF ;
  2453. lsouF = qte61i DROI qti61e 1 ;
  2454. lsurF = qti71e DROI qte71i 1 ;
  2455. SgazF = DALL lsouF ltiF lsurF lteF 'PLAN' ;
  2456.  
  2457. ltiG = qti71e DROI qti81e nhautG ;
  2458. lteG = qte81i DROI qte71i nhautG ;
  2459. lsouG = qte71i DROI qti71e 1 ;
  2460. lsurG = qti81e DROI qte81i 1 ;
  2461. SgazG = DALL lsouG ltiG lsurG lteG 'PLAN' ;
  2462.  
  2463. ltiH = qti81e DROI qti91e nhautH ;
  2464. lteH = qte91i DROI qte81i nhautH ;
  2465. lsouH = qte81i DROI qti81e 1 ;
  2466. lsurH = qti91e DROI qte91i 1 ;
  2467. SgazH = DALL lsouH ltiH lsurH lteH 'PLAN' ;
  2468.  
  2469. ltiI = qti91e DROI qti101e nhautI ;
  2470. lteI = qte101i DROI qte91i nhautI ;
  2471. lsouI = qte91i DROI qti91e 1 ;
  2472. lsurI = qti101e DROI qte101i 1 ;
  2473. SgazI = DALL lsouI ltiI lsurI lteI 'PLAN' ;
  2474.  
  2475. ltiJ = qti101e DROI qti111e nhautJ ;
  2476. lteJ = qte111i DROI qte101i nhautJ ;
  2477. lsouJ = qte101i DROI qti101e 1 ;
  2478. lsurJ = qti111e DROI qte111i 1 ;
  2479. SgazJ = DALL lsouJ ltiJ lsurJ lteJ 'PLAN' ;
  2480.  
  2481. ltiK = qti111e DROI qtiM1e nhautK ;
  2482. lteK = qteM1i DROI qte111i nhautK ;
  2483. lsouK = qte111i DROI qti111e 1 ;
  2484. lsurK = qtiM1e DROI qteM1i 1 ;
  2485. SgazK = DALL lsouK ltiK lsurK lteK 'PLAN' ;
  2486.  
  2487. Sgaz = SgazA ET SgazB ET SgazC ET SgazD ET SgazE ET SgazF ET SgazG ET
  2488. SgazH ET SgazI ET SgazJ ET SgazK ;
  2489. ELIM 1.e-8 Sgaz ;
  2490.  
  2491.  
  2492. ** V. Construction des volumes :
  2493.  
  2494. * V.1. Gaine - Fluide chaud - Panier - PE - Fluide froid - tdf interne :
  2495.  
  2496. *** definition des elements dans une hauteur elementaire
  2497. bahe = sthe1 ;
  2498. hahe = stheM ;
  2499. bahe_p = sthe_p1 ;
  2500. hahe_p = sthe_pM ;
  2501. tabfac = 'TABLE' ; comm gaine ;
  2502. tabfac_q = 'TABLE' ; comm panier ;
  2503. tabele = 'TABLE' ; comm fluide chaud ;
  2504. tabfac_p = 'TABLE' ; comm PE ;
  2505. tabfac_t = 'TABLE' ; comm tdf interne ;
  2506. tabele_t = 'TABLE' ; comm fluide froid ;
  2507. icpt = 1 ;
  2508.  
  2509.  
  2510. *** Ecriture des tables de correspondances :
  2511.  
  2512. * 1.PartA :
  2513. mtheA mthe_pA mtinA mtifA mtcbA mtin_pA mtif_pA mtcb_pA
  2514. mtin_peA mtif_peA mt_peA mtin_tA mtif_tA mt_tfiA
  2515. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt
  2516. = VOLUJU sthe1 sthe_p1 lt1i lt1e stcb1 lt1i_p lt1e_p stcb_p1
  2517. lpet1i lpet1e stpe1 ltit1i_p ltit1e_p stfint1
  2518. z1 z2 nhautA
  2519. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2520.  
  2521. * 2.PartB :
  2522. mtheB mthe_pB mtinB mtifB mtcbB mtin_pB mtif_pB mtcb_pB
  2523. mtin_peB mtif_peB mt_peB mtin_tB mtif_tB mt_tfiB
  2524. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt
  2525. = VOLUJU sthe2 sthe_p2 lt2i lt2e stcb2 lt2i_p lt2e_p stcb_p2
  2526. lpet2i lpet2e stpe2 ltit2i_p ltit2e_p stfint2
  2527. z2 z3 nhautB
  2528. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2529.  
  2530. * 3.PartC :
  2531. mtheC mthe_pC mtinC mtifC mtcbC mtin_pC mtif_pC mtcb_pC
  2532. mtin_peC mtif_peC mt_peC mtin_tC mtif_tC mt_tfiC
  2533. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt
  2534. = VOLUJU sthe3 sthe_p3 lt3i lt3e stcb3 lt3i_p lt3e_p stcb_p3
  2535. lpet3i lpet3e stpe3 ltit3i_p ltit3e_p stfint3
  2536. z3 z4 nhautC
  2537. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2538.  
  2539. * 4.PartD :
  2540. mtheD mthe_pD mtinD mtifD mtcbD mtin_pD mtif_pD mtcb_pD
  2541. mtin_peD mtif_peD mt_peD mtin_tD mtif_tD mt_tfiD
  2542. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt
  2543. = VOLUJU sthe4 sthe_p4 lt4i lt4e stcb4 lt4i_p lt4e_p stcb_p4
  2544. lpet4i lpet4e stpe4 ltit4i_p ltit4e_p stfint4
  2545. z4 z5 nhautD
  2546. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2547.  
  2548. * 5.PartE :
  2549. mtheE mthe_pE mtinE mtifE mtcbE mtin_pE mtif_pE mtcb_pE
  2550. mtin_peE mtif_peE mt_peE mtin_tE mtif_tE mt_tfiE
  2551. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt
  2552. = VOLUJU sthe5 sthe_p5 lt5i lt5e stcb5 lt5i_p lt5e_p stcb_p5
  2553. lpet5i lpet5e stpe5 ltit5i_p ltit5e_p stfint5
  2554. z5 z6 nhautE
  2555. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2556.  
  2557. * 6.PartF :
  2558. mtheF mthe_pF mtinF mtifF mtcbF mtin_pF mtif_pF mtcb_pF
  2559. mtin_peF mtif_peF mt_peF mtin_tF mtif_tF mt_tfiF
  2560. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt
  2561. = VOLUJU sthe6 sthe_p6 lt6i lt6e stcb6 lt6i_p lt6e_p stcb_p6
  2562. lpet6i lpet6e stpe6 ltit6i_p ltit6e_p stfint6
  2563. z6 z7 nhautF
  2564. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2565.  
  2566.  
  2567. * 7.PartG :
  2568. ** Parties droites :
  2569. mtheG no1 mtinG mtifG mtcbG mtin_pG mtif_pG mtcb_pG
  2570. mtin_peG mtif_peG mt_peG no2 no3 no4
  2571. tabfac tabfac_q tabfac_p no5 tabele no6 icpt1
  2572. = VOLUJU sthe7 sthe_p7 lt7i lt7e stcb7 lt7i_p lt7e_p stcb_p7
  2573. lpet7i lpet7e stpe7 ltit7i_p ltit7e_p stfint7
  2574. z7 z8 nhautG
  2575. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2576.  
  2577. ** Changement de section et raccordement:
  2578. C1 = 0. 0. z7 ;
  2579. C2 = 0. 0. z8 ;
  2580. li = qti71i DROI 1 qti81i ;
  2581. le = qti71e DROI 1 qti81e ;
  2582. np2 = 2 * np ;
  2583.  
  2584. mthe_pG = sthe_p7 VOLU sthe_p8 1 ; comm remplace no1 ;
  2585. mtin_tG = li ROTA (np2) 360. C1 C2 ; comm remplace no2 ;
  2586. mtif_tG = le ROTA (np2) 360. C1 C2 ; comm remplace no3 ;
  2587. mt_tfiG = stfint7 VOLU stfint8 1 ; comm remplace no4 ;
  2588.  
  2589. nmtif1 = 'NBEL' mtin_tG ;
  2590. 'REPETER' imtif1 nmtif1 ;
  2591. lmtif1 = 'ELEM' mtin_tG &imtif1 ;
  2592. tabfac_t . icpt = lmtif1 ;
  2593. tabele_t . icpt = mthe_pG ;
  2594. icpt = '+' icpt 1 ;
  2595. 'FIN' imtif1 ;
  2596.  
  2597.  
  2598. * 8.PartH :
  2599. mtheH mthe_pH mtinH mtifH mtcbH mtin_pH mtif_pH mtcb_pH
  2600. mtin_peH mtif_peH mt_peH mtin_tH mtif_tH mt_tfiH
  2601. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt
  2602. = VOLUJU sthe8 sthe_p8 lt8i lt8e stcb8 lt8i_p lt8e_p stcb_p8
  2603. lpet8i lpet8e stpe8 ltit8i_p ltit8e_p stfint8
  2604. z8 z9 nhautH
  2605. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2606.  
  2607. * 9.PartI : on ne modelise pas l'arret du panier et de la lame d'eau
  2608. * le changement de section du PE et des jambe
  2609. * le capteur ac=vec les bobines.
  2610.  
  2611. mtheI mthe_pI mtinI mtifI mtcbI mtin_pI mtif_pI mtcb_pI
  2612. mtin_peI mtif_peI mt_peI mtin_tI mtif_tI mt_tfiI
  2613. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt
  2614. = VOLUJU sthe9 sthe_p9 lt9i lt9e stcb9 lt9i_p lt9e_p stcb_p9
  2615. lpet9i lpet9e stpe9 ltit9i_p ltit9e_p stfint9
  2616. z9 z10 nhautI
  2617. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2618.  
  2619. * 10.PartJ :
  2620. ** Parties droites :
  2621. no1 mthe_pJ no2 no3 no4 mtin_pJ mtif_pJ mtcb_pJ
  2622. mtin_peJ mtif_peJ mt_peJ mtin_tJ mtif_tJ mt_tfiJ
  2623. no5 tabfac_q tabfac_p tabfac_t no6 tabele_t icpt1
  2624. = VOLUJU sthe10 sthe_p10 lt10i lt10e stcb10 lt10i_p lt10e_p stcb_p10
  2625. lpet10i lpet10e stpe10 ltit10i_ ltit10e_ stfint10
  2626. z10 z11 nhautJ
  2627. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2628.  
  2629. ** Maillage et table du fluide.
  2630. mtheJ = sthe10 VOLU sthe11 1 ; comm remplace no1 ;
  2631.  
  2632. nmtif1 = 'NBEL' mtin_pJ ;
  2633. 'REPETER' imtif1 nmtif1 ;
  2634. tabele . icpt = mtheJ ; comm remplace no6 ;
  2635. icpt = '+' icpt 1 ;
  2636. 'FIN' imtif1 ;
  2637.  
  2638. * 11.PartK :
  2639. mtheK mthe_pK no2 no3 no4 mtin_pK mtif_pK mtcb_pK
  2640. mtin_peK mtif_peK mt_peK mtin_tK mtif_tK mt_tfiK
  2641. no5 tabfac_q tabfac_p tabfac_t tabele tabele_t icpt
  2642. = VOLUJU sthe11 sthe_p11 lt11i lt11e stcb11 lt11i_p lt11e_p stcb_p11
  2643. lpet11i lpet11e stpe11 ltit11i_ ltit11e_ stfint11
  2644. z11 zM nhautK
  2645. tabfac tabfac_q tabfac_p tabfac_t tabele tabele_t icpt ;
  2646.  
  2647.  
  2648. * 12. Assemblage :
  2649.  
  2650. mthe = mtheA ET mtheB ET mtheC ET mtheD ET mtheE ET mtheF ET mtheG ET
  2651. mtheH ET mtheI ET mtheJ ET mtheK ;
  2652. mthe_p = mthe_pA ET mthe_pB ET mthe_pC ET mthe_pD ET mthe_pE ET mthe_pF
  2653. ET mthe_pG ET mthe_pH ET mthe_pI ET mthe_pJ ET mthe_pK ;
  2654. mtin = mtinA ET mtinB ET mtinC ET mtinD ET mtinE ET mtinF ET mtinG ET
  2655. mtinH ET mtinI ;
  2656. mtif = mtifA ET mtifB ET mtifC ET mtifD ET mtifE ET mtifF ET mtifG ET
  2657. mtifH ET mtifI ;
  2658. mtcb = mtcbA ET mtcbB ET mtcbC ET mtcbD ET mtcbE ET mtcbF ET mtcbG ET
  2659. mtcbH ET mtcbI ;
  2660. mtin_p = mtin_pA ET mtin_pB ET mtin_pC ET mtin_pD ET mtin_pE ET mtin_pF
  2661. ET mtin_pG ET mtin_pH ET mtin_pI ET mtin_pJ ET mtin_pK ;
  2662. mtif_p = mtif_pA ET mtif_pB ET mtif_pC ET mtif_pD ET mtif_pE ET mtif_pF
  2663. ET mtif_pG ET mtif_pH ET mtif_pI ET mtif_pJ ET mtif_pK ;
  2664. mtcb_p = mtcb_pA ET mtcb_pB ET mtcb_pC ET mtcb_pD ET mtcb_pE ET mtcb_pF
  2665. ET mtcb_pG ET mtcb_pH ET mtcb_pI ET mtcb_pJ ET mtcb_pK ;
  2666. mtin_pe = mtin_peA ET mtin_peB ET mtin_peC ET mtin_peD ET mtin_peE ET
  2667. mtin_peF ET mtin_peG ET mtin_peH ET mtin_peI ET mtin_peJ ET
  2668. mtin_peK ;
  2669. mtif_pe = mtif_peA ET mtif_peB ET mtif_peC ET mtif_peD ET mtif_peE ET
  2670. mtif_peF ET mtif_peG ET mtif_peH ET mtif_peI ET mtif_peJ ET
  2671. mtif_peK ;
  2672. mt_pe = mt_peA ET mt_peB ET mt_peC ET mt_peD ET mt_peE ET mt_peF ET
  2673. mt_peG ET mt_peH ET mt_peI ET mt_peJ ET mt_peK ;
  2674. mtin_t = mtin_tA ET mtin_tB ET mtin_tC ET mtin_tD ET mtin_tE ET mtin_tF
  2675. ET mtin_tG ET mtin_tH ET mtin_tI ET mtin_tJ ET mtin_tK ;
  2676. mtif_t = mtif_tA ET mtif_tB ET mtif_tC ET mtif_tD ET mtif_tE ET mtif_tF
  2677. ET mtif_tG ET mtif_tH ET mtif_tI ET mtif_tJ ET mtif_tK ;
  2678. mt_tfi = mt_tfiA ET mt_tfiB ET mt_tfiC ET mt_tfiD ET mt_tfiE ET mt_tfiF
  2679. ET mt_tfiG ET mt_tfiH ET mt_tfiI ET mt_tfiJ ET mt_tfiK ;
  2680.  
  2681. ELIM 1.e-8 (mthe ET mthe_p ET mtin ET mtif ET mtcb ET mtin_p ET mtif_p
  2682. ET mtcb_p ET mtin_pe ET mtif_pe ET mt_pe ET mtin_t ET
  2683. mtif_t ET mt_tfi);
  2684.  
  2685. mtt = mthe ET mthe_p ET mtin ET mtif ET mtcb ET mtin_p ET mtif_p ET
  2686. mtcb_p ET mtin_pe ET mtif_pe ET mt_pe ET mtin_t ET mtif_t ET
  2687. mt_tfi ;
  2688. mtt2 = mtt AFFI (1./8) (0. 0. 0.) (0. 0. 1.) ;
  2689.  
  2690.  
  2691. * V.2. Rallonges inferieure et superieure :
  2692. mtcbAr = VOLU stcb1r nhautA TRAN (0. 0. (z2 - z1));
  2693.  
  2694. mtcbErp = VOLU stcb5r nhautE TRAN (0. 0. (z6 - z5)) ;
  2695. mtcbFr = VOLU stcb6r nhautF TRAN (0. 0. (z7 - z6)) ;
  2696. mtcbGr = VOLU stcb7r nhautG TRAN (0. 0. (z8 - z7)) ;
  2697. mtcbHr = VOLU stcb8r nhautH TRAN (0. 0. (z9 - z8)) ;
  2698. mtcbIr = VOLU stcb9r nhautI TRAN (0. 0. (z10 - z9)) ;
  2699. mtcbEr = mtcbErp ET mtcbFr ET mtcbGr ET mtcbHr ET mtcbIr ;
  2700.  
  2701. ELIM 1.e-8 (mtcbEr ET stcb1r ET stcb2r ET stcb3r ET stcb4r ET stcb5r ET
  2702. stcb6r ET stcb7r ET stcb8r ET stcb9r ET stcb10r) ;
  2703.  
  2704.  
  2705. * V.3. Lame d'eau stagnante :
  2706. mt_lamA = VOLU st_lam1 nhautA TRAN (0. 0. (z2 - z1)) ;
  2707. mt_lamB = VOLU st_lam2 nhautB TRAN (0. 0. (z3 - z2)) ;
  2708. mt_lamC = VOLU st_lam3 nhautC TRAN (0. 0. (z4 - z3)) ;
  2709. mt_lamD = VOLU st_lam4 nhautD TRAN (0. 0. (z5 - z4)) ;
  2710. mt_lamE = VOLU st_lam5 nhautE TRAN (0. 0. (z6 - z5)) ;
  2711. mt_lamF = VOLU st_lam6 nhautF TRAN (0. 0. (z7 - z6)) ;
  2712. mt_lamG = VOLU st_lam7 nhautG TRAN (0. 0. (z8 - z7)) ;
  2713. mt_lamH = VOLU st_lam8 nhautH TRAN (0. 0. (z9 - z8)) ;
  2714. mt_lamI = VOLU st_lam9 nhautI TRAN (0. 0. (z10 - z9)) ;
  2715. mt_lamJ = VOLU st_lam10 nhautJ TRAN (0. 0. (z11 - z10)) ;
  2716. mt_lamK = VOLU st_lam11 nhautK TRAN (0. 0. (zM - z11)) ;
  2717.  
  2718. mt_lam = mt_lamA ET mt_lamB ET mt_lamC ET mt_lamD ET mt_lamE ET mt_lamF
  2719. ET mt_lamG ET mt_lamH ET mt_lamI ET mt_lamJ ET mt_lamK ;
  2720.  
  2721. ELIM 1.e-8 (mt_lam ET st_lam1 ET st_lam2 ET st_lam3 ET st_lam4 ET
  2722. st_lam5 ET st_lam6 ET st_lam7 ET st_lam8 ET st_lam9 ET
  2723. st_lam10 ET st_lam11 ET st_lamM) ;
  2724.  
  2725.  
  2726. * V.4. Tube de force externe :
  2727.  
  2728. *** Partie A->E :
  2729. mt_tfeA = VOLU stfext1 nhautA TRAN (0. 0. (z2 - z1)) ; comm volume ;
  2730. mt_tfeB = VOLU stfext2 nhautB TRAN (0. 0. (z3 - z2)) ;
  2731. mt_tfeC = VOLU stfext3 nhautC TRAN (0. 0. (z4 - z3)) ;
  2732. mt_tfeD = VOLU stfext4 nhautD TRAN (0. 0. (z5 - z4)) ;
  2733. mt_tfeE = VOLU stfext5 nhautE TRAN (0. 0. (z6 - z5)) ;
  2734.  
  2735. mten_tA = ltet1i_p TRAN nhautA (0. 0. (z2 - z1)) ; comm paroi interne ;
  2736. mten_tB = ltet2i_p TRAN nhautB (0. 0. (z3 - z2)) ;
  2737. mten_tC = ltet3i_p TRAN nhautC (0. 0. (z4 - z3)) ;
  2738. mten_tD = ltet4i_p TRAN nhautD (0. 0. (z5 - z4)) ;
  2739. mten_tE = ltet5i_p TRAN nhautE (0. 0. (z6 - z5)) ;
  2740.  
  2741. mtef_tA = ltet1e_p TRAN nhautA (0. 0. (z2 - z1)) ; comm paroi externe ;
  2742. mtef_tB = ltet2e_p TRAN nhautB (0. 0. (z3 - z2)) ;
  2743. mtef_tC = ltet3e_p TRAN nhautC (0. 0. (z4 - z3)) ;
  2744. mtef_tD = ltet4e_p TRAN nhautD (0. 0. (z5 - z4)) ;
  2745. mtef_tE = ltet5e_p TRAN nhautE (0. 0. (z6 - z5)) ;
  2746.  
  2747. *** Raccordement Partie F :
  2748. C21 = 0. 0. z6 ;
  2749. C22 = 0. 0. z7 ;
  2750. li2 = qte61i DROI nhautF qte71i ;
  2751. le2 = qte61e DROI nhautF qte71e ;
  2752. np2 = 2 * np ;
  2753.  
  2754. mt_tfeF = stfext6 VOLU stfext7 nhautF ;
  2755. mten_tF = li2 ROTA np2 360 C21 C22 ;
  2756. mtef_tF = le2 ROTA np2 360 C21 C22 ;
  2757.  
  2758. ***Parties G->J :
  2759. mt_tfeG = VOLU stfext7 nhautG TRAN (0. 0. (z8 - z7)) ; comm volume ;
  2760. mt_tfeH = VOLU stfext8 nhautH TRAN (0. 0. (z9 - z8)) ;
  2761. mt_tfeI = VOLU stfext9 nhautI TRAN (0. 0. (z10 - z9)) ;
  2762. mt_tfeJ = VOLU stfext10 nhautJ TRAN (0. 0. (z11 - z10)) ;
  2763. mt_tfeK = VOLU stfext11 nhautK TRAN (0. 0. (zM - z11)) ;
  2764.  
  2765. mten_tG = ltet7i_p TRAN nhautG (0. 0. (z8 - z7)) ; comm paroi interne ;
  2766. mten_tH = ltet8i_p TRAN nhautH (0. 0. (z9 - z8)) ;
  2767. mten_tI = ltet9i_p TRAN nhautI (0. 0. (z10 - z9)) ;
  2768. mten_tJ = ltet10i_ TRAN nhautJ (0. 0. (z11 - z10)) ;
  2769. mten_tK = ltet11i_ TRAN nhautK (0. 0. (zM - z11)) ;
  2770.  
  2771. mtef_tG = ltet7e_p TRAN nhautG (0. 0. (z8 - z7)) ; comm paroi externe ;
  2772. mtef_tH = ltet8e_p TRAN nhautH (0. 0. (z9 - z8)) ;
  2773. mtef_tI = ltet9e_p TRAN nhautI (0. 0. (z10 - z9)) ;
  2774. mtef_tJ = ltet10e_ TRAN nhautJ (0. 0. (z11 - z10)) ;
  2775. mtef_tK = ltet11e_ TRAN nhautK (0. 0. (zM - z11)) ;
  2776.  
  2777. *** Assemblage :
  2778. mt_tfe = mt_tfeA ET mt_tfeB ET mt_tfeC ET mt_tfeD ET mt_tfeE ET mt_tfeF
  2779. ET mt_tfeG ET mt_tfeH ET mt_tfeI ET mt_tfeJ ET mt_tfeK ;
  2780. mten_t = mten_tA ET mten_tB ET mten_tC ET mten_tD ET mten_tE ET mten_tF
  2781. ET mten_tG ET mten_tH ET mten_tI ET mten_tJ ET mten_tK ;
  2782. mtef_t = mtef_tA ET mtef_tB ET mtef_tC ET mtef_tD ET mtef_tE ET mtef_tF
  2783. ET mtef_tG ET mtef_tH ET mtef_tI ET mtef_tJ ET mtef_tK ;
  2784.  
  2785. ELIM 1.e-8 (mt_tfe et mtef_t et mten_t) ;
  2786.  
  2787.  
  2788. * V.5. Lame de gaz :
  2789.  
  2790. *** V.5.1. Cavite de gaz :
  2791. * Surface interne de la lame de gaz = surface externe du tdf interne
  2792. * Orientation vers le gaz ie vers l'exterieur :
  2793. cavint = INVE (ORIE mtif_t 'POINT' (0. 0. zM)) ;
  2794. vers cavint ;
  2795.  
  2796. * Surface externe de la lame de gaz = surface interne du tdf externe
  2797. * Orientation vers le gaz ie vers l'interieur :
  2798. cavext = ORIE mten_t 'POINT' (0. 0. zM) ;
  2799. vers cavext ;
  2800.  
  2801. lcav31 = cavint et cavext ;
  2802.  
  2803.  
  2804. *** V.5.2. Volume interieur pour la conduction :
  2805. mt_gaz = Sgaz VOLU 'ROTA' (np2) 360. C1 C2 ;
  2806.  
  2807.  
  2808.  
  2809.  
  2810. * V.6. ELIMINATION :
  2811.  
  2812. ELIM 1.e-8 (bahe ET hahe ET bahe_p ET hahe_p ET mthe ET mtin ET mtif ET
  2813. mtcb ET mtin_p ET mtif_p ET mtcb_p ET mtin_pe ET mtif_pe ET
  2814. mt_pe ET mtin_t ET mtif_t ET mt_tfi ET mtcbAr ET mtcbEr ET
  2815. mt_lam ET mt_tfe ET mtef_t ET mten_t ET lcav31 ET mt_gaz) ;
  2816.  
  2817. **************************FIN DU MAILLAGE*******************************
  2818. ************************************************************************
  2819.  
  2820.  
  2821. * CONSTRUCTION D'OBJETS UTILES AU CALCUL
  2822. ************************************************************************
  2823.  
  2824. ** I. Rayonnement
  2825.  
  2826. * I.1. Description
  2827. * stefan : constante de Stefan
  2828. * emistf : emmissivite du tube de force
  2829. * emistfi : emmisivite du tube de force interne
  2830. * emistfe : emmisivite du tube de force externe
  2831. * alpha1 : emmisivite equivalente pour le face a face
  2832.  
  2833. * I.2. Valeurs
  2834. stefan = 5.67E-8 ;
  2835. emistf = 0.7 ;
  2836. emistfi = emistf ;
  2837. emistfe = emistf ;
  2838. r_1 = 1. - emistfi ;
  2839. r_2 = 1. - emistfe ;
  2840. alpha1 = (emistfi*emistfe) / (1.-(r_1*r_2)) ;
  2841.  
  2842. * I.3. Rayonnement
  2843. mrcav1 = MODE lcav31 thermique RAYONNEMENT 'CAVITE';
  2844. ecav1 = MATE mrcav1 'EMIS' emistf ;
  2845.  
  2846. * I.4 Parametres pour traiter le rayonnement.
  2847. *Nombre d'iterations internes et facteur de relaxation ;
  2848. SI rayo ;
  2849. nitr1 = 10 ;
  2850. omgr1 = 0.5 ;
  2851. SINON ;
  2852. nitr1 = 1 ;
  2853. omgr1 = 1. ;
  2854. FINSI ;
  2855.  
  2856.  
  2857. ** II.Generation des QUAFs
  2858.  
  2859. _mtcbAr = 'CHANGER' mtcbAr 'QUAF' ;
  2860. _mtcbEr = 'CHANGER' mtcbEr 'QUAF' ;
  2861. _mtcb = 'CHANGER' mtcb 'QUAF' ;
  2862. _mtin = 'CHANGER' mtin 'QUAF' ;
  2863. _mtif = 'CHANGER' mtif 'QUAF' ;
  2864.  
  2865. _mthe = 'CHANGER' mthe 'QUAF' ;
  2866. _bahe = 'CHANGER' bahe 'QUAF' ;
  2867. _hahe = 'CHANGER' hahe 'QUAF' ;
  2868.  
  2869. _mtcb_p = 'CHANGER' mtcb_p 'QUAF' ;
  2870. _mtin_p = 'CHANGER' mtin_p 'QUAF' ;
  2871. _mtif_p = 'CHANGER' mtif_p 'QUAF' ;
  2872. _mt_lam = 'CHANGER' mt_lam 'QUAF' ;
  2873. _mt_pe = 'CHANGER' mt_pe 'QUAF' ;
  2874. _mtin_pe = 'CHANGER' mtin_pe 'QUAF' ;
  2875. _mtif_pe = 'CHANGER' mtif_pe 'QUAF' ;
  2876.  
  2877. _mthe_p = 'CHANGER' mthe_p 'QUAF' ;
  2878. _bahe_p = 'CHANGER' bahe_p 'QUAF' ;
  2879. _hahe_p = 'CHANGER' hahe_p 'QUAF' ;
  2880.  
  2881. _mt_tfi = 'CHANGER' mt_tfi 'QUAF' ;