Télécharger Mooney_LRGTreloar_Traction.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : Mooney_LRGTreloar_Traction.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE MOONEY-RIVLIN INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION SELON LA DIRECTION Y *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2006) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2006, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24.  
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. GRAPH = FAUX ;
  27.  
  28. title = 'CHAINE' 'MOONEY-RIVLIN - ' 'TRACTION UNIAXIALE Y' ;
  29.  
  30. *======================================================================*
  31. * Geometrie - Maillage *
  32. *======================================================================*
  33. * Longueur (direction x) de la plaque/membrane :
  34. Lg_x = 1. ;
  35. * Largeur (direction y) de la plaque/membrane :
  36. Lg_y = 1. ;
  37. * Nombre d'elements selon les directions x et y :
  38. Nel_x = 2 ;
  39. Nel_y = 2 ;
  40. *
  41. 'OPTION' 'ELEM' 'TRI6' ;option epsilon 'UTILISATEUR';
  42. *
  43. P1 = 0. 0. ;
  44. P2 = Lg_x 0. ;
  45. P3 = Lg_x Lg_y ;
  46. P4 = 0. Lg_y ;
  47. *
  48. L1 = 'DROITE' Nel_x P1 P2 ;
  49. L2 = 'DROITE' Nel_y P2 P3 ;
  50. L3 = 'DROITE' Nel_x P3 P4 ;
  51. L4 = 'DROITE' Nel_y P4 P1 ;
  52. *
  53. SU = 'DALLER' L1 L2 L3 L4 ;
  54. 'SI' GRAPH ;
  55. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  56. 'FINSI' ;
  57.  
  58. *======================================================================*
  59. * Modele - Materiau - Caracteristiques (en Pa) *
  60. *======================================================================*
  61. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'ET'
  62. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  63. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  64. 'ERREUR' 5 ;
  65. 'FINSI' ;
  66. *
  67. * Ne pas oublier de definir les parametres lies a l'elasticite.
  68. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  69. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  70. *
  71. LCMAT = 'MOTS' 'YOUN' 'NU ' 'C1 ' 'C2 ' ;
  72. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  73. 'NON_LINEAIRE' 'UTILISATEUR'
  74. 'NUME_LOI' 31 'C_MATERIAU' LCMAT ;
  75. *
  76. * Coefficients du modele de Mooney-Rivlin (en Pa) :
  77. C1 = 0.183E+6 ; C2 = 0.0034E+6 ;
  78. *
  79. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  80. * du fait de l'incompressibilite inherente au modele.
  81. * Le module de Young YOU est alors connu, car, pour ce modele, le
  82. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  83. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  84. * de la traction. En fonction du niveau de deformation atteinte en
  85. * traction, il faut augmenter cette valeur afin de pouvoir faire
  86. * converger les calculs (module tangent en fin de calculs).
  87. * Prendre des valeurs superieures n'entraine pas de modification des
  88. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  89. *
  90. XNU = 0.497 ;
  91. YOUini = 3.*(2.*(C1+C2)) ; YOU = 100. * YOUini ;
  92. *
  93. MA = 'MATERIAU' MO 'YOUN' YOU 'NU ' XNU
  94. 'C1 ' C1 'C2 ' C2 ;
  95.  
  96. *======================================================================*
  97. * Conditions aux limites - Traction suivant UY *
  98. *======================================================================*
  99. BL1 = 'BLOQUER' 'UY ' L1 ;
  100. BL2 = 'BLOQUER' 'UY ' L3 ;
  101. BL4 = 'BLOQUER' 'UX ' P1 ;
  102. BLTOT = BL1 'ET' BL2 'ET' BL4 ;
  103. *
  104. * Definition des instants du chargement :
  105. t_deb = 0. ; t_fin = 10. ;
  106. L_tps = 'PROG' t_deb t_fin ;
  107. * Deplacement suivant Y :
  108. L_UY = 'PROG' 0. ( 3. * Lg_y) ;
  109. FF_y = 'DEPIMP' BL2 1. ;
  110. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMY' L_UY ;
  111. CHARTOT = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  112.  
  113. *======================================================================*
  114. * Initialisation de la table pour appel a PASAPAS *
  115. *======================================================================*
  116. TAB1 = 'TABLE' ;
  117. TAB1.'MODELE' = MO ;
  118. TAB1.'CARACTERISTIQUES' = MA ;
  119. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  120. TAB1.'CHARGEMENT' = CHARTOT ;
  121. *TAB1.'PRECISION' = 1.E-5 ;
  122. *TAB1.'FTOL' = 1.E-5 ;
  123. *TAB1.'MTOL' = 1.E-5 ;
  124. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  125. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  126. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  127. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  128. *
  129. L_abs = TAB1.'TEMPS_SAUVES' ;
  130. n_abs = 'DIMENSION' L_abs ;
  131. *
  132. PASAPAS TAB1 ;
  133. *
  134. * Quelques traces de controle apres calculs
  135. 'SI' GRAPH ;
  136. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  137. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  138. 'TRACER' (Defo_0 'ET' Defo_1)
  139. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  140. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  141. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  142. 'FINSI' ;
  143. *
  144. *======================================================================*
  145. * Construction de la solution analytique *
  146. *======================================================================*
  147. * Definitions :
  148. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  149. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  150. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  151. * Dans le cas du modele de Mooney-Rivlin :
  152. * W = C1*(I1-3.)+C2*(I2-3.) , soit dW/dI1 = C1 et dW/dI2 = C2
  153. *
  154. * Les contraintes de Cauchy sont calculables analytiquement :
  155. * - SCxx = 0.
  156. * - SCyy = 2.(Lamy**2 - 1./Lamy).(dW/dI1 + 1./Lamy.dW/dI2)
  157. * - SCxy = 0 (pas de cisaillement)
  158. * - SCzz = 0 (hypothese des contraintes planes)
  159. *
  160. L_Un = 'PROG' n_abs '*' 1. ;
  161. Lamy = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  162. *
  163. SCxx_th = 0. * L_Un ;
  164. L_z1 = Lamy * Lamy ; L_z2 = L_Un / Lamy ;
  165. SCyy_th = (L_z1 - L_z2) * ((2.*C1*L_Un) + (2.*C2*L_z2)) ;
  166. SCxy_th = 0. * L_Un ;
  167.  
  168. *======================================================================*
  169. * Comparaison des resultats avec la solution analytique *
  170. *======================================================================*
  171. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  172. * calculees et les solutions analytiques correspondantes.
  173. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  174. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  175. *
  176. TabD = TAB1.'DEPLACEMENTS' ;
  177. TabS = TAB1.'CONTRAINTES' ;
  178. Confini = 'FORM' ;
  179. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  180. *
  181. SCxx = 'PROG' 0. ;
  182. SCyy = 'PROG' 0. ;
  183. SCxy = 'PROG' 0. ;
  184. 'REPETER' Boucle (n_abs - 1) ;
  185. 'FORM' (TabD.&Boucle) ;
  186. VolSU = 'INTG' MO ChmUn ;
  187. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  188. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  189. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  190. 'FORM' Confini ;
  191. 'FIN' Boucle ;
  192. *
  193. 'SI' GRAPH ;
  194. tlege = 'TABLE' ;
  195. tlege. 1 = 'MARQ CROI' ;
  196. tlege.'TITRE' = 'TABLE' ;
  197. tlege.'TITRE'. 1 = 'Numerique' ;
  198. tlege.'TITRE'. 2 = 'Analytique' ;
  199. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  200. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  201. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  202. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  203. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  204. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  205. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  206. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  207. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  208. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  209. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  210. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  211. 'FINSI' ;
  212. *
  213. * Tests de bon fonctionnement :
  214. r_z = 'MAXIMUM' ('ABS' SCyy_th) ;
  215. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) / r_z ;
  216. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) / r_z ;
  217. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) / r_z ;
  218. *
  219. MESS ' RESULTATS : ' title ;
  220. MESS ' ------------------------------------------------- ';
  221. 'SAUTER' 1 'LIGNE' ;
  222. 'MESS' ' Tests de bon fonctionnement :' ;
  223. 'MESS' ' -------------------------------' ;
  224. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  225. 'MESS' ' Ecart relatif maximal entre la valeur moyenne '
  226. 'calculee' ;
  227. 'MESS' ' et la '
  228. 'solution analytique associee' ;
  229. 'MESS' ' Composante XX : ' r_xx ;
  230. 'MESS' ' Composante YY : ' r_yy ;
  231. 'MESS' ' Composante XY : ' r_xy ;
  232. 'SAUTER' 1 'LIGNE' ;
  233. * Ecart relatif maximal tolere
  234. Sigref = 1.E-3 ;
  235. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  236. 'MESS' ' ---------------------' ;
  237. 'MESS' ' ECHEC DU CAS-TEST !' ;
  238. 'MESS' ' ---------------------' ;
  239. 'ERREUR' 5 ;
  240. 'SINON' ;
  241. 'MESS' ' ----------------------' ;
  242. 'MESS' ' SUCCES DU CAS-TEST !' ;
  243. 'MESS' ' ----------------------' ;
  244. 'FINSI' ;
  245. 'SAUTER' 1 'LIGNE' ;
  246.  
  247. 'FIN' ;
  248.  
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales