Télécharger @solvmec_03.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : @solvmec_03.dgibi
  2. ************************************************************************
  3. * Test du mini solveur mecanique (procedure @SOLVMEC) *
  4. * - eprouvette entaillee en traction *
  5. * - comportement visco-elastique *
  6. * - calcul en petits deplacements *
  7. * *
  8. * On compare les resultats a ceux de la procedure PASAPAS *
  9. ************************************************************************
  10.  
  11.  
  12.  
  13. ** Options generales
  14. OPTI 'DIME' 2 'ELEM' 'QUA4' 'MODE' 'PLAN' 'CONT' 'ECHO' 1 ;
  15.  
  16.  
  17. ** Geometrie : barre rectangulaire l x h avec une
  18. * entaille circulaire de largeur le et profondeur pe
  19. l = 1.0 ;
  20. h = 0.1 ;
  21. le = 0.1 * l ;
  22. pe = 0.1 * h ;
  23.  
  24.  
  25. ** Maillage
  26. ne = 51 ;
  27. * barre rectangulaire
  28. p0 = 0. 0. ;
  29. p1 = l 0. ;
  30. lb = DROI ne p0 p1 ;
  31. mai = lb TRAN 3 (0. h) ;
  32. ld = mai COTE 2 ;
  33. lh = mai COTE 3 ;
  34. lg = mai COTE 4 ;
  35. * deplacement des noeuds pour l'entaille circulaire
  36. p2 = ((l - le) / 2.) h ;
  37. p3 = ((l + le) / 2.) h ;
  38. re = (pe / 2.) + (le * le / (8. * pe)) ;
  39. p4 = (l / 2.) (h - pe + re) ;
  40. xh yh = COOR lh ;
  41. pmil = xh POIN 'COMPRIS' (COOR 1 p2) (COOR 1 p3) ;
  42. DEPL pmil 'PROJ' 'DIRE' (0. 1.) 'CERC' p4 p2 ;
  43. cmai = CONT mai ;
  44. *****TRAC mai 'TITR' 'Maillage' ;
  45.  
  46.  
  47. ** Modele et caracteristiques materiau
  48. mo = MODE mai 'MECANIQUE' 'ELASTIQUE' 'ISOTROPE' 'FLUAGE' 'NORTON' ;
  49. ma = MATE mo 'YOUN' 1.E9 'NU' 0.3 'SMAX' 0. 'AF1' 3.E-13 'AF2' 1.2 'AF3' 1. ;
  50.  
  51.  
  52. ** Blocages
  53. clg = BLOQ 'UX' lg ;
  54. clb = BLOQ 'UY' lb ;
  55. cld = BLOQ 'UX' ld ;
  56. cl = clg ET clb ET cld ;
  57.  
  58.  
  59. ** Chargement : deplacement impose (essai de relaxation)
  60. uimp = 5.E-3 ;
  61. fuim = DEPI cld uimp ;
  62. ev1 = EVOL 'MANU' 'Temps' (PROG 0. 100. 1000.) 'Coef' (PROG 0. 1. 1.) ;
  63. cha = CHAR 'DIMP' fuim ev1 ;
  64.  
  65.  
  66. ** Resolutions avec PASAPAS et @SOLVMEC
  67. tab1 = TABL ;
  68. tab1 . 'MODELE' = mo ;
  69. tab1 . 'CARACTERISTIQUES' = ma ;
  70. tab1 . 'BLOCAGES_MECANIQUES' = cl ;
  71. tab1 . 'CHARGEMENT' = cha ;
  72. tab1 . 'TEMPS_CALCULES' = PROG 10. 'PAS' 10. 1000. ;
  73. tab2 = COPI tab1 ;
  74.  
  75. PASAPAS tab1 ;
  76. tpp = TEMP 'HORL' ;
  77.  
  78. @SOLVMEC tab2 ;
  79. tms = TEMP 'HORL' ;
  80.  
  81.  
  82. ** Performances
  83. MESS 'Duree d''execution (ms)' ;
  84. MESS '----------------------' ;
  85. MESS 'PASAPAS :' ' ' tpp ;
  86. MESS '@SOLVMEC :' ' ' tms ;
  87.  
  88.  
  89. ** Post traitement : courbes F (resultante des reactions a gauche) vs Temps
  90. * EPSE max (def. plas. eq. max) vs Temps
  91. n1 = DIME (tab2 . 'TEMPS') ;
  92. ltp = PROG ;
  93. lr1 = PROG ;
  94. lr2 = PROG ;
  95. le1 = PROG ;
  96. le2 = PROG ;
  97. lerr = PROG ;
  98. lere = PROG ;
  99. REPE b1 n1 ;
  100. * temps
  101. ltp = ltp ET (tab1 . 'TEMPS' . (&b1 - 1)) ;
  102. * effort de reaction
  103. r1 = tab1 . 'REACTIONS' . (&b1 - 1) ;
  104. r2 = tab2 . 'REACTIONS' . (&b1 - 1) ;
  105. SI (EGA &b1 1) ;
  106. rr1 = 0. ;
  107. rr2 = 0. ;
  108. SINON ;
  109. rr1 = -1. * (@TOTAL r1 lg 'FX') ;
  110. rr2 = -1. * (@TOTAL r2 lg 'FX') ;
  111. lerr = lerr ET (ABS ((rr1 - rr2) / rr1)) ;
  112. FINSI ;
  113. lr1 = lr1 ET rr1 ;
  114. lr2 = lr2 ET rr2 ;
  115. * deformation plastique equivalente
  116. vi1 = tab1 . 'VARIABLES_INTERNES' . (&b1 - 1) ;
  117. vi2 = tab2 . 'VARIABLES_INTERNES' . (&b1 - 1) ;
  118. epqmax1 = MAXI (EXCO 'EPSE' vi1) ;
  119. epqmax2 = MAXI (EXCO 'EPSE' vi2) ;
  120. le1 = le1 ET epqmax1 ;
  121. le2 = le2 ET epqmax2 ;
  122. SI (epqmax1 > 1.E-10) ;
  123. lere = lere ET (ABS ((epqmax1 - epqmax2) / epqmax1)) ;
  124. FINSI ;
  125. FIN b1 ;
  126. * ecarts relatifs max
  127. err = MAXI 'ABS' lerr ;
  128. ere = MAXI 'ABS' lere ;
  129. MESS 'Ecarts relatifs max' ;
  130. MESS '-------------------' ;
  131. MESS 'Defo. plast. eq. max :' ' ' ere ;
  132. MESS 'Reaction :' ' ' err ;
  133. * trace des courbes
  134. tleg = TABL ;
  135. tleg . 'TITRE' = TABL ;
  136. tleg . 'TITRE' . 1 = CHAI 'Pasapas' ;
  137. tleg . 'TITRE' . 2 = CHAI 'Mini solveur' ;
  138. tleg . 2 = MOT 'MARQ ROND NOLI' ;
  139. eve1 = EVOL 'MANU' 'Temps' ltp 'EPSE max' le1 ;
  140. eve2 = EVOL 'ROUG' 'MANU' 'Temps' ltp 'EPSE max' le2 ;
  141. *****DESS (eve1 ET eve2) 'TITR' 'EPSE max vs Temps' 'LEGE' tleg 'NO' ;
  142. evr1 = EVOL 'MANU' 'Temps' ltp 'Reaction' lr1 ;
  143. evr2 = EVOL 'ROUG' 'MANU' 'Temps' ltp 'Reaction' lr2 ;
  144. *****DESS (evr1 ET evr2) 'TITR' 'Force vs Temps' 'LEGE' tleg 'NE' ;
  145.  
  146. ** Test et erreur si ecart trop important
  147. SI ((ere > 1.E-5) OU (err > 1.E-4)) ;
  148. ERRE 'Ecart trop important entre les resultats de @SOLVMEC et de PASAPAS' ;
  149. FINSI ;
  150.  
  151. FIN ;
  152.  
  153.  
  154.  
  155.  
  156.  
  157.  
  158.  
  159.  
  160.  
  161.  
  162.  
  163.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales