Télécharger Condens.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : condens.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. GRAPH = FAUX ;
  6.  
  7. ************************************************************************
  8. * condens.dgibi : bas Mach + condensation en paroi *
  9. ************************************************************************
  10. * MODELE MISTRA AVEC CONDENSEURS *
  11. * ------------------------------ *
  12. * INJECTION DE VAPEUR DANS UNE ENCEINTE FERMEE CONTENANT DE L'AIR *
  13. * TEMPERATURE DE PAROI IMPOSEE (PAROI VERTICALE) NON CALCULEE *
  14. * MODELE DE CONDENSATION : CHILTON-COLBURN + ANALOGIE HMT *
  15. * ECHANGES PAR CONVECTION ET CONDENSATION *
  16. * EQUATION D'ENERGIE EN TEMPERATURE *
  17. * ECOULEMENTS TURBULENTS *
  18. * MAILLAGE 2D AXI FORMULATION EF QUA8 *
  19. * P. CORNET SEMT/TTMF 23 DECEMBRE 1998 *
  20. ************************************************************************
  21. *
  22. ************************************************************************
  23. * PROCEDURE FILTREKE *
  24. * VERSION non encore évoluée à ce jour *
  25. ************************************************************************
  26. *
  27. * 4 arguments : U0 L0 NU UN
  28. *
  29. * Filtre sur K et Epsilon
  30. * - Echelle de vitesse (K**0.5) inférieure à une fraction (alfk)
  31. * de Uref (vitesse caractéristique) (alfk=1 pour l'instant)
  32. * Uref=max(UN,U0)
  33. * - K > K0
  34. * - Epsilon tel que l'echelle de longueur reste inférieure
  35. * à (L0/a) où L0 = diamètre enceinte et a=f(Re)
  36. * => Nut < Uref*L0/a
  37.  
  38. DEBP FILTREKE ;
  39. ARGU RX*TABLE ;
  40. rv=rx.'EQEX' ;
  41. rvp=rv.'PRESSION' ;
  42.  
  43. rv=rx.'EQEX' ;
  44. iarg=rx.'IARG' ;
  45. si( non ( ega iarg 4)) ;
  46. mess 'Procedure FILTREKE : nombre d arguments incorrect ' iarg ;
  47. quitter FILTREKE ;
  48. finsi ;
  49. si ( ega ('TYPE' rx.'ARG1') 'MOT ') ;
  50. U1=rv.'INCO'.(rx.'ARG1') ;
  51. sinon ;
  52. si ( ega ('TYPE' (rx.'ARG1')) 'FLOTTANT') ;
  53. U1=rx.'ARG1' ;
  54. sinon ;
  55. mess 'Procedure FILTREKE : type argument 1 invalide ' ;
  56. quitter FILTREKE ;
  57. finsi ;
  58. finsi ;
  59.  
  60. si ( ega ('TYPE' rx.'ARG2') 'MOT ') ;
  61. L0=rv.'INCO'.(rx.'ARG2') ;
  62. sinon ;
  63. si ( ega ('TYPE' (rx.'ARG2')) 'FLOTTANT') ;
  64. L0=rx.'ARG2' ;
  65. sinon ;
  66. mess 'Procedure FILTREKE : type argument 2 invalide ' ;
  67. quitter FILTREKE ;
  68. finsi ;
  69. finsi ;
  70.  
  71. si ( ega ('TYPE' rx.'ARG3') 'MOT ') ;
  72. NU=rv.'INCO'.(rx.'ARG3') ;
  73. sinon ;
  74. si ( ega ('TYPE' (rx.'ARG3')) 'FLOTTANT') ;
  75. NU=rx.'ARG3' ;
  76. sinon ;
  77. mess 'Procedure FILTREKE : type argument 3 invalide ' ;
  78. quitter FILTREKE ;
  79. finsi ;
  80. finsi ;
  81.  
  82. si ( ega ('TYPE' rx.'ARG4') 'MOT ') ;
  83. UN=rv.'INCO'.(rx.'ARG4') ;
  84. sinon ;
  85. si ( ega ('TYPE' (rx.'ARG4')) 'CHPOINT') ;
  86. UN=rx.'ARG4' ;
  87. sinon ;
  88. mess 'Procedure FILTREKE : type argument 4 invalide ' ;
  89. quitter FILTREKE ;
  90. finsi ;
  91. finsi ;
  92.  
  93. nic=dime (rx.'LISTINCO') ;
  94. si( non ( ega nic 2)) ;
  95. mess 'Procedure FILTREKE : nombre d inconnues incorrect ' nic ;
  96. quitter FILTREKE ;
  97. finsi ;
  98.  
  99. nomi1=extr 1 (rx.'LISTINCO');
  100. nomi2=extr 2 (rx.'LISTINCO');
  101. nom1= mot (text (chai nomi1)) ;
  102. nom2= mot (text (chai nomi2)) ;
  103.  
  104. en=rv.'INCO'.nom2 ;
  105. kn=rv.'INCO'.nom1 ;
  106.  
  107. Rec=100.;
  108. k0 = 1.e-10 ;
  109. cnu=0.09;
  110.  
  111. lcu=extr un 'COMP' ;
  112. mdu=un lcu 'PSCA' un lcu;
  113. mdu=mdu ** 0.5 ;
  114.  
  115. Re=kops (kops (kops mdu '*' L0) '/' nu) '+' (Rec / 10.) ;
  116. a= exp (kops Rec '/' Re ) ;
  117.  
  118. mdu = kops mdu '|<' u1 ;
  119. mdu2= kops mdu '*' mdu ;
  120.  
  121. kn=kops kn '|<' k0 ;
  122. kn=kops kn '>|' mdu2 ;
  123.  
  124. E0= kops (kops kn '**' 1.5) '*' (a / L0) ;
  125. en=kops en '|<' E0 ;
  126.  
  127. rv.'INCO'.nom2=en ;
  128. rv.'INCO'.nom1=kn ;
  129.  
  130. finproc ;
  131.  
  132. ************************************************************************
  133. * PROCEDURE CALCUL1 *
  134. ************************************************************************
  135.  
  136. DEBPROC CALCUL1 ;
  137. ARGU RVX*'TABLE' ;
  138. RV = RVX.'EQEX' ;
  139. $MT = RV.'DOMAINE' ;
  140.  
  141. * on récupère le pas de temps (tn - tn-1)
  142.  
  143. DT = RV.PASDETPS.'DELTAT-1' ;
  144. SI (RV.PASDETPS.'NUPASDT' EGA 1) ;
  145. RV.PASDETPS.'DELTAT' = 1.0E-5 ;
  146. DT = 0. ;
  147. FINSI ;
  148.  
  149. * filtre sur la fraction massique de vapeur et calcul fraction air
  150.  
  151. YH2O = RV.INCO.'YH2O' ;
  152. YH2O = KOPS YH2O '|<' 0. ;
  153. YH2O = KOPS YH2O '>|' 1. ;
  154. YAIR = KOPS 1.0 '-' YH2O ;
  155. RV.INCO.'YAIR' = YAIR ;
  156.  
  157. * calcul de Cv, Cp et R du mélange
  158.  
  159. CV1 = kops YH2O '*' CVH2O ;
  160. CV2 = kops YAIR '*' CVAIR ;
  161. CV = kops CV1 '+' CV2 ;
  162.  
  163. CP1 = kops YH2O '*' CPH2O ;
  164. CP2 = kops YAIR '*' CPAIR ;
  165. CP = kops CP1 '+' CP2 ;
  166.  
  167. RR1 = kops YH2O '*' RH2O ;
  168. RR2 = kops YAIR '*' RAIR ;
  169. RR = kops RR1 '+' RR2 ;
  170.  
  171. RV.INCO.'CV' = CV ;
  172. RV.INCO.'CP' = CP ;
  173. RV.INCO.'RN' = RR ;
  174.  
  175. * calcul de la densité totale moyenne 0D (kg/m3)
  176.  
  177. Q0 = RV.INCO.'DEBIT' ;
  178. QC = RV.INCO.'QC' ;
  179. DRO = DT*(Q0+QC)/VOLT ;
  180. ROT0D = RV.INCO.'ROT0D' + DRO ;
  181. RV.INCO.'ROT0D' = ROT0D ;
  182.  
  183. * calcul de la densité de vapeur moyenne 0D (kg/m3)
  184.  
  185. QV = Q0*YH2Ojet ;
  186. DROV = DT*(QV+QC)/VOLT ;
  187. ROV0D = RV.INCO.'ROV0D' + DROV ;
  188. RV.INCO.'ROV0D' = ROV0D ;
  189.  
  190. * calcul de l'énergie emmenée par la condensation (W)
  191.  
  192. TNP = KCHT $PCON SCAL SOMMET RV.INCO.'TN' ;
  193. CVT = KOPS CVH2O '*' TNP ;
  194. ENC = KOPS CVT '*' RV.INCO.'FCOND' ;
  195. ENC = RV.'DI' '*' ENC ;
  196. ENC = SOMT ENC ;
  197.  
  198. * calcul de l'énergie emmenée par la convection (W)
  199.  
  200. ROP = KCHT $PCON SCAL SOMMET RV.INCO.'RHO' ;
  201. CPP = KCHT $PCON SCAL SOMMET CP ;
  202. RCP = KOPS ROP '*' CPP ;
  203. DTP = KOPS TNP '-' RV.INCO.'TC' ;
  204. RCT = KOPS RCP '*' DTP ;
  205. EHI = NOEL $PCON RCT ;
  206. EHI = KOPS EHI '*' RV.INCO.'H' ;
  207. EHI = KOPS EHI '*' SURFC ;
  208. EHI = SOMT EHI ;
  209.  
  210. * calcul de l'énergie moyenne 0D (J/m3)
  211.  
  212. DES = (Q0*EMjet) + Etran - ENC - EHI ;
  213. DES = DES*DT/VOLT ;
  214. ES0D = RV.INCO.'ES0D' + DES ;
  215. RV.INCO.'ES0D' = ES0D ;
  216.  
  217. * Cp et Cv 0D du mélange
  218.  
  219. YV0D = ROV0D/ROT0D ;
  220. YA0D = 1.0 - YV0D ;
  221. CP0D = (YV0D*CPH2O) + (YA0D*CPAIR) ;
  222. CV0D = (YV0D*CVH2O) + (YA0D*CVAIR) ;
  223.  
  224. * calcul de la pression moyenne 0D
  225.  
  226. GAM0D = CP0D/CV0D ;
  227. RV.INCO.'PR0D' = (GAM0D - 1.0)*ES0D ;
  228.  
  229. * calcul de la masse volumique du melange
  230.  
  231. PSIN = KOPS (RV.INCO.'TN') '*' (RV.INCO.'RN') ;
  232. RHO = KOPS (RV.INCO.'PM') '/' PSIN ;
  233. ROM = KOPS RV.'D0' '*' RHO ;
  234. ROM = (somt ROM)/VOLT ;
  235. DRO1 = RV.INCO.'ROT0D' - ROM ;
  236. DRHO = KCHT $MT SCAL SOMMET DRO1 ;
  237. RV.INCO.'RHO' = KOPS RHO '+' DRHO ;
  238. RV.INCO.'RHO1' = RHO ;
  239. RV.INCO.'RHOC' = NOEL $MT RV.INCO.'RHO' ;
  240.  
  241. * contrainte sur rhoh2o pour conservation 0D
  242.  
  243. ROVM = kops YH2O '*' RHO ;
  244. ROVM = kops RV.'D0' '*' ROVM ;
  245. ROVM = (somt ROVM)/VOLT ;
  246. DROV = RV.INCO.'ROV0D' - ROVM ;
  247. DYV = DROV/ROM ;
  248. DYH2O = kcht $mt SCAL SOMMET DYV ;
  249. YH2OC = kops YH2O '+' DYH2O ;
  250. YH2OF = kops YH2OC '|<' 0. ;
  251. YH2OF = kops YH2OF '>|' 1. ;
  252. RV.INCO.'YH2O' = YH2OF ;
  253.  
  254. * contrainte sur l'énergie e=rho.Cv.T pour conservation 0D
  255.  
  256. RCV = KOPS RHO '*' CV ;
  257. ENM = KOPS RV.INCO.'TN' '*' RCV ;
  258. ENM = KOPS RV.'D0' '*' ENM ;
  259. ENM = (SOMT ENM)/VOLT ;
  260. DEN = RV.INCO.'ES0D' - ENM ;
  261. RCVM = KOPS RV.'D0' '*' RCV ;
  262. RCVM = (SOMT RCVM)/VOLT ;
  263. DTN = DEN/RCVM ;
  264. DTN = KCHT $MT SCAL SOMMET DTN ;
  265. RV.INCO.'TN' = KOPS RV.INCO.'TN' '+' DTN ;
  266.  
  267. * calcul du terme (rho-rhom)*g de la QDM
  268.  
  269. DRHO = KOPS (RV.INCO.'RHOC') '-' (RV.INCO.'ROT0D') ;
  270. rogx = KCHT (RV.'DOMAINE') SCAL CENTRE 0. ;
  271. rogy = KCHT (RV.'DOMAINE') SCAL CENTRE (-9.81*DRHO) ;
  272. rogx = nomc 'UX' rogx 'NATU' 'DISCRET' ;
  273. rogy = nomc 'UY' rogy 'NATU' 'DISCRET' ;
  274. RV.INCO.'ROG' = KCHT (RV.'DOMAINE') VECT CENTRE (rogx ET rogy) ;
  275.  
  276. * calcul la vitesse à partir de la qdm
  277.  
  278. GN = RV.INCO.'GN' ;
  279. gnx= kcht (rv.'DOMAINE') scal sommet (exco 'UX' gn) ;
  280. gny= kcht (rv.'DOMAINE') scal sommet (exco 'UY' gn) ;
  281. unx = kops gnx '/' RV.INCO.'RHO' ;
  282. uny = kops gny '/' RV.INCO.'RHO' ;
  283. unx = nomc 'UX' unx 'NATU' 'DISCRET' ;
  284. uny = nomc 'UY' uny 'NATU' 'DISCRET' ;
  285. un = kcht (RV.'DOMAINE') vect sommet (unx et uny) ;
  286. RV.INCO.'UN' = un ;
  287.  
  288. * calcul de nut et uet (pour FPT)
  289.  
  290. RV.INCO.'NUT' = KOPS (RV.INCO.'MUT') '/' (RV.INCO.'RHOC') ;
  291. RV.INCO.'UTC' = KCHT $PCON SCAL CENTRE RV.INCO.'UET' ;
  292.  
  293. *-------------------------------------------------*
  294. * calcul du flux condensé Jv par Chilton-Colburn *
  295. * et la corrélation de convection naturelle *
  296. * Sh = kL/Dv = 0.13 (Gr Sc)**1/3 *
  297. * Jv = k ro (Yv - Yvsat) en kg/m²s *
  298. *-------------------------------------------------*
  299.  
  300. * pression de saturation à l'interface
  301.  
  302. TC = KOPS (RV.INCO.'TC') '-' 273.15 ;
  303. PSAT = KOPS TC '/' 100. ;
  304. PSAT = KOPS PSAT '**' 4 ;
  305. PSAT = KOPS PSAT '*' 1.0E5 ;
  306.  
  307. * pression de vapeur pres de la paroi
  308.  
  309. YVP = KCHT $PCON SCAL SOMMET RV.INCO.'YH2O' ;
  310. RVT = KOPS RH2O '*' TNP ;
  311. ROV = KOPS ROP '*' YVP ;
  312. PV = KOPS ROV '*' RVT ;
  313.  
  314. * masse volumique à l'interface
  315.  
  316. RVTI = KOPS RH2O '*' RV.INCO.'TC' ;
  317. ROVI = KOPS PSAT '/' RVTI ;
  318. RATI = KOPS RAIR '*' RV.INCO.'TC' ;
  319. PAIR = KOPS RV.INCO.'PM' '-' PSAT ;
  320. RAVI = KOPS PAIR '/' RATI ;
  321. ROI = KOPS ROVI '+' RAVI ;
  322.  
  323. * fraction massique vapeur à l'interface
  324.  
  325. YVI = KOPS ROVI '/' ROI ;
  326. RV.INCO.'YVS' = YVI ;
  327. RV.INCO.'YVI' = NOEL $PCON YVI ;
  328.  
  329. * coefficient de diffusion de la vapeur dans l'air (m2/s)
  330.  
  331. AA = 2.2 / RV.INCO.'PM' ;
  332. TFP = KOPS TNP '/' 273. ;
  333. DV = KOPS TFP '**' 1.75 ;
  334. DV = KOPS DV '*' AA ;
  335.  
  336. * coefficient d'échange de masse k (m/s)
  337.  
  338. BB = 0.13 * (9.81 * RV.INCO.'ROT0D' / MU)**0.33333 ;
  339. DRO = KOPS ROP '-' ROI ;
  340. DRO = ABS DRO ;
  341. DRO = KOPS DRO '**' 0.33333 ;
  342. KK = KOPS DV '**' 0.66667 ;
  343. KK = KOPS KK '*' DRO ;
  344. KK = KOPS KK '*' BB ;
  345. RV.INCO.'K' = KK ;
  346.  
  347. * fonction indicatrice de la condensation
  348.  
  349. DPV = KOPS PV '-' PSAT ;
  350. IND = DPV MASQUE 'EGSUP' 0. ;
  351. IND = KCHT $PCON SCAL SOMMET IND ;
  352.  
  353. * coefficient d'échange pour yh2o (kg/m2s)
  354.  
  355. KRO = KOPS KK '*' ROP ;
  356. KRO = KOPS KRO '*' IND ;
  357. RV.INCO.'KS' = KRO ;
  358. RV.INCO.'KY' = NOEL $PCON KRO ;
  359.  
  360. * calcul de la masse de vapeur condensée QC (kg/s)
  361.  
  362. DYV = KOPS YVP '-' RV.INCO.'YVS' ;
  363. FCOND = KOPS DYV '*' RV.INCO.'KS' ;
  364. QC = RV.'DI' '*' FCOND ;
  365. QC = (SOMT QC)*(-1.) ;
  366. RV.INCO.'FCOND' = FCOND ;
  367. RV.INCO.'QC' = QC ;
  368.  
  369. * suivi masse condensée
  370.  
  371. RV.INCO.'MCOND' = RV.INCO.'MCOND' + (QC*DT) ;
  372.  
  373. * suivi des inconnues OD et messages
  374.  
  375. DD = RV.PASDETPS.'NUPASDT' ;
  376. NN = DD/NSAUV ;
  377. LO = (DD-(NSAUV*NN)) EGA 0 ;
  378. SI ( LO ) ;
  379. MESSAGE '===============================================================
  380. =====================================' ;
  381.  
  382. * suivi pression, masse vol tot, temperature, enthalpie OD, condensation
  383.  
  384. RV.INCO.'PT0D' = RV.INCO.'PT0D' et (prog RV.INCO.'PR0D') ;
  385. R0D = (YV0D*RH2O) + (YA0D*RAIR) ;
  386. PVAP = RV.INCO.'PR0D'*YV0D*RH2O/R0D ;
  387. PAIR = RV.INCO.'PR0D'*YA0D*RAIR/R0D ;
  388. RV.INCO.'PV0D' = RV.INCO.'PV0D' et (prog PVAP) ;
  389. RV.INCO.'PA0D' = RV.INCO.'PA0D' et (prog PAIR) ;
  390. RV.INCO.'RO0D' = RV.INCO.'RO0D' et (prog RV.INCO.'ROT0D') ;
  391. T0D = ES0D/ROT0D/CV0D - 273.15 ;
  392. RV.INCO.'T0D' = RV.INCO.'T0D' et (prog T0D) ;
  393. H0D = GAM0D * ES0D / ROT0D + LAT ;
  394. RV.INCO.'H0D' = RV.INCO.'H0D' et (prog H0D) ;
  395. QC1 = -1.* QC ;
  396. RV.INCO.'FCDST' = RV.INCO.'FCDST' et (prog QC1) ;
  397.  
  398. ener = kops RV.INCO.'RHO' '*' RV.INCO.'CV' ;
  399. ener = kops ener '*' RV.INCO.'TN' ;
  400. ener = noel $mt ener ;
  401. ener = kops ener '*' vol ;
  402. RV.INCO.'ETOT' = RV.INCO.'ETOT' et (prog ener) ;
  403. en2 = ES0D*VOLT ;
  404. RV.INCO.'ET0D' = RV.INCO.'ET0D' et (prog en2) ;
  405.  
  406. FINSI ;
  407.  
  408. FINPROC ;
  409.  
  410. ************************************************************************
  411. * PROCEDURE CALCUL2 *
  412. ************************************************************************
  413.  
  414. DEBPROC CALCUL2 ;
  415. ARGU RVX*'TABLE' ;
  416. RV = RVX.'EQEX' ;
  417. $MT = RV.'DOMAINE' ;
  418.  
  419. * on récupère le pas de temps
  420.  
  421. Dt = RV.PASDETPS.'DELTAT' ;
  422. Dt = Dt * RV.'ALFA' ;
  423.  
  424. * calcul de l'intégrale se trouvant dans le terme Dp/Dt.
  425.  
  426. RV.INCO.'PSIN' = KOPS (RV.INCO.'TN') '*' (RV.INCO.'RN') ;
  427. ZT = KOPS (RV.INCO.'PSIN') '-' (RV.INCO.'PSI1') ;
  428. ZT = KOPS ZT '/' Dt ;
  429. ZT = KOPS ZT '/' (RV.INCO.'PSIN') ;
  430. ZZ = KOPS ZT '*' RV.INCO.'RHO' ;
  431. ZZ = NOEL $MT ZZ ;
  432. ZZ = KCHT $MT 'SCAL' 'CENTRE' ZZ ;
  433. ZZT = SOMT ( KOPS ZZ '*' VOL ) ;
  434. RV.INCO.'PSI1' = KCHT $MT 'SCAL' 'SOMMET' (RV.INCO.'PSIN') ;
  435.  
  436. * calcul de dP/dt
  437.  
  438. * Q0 = 'DBIT' RV.INCO.'GN' $BAS ;
  439. dPdt = ZZT + RV.INCO.'DEBIT' + RV.INCO.'QC' ;
  440. dPdt = dPdt*(RV.INCO.'PM')/VOLT/RV.INCO.'ROT0D' ;
  441.  
  442. * terme source de l'équation d'énergie (terme en dP/dt)
  443.  
  444. CPC = NOEL $MT RV.INCO.'CP' ;
  445. SE = KOPS dPdt '/' RV.INCO.'RHOC' ;
  446. SE = KOPS SE '/' CPC ;
  447. RV.INCO.'SE' = KCHT $MT 'SCAL' 'CENTRE' SE ;
  448.  
  449. * terme source équation de Poisson
  450.  
  451. Z1 = dPdt/RV.INCO.'PM' ;
  452. ZP = KOPS RV.INCO.'RHOC' '*' Z1 ;
  453. ZS = KOPS ZP '-' ZZ ;
  454. ZZS = KOPS ZS '*' VOL ;
  455. ZZS = ZZS * (-1.0) ;
  456. RV.INCO.'SP' = KCHT $MT 'SCAL' 'CENTRE' ZZS ;
  457.  
  458. * calcul de l'évolution de la pression
  459.  
  460. RV.INCO.'PM' = RV.INCO.'PM' + (dPdt*dt) ;
  461.  
  462. * affichage informations toutes les NSAUV iterations
  463. ************************************************************************
  464.  
  465. DD = RV.PASDETPS.'NUPASDT' ;
  466. NN = DD/NSAUV ;
  467. LO = (DD-(NSAUV*NN)) EGA 0 ;
  468. SI ( LO ) ;
  469.  
  470. mess 'TEMPS (s) = ' RV.PASDETPS.'TPS'
  471. 'PRESSION (Pa) =' RV.INCO.'PM' ;
  472. PT = PROG RV.'PASDETPS'.'TPS' ;
  473. PP = PROG RV.INCO.'PM' ;
  474. PMas = MASINI + ( RV.INCO.'DEBIT' * RV.PASDETPS.'TPS')
  475. + RV.INCO.'MCOND' ;
  476. PMTH = PROG PMas ;
  477. RHO = RV.INCO.'RHO1' ;
  478. RHO = noel $mt RHO ;
  479. RHO = kops RHO '*' VOL ;
  480. ROM = somt RHO ;
  481. PMTO = PROG ROM ;
  482. RV.INCO.'TEMPS' = RV.INCO.'TEMPS' ET PT ;
  483. RV.INCO.'PRESS' = RV.INCO.'PRESS' ET PP ;
  484. RV.INCO.'MTOTA' = RV.INCO.'MTOTA' ET PMTO ;
  485. RV.INCO.'MTHEO' = RV.INCO.'MTHEO' ET PMTH ;
  486.  
  487. RHOH2O = KOPS RV.INCO.'RHO' '*' RV.INCO.'YH2O' ;
  488. RHOAIR = KOPS RV.INCO.'RHO' '*' RV.INCO.'YAIR' ;
  489. RHOH2OC = NOEL $MT RHOH2O ;
  490. RHOAIRC = NOEL $MT RHOAIR ;
  491. MASH2O = SOMT (KOPS RHOH2OC '*' VOL) ;
  492. MASAIR = SOMT (KOPS RHOAIRC '*' VOL) ;
  493. MESSAGE 'MASSES (kg): H2O =' MASH2O 'AIR =' MASAIR
  494. 'TOTALE = ' (MASH2O + MASAIR) ;
  495. PMH2O = PROG MASH2O ;
  496. PMAIR = PROG MASAIR ;
  497. PMAIRT = PROG (MAIRINI +
  498. (RV.INCO.'DEBIT' * RV.PASDETPS.'TPS'* YAIRJet)) ;
  499. PMH2OT = PROG (MH2OINI +
  500. (RV.INCO.'DEBIT' * RV.PASDETPS.'TPS'* YH2OJet) +
  501. RV.INCO.'MCOND');
  502. RV.INCO.'PMH2O' = RV.INCO.'PMH2O' ET PMH2O ;
  503. RV.INCO.'PMAIR' = RV.INCO.'PMAIR' ET PMAIR ;
  504. RV.INCO.'PMH2OT' = RV.INCO.'PMH2OT' ET PMH2OT ;
  505. RV.INCO.'PMAIRT' = RV.INCO.'PMAIRT' ET PMAIRT ;
  506.  
  507. FINSI ;
  508.  
  509. FINPROC ;
  510.  
  511. ************************************************************************
  512. * GENERATION DU MAILLAGE *
  513. ************************************************************************
  514. *
  515. * cuve cylindrique de rayon interieur RA
  516. * de hauteur HA
  517. * de rayon d'injection RJ.
  518. *------------------------------------------
  519.  
  520. 'OPTION' 'DIME' 2 'ELEM' 'QUA8' ;
  521. 'OPTION' 'ISOV' 'LIGN' ;
  522. 'OPTION' 'MODE' 'AXIS' ;
  523.  
  524. * Dimensions de la cuve et de la zone d'injection
  525.  
  526. HA = 6.2 ;
  527. RA = 1.9 ;
  528. RJ = 0.1 ;
  529.  
  530. * Nombre d'elements injection et cotés
  531. * en MACRO, N réel = n x 2
  532.  
  533. nj = 1 ;
  534. nr = 10 ;
  535. nh = 20 ;
  536.  
  537. * Definition des points utiles pour la creation du maillage
  538. * ---------------------------------------------------------
  539. *
  540. * B0| BJ B1
  541. * .----------------|
  542. * | |
  543. * . |
  544. * | |
  545. * . |
  546. * | |
  547. * . |
  548. * | |
  549. * . |
  550. * | |
  551. * . |
  552. * | |
  553. * . |
  554. * | |
  555. * . |
  556. * | |
  557. * . |
  558. * | |
  559. * .----------------|
  560. * A0| |AJ A1
  561. *
  562. * ----------------------------------------------------------------------
  563.  
  564. A0 = 0. 0. ;
  565. AJ = RJ 0. ;
  566. A1 = RA 0. ;
  567.  
  568. B0 = 0. HA ;
  569. BJ = RJ HA ;
  570. B1 = RA HA ;
  571.  
  572. * Définition des segments
  573.  
  574. A0J = A0 'DROI' nj AJ ;
  575. AJ1 = AJ 'DROI' nr A1 ;
  576.  
  577. B0J = B0 'DROI' nj BJ ;
  578. BJ1 = BJ 'DROI' nr B1 ;
  579.  
  580. AB0 = A0 'DROI' nh B0 ;
  581. AB1 = A1 'DROI' nh B1 ;
  582.  
  583. A01 = A0J ET AJ1 ;
  584. B01 = B0J ET BJ1 ;
  585.  
  586. * Maillage total
  587.  
  588. MT = 'DALL' A01 AB1 B01 AB0 ;
  589. 'ORIENTER' MT ;
  590.  
  591. * Lignes pour conditions aux limites et post-traitement
  592.  
  593. AXE = AB0 ;
  594. BAS = A01 ;
  595. INJ = A0J ;
  596. BAS2 = AJ1 ;
  597. HAUT = B01 ;
  598. PCON = AB1 ;
  599. PTOT = AJ1 ET PCON ET ('INVE' HAUT) ;
  600.  
  601. * Définition des tables domaine
  602.  
  603. $MT = 'DOMA' MT 1.E-5 'MACRO' impr;
  604. $INJ = 'DOMA' INJ 'MACRO' 'INCL' $MT 1.e-5 ;
  605. $AXE = 'DOMA' AXE 'MACRO' 'INCL' $MT 1.e-5 ;
  606. $BAS = 'DOMA' BAS 'MACRO' 'INCL' $MT 1.e-5 ;
  607. $PCON = 'DOMA' PCON 'MACRO' 'INCL' $MT 1.e-5 ;
  608. $PTOT = 'DOMA' PTOT 'MACRO' 'INCL' $MT 1.e-5 ;
  609.  
  610. * Maillage final
  611.  
  612. MT = $MT.MAILLAGE ;
  613.  
  614. CNT = CONT MT ;
  615. INJ = INJ COUL ROUG ;
  616. PCON = PCON COUL VERT ;
  617. AXE = AXE COUL JAUN ;
  618.  
  619. * TRAC (BAS ET AXE ET PCON ET HAUT) ;
  620. * TRAC (MT ET INJ ET PCON ET AXE) ;
  621. * TRAC (PTOT ET AXE) ;
  622.  
  623. * Volume, nbre d'éléments, surface condensante
  624.  
  625. VOL = 'DOMA' $MT 'VOLUME' ;
  626. VOLT = 'SOMT' VOL ;
  627. NEMT = NBEL MT ;
  628. SURFC = 'DOMA' $PCON 'VOLUME' ;
  629. SURFT = 'SOMT' SURFC ;
  630.  
  631.  
  632. ************************************************************************
  633. * DONNEES PHYSIQUES *
  634. ************************************************************************
  635.  
  636. *--------------------------------------
  637. * masses molaires et constantes des gaz
  638. *--------------------------------------
  639.  
  640. MH2O = 18.0E-3 ;
  641. MAIR = 28.8E-3 ;
  642.  
  643. Rg = 8.313 ;
  644.  
  645. RH2O = Rg/MH2O ;
  646. RAIR = Rg/MAIR ;
  647.  
  648. *------------------------------------------------
  649. * fractions massiques des differents constituants
  650. *------------------------------------------------
  651.  
  652. YAIR = 0.664;
  653.  
  654. YH2O = 1-YAIR ;
  655.  
  656. *---------------------------------------------
  657. * constante du gaz
  658. *---------------------------------------------
  659.  
  660. R = (RH2O*YH2O)+(RAIR*YAIR) ;
  661.  
  662. *------------------------------------------------------------
  663. * pression, temperature et densite du melange (loi d'etat GP)
  664. *------------------------------------------------------------
  665.  
  666. Pbar = 1.5 ;
  667. T°C = 100. ;
  668.  
  669. P = Pbar /1.013 ;
  670. P = P * 1.0E5 ;
  671. T = T°C + 273.15 ;
  672. PSI = R*T ;
  673. RHO = P/PSI ;
  674.  
  675. *-------------------------------------------------------------
  676. * Masse volumique des constituants
  677. *-------------------------------------------------------------
  678.  
  679. RHOAIR= P*YAIR/(T*R);
  680. RHOH2O= RHOAIR*YH2O/YAIR;
  681.  
  682. *---------------------
  683. * pressions partielles
  684. *---------------------
  685.  
  686. PH2O = RHOH2O*RH2O*T ;
  687. PAIR = RHOAIR*RAIR*T ;
  688.  
  689. *----------------------------------------------------------
  690. * fractions molaires des differents constituants du melange
  691. *----------------------------------------------------------
  692.  
  693. XH2O = PH2O/P ;
  694. XAIR = PAIR/P ;
  695.  
  696. *---------------------------------------------
  697. * Masse molaire du mélange
  698. *---------------------------------------------
  699.  
  700. M = (XH2O*MH2O) + (XAIR*MAIR) ;
  701.  
  702. *----------------------------------------------------
  703. * Cp et Cv des différents constituants et du mélange
  704. *----------------------------------------------------
  705.  
  706. CPH2O = 1715.632 + (0.552805*T) ;
  707. CPN2 = 1006.15 + (0.1387166*T) ;
  708. CPO2 = 907.580 + (0.1420522*T) ;
  709. CPAIR = (0.2*CPO2) + (0.8*CPN2) ;
  710. CVH2O = CPH2O - RH2O ;
  711. CVAIR = CPAIR - RAIR ;
  712.  
  713. CP = (YH2O*CPH2O) + (YAIR*CPAIR) ;
  714. CV = (YH2O*CVH2O) + (YAIR*CVAIR) ;
  715.  
  716. gamma = CP/(CP-R) ;
  717.  
  718. *------------------------
  719. * Caractéristiques du jet
  720. * (Qjet en kg/s)
  721. *------------------------
  722.  
  723. XH2OJet = 1.0 ;
  724. XAIRJet = 1.0 - XH2OJet ;
  725. YAIRJet = 0. ;
  726. YH2OJet = 1-YAIRJet;
  727. MJet = (XH2OJet*MH2O) + (XAIRJet*MAIR) ;
  728. RJet = Rg/MJet ;
  729. CVJet = (YH2OJet*CVH2O) + (YAIRJet*CVAIR) ;
  730.  
  731. SJet = PI*RJ*RJ ;
  732.  
  733. *°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
  734. * °
  735. * ATTENTION : °
  736. * °
  737. * Pour que le débit effectif soit 'Q0' kg/s °
  738. * °
  739. * il faut que Qjet imposé soit < Q0 °
  740. * °
  741. * ==> imposer un certain Qjet par tatonnement et vérifier ensuite °
  742. * avec l'opérateur DBIT que l'on a bien le débit voulu °
  743. * °
  744. *°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°°
  745. * nr = 10 , QJet = 0.069124 => Q0 effectif = 0.149999079999999979 kg/s
  746. *
  747.  
  748. TJ°C = 180. ;
  749. QJet = 0.069124 ;
  750. GJet = QJet/SJet ;
  751. * Q0 = QJet ;
  752. Q0 = 0.149999079999999979 ;
  753.  
  754. TJet = TJ°C + 273.15 ;
  755. PSIJet = Rjet*Tjet ;
  756. RhoJet = P/PSIJet ;
  757. EMJet = CVJet*TJet ;
  758. EJet = Q0*EMJet ;
  759. UJet = GJet/RhoJet ;
  760.  
  761. * K et epsilon
  762.  
  763. KJet = 4.3E-3*UJet*UJet ;
  764. EPJet = 4.3E-4*(UJet**3.)/RJ ;
  765.  
  766. * énergie de transvasement PUjSj
  767.  
  768. Etran = Q0*Rjet*Tjet ;
  769.  
  770. *-------------------------------------------------
  771. * energie, enthalpie massique et masses du melange
  772. *-------------------------------------------------
  773.  
  774. ESini = RHO*CV*T ;
  775. ETini = ESini*VOLT ;
  776. Pini = (gamma-1.)*ESini ;
  777. LAT = 2.3E6 ;
  778. MASINI = RHO*VOLT ;
  779. Hini = gamma*ETini/MASINI + LAT ;
  780.  
  781. MH2OINI = MASINI*YH2O ;
  782. MAIRINI = MASINI*YAIR ;
  783.  
  784. *--------------------------------------------------
  785. * vitesses de référence (tracés, filtre, fct paroi)
  786. *--------------------------------------------------
  787.  
  788. ampl = 0.25/Ujet ;
  789. U0 = 1.0*UJet ;
  790. L0 = 0.7 ;
  791. UET0 = Ujet/10.0 ;
  792. YP = 0.05 ;
  793. YPT= 0.05 ;
  794.  
  795. *------------------------------------------------------------------------
  796. * Prandtl, Schmidt, viscosité (loi de Sutherland), conductivité thermique
  797. * coefficients de diffusion moléculaire, coeff. d'échange par convection
  798. *------------------------------------------------------------------------
  799.  
  800. Pr = 0.7 ;
  801. Prt = 1.0 ;
  802. Sct = 1.0 ;
  803.  
  804. MUvap = 1.6E-5 ;
  805. MU = 1.716E-5*((T/273.0)**1.5)*(273.0+110.5)/(T+110.5) ;
  806. NU = MU/RHO ;
  807. Lambda = Mu*CP/Pr ;
  808. alpha = Lambda/RHO/CP ;
  809.  
  810. DH2O = 2.55E-5 ;
  811. DH2 = 7.12E-5 ;
  812. DO2 = 2.06E-5 ;
  813.  
  814. H1 = 10.0 ;
  815. H2 = H1/CP/RHO ;
  816.  
  817. *-----------------------------------
  818. * température initiale du condenseur
  819. *-----------------------------------
  820.  
  821. TP°C = 40. ;
  822.  
  823. Tcond = TP°C + 273.15 ;
  824.  
  825. *-----------------------------------
  826. * Reynolds et Richardson d'injection
  827. *-----------------------------------
  828.  
  829. VD = Q0 / (RHOjet*Sjet) ;
  830. RI0 = (RHO - RHOjet)*2.0*RJ*9.81 / (RHO*VD*VD) ;
  831. RE0 = RHOjet*VD*2.0*RJ / MUvap ;
  832.  
  833. opti echo 0 ;
  834. mess '______________________________________________________________';
  835. mess ' ' ;
  836. mess 'VOLUME FLUIDE (m3) =' VOLT ;
  837. mess 'NOMBRE D ELTS TOTAL =' nemt ;
  838. mess 'SURFACE DE CONDENSATION (m2) =' SURFT ;
  839. mess 'MASSE TOTALE ini =' MASINI 'MAIRini =' MAIRINI
  840. 'MH2Oini =' MH2OINI ;
  841. mess 'YH2Oini =' YH2O 'YAIRini =' YAIR ;
  842. mess 'RHOini =' RHO 'RHOH2Oini =' RHOH2O 'RHOAIRini =' RHOAIR ;
  843. mess 'RTini =' PSI 'RTjet =' PSIJet ;
  844. mess 'ETOTini (J) =' ETini 'Ejet (J/s) =' Ejet ;
  845. mess 'ESini (J/m3) =' ESini ;
  846. mess 'Etransv (J/s) =' Etran ;
  847. mess 'CPAIR =' CPAIR 'CPH2O =' CPH2O 'CPini =' CP ;
  848. mess 'CVAIR =' CVAIR 'CVH2O =' CVH2O 'CVini =' CV ;
  849. mess 'GAMMA =' gamma ;
  850. mess 'RAIR =' RAIR 'RH2O =' RH2O 'Rini =' R ;
  851. mess 'YH2OJet =' YH2OJet 'YAIRJet =' YAIRJet ;
  852. mess 'RHOjet =' RhoJet 'Gjet =' GJet 'UJet =' UJet ;
  853. mess 'NU =' nu 'MU =' MU 'alpha gaz =' alpha ;
  854. mess 'RICHARDSON =' RI0 'REYNOLDS =' RE0 ;
  855. mess 'Pression en Pa =' P 'Pression en bar =' Pbar;
  856. mess 'Vdéb =' VD ;
  857. mess '______________________________________________________________';
  858. opti echo 1 ;
  859.  
  860. * opti donn 5 ;
  861.  
  862. *=====================================================================*
  863. * TABLE EQEX CONTENANT LES EQUATIONS A RESOUDRE : *
  864. * 0) FILTRE K-E *
  865. * 1) QUANTITE DE MOUVEMENT --- OPERATEUR NSKE *
  866. * 2) EQUATION DE L'ENERGIE --- OPERATEUR TSCAL *
  867. * 3) TRANSPORT DES ESPECES --- OPERATEUR TSCAL *
  868. * AINSI QUE 2 PROCEDURES (CALCUL1 ET CALCUL2) POUR L'ALGORITHME *
  869. * 'FAIBLE MACH' *
  870. * 4) CONDITIONS AUX LIMITES *
  871. *=====================================================================*
  872.  
  873. RV = 'EQEX' $MT 'ITMA' 200 'ALFA' 0.9 'TFINAL' 2.5
  874.  
  875. 'ZONE' $MT 'OPER' 'CALCUL1'
  876. 'ZONE' $MT 'OPER' 'FILTREKE' U0 L0 NU 'UN' 'INCO' 'KN' 'EN'
  877. 'ZONE' $PTOT 'OPER' 'FPU' NU 'UET' YP 'INCO' 'UN' 'KN' 'EN'
  878. 'OPTI' 'CONS' 'SUPG'
  879. 'ZONE' $MT 'OPER' 'NSKE' 'RHOC' MU 'MUT' 'UN' 'ROG'
  880. 'INCO' 'GN' 'KN' 'EN' ;
  881.  
  882. RV = 'EQEX' RV
  883. 'ZONE' $PCON 'OPER' 'FPT' 1. NU 1. alpha 'UTC' YPT 'H' 'TP' 'INCO' 'TN'
  884. 'OPTI' 'NOCONS' 'SUPG'
  885. 'ZONE' $MT 'OPER' 'TSCAL' alpha 'UN' 'SE' 'NUT' Prt 'INCO' 'TN'
  886.  
  887. 'ZONE' $PCON 'OPER' 'ECHI' 'KY' 'YVI' 'INCO' 'YH2O'
  888. 'OPTI' 'NOCONS' 'SUPG'
  889. 'ZONE' $MT 'OPER' 'TSCAL' DH2O 'UN' 0. 'NUT' SCT 'INCO' 'YH2O'
  890. 'ZONE' $MT 'OPER' 'CALCUL2' ;
  891.  
  892.  
  893. *===================== conditions aux limites ==========================
  894.  
  895. RV = 'EQEX' RV
  896. 'CLIM' 'GN' 'UIMP' (AXE et PCON) 0.
  897. 'GN' 'VIMP' (BAS2 et HAUT) 0.
  898. 'GN' 'UIMP' INJ 0.
  899. 'GN' 'VIMP' INJ GJet
  900. 'KN' 'TIMP' INJ KJet
  901. 'EN' 'TIMP' INJ EPJet ;
  902. RV = 'EQEX' RV
  903. 'CLIM' 'TN' 'TIMP' INJ TJet
  904. 'YH2O' 'TIMP' INJ YH2OJet ;
  905.  
  906. *===========================================================
  907. * TABLE EQPR POUR L'EQUATION DE POISSON (SOLVEUR ELLIPTIQUE)
  908. *===========================================================
  909.  
  910. RVP = 'EQPR' $MT KTYPI 1
  911. 'ZONE' $MT 'OPER' 'PRESSION' 'SP'
  912. 'PIMP' 0. ;
  913.  
  914.  
  915. *==========================================================
  916. * TABLE INCO CONTENANT LES INCONNUES ET DONNEES DU PROBLEME
  917. *==========================================================
  918.  
  919. RV.'PRESSION' = RVP ;
  920. RV.'NOMVI' = 'GN' ;
  921. RV.'INCO' = 'TABLE' 'INCO' ;
  922. RVP.'INCO' = RV.'INCO' ;
  923.  
  924. $FLUID = $MT ;
  925. $PAROI = $PTOT ;
  926.  
  927. * inconnues des équations différentielles
  928.  
  929. RV.INCO.'GN' = kcht $FLUID VECT SOMMET (0. 0.) ;
  930. RV.INCO.'EN' = kcht $FLUID SCAL SOMMET 1.E-5 ;
  931. RV.INCO.'KN' = kcht $FLUID SCAL SOMMET 1.E-5 ;
  932. RV.INCO.'YH2O'= kcht $FLUID SCAL SOMMET YH2O ;
  933. RV.INCO.'TN' = kcht $FLUID SCAL SOMMET T ;
  934.  
  935. * matrices masse pour calcul des moyennes aux noeuds
  936.  
  937. RV.'D0' = DOMA $FLUID 'XXDIAGSI' ;
  938. RV.'DI' = DOMA $PCON 'XXDIAGSI' ;
  939.  
  940. * variables 0D : masse totale, masse vapeur, energie, pression
  941.  
  942. RV.INCO.'ROT0D' = RHO ;
  943. RV.INCO.'ROV0D' = RHOH2O ;
  944. RV.INCO.'ES0D' = ESini ;
  945. RV.INCO.'PR0D' = P ;
  946.  
  947. * debit de masse injecté, masse condensée
  948.  
  949. RV.INCO.'DEBIT' = Q0 ;
  950. RV.INCO.'MASCD' = 0. ;
  951.  
  952. * inconnues auxiliaires
  953.  
  954. RV.INCO.'UN' = kcht $FLUID VECT SOMMET (0. 0.) ;
  955. RV.INCO.'PSIN' = kcht $FLUID SCAL SOMMET PSI ;
  956. RV.INCO.'PSI1' = kcht $FLUID SCAL SOMMET PSI ;
  957.  
  958. * variables modèle de turbulence
  959.  
  960. RV.INCO.'UET' = kcht $PTOT SCAL CENTRE UET0 ;
  961. RV.INCO.'UTC' = kcht $PCON SCAL CENTRE UET0 ;
  962. RV.INCO.'MUT' = kcht $FLUID SCAL CENTRE Mu ;
  963. RV.INCO.'NUT' = kcht $FLUID SCAL CENTRE Nu ;
  964.  
  965. * masse volumique
  966.  
  967. RV.INCO.'RHO' = kcht $FLUID SCAL SOMMET RHO ;
  968. RV.INCO.'RHO1'= kcht $FLUID SCAL SOMMET RHO ;
  969. RV.INCO.'RHOC'= kcht $FLUID SCAL CENTRE RHO ;
  970.  
  971. * fractions massiques
  972.  
  973. RV.INCO.'YAIR' = kcht $FLUID SCAL SOMMET YAIR ;
  974.  
  975. * Cv, R, et Cp du mélange
  976.  
  977. RV.INCO.'CV' = kcht $FLUID SCAL SOMMET CV ;
  978. RV.INCO.'RN' = kcht $FLUID SCAL SOMMET R ;
  979. RV.INCO.'CP' = kcht $FLUID SCAL SOMMET CP ;
  980.  
  981. * à la paroi coef d'ech, frac vap, temp, flux de masse
  982.  
  983. RV.INCO.'H' = kcht $PCON SCAL CENTRE H2 ;
  984. RV.INCO.'K' = kcht $PCON SCAL CENTRE 0. ;
  985. RV.INCO.'KY' = kcht $PCON SCAL CENTRE 0. ;
  986. RV.INCO.'KS' = kcht $PCON SCAL SOMMET 0. ;
  987. RV.INCO.'YVI' = kcht $PCON SCAL CENTRE 0. ;
  988. RV.INCO.'YVS' = kcht $PCON SCAL SOMMET 0. ;
  989. RV.INCO.'TC' = kcht $PCON SCAL SOMMET Tcond ;
  990. RV.INCO.'TP' = kcht $PCON SCAL CENTRE Tcond ;
  991. RV.INCO.'FCOND' = kcht $PCON SCAL SOMMET 0. ;
  992. RV.INCO.'QC' = 0. ;
  993. RV.INCO.'MCOND' = 0. ;
  994.  
  995. * termes sources (Poisson/énergie/QDM)
  996.  
  997. RV.INCO.'SP' = KCHT $FLUID SCAL CENTRE 0. ;
  998. RV.INCO.'SE' = kcht $FLUID SCAL CENTRE 0. ;
  999. RV.INCO.'ROG'= kcht $FLUID VECT CENTRE (0. 0.) ;
  1000.  
  1001. * pression
  1002.  
  1003. RV.INCO.'PM' = P ;
  1004.  
  1005. * suivi des valeurs moyennes calculées en 2D
  1006.  
  1007. RV.INCO.'TEMPS' = PROG 0. ;
  1008. RV.INCO.'PRESS' = PROG P ;
  1009. RV.INCO.'MTOTA' = PROG MASINI ;
  1010. RV.INCO.'MTHEO' = PROG MASINI ;
  1011. RV.INCO.'ETOT' = PROG ETini ;
  1012. RV.INCO.'PMH2O' = PROG MH2OINI ;
  1013. RV.INCO.'PMAIR' = PROG MAIRINI ;
  1014. RV.INCO.'PMH2OT' = PROG MH2OINI ;
  1015. RV.INCO.'PMAIRT' = PROG MAIRINI ;
  1016. RV.INCO.'FCDST' = PROG 0. ;
  1017.  
  1018. * suivi des variables purement 0D
  1019.  
  1020. RV.INCO.'MT0D' = prog MASINI ;
  1021. RV.INCO.'MV0D' = prog MH2OINI ;
  1022. RV.INCO.'PT0D' = prog P ;
  1023. RV.INCO.'PV0D' = prog PH2O ;
  1024. RV.INCO.'PA0D' = prog PAIR ;
  1025. RV.INCO.'ET0D' = prog ETini ;
  1026. RV.INCO.'RO0D' = prog RHO ;
  1027. RV.INCO.'T0D' = prog (T-273.15) ;
  1028. RV.INCO.'H0D' = prog Hini ;
  1029.  
  1030. *===================================================================*
  1031. * EXECUTION ET SAUVEGARDE *
  1032. *===================================================================*
  1033.  
  1034. * on gardera une valeur tous les NSAUV pas de temps
  1035.  
  1036. NSAUV = 20 ;
  1037. RV.'FIDT' = NSAUV ;
  1038.  
  1039. exec rv ;
  1040.  
  1041. *===================================================================*
  1042. * POST TRAITEMENT *
  1043. *===================================================================*
  1044. SI GRAPH ;
  1045.  
  1046.  
  1047. TRAC MT 'TITR' 'MAILLAGE ' ;
  1048.  
  1049. MFLUID = MT ;
  1050.  
  1051. gn1 = 'VECT' (RV.'INCO'.'GN') ampl UX UY VERT ;
  1052. 'TRAC' gn1 mt cnt
  1053. 'TITR' ' CHAMP DE LA VITESSE MASSIQUE rho.u (Kg.m-².s-1)' ;
  1054.  
  1055. un1 = 'VECT' (RV.'INCO'.'UN') ampl UX UY VERT ;
  1056. 'TRAC' un1 mt cnt
  1057. 'TITR' ' CHAMP DE VITESSES U (m/s)' ;
  1058.  
  1059. Vy = EXCO UY RV.INCO.'UN' ;
  1060. EVOLVP = evol CHPO Vy AXE ;
  1061. DESS EVOLVP TITX 'AXE (m)' TITY 'Vitesse (m/s)'
  1062. TITR 'VITESSE LE LONG DE L AXE (m/s)';
  1063.  
  1064. EVOLVP = evol CHPO Vy PCON ;
  1065. DESS EVOLVP TITX 'PAROI COND. (m)' TITY 'Vitesse (m/s)'
  1066. TITR 'VITESSE LE LONG DE LA PAROI CONDENSANTE (m/s)';
  1067.  
  1068. EVOLC = evol CHPO RV.INCO.'FCOND' PCON ;
  1069. DESS EVOLC TITX 'PAROI COND. (m)' TITY 'FLUX (kg/m2s)'
  1070. TITR 'FLUX DE CONDENSATION SUR LA PAROI VERTICALE (kg/m2s)';
  1071.  
  1072. 'TRAC' RV.'INCO'.'RHO' MFLUID cnt
  1073. 'TITR' 'CHAMP DE LA MASSE VOLUMIQUE: RHO (Kg.m-3)' ;
  1074.  
  1075. 'TRAC' RV.'INCO'.'YH2O' MFLUID cnt
  1076. 'TITR' 'CHAMP DE LA FRACTION MASSIQUE DE VAPEUR YH2O' ;
  1077.  
  1078.  
  1079. TN = kops RV.'INCO'.'TN' '-' 273.15 ;
  1080. 'TRAC' TN MFLUID cnt
  1081. 'TITR' 'TEMPERATURE DU GAZ (en °C)' ;
  1082.  
  1083. nut = RV.INCO.'NUT' ;
  1084. nutnu = kops NUT '/' NU ;
  1085. nutnu = elno $fluid nutnu ;
  1086. 'TRAC' NUTNU MFLUID cnt
  1087. 'TITR' 'VISCOSITE TURBULENTE ADIMENSIONNEE: NUT/NU' ;
  1088.  
  1089.  
  1090.  
  1091. EVOLP1 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'PRESSION'
  1092. RV.INCO.'PRESS' ;
  1093. EVOLP2 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'PRESSION'
  1094. RV.INCO.'PT0D' ;
  1095. EVOLP3 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'PRESSION'
  1096. RV.INCO.'PV0D' ;
  1097. EVOLP4 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'PRESSION'
  1098. RV.INCO.'PA0D' ;
  1099. EVOLP1 = EVOLP1 coul vert ;
  1100. TAB1 = TABLE ;
  1101. TAB1.1 = 'REGU MARQ CROI ' ;
  1102. TAB1.2 = 'REGU MARQ PLUS ' ;
  1103. TAB1.3 = 'REGU MARQ CARR ' ;
  1104. TAB1.4 = 'REGU MARQ TRIA ' ;
  1105. TAB1 . 'TITRE' = TABLE ;
  1106. TAB1.'TITRE' . 1 = MOT 'PTOT MULTI-D' ;
  1107. TAB1.'TITRE' . 2 = MOT 'PTOT 0D' ;
  1108. TAB1.'TITRE' . 3 = MOT 'P VAPEUR 0D' ;
  1109. TAB1.'TITRE' . 4 = MOT 'P AIR 0D' ;
  1110. DESS (EVOLP1 ET EVOLP2 ET EVOLP3 ET EVOLP4)
  1111. LEGE MIMA TAB1 TITR 'PRESSIONS MOYENNES (Pa)' ;
  1112. DESS (EVOLP1 ET EVOLP2)
  1113. LEGE MIMA TAB1 TITR 'PRESSION TOTALE (Pa)' ;
  1114.  
  1115. EVOLR = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'RHO 0D'
  1116. RV.INCO.'RO0D' ;
  1117. DESS EVOLR MIMA TITR 'MASSE VOLUMIQUE MOYENNE (kg/m-3)' ;
  1118.  
  1119. EVOLT = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'TEMPERATURE'
  1120. RV.INCO.'T0D' ;
  1121. DESS EVOLT MIMA TITR 'TEMPERATURE MOYENNE (°C)' ;
  1122.  
  1123. EVOLH = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'ENTHALPIE'
  1124. RV.INCO.'H0D' ;
  1125. DESS EVOLH MIMA TITR 'ENTHALPIE MASSIQUE MOYENNE (J/kg)' ;
  1126.  
  1127. EVOLF = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'FLUX CONDENSE'
  1128. RV.INCO.'FCDST' ;
  1129. DESS EVOLF MIMA TITR 'FLUX DE MASSE CONDENSEE (kg/s)' ;
  1130.  
  1131.  
  1132. EVOLM1 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE [kg]'
  1133. RV.INCO.'MTHEO' ;
  1134. EVOLM2 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE [kg]'
  1135. RV.INCO.'MTOTA' ;
  1136. EVOLM1 = EVOLM1 COUL ROUG ;
  1137. EVOLM2 = EVOLM2 COUL VERT ;
  1138. TAB1 = TABLE ;
  1139. TAB1.1 = 'REGU MARQ CROI' ;
  1140. TAB1.2 = 'REGU MARQ PLUS' ;
  1141. TAB1 . 'TITRE' = TABLE ;
  1142. TAB1.'TITRE' . 1 = MOT 'THEORIQUE' ;
  1143. TAB1.'TITRE' . 2 = MOT 'BILAN MULTI-D' ;
  1144. DESS (EVOLM1 ET EVOLM2) LEGE MIMA TAB1 titr 'MASSE TOTALE (kg)' ;
  1145.  
  1146.  
  1147. EVOLM1 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE H2O kg'
  1148. RV.INCO.'PMH2OT' ;
  1149. EVOLM2 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE H2O kg'
  1150. RV.INCO.'PMH2O' ;
  1151. EVOLM1 = EVOLM1 COUL ROUG ;
  1152. EVOLM2 = EVOLM2 COUL VERT ;
  1153. TAB1 = TABLE ;
  1154. TAB1.1 = 'REGU MARQ CROI ' ;
  1155. TAB1.2 = 'REGU MARQ PLUS ' ;
  1156. TAB1 . 'TITRE' = TABLE ;
  1157. TAB1.'TITRE' . 1 = MOT 'THEORIQUE' ;
  1158. TAB1.'TITRE' . 2 = MOT 'BILAN MULTI-D' ;
  1159. DESS (EVOLM1 ET EVOLM2) LEGE MIMA TAB1 titr 'MASSE H2O (kg)' ;
  1160.  
  1161.  
  1162. EVOLM1 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE AIR kg'
  1163. RV.INCO.'PMAIRT' ;
  1164. EVOLM1 = EVOLM1 COUL ROUG ;
  1165. EVOLM2 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'MASSE AIR kg'
  1166. RV.INCO.'PMAIR' ;
  1167. EVOLM2 = EVOLM2 COUL VERT ;
  1168. TAB1 = TABLE ;
  1169. TAB1.1 = 'REGU MARQ CROI ' ;
  1170. TAB1.2 = 'REGU MARQ PLUS ' ;
  1171. TAB1 . 'TITRE' = TABLE ;
  1172. TAB1.'TITRE' . 1 = MOT 'THEORIQUE' ;
  1173. TAB1.'TITRE' . 2 = MOT 'BILAN MULTI-D' ;
  1174. DESS (EVOLM1 ET EVOLM2) LEGE TAB1 titr 'MASSE AIR (kg)' ;
  1175.  
  1176.  
  1177. EVOLE1 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'ENERGIE'
  1178. RV.INCO.'ETOT' ;
  1179. EVOLE2 = EVOL MANU 'TEMPS [s]' RV.INCO.'TEMPS' 'ENERGIE'
  1180. RV.INCO.'ET0D' ;
  1181. EVOLE1 = EVOLE1 coul vert ;
  1182. TAB1 = TABLE ;
  1183. TAB1.1 = 'REGU MARQ CROI ' ;
  1184. TAB1.2 = 'REGU MARQ CARR ' ;
  1185. TAB1 . 'TITRE' = TABLE ;
  1186. TAB1.'TITRE' . 1 = MOT 'MULTI-D' ;
  1187. TAB1.'TITRE' . 2 = MOT '0D' ;
  1188. DESS (EVOLE1 ET EVOLE2) LEGE MIMA TAB1 TITR 'ENERGIE TOTALE (J)' ;
  1189.  
  1190. FINSI ;
  1191.  
  1192. *===================================================================*
  1193. * TESTS DE BON FONCTIONNEMENT (à 5 %) *
  1194. *===================================================================*
  1195.  
  1196. DELTAP = (P - RV.INCO.'PM' - 1673.)/1673. ;
  1197. MH2O = RV.INCO.'ROV0D' * VOLT ;
  1198. DELTAM = (MH2OINI - MH2O - 0.586)/0.586 ;
  1199.  
  1200. SI ( (ABS DELTAP) > 0.05 ) ;
  1201. ERREUR 5 ;
  1202. FINSI ;
  1203.  
  1204. SI ( (ABS DELTAM) > 0.05 ) ;
  1205. ERREUR 5 ;
  1206. FINSI ;
  1207.  
  1208. FIN ;
  1209.  
  1210.  
  1211.  
  1212.  
  1213.  
  1214.  
  1215.  
  1216.  
  1217.  
  1218.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales