Télécharger J_el_TUB_CDAI_divers_chargements.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. ************************************************************************
  3. * Cas-test de validation pour le calcul de Jel en 2D et en 3D pour un
  4. * Cylindre avec un Defaut Axisymetrique en peau Interne (CDAI) soumis a
  5. * 3 types de chargements :
  6. * - traction
  7. * - pression sur les levres
  8. * - temperature imposee
  9.  
  10. * Verification de la procedure G_THETA avec :
  11. * - elements lineaires et quadratiques
  12. * - le modele complet et le demi-modele
  13. * - solution de type RESO et solution de type PASAPAS
  14. * - un modele 2D et un modele 3D
  15.  
  16. * (Regroupement des cas-test :
  17. * - rupt18.dgibi
  18. * - rupt19.dgibi
  19. * - rupt20.dgibi
  20. * - rupt21.dgibi
  21. * - rupt22.dgibi
  22. * - rupt23.dgibi
  23. * - rupt24.dgibi
  24. * - rupt25.dgibi
  25. * en un seul cas-test)
  26.  
  27. * ^ z ______
  28. * | | |
  29. * | | |
  30. * | | |
  31. * | | |
  32. * | | |
  33. * | | |
  34. * | | |
  35. * | | |
  36. * |----> |-- |
  37. * r | |
  38. * | |
  39. * | |
  40. * | |
  41. * | |
  42. * | |
  43. * | |
  44. * |______|
  45.  
  46. OPTI 'ECHO' 0;
  47.  
  48.  
  49. * -----------------------------------
  50. * DONNEES GEOMETRIQUES ET PHYSIQUES
  51. * -----------------------------------
  52.  
  53. * H : HAUTEUR DU TUBE
  54. * T : EPAISSEUR DU TUBE
  55. * A : PROFONDEUR DE LA FISSURE
  56. * RI : RAYON INTERNE
  57. * RE : RAYON EXTERNE
  58. H = 1.;
  59. T = 60.E-3;
  60. A = T / 5;
  61. RI = T * 5;
  62. RE = RI + T;
  63.  
  64. * PROPRIETE MATERIAUX
  65. E0 = 185E3;
  66. NU0 = 0.3;
  67. ALFA0 = 13.08E-6;
  68.  
  69. * NIVEAU DE CHARGEMENT
  70. P0T = -400.;
  71. P0P = 400.;
  72. DT0 = 300.;
  73.  
  74.  
  75. * -----------------------
  76. * SOLUTIONS ANALYTIQUES
  77. * -----------------------
  78.  
  79. * FONCTIONS D'INFLUENCE
  80. I0 = 1.211;
  81. I1 = 0.718;
  82.  
  83. * CONTRAINTES IMPOSEES POUR LE GRADIENT DE TEMPERATURE
  84. SIG0 = ((E0*ALFA0*DT0)/(1-NU0)) * (RI/(3*T)) * ((2*(RE**2))/(RI*(RE+RI)) - 1);
  85. SIG1 = -1. * ((E0*ALFA0*DT0)/(1-NU0));
  86.  
  87. * J ANALYTIQUES
  88. JT = (1-(NU0**2)) * ((I0*(-1.*P0T)*((PI*A)**(1./2.)))**2) / E0;
  89. JP = (1-(NU0**2)) * ((I0*(-1.*P0P)*((PI*A)**(1./2.)))**2) / E0;
  90. JTH = (1-(NU0**2)) * ((((I0*SIG0)+ (I1*SIG1*(A/T)))*((PI*A)**(1./2.)))**2) / E0;
  91.  
  92.  
  93. * -----------
  94. * MAILLAGE
  95. * -----------
  96.  
  97. * ON COMMENCE PAR UN MAILLAGE QUADRATIQUE 2D, ON LE TRANSFORMERA ENSUITE AU BESOIN
  98. OPTI 'DIME' 2 'ELEM' 'QUA8' 'MODE' 'AXIS';
  99.  
  100. * 1ER CARRE AUTOUR DE LA POINTE DE FISSURE
  101. NELP = 10;
  102. DX1 = 200.E-6;
  103. L1 = DX1 * NELP;
  104. PF = (RI + A) 0.;
  105. P1 = PF PLUS (L1 0.);
  106. P2 = P1 PLUS (0. L1);
  107. D12 = DROI NELP P1 P2;
  108. CAR1 = D12 TRAN NELP ((0. - L1) 0.);
  109. ELIM (CAR1 ET PF) 1.E-10;
  110. CAR1 = COUL 'JAUN' CAR1;
  111.  
  112. * DEBUT DU 2EME CARRE AUTOUR DE LA POINTE DE FISSURE
  113. DX2 = 400.E-6;
  114. L2 = DX2 * NELP;
  115. D34 = D12 HOMO (L2/L1) PF;
  116. HOMO1 = REGL NELP D12 D34;
  117. HOMO1 = COUL 'VERT' HOMO1;
  118. CAR2 = CAR1 ET HOMO1;
  119.  
  120. * DERAFFINEMENT 3 POUR 1
  121. LDERAF = DX2*4;
  122. ELS = D34 ELEM (LECT 1 2 3);
  123. P1 = ELS POIN 'INIT';
  124. P2 = ELS POIN 'FINA';
  125. P3 P4 = P2 P1 PLUS (LDERAF 0.);
  126. COTE2 = DROI 1 P2 P3;
  127. COTE3 = DROI 1 P3 P4;
  128. COTE4 = DROI 1 P4 P1;
  129. DERAF1 = DALL ELS COTE2 COTE3 COTE4;
  130.  
  131. * DERAFFINEMENT 3 POUR 1
  132. ELS = D34 ELEM (LECT 4 5 6);
  133. P1 = P2;
  134. P2 = ELS POIN 'FINA';
  135. P4 = P3;
  136. P3 = P2 PLUS (LDERAF 0.);
  137. COTE2 = DROI 1 P2 P3;
  138. COTE3 = DROI 1 P3 P4;
  139. COTE4 = DROI 1 P4 P1;
  140. DERAF2 = DALL ELS COTE2 COTE3 COTE4;
  141.  
  142. * DERAFFINEMENT 4 POUR 2
  143. ELS = D34 ELEM (LECT 7 8 9 10);
  144. P1 = P2;
  145. P2 = ELS POIN 'FINA';
  146. P4 = P3;
  147. P3 = P2 PLUS (LDERAF 0.);
  148. COTE2 = DROI 1 P2 P3;
  149. COTE3 = DROI 2 P3 P4;
  150. COTE4 = DROI 1 P4 P1;
  151. DERAF3 = DALL ELS COTE2 COTE3 COTE4;
  152.  
  153. * SYMETRIE PAR RAPPORT A LA DIAGONALE
  154. DERAF0 = DERAF1 ET DERAF2 ET DERAF3;
  155. SYME1 = (HOMO1 ET DERAF0) SYME 'DROI' PF (PF PLUS (1. 1.));
  156.  
  157. * COIN
  158. COIN1 = COTE2 TRAN 1 (0. LDERAF);
  159. MOITIE_DROITE = CAR2 ET DERAF0 ET SYME1 ET COIN1;
  160. ELIM MOITIE_DROITE 1.E-10;
  161.  
  162. * SYMETRIE PAR RAPPORT A LA VERTICALE
  163. MOITIE_GAUCHE = MOITIE_DROITE SYME 'DROI' PF (PF PLUS (0. 1.));
  164. ELIM MOITIE_GAUCHE MOITIE_DROITE 1.E-10;
  165. REC1 = MOITIE_DROITE ET MOITIE_GAUCHE;
  166.  
  167. * TRANSLATION JUSQU'A LA PEAU INTERNE
  168. XMIN = MINI (COOR 1 REC1);
  169. PGAUCHE = REC1 POIN 'DROI' (XMIN 0.) (XMIN 1.) 1.E-10;
  170. CONREC1 = CONT REC1;
  171. ELGAUCHE = CONREC1 ELEM 'APPUYE' PGAUCHE;
  172. DX3 = 1.6E-3;
  173. TRGAUCHE = ELGAUCHE TRAN ((RI - XMIN) 0.) 'DINI' DX3 'DFIN' (DX3*2);
  174.  
  175. * TRANSLATION JUSQU'A LA PEAU EXTERNE
  176. XMAX = MAXI (COOR 1 REC1);
  177. PDROITE = REC1 POIN 'DROI' (XMAX 0.) (XMAX 1.) 1.E-10;
  178. ELDROITE = CONREC1 ELEM 'APPUYE' PDROITE;
  179. TRDROITE = ELDROITE TRAN ((RE - XMAX) 0.) 'DINI' DX3 'DFIN' (DX3*2);
  180. REC2 = REC1 ET TRDROITE ET TRGAUCHE;
  181.  
  182. * TRANSLATION JUSQU'AU FOND DU CYLINDRE
  183. YMAX = MAXI (COOR 2 REC2);
  184. PHAUT = REC2 POIN 'DROI' (0. YMAX) (1. YMAX) 1.E-10;
  185. ELHAUT = (CONT REC2) ELEM 'APPUYE' PHAUT;
  186. TRHAUT = ELHAUT TRAN (0. (((H/2) - YMAX))) 'DINI' DX3 'DFIN' T;
  187. CYL_SUP = REC2 ET TRHAUT;
  188.  
  189. * SYMETRIE PAR RAPPORT A L'HORIZONTALE
  190. CYL_INF = CYL_SUP SYME 'DROI' PF (PF PLUS (1. 0.));
  191.  
  192. * DEFINITION DU LIGAMENT
  193. PEXT = CYL_SUP POIN 'PROC' (RE 0.);
  194. CONSUP = CONT CYL_SUP;
  195. PART1 = CONSUP ELEM 'COMPRIS' PF PEXT;
  196. PART2 = CONSUP ELEM 'COMPRIS' PEXT PF;
  197. LIGAMENT = PART1;
  198. SI ((NBEL LIGAMENT) > (NBEL PART2));
  199. LIGAMENT = PART2;
  200. FINSI;
  201. ELIM LIGAMENT CYL_INF 1.E-10;
  202.  
  203. * DEFINITION DES LEVRES
  204. PINT = CYL_SUP POIN 'PROC' (RI 0.);
  205. PART1 = CONSUP ELEM 'COMPRIS' PF PINT;
  206. PART2 = CONSUP ELEM 'COMPRIS' PINT PF;
  207. LVSUP = PART1;
  208. SI ((NBEL LVSUP) > (NBEL PART2));
  209. LVSUP = PART2;
  210. FINSI;
  211. SI (NEG (NOEU (LVSUP POIN 'INIT')) (NOEU PF));
  212. LVSUP = INVE LVSUP;
  213. FINSI;
  214. PINT = CYL_INF POIN 'PROC' (RI 0.);
  215. CONINF = CONT CYL_INF;
  216. PART1 = CONINF ELEM 'COMPRIS' PF PINT;
  217. PART2 = CONINF ELEM 'COMPRIS' PINT PF;
  218. LVINF = PART1;
  219. SI ((NBEL LVINF) > (NBEL PART2));
  220. LVINF = PART2;
  221. FINSI;
  222. SI (NEG (NOEU (LVINF POIN 'FINA')) (NOEU PF));
  223. LVINF = INVE LVINF;
  224. FINSI;
  225.  
  226. * BORDS DU HAUT ET DU BAS
  227. YMAX = H/2;
  228. YMIN = 0. - YMAX;
  229. PHAUT = CYL_SUP POIN 'DROI' (0. YMAX) (1. YMAX) 1.E-10;
  230. BHAUT = (CONT CYL_SUP) ELEM 'APPUYE' PHAUT;
  231. SI ((COOR 1 (BHAUT POIN 'INIT')) < (COOR 1 (BHAUT POIN 'FINA')));
  232. BHAUT = INVE BHAUT;
  233. FINSI;
  234. PBAS = CYL_INF POIN 'DROI' (0. YMIN) (1. YMIN) 1.E-10;
  235. BBAS = (CONT CYL_INF) ELEM 'APPUYE' PBAS;
  236. SI ((COOR 1 (BBAS POIN 'INIT')) > (COOR 1 (BBAS POIN 'FINA')));
  237. BBAS = INVE BBAS;
  238. FINSI;
  239.  
  240.  
  241. * ---------------------
  242. * CALCUL PRELIMINAIRE
  243. * ---------------------
  244.  
  245. * ON FAIT UN PREMIER CALCUL AVEC RESO SUR LA STRUCTURE COMPLETE
  246. * PUIS ON EN DEDUIT LES SOLUTIONS DANS LES AUTRES CAS SANS
  247. * FAIRE DE CALCULS SUPPLEMENTAIRES
  248.  
  249. * MODELE ET MATERIAU
  250. OMEGA = CYL_SUP ET CYL_INF;
  251. MO = MODE OMEGA 'MECANIQUE' 'ELASTIQUE';
  252. MA = MATE MO 'YOUN' E0 'NU' NU0 'ALPH' ALFA0 'TALP' 0. 'TREF' 0.;
  253.  
  254. * CONDITIONS AUX LIMITES
  255. CL1 = RELA 'ENSE' 'UZ' PHAUT;
  256. CL2 = RELA 'ENSE' 'UZ' PBAS;
  257. CL3 = BLOQ 'UZ' PF;
  258. CL0 = CL1 ET CL2 ET CL3;
  259.  
  260. * CHARGEMENTS
  261. MO_T = MODE (BHAUT ET BBAS) 'CHARGEMENT' 'PRESSION' 'CONS' 'DOMEGAF';
  262. CH_T = PRES MO_T 'PRES' P0T;
  263. F_T = BSIG MO_T CH_T;
  264.  
  265. LEVRES = LVSUP ET LVINF;
  266. MO_P = MODE LEVRES 'CHARGEMENT' 'PRESSION' 'CONS' 'LEVRES';
  267. CH_P = PRES MO_P 'PRES' P0P;
  268. F_P = BSIG MO_P CH_P;
  269.  
  270. CHR = ((OMEGA COOR 1) - RI) / (RE - RI);
  271. CHT0 = NOMC 'T' (DT0 * CHR);
  272. SIG0 = THET MO MA CHT0;
  273. F_TH = BSIG MO SIG0;
  274.  
  275. * APPEL A RESO
  276. RI0 = RIGI MO MA;
  277. UT UP UTH = RESO (RI0 ET CL0) F_T F_P F_TH;
  278. U0 = MANU 'CHPO' OMEGA 2 'UR' 0. 'UZ' 0.;
  279.  
  280.  
  281. * ------------
  282. * PROCEDURES
  283. * ------------
  284.  
  285. * PROCEDURE DE VERIFICATION DE LA PRECISION DU RESULTAT
  286. DEBP CHECKERR ERR*'FLOTTANT' LIM*'FLOTTANT' M1*'MOT';
  287. MESS ' ERREUR EN' ' ' M1 ' = ' ERR '%';
  288. SI (ERR > LIM);
  289. ERRE 'ERREUR TROP GRANDE EN' ' ' M1;
  290. SINON;
  291. MESS ' => OK';
  292. FINSI;
  293. FINP;
  294.  
  295. * PROCEDURE QUI APPELLE G_THETA
  296. * DANS CETTE PROCEDURE, ON REDEFINIT LE MODELE, LE CHARGEMENT ET LES CONDITIONS
  297. * AUX LIMITES. MEME SI ON N'APPELLE NI RESO, NI PASAPAS, ON EN A BESOIN POUR
  298. * APPELER G_THETA
  299. DEBP CASTEST DIMENSION*'MOT' INTERPOLATION*'MOT' SYSTEME*'MOT';
  300.  
  301. DIM1 DIM2 = '2D' '3D';
  302. SI ((NEG DIMENSION DIM1) ET (NEG DIMENSION DIM2));
  303. ERR1 = CHAI 'DIMENSION DOIT VALOIR ''' DIM1 ''' ' 'OU' ' ''' DIM2 '';
  304. ERRE ERR1;
  305. FINSI;
  306. INT1 INT2 = 'LINEAIRE' 'QUADRATIQUE';
  307. SI ((NEG INTERPOLATION INT1) ET (NEG INTERPOLATION INT2));
  308. ERR1 = CHAI 'INTERPOLATION DOIT VALOIR ''' INT1 ''' ' 'OU' ' ''' INT2 '';
  309. ERRE ERR1;
  310. FINSI;
  311. MOD1 = MOT 'COMPLET';
  312. MOD2 = 'MOITIE';
  313. SI ((NEG SYSTEME MOD1) ET (NEG SYSTEME MOD2));
  314. ERR1 = CHAI 'SYSTEME DOIT VALOIR ''' MOD1 ''' ' 'OU' ' ''' MOD2 '';
  315. ERRE ERR1;
  316. FINSI;
  317.  
  318. * DEFINITION DU SYSTEME
  319. SI (EGA SYSTEME 'COMPLET');
  320. OMEGA = CYL_SUP ET CYL_INF;
  321. SINON;
  322. OMEGA = CYL_SUP;
  323. FINSI;
  324.  
  325. * PASSAGE EN LINEAIRE LE CAS ECHEANT
  326. SI (EGA INTERPOLATION 'LINEAIRE');
  327. OMEGA = CHAN 'LINE' OMEGA;
  328. LVSUP = CHAN 'LINE' LVSUP;
  329. LVINF = CHAN 'LINE' LVINF;
  330. BHAUT = CHAN 'LINE' BHAUT;
  331. SI (EGA SYSTEME 'MOITIE');
  332. LIGAMENT = CHAN 'LINE' LIGAMENT;
  333. SINON;
  334. BBAS = CHAN 'LINE' BBAS;
  335. FINSI;
  336. SI (EGA DIMENSION '3D');
  337. PF = CHAN 'LINE' PF;
  338. FINSI;
  339. FINSI;
  340.  
  341. * MODELE ET MATERIAU
  342. MO = MODE OMEGA 'MECANIQUE' 'ELASTIQUE';
  343. MA = MATE MO 'YOUN' E0 'NU' NU0 'ALPH' ALFA0 'TALP' 0. 'TREF' 0.;
  344.  
  345. * CONDITIONS AUX LIMITES
  346. SI (EGA DIMENSION '2D');
  347. U_AXE = 'UZ';
  348. SINON;
  349. U_AXE = 'UY';
  350. FINSI;
  351. PHAUT = CHAN 'POI1' BHAUT;
  352. CL1 = RELA 'ENSE' U_AXE PHAUT;
  353. CL0 = CL1 ET CL2;
  354. SI (EGA SYSTEME 'COMPLET');
  355. PBAS = CHAN 'POI1' BBAS;
  356. CL2A = RELA 'ENSE' U_AXE PBAS;
  357. CL2B = BLOQ U_AXE PF;
  358. CL2 = CL2A ET CL2B;
  359. SINON;
  360. CL2 = BLOQ U_AXE LIGAMENT;
  361. FINSI;
  362. CL0 = CL1 ET CL2;
  363. SI (EGA DIMENSION '3D');
  364. CL3 = OMEGA SYMT 'DEPL' PSYM11 PSYM12 PSYM13 1.E-10;
  365. CL4 = OMEGA SYMT 'DEPL' PSYM21 PSYM22 PSYM23 1.E-10;
  366. CL0 = CL0 ET CL3 ET CL4;
  367. FINSI;
  368.  
  369. * CHARGEMENTS
  370. SI (EGA SYSTEME 'COMPLET');
  371. MO_T = MODE (BHAUT ET BBAS) 'CHARGEMENT' 'PRESSION' 'CONS' 'DOMEGAF';
  372. SINON;
  373. MO_T = MODE BHAUT 'CHARGEMENT' 'PRESSION' 'CONS' 'HAUT';
  374. FINSI;
  375. CH_T = PRES MO_T 'PRES' P0T;
  376. EVT = EVOL 'MANU' 'TEMP' (PROG 0. 1. 2. 3.) 'PRES' (PROG 0. 1. 0. 0.);
  377. CHA_T = CHAR 'PRES' CH_T EVT;
  378.  
  379. LEVRES = LVSUP;
  380. SI (EGA SYSTEME 'COMPLET');
  381. LEVRES = LEVRES ET LVINF;
  382. FINSI;
  383. MO_P = MODE LEVRES 'CHARGEMENT' 'PRESSION' 'CONS' 'LEVRES';
  384. CH_P = PRES MO_P 'PRES' P0P;
  385. EVP = EVOL 'MANU' 'TEMP' (PROG 0. 1. 2. 3.) 'PRES' (PROG 0. 0. 1. 0.);
  386. CHA_P = CHAR 'PRES' CH_P EVP;
  387.  
  388. CHR = ((OMEGA COOR 1) - RI) / (RE - RI);
  389. CHT0 = NOMC 'T' (DT0 * CHR);
  390. EVTH = EVOL 'MANU' (PROG 0. 1. 2. 3.) (PROG 0. 0. 0. 1.);
  391. CHA_TH = CHAR 'T' CHT0 EVTH;
  392.  
  393. * SOLUTIONS A PARTIR DU CALCUL PRELIMINAIRE
  394. UT = REDU UT OMEGA;
  395. UP = REDU UP OMEGA;
  396. UTH = REDU UTH OMEGA;
  397.  
  398. * APPELS A G_THETA
  399. J0 = TABL;
  400. J0.'OBJECTIF' = MOT 'J';
  401. J0.'FRONT_FISSURE' = PF;
  402. J0.'COUCHE' = 5;
  403. J0.'LEVRE_SUPERIEURE' = LVSUP;
  404. SI (EGA SYSTEME 'COMPLET');
  405. J0.'LEVRE_INFERIEURE' = LVINF;
  406. FINSI;
  407. J0.'CARACTERISTIQUES' = MA;
  408. J0.'BLOCAGES_MECANIQUES' = CL0;
  409. * TRACTION
  410. J = COPI J0;
  411. J.'MODELE' = MO ET MO_T;
  412. J.'PRESSION' = CH_T;
  413. J.'SOLUTION_RESO' = UT;
  414. JELT = J.'RESULTATS';
  415. * PRESSION
  416. J = COPI J0;
  417. J.'MODELE' = MO ET MO_P;
  418. J.'PRESSION' = CH_P;
  419. J.'SOLUTION_RESO' = UP;
  420. JELP = J.'RESULTATS';
  421. * TEMPERATURE
  422. J = COPI J0;
  423. J.'MODELE' = MO;
  424. J.'TEMPERATURES' = CHT0;
  425. J.'SOLUTION_RESO' = UTH;
  426. JELTH = J.'RESULTATS';
  427.  
  428. * ERREURS SUR J
  429. EMAXT EMAXP EMAXTH = 0.3 0.3 0.4;
  430. SI (EGA DIMENSION '3D');
  431. JELT = JELT.'GLOBAL';
  432. JELP = JELP.'GLOBAL';
  433. JELTH = JELTH.'GLOBAL';
  434. FINSI;
  435. ERRT = ABS ((JELT-JT)/JT)*100.;
  436. ERRP = ABS ((JELP-JP)/JP)*100.;
  437. ERRTH = ABS ((JELTH-JTH)/JTH)*100.;
  438. MESS '- AVEC RESO :';
  439. CHECKERR ERRT EMAXT 'TRACTION';
  440. CHECKERR ERRP EMAXP 'PRESSION SUR LES LEVRES';
  441. CHECKERR ERRTH EMAXTH 'TEMPERATURE';
  442.  
  443. * RESOLUTION AVEC PASAPAS DES 3 PROBLEMES (UN A CHAQUE PAS DE TEMPS)
  444. * AU PAS 1 : TRACTION SEULE
  445. * AU PAS 2 : PRESSION SUR LES LEVRES
  446. * AU PAS 3 : GRADIENT DE TEMPERATURE
  447. * ENCORE UNE FOIS, ON N'APPELLE PAS PASAPAS MAIS ON REMPLIT UNE TABLE ET
  448. * ON FAIT COMME SI ELLE ETAIT ISSUE DE PASAPAS
  449. CALCUL = TABL;
  450. CALCUL.'MODELE' = MO ET MO_T ET MO_P;
  451. CALCUL.'CARACTERISTIQUES' = MA;
  452. CALCUL.'BLOCAGES_MECANIQUES' = CL0;
  453. CALCUL.'CHARGEMENT' = CHA_T ET CHA_P ET CHA_TH;
  454. CALCUL.'TEMPS_CALCULES' = PROG 1. 2. 3.;
  455. TEM = TABL;
  456. TEM.(0) TEM.(1) TEM.(2) TEM.(3) = 0. 1. 2. 3.;
  457. CALCUL.'TEMPS' = TEM;
  458. USOL = TABL;
  459. USOL.(0) USOL.(1) USOL.(2) USOL.(3) = U0 UT UP UTH;
  460. CALCUL.'DEPLACEMENTS' = USOL;
  461. SSOL = TABL;
  462. REPE I 4;
  463. SSOL.(&I-1) = SIGM MO MA USOL.(&I-1);
  464. FIN I;
  465. SSOL.(3) = SSOL.(3) - (THET MO MA CHT0);
  466. CALCUL.'CONTRAINTES' = SSOL;
  467. CALCUL.'GRANDS_DEPLACEMENTS' = FAUX;
  468. CALCUL.'DYNAMIQUE' = FAUX;
  469.  
  470. * APPEL A G_THETA
  471. J = COPI J0;
  472. OTER J 'BLOCAGES_MECANIQUES';
  473. OTER J 'CARACTERISTIQUES';
  474. J.'SOLUTION_PASAPAS' = CALCUL;
  475. JELT = J.'RESULTATS'.(1);
  476. JELP = J.'RESULTATS'.(2);
  477. JELTH = J.'RESULTATS'.(3);
  478. SI (EGA DIMENSION '3D');
  479. JELT = JELT.'GLOBAL';
  480. JELP = JELP.'GLOBAL';
  481. JELTH = JELTH.'GLOBAL';
  482. FINSI;
  483. ERRT = ABS ((JELT-JT)/JT)*100.;
  484. ERRP = ABS ((JELP-JP)/JP)*100.;
  485. ERRTH = ABS ((JELTH-JTH)/JTH)*100.;
  486.  
  487. * ERREURS
  488. MESS '- AVEC PASAPAS :';
  489. CHECKERR ERRT EMAXT 'TRACTION';
  490. CHECKERR ERRP EMAXP 'PRESSION SUR LES LEVRES';
  491. CHECKERR ERRTH EMAXTH 'TEMPERATURE';
  492.  
  493. FINP;
  494.  
  495.  
  496. * ------------
  497. * CALCULS 2D
  498. * ------------
  499.  
  500. * ON LANCE LES TESTS
  501. CASTEST '2D' 'QUADRATIQUE' 'COMPLET';
  502. CASTEST '2D' 'QUADRATIQUE' 'MOITIE';
  503. CASTEST '2D' 'LINEAIRE' 'COMPLET';
  504. CASTEST '2D' 'LINEAIRE' 'MOITIE';
  505.  
  506.  
  507. * ------------
  508. * CALCULS 3D
  509. * ------------
  510.  
  511. * ASTUCE : PAS BESOIN DE RESOUDRE DE NOUVEAU LES 3 PROBLEMES MECANIQUES,
  512. * ON PEUT UTILISER LA SOLUTION 2D ET L'OPERATEUR 'MOIN' POUR
  513. * OBTENIR LA SOLUTION PAR DIFFERENCE ENTRE LES GEOMETRIES
  514. * INITIALES ET DEFORMEES
  515.  
  516. OMEGA_T = OMEGA PLUS UT;
  517. OMEGA_P = OMEGA PLUS UP;
  518. OMEGA_TH = OMEGA PLUS UTH;
  519.  
  520. OPTI 'DIME' 3 'ELEM' 'CU20';
  521.  
  522. * ANGLE DE ROTATION
  523. ANG1 = 0.5;
  524. * POINTS DE L'AXE DE ROTATION
  525. PA = 0. 0. 0.;
  526. PB = 0. 1. 0.;
  527. * NOMBRE D'ELEMENTS DANS L'EPAISSEUR
  528. NEP = 1;
  529.  
  530. OMEGA = OMEGA VOLU NEP 'ROTA' ANG1 PA PB;
  531. OMEGA_T = OMEGA_T VOLU NEP 'ROTA' ANG1 PA PB;
  532. OMEGA_P = OMEGA_P VOLU NEP 'ROTA' ANG1 PA PB;
  533. OMEGA_TH = OMEGA_TH VOLU NEP 'ROTA' ANG1 PA PB;
  534.  
  535. * VOICI LES SOLUTIONS 3D :
  536. UT = OMEGA_T MOIN OMEGA;
  537. UP = OMEGA_P MOIN OMEGA;
  538. UTH = OMEGA_TH MOIN OMEGA;
  539. U0 = MANU 'CHPO' OMEGA 3 'UX' 0. 'UY' 0. 'UZ' 0.;
  540.  
  541. * IL FAUT REDEFINIR LES ENTITES GEOMETRIQUES IMPORTANTES
  542. PSUP = (COOR 2 OMEGA) POIN 'EGSUPE' (0. - 1.E-10);
  543. CYL_SUP = OMEGA ELEM 'APPUYE' PSUP;
  544. PINF = (COOR 2 OMEGA) POIN 'EGINFE' 1.E-10;
  545. CYL_INF = OMEGA ELEM 'APPUYE' PINF;
  546. LVSUP = LVSUP ROTA NEP ANG1 PA PB;
  547. LVINF = LVINF ROTA NEP ANG1 PA PB;
  548. LIGAMENT = LIGAMENT ROTA NEP ANG1 PA PB;
  549. BHAUT = BHAUT ROTA NEP ANG1 PA PB;
  550. BBAS = BBAS ROTA NEP ANG1 PA PB;
  551. PF = CERC NEP 'ROTA' ANG1 PF PA PB;
  552. ELIM CYL_SUP (BHAUT ET LVSUP) 1.E-10;
  553. ELIM CYL_INF (BBAS ET LVINF) 1.E-10;
  554. ELIM OMEGA LIGAMENT 1.E-10;
  555. ELIM PF LIGAMENT 1.E-10;
  556.  
  557. * ON AJOUTE LES POINTS POUR LES 2 PLANS DE SYMETRIE EN 3D
  558. PSYM11 = CYL_SUP POIN 'PROC' (RI 0. 0.);
  559. PSYM12 = CYL_SUP POIN 'PROC' (RE 0. 0.);
  560. PSYM13 = CYL_SUP POIN 'PROC' (RI (H/2) 0.);
  561. PSYM21 = CYL_SUP POIN 'PROC' (PSYM11 TOUR ANG1 PA PB);
  562. PSYM22 = CYL_SUP POIN 'PROC' (PSYM12 TOUR ANG1 PA PB);
  563. PSYM23 = CYL_SUP POIN 'PROC' (PSYM13 TOUR ANG1 PA PB);
  564.  
  565. * ON LANCE LES TESTS
  566. CASTEST '3D' 'QUADRATIQUE' 'COMPLET';
  567. CASTEST '3D' 'QUADRATIQUE' 'MOITIE';
  568. CASTEST '3D' 'LINEAIRE' 'COMPLET';
  569. CASTEST '3D' 'LINEAIRE' 'MOITIE';
  570.  
  571. FIN;
  572.  
  573.  
  574.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales