Télécharger Mooney_Traction3D.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : Mooney_Traction3D.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE MOONEY RIVLIN QUASI-INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION (3D) SIMPLE SELON AXE Z *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE INCOMPRESSIBLE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2008) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2006, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 3 'MODE' 'TRID' 'ECHO' 0 ;
  24. option epsilon 'UTILISATEUR';
  25.  
  26. * Mettre VRAI si l'on souhaite divers traces.
  27. GRAPH = FAUX ;
  28. * Mettre 1 ou 2 selon le type de calcul voulu
  29. ICALCUL = 1 ;
  30. *
  31. 'SI' ('>' ICALCUL 2) ;
  32. 'MESS' 'ICALCUL doit valoir 1 ou 2' ;
  33. 'ERREUR' 5 ;
  34. 'FINSI' ;
  35.  
  36. title = 'CHAINE' 'MOONEY RIVLIN - ' 'TRACTION UNIAXIALE Z' ;
  37.  
  38. *======================================================================*
  39. * Geometrie - Maillage *
  40. *======================================================================*
  41. * Longueur (direction x) du pave :
  42. Lg_x = 1. ;
  43. * Largeur (direction y) du pave :
  44. Lg_y = 1. ;
  45. * Hauteur (direction z) du pave :
  46. Lg_z = 1. ;
  47. * Nombre d'elements selon les directions x, y et z :
  48. 'SI' ('EGA' ICALCUL 1) ;
  49. Nel_x = 2 ;
  50. Nel_y = 2 ;
  51. Nel_z = 2 ;
  52. 'OPTION' 'ELEM' 'CUB8' ;
  53. 'FINSI' ;
  54. 'SI' ('EGA' ICALCUL 2) ;
  55. Nel_x = 3 ;
  56. Nel_y = 3 ;
  57. Nel_z = 7 ;
  58. 'OPTION' 'ELEM' 'CU20' ;
  59. 'FINSI' ;
  60. *
  61. P1 = 0. 0. 0. ;
  62. P2 = Lg_x 0. 0. ;
  63. P3 = Lg_x Lg_y 0. ;
  64. P4 = 0. Lg_y 0. ;
  65. *
  66. L1 = 'DROITE' Nel_x P1 P2 ;
  67. L2 = 'DROITE' Nel_y P2 P3 ;
  68. L3 = 'DROITE' Nel_x P3 P4 ;
  69. L4 = 'DROITE' Nel_y P4 P1 ;
  70. *
  71. SBas = 'DALLER' L1 L2 L3 L4 ;
  72. Pave = 'VOLUME' SBas 'TRANS' Nel_z (0. 0. Lg_z) ;
  73. Shau = 'FACE' 2 Pave 'COULEUR' 'BLEU' ;
  74. 'SI' GRAPH ;
  75. 'TRACER' Pave 'TITRE' ('CHAINE' title ' - MAILLAGE') 'CACH' ;
  76. 'FINSI' ;
  77.  
  78. *======================================================================*
  79. * Modele - Materiau - Caracteristiques (en Pa) *
  80. *======================================================================*
  81. * Ne pas oublier de definir les parametres lies a l'elasticite.
  82. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  83. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  84. *
  85. LCMAT = 'MOTS' 'YOUN' 'NU ' 'D ' 'C1' 'C2' ;
  86. MO = 'MODELISER' Pave 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  87. 'NON_LINEAIRE' 'UTILISATEUR'
  88. 'NUME_LOI' 31 'C_MATERIAU' LCMAT ;
  89. *
  90. * Coefficients du modele de Mooney-Rivlin (en MPa) :
  91. CoeC1 = 0.183 ; CoeC2 = 0.0034 ;
  92. * CoeC1 = 1. MPa et CoeD = 1.E-4 MPa**-1 !
  93. * Lorsque CoeD tend vers 0, on retrouve un modele de type Mooney-Rivlin
  94. * incompressible. Ici on met une valeur "petite" de CoeD pour pouvoir
  95. * utiliser la solution analytique du modele de Mooney-Rivlin correspon-
  96. * dant pour les tests de comparaison. Si CoeD a une valeur trop "impor-
  97. * tante", il faut modifier la valeur du coefficient de Poisson, qui
  98. * s'eloigne alors de 0.5 (incompressibilite).
  99. * On fixe le coefficient de Poisson ("proche" de 0.5 si D est "petit").
  100. * Le module de Young initial est alors connu :
  101. * (le module de cisaillement vaut pour ce modele : mu = 2.CoeC1)
  102. * La valeur du module de Young utilise pour les estimations elastiques
  103. * doit etre superieure au module tangent pour le niveau de deformation
  104. * atteint en fin de calcul (sinon risque de non convergence).
  105.  
  106. *XNU = 0.499 ;
  107. YOUini = 3.*(2.*(CoeC1+CoeC2)) ;
  108. *
  109. 'SI' ('EGA' ICALCUL 1) ;
  110. XNU = 0.497 ;
  111. CoeD = 1.E-4 ;
  112. YOU = 100. * YOUini ;
  113. 'FINSI' ;
  114. 'SI' ('EGA' ICALCUL 2) ;
  115. XNU = 0.495 ;
  116. CoeD = 1.E-2 ;
  117. YOU = 200. * YOUini ;
  118. 'FINSI' ;
  119. *
  120. MA = 'MATERIAU' MO 'YOUN' YOU 'NU ' XNU
  121. 'D ' CoeD 'C1 ' CoeC1 'C2 ' CoeC2 ;
  122.  
  123. *==================================================================*
  124. * Conditions aux limites *
  125. *==================================================================*
  126. BL1 = 'BLOQUER' 'UZ ' Shau ;
  127. BL2 = 'BLOQUER' 'UZ ' Sbas ;
  128. BL3 = 'BLOQUER' 'UX ' L4 ;
  129. BL4 = 'BLOQUER' 'UY ' L1 ;
  130. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  131. *
  132. * Definition des instants du chargement :
  133. t_deb = 0. ; t_fin = 10. ;
  134. L_tps = 'PROG' t_deb t_fin ;
  135. * Deplacement suivant Z :
  136. L_UZ = 'PROG' 0. (3.0 * Lg_z) ;
  137. FF_z = 'DEPIMP' BL1 1. ;
  138. EV_z = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMZ' L_UZ ;
  139. CHARTOT = 'CHARGEMENT' 'DIMP' FF_z EV_z ;
  140.  
  141. *======================================================================*
  142. * Initialisation de la table pour appel a PASAPAS *
  143. *======================================================================*
  144. TAB1 = 'TABLE' ;
  145. TAB1.'MODELE' = MO ;
  146. TAB1.'CARACTERISTIQUES' = MA ;
  147. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  148. TAB1.'CHARGEMENT' = CHARTOT ;
  149. *TAB1.'PRECISION' = 1.E-7 ;
  150. *TAB1.'FTOL' = 1.E-5 ;
  151. *TAB1.'MTOL' = 1.E-5 ;
  152. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  153. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  154. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  155. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  156. *
  157. L_abs = TAB1.'TEMPS_SAUVES' ;
  158. n_abs = 'DIMENSION' L_abs ;
  159. *
  160. TAB1.'K_SIGMA'=faux;
  161. TAB1 . 'REAC_GRANDS' = 1. ;
  162. PASAPAS TAB1 ;
  163. *
  164. * Quelques traces de controle apres calculs
  165. 'SI' GRAPH ;
  166. Defo_0 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  167. Defo_1 = 'DEFORMEE' Pave (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  168. 'TRACER' (Defo_0 'ET' Defo_1)
  169. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  170. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  171. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  172. 'FINSI' ;
  173. *
  174. *======================================================================*
  175. * Construction de la solution analytique INCOMPRESSIBLE *
  176. *======================================================================*
  177. * Definitions :
  178. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  179. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  180. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  181. * Dans le cas du modele Neo-Hookeen :
  182. * W = CoeC1*(I1-3.) , soit dW/dI1 = CoeC1 et dW/dI2 = 0.
  183. *
  184. * Les contraintes de Cauchy sont calculables analytiquement :
  185. * - SCxx = 0.
  186. * - SCyy = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  187. * - SCxy = 0 (pas de cisaillement)
  188. * - SCzz = 0 (hypothese des contraintes planes)
  189. *
  190. L_Un = 'PROG' n_abs '*' 1. ;
  191. Lamz = L_Un + (('IPOL' L_abs L_tps L_UZ) / Lg_z) ;
  192. *
  193. SCxx_th = 0. * L_Un ;
  194. SCyy_th = 0. * L_Un ;
  195. L_z1 = Lamz * Lamz ; L_z2 = L_Un / Lamz ;
  196. SCzz_th = (L_z1 - L_z2) * ((2.*CoeC1*L_Un) + (2.*CoeC2*L_z2)) ;
  197. SCxy_th = 0. * L_Un ;
  198. SCxz_th = 0. * L_Un ;
  199. SCyz_th = 0. * L_Un ;
  200. *
  201. *======================================================================*
  202. * Comparaison des resultats avec la solution analytique *
  203. *======================================================================*
  204. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  205. * calculees et les solutions analytiques correspondantes.
  206. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  207. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  208. *
  209. TabD = TAB1.'DEPLACEMENTS' ;
  210. TabS = TAB1.'CONTRAINTES' ;
  211. Confini = 'FORM' ;
  212. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  213. *
  214. SCxx = 'PROG' 0. ;
  215. SCyy = 'PROG' 0. ;
  216. SCzz = 'PROG' 0. ;
  217. SCxy = 'PROG' 0. ;
  218. SCxz = 'PROG' 0. ;
  219. SCyz = 'PROG' 0. ;
  220. 'REPETER' Boucle (n_abs - 1) ;
  221. 'FORM' (TabD.&Boucle) ;
  222. VolSU = 'INTG' MO ChmUn ;
  223. mess ' volsu ' volsu;
  224. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  225. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  226. SCzz = SCzz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMZZ')/VolSU)) ;
  227. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  228. SCxz = SCxz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXZ')/VolSU)) ;
  229. SCyz = SCyz 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYZ')/VolSU)) ;
  230. 'FORM' Confini ;
  231. 'FIN' Boucle ;
  232. *
  233. * LG lamb
  234. L_abs = Lamz;
  235. *
  236. 'SI' GRAPH ;
  237. tlege = 'TABLE' ;
  238. tlege. 1 = 'MARQ CROI' ;
  239. tlege.'TITRE' = 'TABLE' ;
  240. tlege.'TITRE'. 1 = 'Numerique' ;
  241. tlege.'TITRE'. 2 = 'Analytique' ;
  242. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  243. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  244. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  245. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  246. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  247. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  248. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  249. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  250. Evzz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz ;
  251. Evzz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCZZ' SCzz_th ;
  252. 'DESSIN' (Evzz 'ET' Evzz_th) 'LEGE' tlege
  253. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY ZZ (Pa)') ;
  254. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  255. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  256. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  257. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  258. Evxz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz ;
  259. Evxz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXZ' SCxz_th ;
  260. 'DESSIN' (Evxz 'ET' Evxz_th) 'LEGE' tlege
  261. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  262. Evyz = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz ;
  263. Evyz_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYZ' SCyz_th ;
  264. 'DESSIN' (Evyz 'ET' Evyz_th) 'LEGE' tlege
  265. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  266. 'FINSI' ;
  267. *
  268. * Tests de bon fonctionnement :
  269. Smaxref = 'MAXIMUM' ('ABS' SCzz_th) ;
  270. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / Smaxref ;
  271. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / Smaxref ;
  272. r_zz = 'MAXIMUM' ('ABS' (SCzz - SCzz_th)) / Smaxref ;
  273. uu= ('ABS' (SCzz - SCzz_th)) / Smaxref;
  274. list sczz; list SCzz_th; list uu;
  275. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / Smaxref ;
  276. r_xz = 'MAXIMUM' ('ABS' (SCxz - SCxz_th)) / Smaxref ;
  277. r_yz = 'MAXIMUM' ('ABS' (SCyz - SCyz_th)) / Smaxref ;
  278. *
  279. MESS ' RESULTATS : ' title ;
  280. MESS ' ------------------------------------------------- ';
  281. 'SAUTER' 1 'LIGNE' ;
  282. 'MESS' ' Tests de bon fonctionnement :' ;
  283. 'MESS' ' -------------------------------' ;
  284. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  285. 'MESS' ' Ecart relatif maximal entre la valeur moyenne calculee' ;
  286. 'MESS' ' et la solution analytique' ;
  287. 'MESS' ' Composante XX : ' r_xx ;
  288. 'MESS' ' Composante YY : ' r_yy ;
  289. 'MESS' ' Composante ZZ : ' r_zz ;
  290. 'MESS' ' Composante XY : ' r_xy ;
  291. 'MESS' ' Composante XZ : ' r_xz ;
  292. 'MESS' ' Composante YZ : ' r_yz ;
  293. 'SAUTER' 1 'LIGNE' ;
  294. * Ecart relatif maximal tolere
  295. 'SI' ('EGA' ICALCUL 1) ;
  296. Sigref = 1.E-3 ;
  297. 'FINSI' ;
  298. 'SI' ('EGA' ICALCUL 2) ;
  299. Sigref = 1.E-2 ;
  300. 'FINSI' ;
  301. *
  302. L_z = 'PROG' r_xx r_yy r_zz r_xy r_xz r_yz ;
  303. 'SI' ('>EG' ('MAXIMUM' L_z) Sigref) ;
  304. 'MESS' ' ---------------------' ;
  305. 'MESS' ' ECHEC DU CAS-TEST !' ;
  306. 'MESS' ' ---------------------' ;
  307. 'ERREUR' 5 ;
  308. 'SINON' ;
  309. 'MESS' ' ----------------------' ;
  310. 'MESS' ' SUCCES DU CAS-TEST !' ;
  311. 'MESS' ' ----------------------' ;
  312. 'FINSI' ;
  313. 'SAUTER' 1 'LIGNE' ;
  314.  
  315. 'FIN' ;
  316.  
  317.  
  318.  
  319.  
  320.  
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  
  327.  
  328.  
  329.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales