Télécharger Mooney_LRGTreloar_Bitraction.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : Mooney_LRGTreloar_Bitraction.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *======================================================================*
  5. * MODELE HYPERELASTIQUE MOONEY-RIVLIN INCOMPRESSIBLE *
  6. * EN GRANDES TRANSFORMATIONS - CONTRAINTES PLANES *
  7. * *
  8. * TEST DE VALIDATION DU MODELE : TRACTION BIAXIALE DANS LE PLAN X,Y *
  9. * COMPARAISON AVEC LA SOLUTION ANALYTIQUE *
  10. * *
  11. * Contribution de Laurent Gornet - Ecole Centrale de Nantes (2006) *
  12. *======================================================================*
  13. * Pour plus d'informations, voir la presentation de L. Gornet lors *
  14. * du Club Cast3m 2006, disponible sur le site Web de Cast3m. *
  15. *======================================================================*
  16. * Exemple d'utilisation d'un modele UMAT en grandes transformations *
  17. * *
  18. * Note : Actuellement en grandes deformations dans PASAPAS, le modele *
  19. * ne peut contenir que des modeles de type UMAT. On ne peut *
  20. * pas melanger les derivees objectives et les modeles de C3m. *
  21. *======================================================================*
  22.  
  23. 'OPTION' 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ECHO' 0 ;
  24. *
  25. * Mettre VRAI si l'on souhaite divers traces.
  26. GRAPH = FAUX ;
  27.  
  28. title = 'CHAINE' 'MOONEY-RIVLIN - ' 'TRACTION BIAXIALE XY' ;
  29.  
  30. *======================================================================*
  31. * Geometrie - Maillage *
  32. *======================================================================*
  33. * Longueur (direction x) de la plaque/membrane :
  34. Lg_x = 1. ;
  35. * Largeur (direction y) de la plaque/membrane :
  36. Lg_y = 0.5 ;
  37. * Nombre d'elements selon les directions x et y :
  38. Nel_x = 3 ;
  39. Nel_y = 1 ;
  40. *
  41. 'OPTION' 'ELEM' 'QUA8' ;
  42. *
  43. P1 = 0. 0. ;
  44. P2 = Lg_x 0. ;
  45. P3 = Lg_x Lg_y ;
  46. P4 = 0. Lg_y ;
  47. *
  48. L1 = 'DROITE' Nel_x P1 P2 ;
  49. L2 = 'DROITE' Nel_y P2 P3 ;
  50. L3 = 'DROITE' Nel_x P3 P4 ;
  51. L4 = 'DROITE' Nel_y P4 P1 ;
  52. *
  53. SU = 'DALLER' L1 L2 L3 L4 ;
  54. 'SI' GRAPH ;
  55. 'TRACER' SU 'TITRE' ('CHAINE' title ' - MAILLAGE') ;
  56. 'FINSI' ;
  57.  
  58. *======================================================================*
  59. * Modele - Materiau - Caracteristiques (en Pa) *
  60. *======================================================================*
  61. 'SI' (('NEG' ('VALEUR' 'DIME') 2) 'ET'
  62. ('NEG' ('VALEUR' 'MODE') 'PLANCONT')) ;
  63. 'MESS' 'Ce modele ne fonctionne qu en 2D CONTRAINTES PLANES' ;
  64. 'ERREUR' 5 ;
  65. 'FINSI' ;
  66. *
  67. * Ne pas oublier de definir les parametres lies a l'elasticite.
  68. * Meme si ce n'est pas utilise dans le modele, cela est utile pour
  69. * l'operateur de convergence mecanique de PASAPAS-INCREME.
  70. *
  71. LCMAT = 'MOTS' 'YOUN' 'NU ' 'C1 ' 'C2 ' ;
  72. MO = MODE SU 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE'
  73. 'NON_LINEAIRE' 'UTILISATEUR'
  74. 'NUME_LOI' 31 'C_MATERIAU' LCMAT ;
  75. *
  76. * Coefficients du modele de Mooney-Rivlin (en Pa) :
  77. C1 = 0.183E+6 ; C2 = 0.0034E+6 ;
  78. *
  79. * On fixe le coefficient de Poisson XNU a une valeur proche de 0.5
  80. * du fait de l'incompressibilite inherente au modele.
  81. * Le module de Young YOU est alors connu, car, pour ce modele, le
  82. * module de cisaillement MU vaut : MU = YOU/(2*(1+XNU)) = 2.(C1+C2)
  83. * Il s'agit de la valeur initiale et de la borne inferieure dans le cas
  84. * de la traction. En fonction du niveau de deformation atteinte en
  85. * traction, il faut augmenter cette valeur afin de pouvoir faire
  86. * converger les calculs. Prendre des valeurs superieures n'entraine pas
  87. * de modification des resultats, cela modifie seulement le nombre
  88. * d'iterations mecaniques.
  89. * Par ex. : pour 1000 %, il faut multiplier par 30 la valeur initiale.
  90. * Si l'on se contente de 10., les calculs s'arretent vers 900 %.
  91. *
  92. XNU = 0.499 ;
  93. YOUini = 3.*(2.*(C1+C2)) ; YOU = 100. * YOUini ;
  94. *
  95. MA = 'MATERIAU' MO 'YOUN' YOU 'NU ' XNU
  96. 'C1 ' C1 'C2 ' C2 ;
  97.  
  98. *======================================================================*
  99. * Conditions aux limites - Chargement bi-axe *
  100. *======================================================================*
  101. BL1 = 'BLOQUER' 'UY ' L1 ;
  102. BL2 = 'BLOQUER' 'UY ' L3 ;
  103. BL4 = 'BLOQUER' 'UX ' L4 ;
  104. BL3 = 'BLOQUER' 'UX ' L2 ;
  105. BLTOT = BL1 'ET' BL2 'ET' BL3 'ET' BL4 ;
  106. *
  107. * Definition des instants du chargement :
  108. t_deb = 0. ; t_fin = 10. ;
  109. L_tps = 'PROG' t_deb t_fin ;
  110. * Deplacement suivant X :
  111. FF_x = 'DEPIMP' BL3 1. ;
  112. L_UX = 'PROG' 0. (10. * Lg_x) ;
  113. EV_x = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMX' L_UX ;
  114. CHAR_x = 'CHARGEMENT' 'DIMP' FF_x EV_x ;
  115. * Deplacement suivant Y :
  116. L_UY = 'PROG' 0. ( 2. * Lg_y) ;
  117. FF_y = 'DEPIMP' BL2 1. ;
  118. EV_y = 'EVOL' 'MANU' 'TEMPS' L_tps 'LAMY' L_UY ;
  119. CHAR_y = 'CHARGEMENT' 'DIMP' FF_y EV_y ;
  120. *
  121. CHARTOT = CHAR_x 'ET' CHAR_y ;
  122.  
  123. *======================================================================*
  124. * Initialisation de la table pour appel a PASAPAS *
  125. *======================================================================*
  126. TAB1 = 'TABLE' ;
  127. TAB1.'MODELE' = MO ;
  128. TAB1.'CARACTERISTIQUES' = MA ;
  129. TAB1.'BLOCAGES_MECANIQUES' = BLTOT ;
  130. TAB1.'CHARGEMENT' = CHARTOT ;
  131. *TAB1.'PRECISION' = 1.E-6 ;
  132. *TAB1.'FTOL' = 1.E-5 ;
  133. *TAB1.'MTOL' = 1.E-5 ;
  134. TAB1.'CONVERGENCE_FORCEE' = FAUX ;
  135. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  136. TAB1.'HYPOTHESE_DEFORMATIONS' = MOT 'UTILISATEUR' ;
  137. TAB1.'TEMPS_CALCULES' = 'PROG' t_deb 'PAS' 0.1 t_fin ;
  138. TAB1.'TEMPS_SAUVES' = 'PROG' t_deb 'PAS' 0.5 t_fin ;
  139. *
  140. L_abs = TAB1.'TEMPS_SAUVES' ;
  141. n_abs = 'DIMENSION' L_abs ;
  142. *
  143. PASAPAS TAB1 ;
  144. *
  145. * Quelques traces de controle apres calculs
  146. 'SI' GRAPH ;
  147. Defo_0 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 0. ;
  148. Defo_1 = 'DEFORMEE' SU (TAB1.'DEPLACEMENTS'.(n_abs-1)) 1. 'VERT' ;
  149. 'TRACER' (Defo_0 'ET' Defo_1)
  150. 'TITRE' ('CHAINE' title ' - DEFORMEES INITIALE ET FINALE') ;
  151. 'TRACER' MO (TAB1.'CONTRAINTES'.(n_abs-1))
  152. 'TITRE' ('CHAINE' title ' - CONTRAINTES EN FIN DE CALCUL') ;
  153. 'FINSI' ;
  154. *
  155. *======================================================================*
  156. * Construction de la solution analytique *
  157. *======================================================================*
  158. * Definitions :
  159. * - Allongement selon direction x : Lamx = 1 + (UX/Lg_x)
  160. * - Allongement selon direction y : Lamy = 1 + (UY/Lg_y)
  161. * - Densite d'energie de deformation hyperelastique : W(I1,I2)
  162. * - I1, I2 : trois invariants du tenseur de Cauchy-Green droit
  163. * Dans le cas du modele de Mooney-Rivlin :
  164. * W = C1*(I1-3.)+C2*(I2-3.) , soit dW/dI1 = C1 et dW/dI2 = C2
  165. *
  166. * Les contraintes de Cauchy sont calculables analytiquement :
  167. * - SCxx = 2.(Lamx**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamy**2.dW/dI2)
  168. * - SCyy = 2.(Lamy**2 - (Lamx*Lamy)**-2).(dW/dI1 + Lamx**2.dW/dI2)
  169. * - SCxy = 0 (pas de cisaillement)
  170. * - SCzz = 0 (hypothese des contraintes planes)
  171. *
  172. L_Un = 'PROG' n_abs '*' 1. ;
  173. Lamx = L_Un + (('IPOL' L_abs L_tps L_UX) / Lg_X) ;
  174. Lamy = L_Un + (('IPOL' L_abs L_tps L_UY) / Lg_Y) ;
  175. *
  176. L_z1 = Lamx * Lamx ; L_z2 = Lamy * Lamy ;
  177. L_z3 = L_z1 - ((L_z1*L_z2)**-1) ;
  178. SCxx_th = L_z3 * ((2.*C1*L_Un) + (2.*C2*L_z2)) ;
  179. L_z3 = L_z2 - ((L_z1*L_z2)**-1) ;
  180. SCyy_th = L_z3 * ((2.*C1*L_Un) + (2.*C2*L_z1)) ;
  181. SCxy_th = 0. * L_Un ;
  182.  
  183. *======================================================================*
  184. * Comparaison des resultats avec la solution analytique *
  185. *======================================================================*
  186. * La comparaison s'effectue entre les valeurs moyennes des contraintes
  187. * calculees et les solutions analytiques correspondantes.
  188. * On ne cherche pas a verifier l'uniformite du champ de contraintes.
  189. * (Faire le calcul en mettant GRAPH a VRAI et voir les isovaleurs !)
  190. *
  191. TabD = TAB1.'DEPLACEMENTS' ;
  192. TabS = TAB1.'CONTRAINTES' ;
  193. Confini = 'FORM' ;
  194. ChmUn = 'MANU' 'CHML' MO 'SCAL' 1. ;
  195. *
  196. SCxx = 'PROG' 0. ;
  197. SCyy = 'PROG' 0. ;
  198. SCxy = 'PROG' 0. ;
  199. 'REPETER' Boucle (n_abs - 1) ;
  200. 'FORM' (TabD.&Boucle) ;
  201. VolSU = 'INTG' MO ChmUn ;
  202. SCxx = SCxx 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXX')/VolSU)) ;
  203. SCyy = SCyy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMYY')/VolSU)) ;
  204. SCxy = SCxy 'ET' ('PROG' (('INTG' MO (TabS. &Boucle) 'SMXY')/VolSU)) ;
  205. 'FORM' Confini ;
  206. 'FIN' Boucle ;
  207. *
  208. 'SI' GRAPH ;
  209. tlege = 'TABLE' ;
  210. tlege. 1 = 'MARQ CROI' ;
  211. tlege.'TITRE' = 'TABLE' ;
  212. tlege.'TITRE'. 1 = 'Numerique' ;
  213. tlege.'TITRE'. 2 = 'Analytique' ;
  214. Evxx = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXX' SCxx ;
  215. Evxx_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXX' SCxx_th ;
  216. 'DESSIN' (Evxx 'ET' Evxx_th) 'LEGE' tlege
  217. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XX (Pa)') ;
  218. Evyy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCYY' SCyy ;
  219. Evyy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCYY' SCyy_th ;
  220. 'DESSIN' (Evyy 'ET' Evyy_th) 'LEGE' tlege
  221. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY YY (Pa)') ;
  222. Evxy = 'EVOL' 'ROUG' 'MANU' 'LAMB' L_abs 'SCXY' SCxy ;
  223. Evxy_th = 'EVOL' 'BLEU' 'MANU' 'LAMB' L_abs 'SCXY' SCxy_th ;
  224. 'DESSIN' (Evxy 'ET' Evxy_th) 'LEGE' tlege
  225. 'TITRE' ('CHAINE' title ' - CONTRAINTE DE CAUCHY XY (Pa)');
  226. 'FINSI' ;
  227. *
  228. * Tests de bon fonctionnement :
  229. r_xx = 'MAXIMUM' ('ABS' (SCxx - SCxx_th)) ;
  230. r_yy = 'MAXIMUM' ('ABS' (SCyy - SCyy_th)) ;
  231. r_xy = 'MAXIMUM' ('ABS' (SCxy - SCxy_th)) ;
  232. *
  233. MESS ' RESULTATS : ' title ;
  234. MESS ' ------------------------------------------------ ';
  235. 'SAUTER' 1 'LIGNE' ;
  236. 'MESS' ' Tests de bon fonctionnement :' ;
  237. 'MESS' ' -------------------------------' ;
  238. 'MESS' ' Comparaison effectuee sur les contraintes de Cauchy' ;
  239. 'MESS' ' Ecart maximal en valeur absolue entre la valeur moyenne '
  240. 'calculee' ;
  241. 'MESS' ' et la '
  242. 'solution analytique associee' ;
  243. 'MESS' ' Composante XX : ' r_xx ' Pa' ;
  244. 'MESS' ' Composante YY : ' r_yy ' Pa' ;
  245. 'MESS' ' Composante XY : ' r_xy ' Pa' ;
  246. 'SAUTER' 1 'LIGNE' ;
  247. * Ecart maximal tolere sur la contrainte (en Pa)
  248. Sigref = 1.E-3 ;
  249. 'SI' ('>EG' ('MAXIMUM' ('PROG' r_xx r_yy r_xy)) Sigref) ;
  250. 'MESS' ' ---------------------' ;
  251. 'MESS' ' ECHEC DU CAS-TEST !' ;
  252. 'MESS' ' ---------------------' ;
  253. 'ERREUR' 5 ;
  254. 'SINON' ;
  255. 'MESS' ' ----------------------' ;
  256. 'MESS' ' SUCCES DU CAS-TEST !' ;
  257. 'MESS' ' ----------------------' ;
  258. 'FINSI' ;
  259. 'SAUTER' 1 'LIGNE' ;
  260.  
  261. 'FIN' ;
  262.  
  263.  
  264.  
  265.  
  266.  
  267.  
  268.  
  269.  
  270.  
  271.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales