Télécharger Mooney_LRGTreloar_Cisaillementsimple.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : Mooney_LRGTreloar_Cisaillementsimple.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE MOONEY-RIVLIN INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : CISAILLEMENT DANS LA DIRECTION X *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2006) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2006, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24. *
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. GRAPH = FAUX ; monop=faux;
  27.  
  28. title = 'CHAINE' 'MOONEY-RIVLIN - ' 'CISAILLEMENT SIMPLE XY' ;
  29.  
  30. *======================================================================*
  31. * Geometrie - Maillage *
  32. *======================================================================*
  33. * Longueur (direction x) de la plaque/membrane :
  34. Lg_x = 1.8 ;
  35. * Largeur (direction y) de la plaque/membrane :
  36. Lg_y = 1. ;
  37. * Nombre d'elements selon les directions x et y :
  38. Nel_x = 5 ;
  39. Nel_y = 2 ;
  40. *
  41. 'OPTION' 'ELEM' 'QUA4' ;option epsilon 'UTILISATEUR';
  42.  
  43. *
  44. P1 = 0. 0. ;
  45. P2 = Lg_x 0. ;
  46. P3 = Lg_x Lg_y ;
  47. P4 = 0. Lg_y ;
  48. *
  49. L1 = 'DROITE' Nel_x P1 P2 ;
  50. L2 = 'DROITE' Nel_y P2 P3 ;
  51. L3 = 'DROITE' Nel_x P3 P4 ;
  52. L4 = 'DROITE' Nel_y P4 P1 ;
  53. *
  54. SU = 'DALLER' L1 L2 L3 L4 ;
  55. 'SI' GRAPH ;
  56. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  57. 'FINSI' ;
  58.  
  59. *======================================================================*
  60. * Modele - Materiau - Caracteristiques (en Pa) *
  61. *======================================================================*
  62. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'ET'
  63. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  64. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  65. 'ERREUR' 5 ;
  66. 'FINSI' ;
  67. *
  68. * Ne pas oublier de definir les parametres lies a l'elasticite.
  69. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  70. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  71. *
  72. LCMAT = 'MOTS' 'YOUN' 'NU ' 'C1 ' 'C2 ' ;
  73. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  74. 'NON_LINEAIRE' 'UTILISATEUR'
  75. 'NUME_LOI' 31 'C_MATERIAU' LCMAT ;
  76. *
  77. * Coefficients du modele de Mooney-Rivlin (en Pa) :
  78. C1 = 0.183E+6 ; C2 = 0.0034E+6 ;
  79. *
  80. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  81. * du fait de l'incompressibilite inherente au modele.
  82. * Le module de Young YOU est alors connu, car, pour ce modele, le
  83. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  84. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  85. * de la traction. En fonction du niveau de deformation atteinte en
  86. * traction, il faut augmenter cette valeur afin de pouvoir faire
  87. * converger les calculs (module tangent en fin de calculs).
  88. * Prendre des valeurs superieures n'entraine pas de modification des
  89. * resultats, cela modifie seulement le nombre d'iterations mecaniques.
  90. *
  91. XNU = 0.499 ;
  92. YOUini = 3.*(2.*(C1+C2)) ; YOU = 1. * YOUini ;
  93. *
  94. MA = 'MATERIAU' MO 'YOUN' YOU 'NU ' XNU
  95. 'C1 ' C1 'C2 ' C2 ;
  96.  
  97. *======================================================================*
  98. * Conditions aux limites - Traction suivant UY *
  99. *======================================================================*
  100. CTOT = 'CONTOUR' SU ;
  101. BL1 = 'BLOQUER' 'UX ' CTOT ;
  102. BL2 = 'BLOQUER' 'UY ' CTOT ;
  103. BLTOT = BL1 'ET' BL2 ;
  104. *
  105. * Definition des instants du chargement :
  106. t_deb = 0. ; t_fin = 10. ;
  107. L_tps = 'PROG' t_deb t_fin ;
  108. * Cisaillement suivant X :
  109. UX_deb = 0. ; UX_fin = 3. * Lg_y ;
  110. L_UX = 'PROG' UX_deb UX_fin ;
  111. EV_xy = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMX' L_UX ;
  112. chp_y = 'NOMC' 'UX ' ('COORD' 2 CTOT) ;
  113. FF_xy = 'DEPIMP' BL1 chp_y ;
  114. CHARTOT = 'CHARGEMENT' 'DIMP' FF_xy EV_xy ;
  115.  
  116. *======================================================================*
  117. * Initialisation de la table pour appel a PASAPAS *
  118. *======================================================================*
  119. TAB1 = 'TABLE' ;
  120. TAB1.'MODELE' = MO ;
  121. TAB1.'CARACTERISTIQUES' = MA ;
  122. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  123. TAB1.'CHARGEMENT' = CHARTOT ;
  124. *TAB1.'PRECISION' = 1.E-6 ;
  125. *TAB1.'FTOL' = 1.E-5 ;
  126. *TAB1.'MTOL' = 1.E-5 ;
  127. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  128. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  129. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  130. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  131. TAB1.'REAC_GRANDS'=0.4;
  132. *
  133. L_abs = TAB1.'TEMPS_SAUVES' ;
  134. n_abs = 'DIMENSION' L_abs ;
  135. *
  136. tab1.'PROCESSEURS'='MOT' 'MONO_PROCESSEUR';
  137. PASAPAS TAB1 ;
  138. *
  139. * Quelques traces de controle apres calculs
  140. 'SI' GRAPH ;
  141. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  142. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  143. 'TRACER' (Defo_0 'ET' Defo_1)
  144. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  145. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  146. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  147. 'FINSI' ;
  148. *
  149. *======================================================================*
  150. * Construction de la solution analytique *
  151. *======================================================================*
  152. * Definitions :
  153. * - Cisaillement selon xy : Cisx = UX/Lg_y
  154. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  155. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  156. * Dans le cas du modele de Mooney-Rivlin :
  157. * W = C1*(I1-3.)+C2*(I2-3.) , soit dW/dI1 = C1 et dW/dI2 = C2
  158. *
  159. * Les contraintes de Cauchy sont calculables analytiquement :
  160. * - SCxx = 2.(Cisx**2).dW/dI1
  161. * - SCyy = -2.(Cisx**2).dW/dI2
  162. * - SCxy = 2.Cisx.(dW/dI1 + dW/dI2)
  163. * - SCzz = 0 (hypothese des contraintes planes)
  164. *
  165. Cisx = ('IPOL' L_abs L_tps L_UX) / Lg_y ;
  166. L_z1 = Cisx * Cisx ;
  167. *
  168. SCxx_th = 2.*C1*L_z1 ;
  169. SCyy_th = -2.*C2*L_z1 ;
  170. SCxy_th = 2.*(C1+C2)*Cisx ;
  171.  
  172. *======================================================================*
  173. * Comparaison des resultats avec la solution analytique *
  174. *======================================================================*
  175. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  176. * calculees et les solutions analytiques correspondantes.
  177. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  178. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  179. *
  180. TabD = TAB1.'DEPLACEMENTS' ;
  181. TabS = TAB1.'CONTRAINTES' ;
  182. Confini = 'FORM' ;
  183. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  184. *
  185. SCxx = 'PROG' 0. ;
  186. SCyy = 'PROG' 0. ;
  187. SCxy = 'PROG' 0. ;
  188. 'REPETER' Boucle (n_abs - 1) ;
  189. 'FORM' (TabD.&Boucle) ;
  190. VolSU = 'INTG' MO ChmUn ;
  191. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  192. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  193. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  194. 'FORM' Confini ;
  195. 'FIN' Boucle ;
  196. *
  197. 'SI' GRAPH ;
  198. tlege = 'TABLE' ;
  199. tlege. 1 = 'MARQ CROI' ;
  200. tlege.'TITRE' = 'TABLE' ;
  201. tlege.'TITRE'. 1 = 'Numerique' ;
  202. tlege.'TITRE'. 2 = 'Analytique' ;
  203. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  204. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  205. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  206. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  207. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  208. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  209. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  210. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  211. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  212. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  213. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  214. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  215. 'FINSI' ;
  216. *
  217. * Tests de bon fonctionnement :
  218. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  219. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  220. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  221. *
  222. MESS ' RESULTATS : ' title ;
  223. MESS ' ------------------------------------------------- ';
  224. 'SAUTER' 1 'LIGNE' ;
  225. 'MESS' ' Tests de bon fonctionnement :' ;
  226. 'MESS' ' -------------------------------' ;
  227. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  228. 'MESS' ' Ecart maximal absolu entre la valeur moyenne calculee' ;
  229. 'MESS' ' et la '
  230. 'solution analytique associee' ;
  231. 'MESS' ' Composante XX : ' r_xx ' Pa' ;
  232. 'MESS' ' Composante YY : ' r_yy ' Pa' ;
  233. 'MESS' ' Composante XY : ' r_xy ' Pa' ;
  234. 'SAUTER' 1 'LIGNE' ;
  235. * Ecart relatif maximal tolere
  236. Sigref = 1.E-3 ;
  237. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  238. 'MESS' ' ---------------------' ;
  239. 'MESS' ' ECHEC DU CAS-TEST !' ;
  240. 'MESS' ' ---------------------' ;
  241. 'ERREUR' 5 ;
  242. 'SINON' ;
  243. 'MESS' ' ----------------------' ;
  244. 'MESS' ' SUCCES DU CAS-TEST !' ;
  245. 'MESS' ' ----------------------' ;
  246. 'FINSI' ;
  247. 'SAUTER' 1 'LIGNE' ;
  248.  
  249. 'FIN' ;
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257.  
  258.  
  259.  
  260.  
  261.  
  262.  
  263.  
  264.  
  265.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales