Télécharger Contact3D.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : Contact3D.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *----------------------------------------------------------------------*
  5. * Ce cas-test permet de tester la gestion du contact par PASAPAS. *
  6. * Il simule la mise en contact, en deplacements imposes, d'un cube *
  7. * sur une sol rigide. On impose le deplacement de la face superieure *
  8. * du cube. Sa base entre en contact, le cube est mis en compression. *
  9. * On compare la solution EF a la solution analytique. *
  10. *----------------------------------------------------------------------*
  11. * *
  12. 'OPTI' 'DIME' 3 'ELEM' CUB8 'EPSI' 'LINEAIRE' ;
  13. * *
  14. * Si TRACes desires, mettre IG1 a VRAI : *
  15. IG1 = FAUX ;
  16. * *
  17. *----------------------------------------------------------------------*
  18. * MAILLAGE *
  19. *----------------------------------------------------------------------*
  20. * *
  21. * Maillage "Sol" : *
  22. S1 = -10. -5. 0. ;
  23. S2 = +10. -5. 0. ;
  24. NLS1 = 5 ;
  25. LS1 = S1 'DROI' NLS1 S2 ;
  26. SOL1 = LS1 'TRAN' NLS1 (0. 20. 0.) ;
  27. SOL1 = SOL1 'COUL' 'OLIV' ;
  28. * *
  29. * Maillage "Cube" : *
  30. C1 = -5. 0. 0.1 ;
  31. M2 = +5. 0. 0.1 ;
  32. NLC1 = 7 ;
  33. LC1 = C1 'DROI' NLC1 M2 ;
  34. SC1 = LC1 'TRAN' NLC1 (0. 10. 0.) ;
  35. CUB1 = SC1 'VOLU' NLC1 'TRAN' (0. 0. 10.) ;
  36. CUB1 = CUB1 'COUL' 'ORAN' ;
  37. * *
  38. MTOT1 = (SOL1 'ET' CUB1) 'COUL' 'DEFA' ;
  39. * *
  40. * Maillages de contact orientes : *
  41. SOL2 = 'ORIE' ('CHAN' 'TRI3' SOL1) (0. 0. +1.) ;
  42. SCC1 = 'ORIE' ('CHAN' 'TRI3' SC1 ) (0. 0. -1.) ;
  43. MCONT1 = ('IMPO' 'MAIL' SOL2 SCC1) 'COUL' 'ROUG' ;
  44. * *
  45. * Traces : *
  46. 'SI' IG1 ;
  47. 'TITR' 'Maillages Cube / Sol ' ;
  48. 'TRAC' 'FACE' (CUB1 ET SOL1) ;
  49. 'TITR' 'Maillages Cube / Sol & Maillage de contact (rouge) ' ;
  50. 'TRAC' 'FACE' (MTOT1 ET MCONT1) ;
  51. 'FINS' ;
  52. * *
  53. *----------------------------------------------------------------------*
  54. * MODELES / CARACTERISTIQUES *
  55. *----------------------------------------------------------------------*
  56. * *
  57. MOD1 = 'MODE' CUB1 'MECANIQUE' 'ELASTIQUE' ;
  58. MAT1 = 'MATE' MOD1 'YOUN' 1.E3 'NU' 0.3 ;
  59. * *
  60. MODC1 = 'MODE' MCONT1 'CONTACT' 'UNILATERAL' ;
  61. * *
  62. MOD0 = MOD1 'ET' MODC1 ;
  63. MAT0 = MAT1 ;
  64. * *
  65. *----------------------------------------------------------------------*
  66. * C.L. / CHARGEMENT *
  67. *----------------------------------------------------------------------*
  68. * *
  69. * Deplacements imposes : *
  70. CL1 = 'BLOQ' SOL1 'DEPL' ;
  71. * *
  72. SC2 = 'FACE' CUB1 2 ;
  73. SCX0 = (CUB1 'ENVE') 'ELEM' 'APPU' ((CUB1 'COOR' 1) 'POIN' 'MINI') ;
  74. SCY0 = (CUB1 'ENVE') 'ELEM' 'APPU' ((CUB1 'COOR' 2) 'POIN' 'MINI') ;
  75. CLSC2 = 'BLOQ' SC2 'UZ' ;
  76. CLSCX0 = 'BLOQ' SCX0 'UX' ;
  77. CLSCY0 = 'BLOQ' SCY0 'UY' ;
  78. *
  79. CL0 = CL1 'ET' CLSC2 'ET' CLSCX0 'ET' CLSCY0 ;
  80. * *
  81. UZ0 = -0.101 ;
  82. DCLC2 = 'DEPI' CLSC2 UZ0 ;
  83. * *
  84. 'SI' IG1 ;
  85. 'TRAC' ('VECT' ('EXCO' DCLC2 'FLX' 'UZ') 'DEPL' 'ROUG') ('ARET' MTOT1)
  86. 'TITR' 'Deplacement impose a la surface superieure du cube.' ;
  87. 'FINS' ;
  88. * *
  89. * Chargements : *
  90. LTPS1 = 'PROG' 0. 1. ;
  91. EV1 = 'EVOL' 'MANU' 'TEMPS' LTPS1 LTPS1 ;
  92. CHARU1 = 'CHAR' 'DIMP' DCLC2 EV1 ;
  93. CHAR0 = CHARU1 ;
  94. * *
  95. *----------------------------------------------------------------------*
  96. * RESOLUTION *
  97. *----------------------------------------------------------------------*
  98. * *
  99. * Construction de la table PASAPAS : *
  100. * *
  101. TAB1 = 'TABL' ;
  102. TAB1 . 'MODELE' = MOD0 ;
  103. TAB1 . 'CARACTERISTIQUES' = MAT0 ;
  104. TAB1 . 'BLOCAGES_MECANIQUES' = CL0 ;
  105. TAB1 . 'CHARGEMENT' = CHAR0 ;
  106. TAB1 . 'TEMPS_CALCULES' = LTPS1 ;
  107. * *
  108. * Resolution : *
  109. * *
  110. TAB2 = PASAPAS TAB1 ;
  111. * *
  112. *----------------------------------------------------------------------*
  113. * DEPOUILLEMENT *
  114. *----------------------------------------------------------------------*
  115. * *
  116. DEP1 = (TAB2 . 'DEPLACEMENTS' . 1) 'ENLE' 'LX' ;
  117. * *
  118. * Deformee : *
  119. DEFO0 = 'DEFO' (CUB1 'ET' SOL1) DEP1 0. 'VERT' ;
  120. DEFO1 = 'DEFO' (CUB1 'ET' SOL1) DEP1 1. 'ROUG' ;
  121. * *
  122. 'SI' IG1 ;
  123. 'TITR' 'Maillages non deforme (vert) et deforme (rouge).' ;
  124. 'TRAC' (DEFO0 'ET' DEFO1) ;
  125. 'FINS' ;
  126. * *
  127. * On verifie qu'on ne tranverse pas la surface : *
  128. ERR1 = ('MAXI' (SOL1 'COOR' 3))
  129. - ('MINI' ((CUB1 'COOR' 3) + ('EXCO' 'UZ' DEP1))) ;
  130. 'MESS' ' ****** ECART RELATIF POSITION DE CONTACT : ' ERR1 ;
  131. ERR0 = ERR1 ;
  132. * *
  133. * Definition des deplacements solutions et comparaison avec la *
  134. * solution EF : *
  135. 'SI' ('EGA' ('VALE' 'EPSI') 'LINEAIRE') ;
  136. EPXX1 = ((-1. * UZ0) - 0.1) * 0.1 * 0.3 ;
  137. UXCUB1 = (('COOR' 1 CUB1) + 5.) * EPXX1 ;
  138. SOLUX1 = UXCUB1 'NOMC' 'UX' ;
  139. EPYY1 = EPXX1 ;
  140. UYCUB1 = ('COOR' 2 CUB1) * EPYY1 ;
  141. SOLUY1 = UYCUB1 'NOMC' 'UY' ;
  142. EPZZ1 = (UZ0 + 0.1) * 0.1 ;
  143. UZCUB1 = -0.1 + ((('COOR' 3 CUB1) - 0.1) * EPZZ1) ;
  144. SOLUZ1 = UZCUB1 'NOMC' 'UZ' ;
  145. SOLU1 = SOLUX1 'ET' SOLUY1 'ET' SOLUZ1 ;
  146. ERR2 = 'MAXI' ('ABS' ((SOLU1 - DEP1) / ('MAXI' 'ABS' SOLU1))) ;
  147. 'MESS' ' ****** ERREUR RELATIVE EN DEPLACEMENT : ' ERR2 ;
  148. ERR0 = ERR0 + ERR2 ;
  149. 'FINS' ;
  150. * *
  151. 'SI' IG1 ;
  152. 'TITR' 'Champ de deplacements.' ;
  153. 'TRAC' ('CHAN' 'CHAM' DEP1 MOD1 'NOEUDS') MOD1 ;
  154. 'FINS' ;
  155. * *
  156. * Comparaison des champs de contraintes : *
  157. * *
  158. 'SI' ('EGA' ('VALE' 'EPSI') 'LINEAIRE') ;
  159. SIG1 = 'SIGM' MOD1 MAT1 SOLU1 ;
  160. SIG1 = 'PICA' MOD1 SIG1 SOLU1 ;
  161. SIG2 = TAB2 . 'CONTRAINTES' . 1 ;
  162. ERR3 = ('MAXI' 'ABS' (SIG1 - SIG2)) / ('MAXI' 'ABS' SIG1) ;
  163. 'MESS' ' ****** ERREUR RELATIVE EN CONTRAINTE : ' ERR3 ;
  164. ERR0 = ERR0 + ERR3 ;
  165. 'FINS' ;
  166. * *
  167. * Test calcul critere de Tresca avec modele de contact dans objet *
  168. * modele en argument : *
  169. TRE1 = 'TRES' MOD0 SIG2 ;
  170. 'SI' IG1 ;
  171. 'TITR' 'Champ de contraintes.' ;
  172. 'TRAC' SIG2 MOD0 ;
  173. 'TRAC' TRE1 MOD0 'TITR' 'Critere de Tresca' ;
  174. 'FINS' ;
  175. * *
  176. * Visualisations des reactions : *
  177. * *
  178. 'SI' IG1 ;
  179. REAC1 = TAB2 . 'REACTIONS' . 1 ;
  180. VR1 = 'VECT' REAC1 'FORC' 'ROUG' ;
  181. 'TITR' 'Forces de reaction.' ;
  182. 'TRAC' VR1 ('ARET' MTOT1) ;
  183. 'FINS' ;
  184. * *
  185. ERRMAX1 = 1.E-4 ;
  186. * *
  187. 'OPTI' 'ECHO' 0 ;
  188. 'SAUT' 1 'LIGN' ;
  189. '---------------------- RESULTAT CAS-TEST ------------------------' ;
  190. 'MESS' ' ' ;
  191. 'Ecart relatif a la solution calculee sur les deplacements' ;
  192. 'et les contraintes :' ;
  193. 'MESS' ;
  194. 'SI' (ERR0 '<EG' ERRMAX1) ;
  195. 'MESS' ('CHAI' ' ==> MAXI ERREUR =' ERR0 ' < ' ERRMAX1 ) ;
  196. 'MESS' ' ' ;
  197. 'MESS' ' __________________' ;
  198. 'MESS' ' | |' ;
  199. 'MESS' ' | TEST REUSSI ! |' ;
  200. 'MESS' ' |________________|' ;
  201. 'SAUT' 1 'LIGN' ;
  202. 'SINO' ;
  203. 'MESS' ('CHAI' ' ==> MAXI ERREUR =' ERR0 ' > ' ERRMAX1 ) ;
  204. 'MESS' ' ' ;
  205. 'MESS' ' __________________' ;
  206. 'MESS' ' | |' ;
  207. 'MESS' ' | ERREUR ! |' ;
  208. 'MESS' ' |________________|' ;
  209. 'SAUT' 1 'LIGN' ;
  210. 'ERRE' 5 ;
  211. 'FINS' ;
  212. '------------------------ FIN CAS-TEST ---------------------------' ;
  213. * *
  214. 'FIN' ;
  215. 'OPTI' 'ECHO' 1 ;
  216.  
  217.  
  218.  
  219.  
  220.  
  221.  
  222.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales