Télécharger la plaquette Cast3M


fr en

Télécharger Random_Set_Theory_03.dgibi

Retour à la liste

Numérotation des lignes : 

  1. ***********************************************************************
  2. *
  3. * RSTHF.dgibi
  4. *
  5. * Random Set Theory analysis with Finite Elements (RS-FEM)
  6. *
  7. ***********************************************************************
  8.  
  9.  
  10. 'OPTI'  'DIME' 2  'MODE' 'AXIS'  'ELEM' 'QUA4' ;
  11. 'OPTI' 'TRAC' 'PSC';
  12. GRAPH = VRAI ;
  13.  
  14. R   =  5.00 ;
  15. RM  = 25.00 ;
  16.  
  17. HSA =  5.00 ;
  18. HSI = 10.00 ;
  19. HCL = 15.00 ;
  20.  
  21.  
  22. P1  ='POIN' 0.0 0.0 ;
  23. P2  ='POIN' 0.0 (-1.0 * HSA) ;
  24. P3  ='POIN' 0.0 (-1.0 * (HSA + HSI)) ;
  25. P4  ='POIN' 0.0 (-1.0 * (HSA + HSI + HCL)) ;
  26.  
  27. P5  ='POIN' R 0.0 ;
  28.  
  29. RH  = 0.50 ;
  30. RV  = 0.50 ;
  31.  
  32.  
  33. NVSA = ('ENTI' (HSA / RV) ) ;
  34. NVSI = ('ENTI' (HSI / RV) ) ;
  35. NVCL = ('ENTI' (HCL / RV) ) ;
  36.  
  37. D1   = DROI  NVSA  P1  P2 ;
  38. D2   = DROI  NVSI  P2  P3 ;
  39. D3   = DROI  NVCL  P3  P4 ;
  40.  
  41.  
  42. NR   = ( 'ENTI' (R   / RH)  ) ;
  43. NRM  = ( 'ENTI' ((RM - R)  / RH) ) ;
  44. NM   = ( 'ENTI' (RM  / RH) ) ;
  45.  
  46.  
  47. 'MESS' 'NR='  NR  ;
  48. 'MESS' 'NRM=' NRM ;
  49. 'MESS' 'NM='  NM  ;
  50.  
  51.  
  52. SRSA = D1  'TRAN'  NR  ('POIN' R        0.0)  'COUL' 'ROUG' ;
  53. D11  ='COTE' 3 SRSA ;
  54. SMSA = D11 'TRAN'  NRM ('POIN' (RM - R) 0.0)  'COUL' 'ROUG' ;
  55.  
  56.  
  57. SRSI = D2  'TRAN'  NR  ('POIN' R        0.0)  'COUL' 'BLEU' ;
  58. D21  ='COTE' 3 SRSI ;
  59. SMSI = D21 'TRAN'  NRM ('POIN' (RM - R) 0.0)  'COUL' 'BLEU' ;
  60.  
  61.  
  62. SRCL = D3  'TRAN'  NR  ('POIN' R        0.0)  'COUL' 'VERT' ;
  63. D31  ='COTE' 3 SRCL ;
  64. SMCL = D31 'TRAN'  NRM ('POIN' (RM - R) 0.0)  'COUL' 'VERT' ;
  65.  
  66.  
  67. DP   ='COTE' 4 SRSA 'COUL' 'NOIR' ;
  68.  
  69.  
  70. ST   = (SRSA 'ET' SMSA 'ET' SRSI 'ET' SMSI 'ET' SRCL 'ET' SMCL) ;
  71.  
  72. ELIM 0.1 ST ;
  73.  
  74.  
  75. CST  = CONT ST COUL NOIR ;
  76.  
  77.  
  78. D4   ='COTE' 2 SMCL ;
  79. D5   ='COTE' 3 SMCL ;
  80. D6   ='COTE' 3 SMSI ;
  81. D7   ='COTE' 3 SMSA ;
  82.  
  83.  
  84. MOCO = 'MODE' DP MECANIQUE ELASTIQUE ISOTROPE COQ2 ;
  85.  
  86. MOSA = 'MODE' (SRSA 'ET' SMSA) MECANIQUE ELASTIQUE ISOTROPE ;
  87. MOSI = 'MODE' (SRSI 'ET' SMSI) MECANIQUE ELASTIQUE ISOTROPE ;
  88. MOCL = 'MODE' (SRCL 'ET' SMCL) MECANIQUE ELASTIQUE ISOTROPE ;
  89.  
  90.  
  91. MOTOT= ( MOCO 'ET' MOSA 'ET' MOSI 'ET' MOCL ) ;
  92.  
  93.  
  94. BLR1 ='BLOQ' UR (D1 'ET' D2 'ET' D3) ;
  95. BLR2 ='BLOQ' UR (D5 'ET' D6 'ET' D7) ;
  96. BLZ1 ='BLOQ' UR UZ D4 ;
  97. BLT  = BLR1 'ET' BLR2 'ET' BLZ1 ;
  98. CACO ='CARA' MOCO 'EPAI' 1.0 ;
  99. MACO ='MATE' MOCO  'YOUN' 3.0e9  'NU' 0.33 ;
  100.  
  101.  
  102.  
  103. RS  = OBJET @RSTH ;
  104. RST ='TABL' ;
  105.  
  106.  
  107. RST.'PRS'        ='TABL' ;
  108. RST.'PRS'.'MIN'  ='PROG' 1.0e5 ;
  109. RST.'PRS'.'MAX'  ='PROG' 2.0e5 ;
  110. RST.'PRS'.'CPB'  ='PROG' 1.0   ;
  111. RST.'PRS'.'MINS' = RS%'SCV'  RST.'PRS'.'MIN' ;
  112. RST.'PRS'.'MAXS' = RS%'SCV'  RST.'PRS'.'MAX' ;
  113. RST.'PRS'.'CPBS' = RS%'SCS'  RST.'PRS'.'CPB' ;
  114.  
  115. PRSN = ('EVOL'  'MANU'  'MIN'  RST.'PRS'.'MINS'
  116.                         'CPB'  RST.'PRS'.'CPBS' ) ;
  117. PRSX = ('EVOL'  'MANU'  'MAX'  RST.'PRS'.'MAXS'
  118.                         'CPB'  RST.'PRS'.'CPBS' ) ;
  119.  
  120.  
  121. RST.'ESA'        ='TABL' ;
  122. RST.'ESA'.'MIN'  ='PROG' 3.0e7 3.2e7;
  123. RST.'ESA'.'MAX'  ='PROG' 3.6e7 3.8e7;
  124. RST.'ESA'.'CPB'  ='PROG' 0.5   0.5  ;
  125. RST.'ESA'.'MINS' = RS%'SCV'  RST.'ESA'.'MIN' ;
  126. RST.'ESA'.'MAXS' = RS%'SCV'  RST.'ESA'.'MAX' ;
  127. RST.'ESA'.'CPBS' = RS%'SCS'  RST.'ESA'.'CPB' ;
  128.  
  129. ESAN = ('EVOL'  'MANU'  'MIN'  RST.'ESA'.'MINS'
  130.                         'CPB'  RST.'ESA'.'CPBS' ) ;
  131. ESAX = ('EVOL'  'MANU'  'MAX'  RST.'ESA'.'MAXS'
  132.                         'CPB'  RST.'ESA'.'CPBS' ) ;
  133.  
  134.  
  135. RST.'NSA'        ='TABL' ;
  136. RST.'NSA'.'MIN'  ='PROG' 0.30 ;
  137. RST.'NSA'.'MAX'  ='PROG' 0.35 ;
  138. RST.'NSA'.'CPB'  ='PROG' 1.00 ;
  139. RST.'NSA'.'MINS' = RS%'SCV'  RST.'NSA'.'MIN' ;
  140. RST.'NSA'.'MAXS' = RS%'SCV'  RST.'NSA'.'MAX' ;
  141. RST.'NSA'.'CPBS' = RS%'SCS'  RST.'NSA'.'CPB' ;
  142.  
  143. NSAN = ('EVOL'  'MANU'  'MIN'  RST.'NSA'.'MINS'
  144.                         'CPB'  RST.'NSA'.'CPBS' ) ;
  145. NSAX = ('EVOL'  'MANU'  'MAX'  RST.'NSA'.'MAXS'
  146.                         'CPB'  RST.'NSA'.'CPBS' ) ;
  147.  
  148.  
  149. RST.'ESI'        ='TABL' ;
  150. RST.'ESI'.'MIN'  ='PROG' 2.0e7 2.2e7 ;
  151. RST.'ESI'.'MAX'  ='PROG' 2.6e7 2.8e7 ;
  152. RST.'ESI'.'CPB'  ='PROG' 0.3   0.7   ;
  153. RST.'ESI'.'MINS' = RS%'SCV'  RST.'ESI'.'MIN' ;
  154. RST.'ESI'.'MAXS' = RS%'SCV'  RST.'ESI'.'MAX' ;
  155. RST.'ESI'.'CPBS' = RS%'SCS'  RST.'ESI'.'CPB' ;
  156.  
  157. ESIN = ('EVOL'  'MANU'  'MIN'  RST.'ESI'.'MINS'
  158.                         'CPB'  RST.'ESI'.'CPBS' ) ;
  159. ESIX = ('EVOL'  'MANU'  'MAX'  RST.'ESI'.'MAXS'
  160.                         'CPB'  RST.'ESI'.'CPBS' ) ;
  161.  
  162.  
  163. RST.'NSI'        ='TABL' ;
  164. RST.'NSI'.'MIN'  ='PROG' 0.35 ;
  165. RST.'NSI'.'MAX'  ='PROG' 0.40 ;
  166. RST.'NSI'.'CPB'  ='PROG' 1.00 ;
  167. RST.'NSI'.'MINS' = RS%'SCV'  RST.'NSI'.'MIN' ;
  168. RST.'NSI'.'MAXS' = RS%'SCV'  RST.'NSI'.'MAX' ;
  169. RST.'NSI'.'CPBS' = RS%'SCS'  RST.'NSI'.'CPB' ;
  170.  
  171. NSIN = ('EVOL'  'MANU'  'MIN'  RST.'NSI'.'MINS'
  172.                         'CPB'  RST.'NSI'.'CPBS' ) ;
  173. NSIX = ('EVOL'  'MANU'  'MAX'  RST.'NSI'.'MAXS'
  174.                         'CPB'  RST.'NSI'.'CPBS' ) ;
  175.  
  176.  
  177. RST.'ECL'        ='TABL' ;
  178. RST.'ECL'.'MIN'  ='PROG' 1.0e7 1.2e7 ;
  179. RST.'ECL'.'MAX'  ='PROG' 1.6e7 1.8e7 ;
  180. RST.'ECL'.'CPB'  ='PROG' 0.2   0.8   ;
  181. RST.'ECL'.'MINS' = RS%'SCV'  RST.'ECL'.'MIN' ;
  182. RST.'ECL'.'MAXS' = RS%'SCV'  RST.'ECL'.'MAX' ;
  183. RST.'ECL'.'CPBS' = RS%'SCS'  RST.'ECL'.'CPB' ;
  184.  
  185. ECLN = ('EVOL'  'MANU'  'MIN'  RST.'ECL'.'MINS'
  186.                         'CPB'  RST.'ECL'.'CPBS' ) ;
  187. ECLX = ('EVOL'  'MANU'  'MAX'  RST.'ECL'.'MAXS'
  188.                         'CPB'  RST.'ECL'.'CPBS' ) ;
  189.  
  190.  
  191. RST.'NCL' ='TABL' ;
  192.  
  193. RST.'NCL'.'MIN' ='PROG' 0.40 ;
  194. RST.'NCL'.'MAX' ='PROG' 0.45 ;
  195. RST.'NCL'.'CPB' ='PROG' 1.00 ;
  196. RST.'NCL'.'MINS' = RS%'SCV'  RST.'NCL'.'MIN' ;
  197. RST.'NCL'.'MAXS' = RS%'SCV'  RST.'NCL'.'MAX' ;
  198. RST.'NCL'.'CPBS' = RS%'SCS'  RST.'NCL'.'CPB' ;
  199.  
  200. NCLN = ('EVOL'  'MANU'  'MIN'  RST.'NCL'.'MINS'
  201.                         'CPB'  RST.'NCL'.'CPBS' ) ;
  202. NCLX = ('EVOL'  'MANU'  'MAX'  RST.'NCL'.'MAXS'
  203.                         'CPB'  RST.'NCL'.'CPBS' ) ;
  204.  
  205.  
  206. RS%'RST' RST ;
  207.  
  208.  
  209. JX = RST.'PRS'.'CX' ;
  210.  
  211.  
  212. 'REPE' J JX ;
  213.  
  214.  'SI' ('EGA' (@MOD &J 100) 0 ) ;
  215.   'MESS' 'J=' &J ;
  216.  'FINS' ;
  217.  
  218.  RS%'RSV'  &J  0 ;
  219.  
  220.  CHP   ='PRES'  'COQU'  MOCO  RST.'PRS'.'VN'  'NORM' ;
  221.  
  222.  MASA  ='MATE'  MOSA  'YOUN'  RST.'ESA'.'VN'  'NU'  RST.'NSA'.'VN' ;
  223.  MASI  ='MATE'  MOSI  'YOUN'  RST.'ESI'.'VN'  'NU'  RST.'NSI'.'VN' ;
  224.  MACL  ='MATE'  MOCL  'YOUN'  RST.'ECL'.'VN'  'NU'  RST.'NCL'.'VN' ;
  225.  
  226.  MAT   = CACO 'ET' MACO 'ET' MASA 'ET' MASI 'ET' MACL ;
  227.  
  228.  RG1   ='RIGI'  MOTOT  MAT ;
  229.  
  230.  RGT   = RG1 'ET' BLT ;
  231.  
  232.  DPT   ='RESO'  RGT  CHP ;
  233.  
  234.  DZT   ='EXCO'  DPT  'UZ'  'UZ' ;
  235.  
  236.  DZDP  ='REDU'  DZT  DP ;
  237.  
  238.  DZDPN ='MINI'  DZDP ;
  239.  
  240.  RS%'RSR'  DZDPN  &J ;
  241.  
  242. 'FIN' J ;
  243.  
  244.  
  245. VCHP ='VECT'  CHP  3.0e-6  'FORC'  'COUL'  'NOIR' ;
  246.  
  247. DFT  ='DEFO'  DZT  ST  VCHP ;
  248.  
  249.  
  250. 'SI' GRAPH ;
  251.  'TRAC'  'FACE'  (ST 'ET' DP)
  252.   'TITR' 'Random-set Theory - Foundation settlement analysis - Mesh' ;
  253.  'TRAC'  DZT  DFT  CST
  254.   'TITR' 'Vertical displacements and deformed state [m] - Example' ;
  255.  'DESS' ( PRSN 'ET' PRSX )
  256.   'TITX' 'Foundation pressure load [N/m^{2}]'
  257.   'POSX' 'CENT'
  258.   'XBOR'  0.0e5   3.0e5
  259.   'XGRA'  2.0e4
  260.   'TITY' 'CPB [1]'
  261.   'POSY' 'CENT'
  262.   'YBOR'  0.0     1.0
  263.   'YGRA'  0.1
  264.   'TITR' 'Random Set Theory - Foundation settlement analysis'
  265.   'GRIL' 'POIN' 'GRIS' ;
  266.  'DESS' ( ESAN 'ET' ESAX )
  267.   'TITX' 'Sand - E [N/m^{2}]'
  268.   'POSX' 'CENT'
  269.   'XBOR'  5.0e6   5.0e7
  270.   'XGRA'  5.0e6
  271.   'TITY' 'CPB [1]'
  272.   'POSY' 'CENT'
  273.   'YBOR'  0.0     1.0
  274.   'YGRA'  0.1
  275.   'TITR' 'Random Set Theory - Foundation settlement analysis'
  276.   'GRIL' 'POIN' 'GRIS' ;
  277.  'DESS' ( NSAN 'ET' NSAX )
  278.   'TITX' 'Sand - Nu [1]'
  279.   'POSX' 'CENT'
  280.   'XGRA'  0.05
  281.   'XBOR'  0.0     0.5
  282.   'TITY' 'CPB [1]'
  283.   'POSY' 'CENT'
  284.   'YBOR'  0.0     1.0
  285.   'YGRA'  0.1
  286.   'TITR' 'Random Set Theory - Foundation settlement analysis'
  287.   'GRIL' 'POIN' 'GRIS' ;
  288.  'DESS' ( ESIN 'ET' ESIX )
  289.   'TITX' 'Silt - E [N/m^{2}]'
  290.   'POSX' 'CENT'
  291.   'XBOR'  5.0e6   5.0e7
  292.   'XGRA'  5.0e6
  293.   'TITY' 'CPB [1]'
  294.   'POSY' 'CENT'
  295.   'YBOR'  0.0     1.0
  296.   'YGRA'  0.1
  297.   'TITR' 'Random Set Theory - Foundation settlement analysis'
  298.   'GRIL' 'POIN' 'GRIS' ;
  299.  'DESS' ( NSIN 'ET' NSIX )
  300.   'TITX' 'Silt - Nu [1]'
  301.   'POSX' 'CENT'
  302.   'XBOR'  0.0     0.5
  303.   'XGRA'  0.05
  304.   'TITY' 'CPB [1]'
  305.   'POSY' 'CENT'
  306.   'YBOR'  0.0     1.0
  307.   'YGRA'  0.1
  308.   'TITR' 'Random Set Theory - Foundation settlement analysis'
  309.   'GRIL' 'POIN' 'GRIS' ;
  310.  'DESS' ( ECLN 'ET' ECLX )
  311.   'TITX' 'Clay - E [N/m^{2}]'
  312.   'POSX' 'CENT'
  313.   'XBOR'  5.0e6   5.0e7
  314.   'XGRA'  5.0e6
  315.   'TITY' 'CPB [1]'
  316.   'POSY' 'CENT'
  317.   'YBOR'  0.0     1.0
  318.   'YGRA'  0.1
  319.   'TITR' 'Random Set Theory - Foundation settlement analysis'
  320.   'GRIL' 'POIN' 'GRIS' ;
  321.  'DESS' ( NCLN 'ET' NCLX )
  322.   'TITX' 'Clay - Nu [1]'
  323.   'POSX' 'CENT'
  324.   'XBOR'  0.0     0.5
  325.   'XGRA'  0.05
  326.   'TITY' 'CPB [1]'
  327.   'POSY' 'CENT'
  328.   'YBOR'  0.0     1.0
  329.   'YGRA'  0.1
  330.   'TITR' 'Random Set Theory - Foundation settlement analysis'
  331.   'GRIL' 'POIN' 'GRIS' ;
  332.  'DESS' ( RS.'RT'.'EN' 'ET' RS.'RT'.'EX' )
  333.   'TITX' 'u_{z} [m]'
  334.   'POSX' 'CENT'
  335.   'XBOR' -4.5e-2  0.0
  336.   'XGRA'  0.005
  337.   'TITY' 'CPB [1]'
  338.   'POSY' 'CENT'
  339.   'YBOR'  0.0     1.0
  340.   'YGRA'  0.1
  341.   'TITR' 'Random Set Theory - Foundation settlement analysis'
  342.   'GRIL' 'POIN' 'GRIS' ;
  343. 'FINS' ;
  344.  
  345. 'FIN' ;
  346.  
  347.  
  348.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales